Tutorial menunjukkan cara menggunakan XIRR dalam Excel untuk mengira kadar pulangan dalaman (IRR) untuk aliran tunai dengan pemasaan yang tidak teratur dan cara membuat kalkulator XIRR anda sendiri.

Apabila anda berhadapan dengan keputusan berintensif modal, pengiraan kadar pulangan dalaman adalah wajar kerana ia membolehkan anda membandingkan unjuran pulangan untuk pelaburan yang berbeza dan memberikan asas kuantitatif untuk membuat keputusan.

Dalam tutorial kami sebelum ini, kami melihat cara mengira kadar pulangan dalaman dengan fungsi Excel IRR. Kaedah itu cepat dan mudah, tetapi ia mempunyai had penting - fungsi IRR mengandaikan bahawa semua aliran tunai berlaku pada selang masa yang sama seperti bulanan atau tahunan. Walau bagaimanapun, dalam situasi kehidupan sebenar, aliran masuk dan keluar tunai sering berlaku pada selang masa yang tidak teratur. Syukurlah, Microsoft Excel mempunyai fungsi lain untuk mencari IRR dalam kes sedemikian, dan tutorial ini akan mengajar anda cara menggunakannya.

Fungsi XIRR dalam Excel

Excel XIRR fungsi mengembalikan kadar pulangan dalaman untuk satu siri aliran tunai yang mungkin atau mungkin tidak berkala.

Fungsi ini diperkenalkan dalam Excel 2007 dan tersedia dalam semua versi Excel 2010, Excel 2013, Excel 2016 yang lebih baharu , Excel 2019 dan Excel untuk Office 365.

Sintaks fungsi XIRR adalah seperti berikut:

Di mana:

• Nilai (diperlukan) – atatasusunan atau julat sel yang mewakili satu siri aliran masuk dan keluar.
• Tarikh (diperlukan) – tarikh yang sepadan dengan aliran tunai. Tarikh mungkin berlaku dalam sebarang susunan, tetapi tarikh pelaburan awal mestilah yang pertama dalam tatasusunan.
• Teka (pilihan) – IRR yang dijangkakan dibekalkan sebagai peratusan atau nombor perpuluhan. Jika ditinggalkan, Excel menggunakan kadar lalai 0.1 (10%).

Sebagai contoh, untuk mengira IRR bagi siri aliran tunai dalam A2:A5 dan tarikh dalam B2:B5, anda akan gunakan formula ini:

=XIRR(A2:A5, B2:B5)

Petua. Untuk keputusan dipaparkan dengan betul, sila pastikan format Peratusan ditetapkan untuk sel formula.

6 perkara yang perlu anda ketahui tentang fungsi XIRR

Nota berikut akan membantu anda memahami dengan lebih baik mekanik dalaman fungsi XIRR dan menggunakannya dalam lembaran kerja anda dengan paling cekap.

1. XIRR dalam Excel direka untuk mengira kadar pulangan dalaman untuk aliran tunai dengan masa yang tidak sama. Untuk aliran tunai berkala dengan tarikh pembayaran yang tepat tidak diketahui, anda boleh menggunakan fungsi IRR.
2. Julat nilai mesti mengandungi sekurang-kurangnya satu nilai positif (pendapatan) dan satu negatif (bayaran keluar).
3. Jika nilai pertama ialah perbelanjaan (pelaburan awal), ia mesti diwakili dengan nombor negatif. Pelaburan awal tidak didiskaun; bayaran seterusnya dibawa balik ke tarikh aliran tunai pertama dan berdasarkan diskaunpada tahun 365 hari.
4. Semua tarikh dipotong kepada integer, bermakna bahagian pecahan tarikh yang mewakili masa dialih keluar.
5. Tarikh mestilah tarikh Excel yang sah dimasukkan sebagai rujukan kepada sel yang mengandungi tarikh atau hasil formula seperti fungsi DATE. Jika tarikh dimasukkan dalam format teks, masalah mungkin berlaku.
6. XIRR dalam Excel sentiasa mengembalikan IRR tahunan walaupun semasa mengira aliran tunai bulanan atau mingguan.

Pengiraan XIRR dalam Excel

Fungsi XIRR dalam Excel menggunakan pendekatan percubaan dan ralat untuk mencari kadar yang memenuhi persamaan ini:

Di mana:

• P - aliran tunai (pembayaran)
• d - tarikh
• i - nombor tempoh
• n - jumlah tempoh

Bermula dengan tekaan jika disediakan atau dengan lalai 10% jika tidak, Excel melalui lelaran untuk mencapai keputusan dengan ketepatan 0.000001%. Jika selepas 100 percubaan kadar yang tepat tidak ditemui, #NUM! ralat dikembalikan.

Untuk menyemak kesahihan persamaan ini, mari kita mengujinya terhadap hasil formula XIRR. Untuk memudahkan pengiraan kami, kami akan menggunakan formula tatasusunan berikut (sila ingat bahawa sebarang formula tatasusunan mesti dilengkapkan dengan menekan Ctrl + Shift + Enter ):

=SUM(A2:A5/((1+$E$1)^((B2:B5-$B$2)/365)))

Di mana:

• A2:A5 ialah aliran tunai
• B2:B5 ialah tarikh
• E1 ialah kadar yang dikembalikan oleh XIRR

Seperti yang ditunjukkan dalam tangkapan skrin di bawah, hasilnya sangat dekatkepada sifar. Q.E.D. :)

Cara mengira XIRR dalam Excel – contoh formula

Di bawah ialah beberapa contoh yang menunjukkan kegunaan biasa fungsi XIRR dalam Excel.

Formula asas XIRR dalam Excel

Andaikan anda melabur $1,000 pada tahun 2017 dan mengharapkan untuk menerima sedikit keuntungan dalam tempoh 6 tahun akan datang. Untuk mencari kadar pulangan dalaman bagi pelaburan ini, gunakan formula ini:

=XIRR(A2:A8, B2:B8)

Di mana A2:A8 ialah aliran tunai dan B2:B8 ialah tarikh yang sepadan dengan aliran tunai:

Untuk menilai keuntungan pelaburan ini, bandingkan output XIRR dengan kos purata wajaran modal atau kadar halangan syarikat anda. Jika kadar pulangan lebih tinggi daripada kos modal, projek itu boleh dianggap sebagai pelaburan yang baik.

Apabila membandingkan beberapa pilihan pelaburan, sila ingat bahawa kadar pulangan yang diunjurkan hanyalah salah satu faktor yang perlu anda anggarkan sebelum membuat keputusan. Untuk mendapatkan maklumat lanjut, sila lihat Apakah kadar pulangan dalaman (IRR)?

Bentuk lengkap fungsi Excel XIRR

Sekiranya anda tahu jenis pulangan yang anda harapkan daripada ini atau itu pelaburan, anda boleh menggunakan jangkaan anda sebagai tekaan. Ia amat membantu apabila formula XIRR yang jelas betul menghasilkan #NUM! ralat.

Untuk input data yang ditunjukkan di bawah, formula XIRR tanpa tekaan mengembalikan ralat:

=XIRR(A2:A7, B2:B7)

Kadar pulangan yang dijangkakan(-20%) dimasukkan ke dalam argumen teka membantu Excel mencapai hasil:

=XIRR(A2:A7, B2:B7, -20%)

Cara mengira XIRR untuk aliran tunai bulanan

Sebagai permulaan, sila ingat ini – apa jua aliran tunai yang anda kira, fungsi Excel XIRR menghasilkan kadar pulangan tahunan .

Untuk memastikan ini, mari cari IRR untuk siri aliran tunai yang sama (A2:A8) yang berlaku setiap bulan dan tahunan (tarikh adalah dalam B2:B8):

=XIRR(A2:A8, B2:B8)

Seperti yang anda lihat dalam tangkapan skrin di bawah, IRR berubah daripada 7.68% sekiranya aliran tunai tahunan kepada kira-kira 145% untuk aliran tunai bulanan! Perbezaannya kelihatan terlalu tinggi untuk dibenarkan oleh faktor nilai masa wang sahaja:

Untuk mencari anggaran XIRR bulanan , anda boleh menggunakan perkara di bawah pengiraan, dengan E1 ialah hasil daripada formula XIRR biasa:

=(1+E1)^(1/12)-1

Atau anda boleh membenamkan XIRR terus dalam persamaan:

=(1+XIRR(A2:A8,B2:B8))^(1/12)-1

Sebagaimana cek tambahan, mari gunakan fungsi IRR pada aliran tunai yang sama. Sila ingat bahawa IRR juga akan mengira kadar anggaran kerana ia menganggap semua tempoh masa adalah sama:

=IRR(A2:A8)

Hasil pengiraan ini, kami mendapat XIRR bulanan sebanyak 7.77 %, iaitu hampir 7.68% yang dihasilkan oleh formula IRR:

Kesimpulannya : jika anda mencari IRR tahunan untuk tunai bulanan mengalir, gunakan fungsi XIRR dalam bentuk tulennya; untuk mendapatkan IRR bulanan, mohonpelarasan yang diterangkan di atas.

Templat XIRR Excel

Untuk mendapatkan kadar pulangan dalaman dengan cepat untuk projek yang berbeza, anda boleh mencipta kalkulator XIRR serba boleh untuk Excel. Begini caranya:

1. Masukkan aliran tunai dan tarikh dalam dua lajur individu (A dan B dalam contoh ini).
2. Buat dua julat yang ditentukan dinamik, dinamakan Aliran_Tunai dan Tarikh . Secara teknikal, ia akan dinamakan formula:

   Cash_flows:

   =OFFSET(Sheet1!$A$2,0,0,COUNT(Sheet1!$A:$A),1)

   Tarikh:

   =OFFSET(Sheet1!$B$2,0,0,COUNT(Sheet1!$B:$B),1)

   Di mana Helaian1 adalah nama lembaran kerja anda, A2 ialah aliran tunai pertama dan B2 ialah tarikh pertama.

   Untuk mendapatkan arahan langkah demi langkah yang terperinci, sila lihat Cara membuat julat bernama dinamik dalam Excel.

3. Bekalkan nama yang ditentukan dinamik yang telah anda buat kepada formula XIRR:

=XIRR(Cash_flows, Dates)

Selesai! Anda kini boleh menambah atau mengalih keluar seberapa banyak aliran tunai yang anda mahu dan formula XIRR dinamik anda akan dikira semula dengan sewajarnya:

XIRR lwn. IRR dalam Excel

Perbezaan utama antara fungsi Excel XIRR dan IRR ialah:

• IRR mengandaikan bahawa semua tempoh dalam satu siri aliran tunai adalah sama. Anda menggunakan fungsi ini untuk mencari kadar pulangan dalaman untuk aliran tunai berkala seperti bulanan, suku tahunan atau tahunan.
• XIRR membolehkan anda menetapkan tarikh kepada setiap aliran tunai individu. Jadi, gunakan fungsi ini untuk mengira IRR bagi aliran tunai yang tidak semestinya berkala.

Secara amnya,jika anda mengetahui tarikh pembayaran yang tepat, adalah dinasihatkan untuk menggunakan XIRR kerana ia memberikan ketepatan pengiraan yang lebih baik.

Sebagai contoh, mari kita bandingkan keputusan IRR dan XIRR untuk aliran tunai yang sama:

Jika semua pembayaran berlaku pada selang masa biasa , fungsi mengembalikan hasil yang sangat hampir:

Jika masa aliran tunai ialah tidak sama , perbezaan antara keputusan agak ketara:

XIRR dan XNPV dalam Excel

XIRR berkait rapat dengan fungsi XNPV kerana hasil XIRR ialah kadar diskaun yang membawa kepada nilai semasa bersih sifar. Dalam erti kata lain, XIRR ialah XNPV = 0. Contoh berikut menunjukkan hubungan antara XIRR dan XNPV dalam Excel.

Katakan anda sedang mempertimbangkan beberapa peluang pelaburan dan ingin memeriksa kedua-dua nilai semasa bersih dan kadar dalaman daripada pulangan pelaburan ini.

Dengan aliran tunai dalam A2:A5, tarikh dalam B2:B5 dan kadar diskaun dalam E1, formula XNPV berikut akan memberi anda nilai semasa bersih aliran tunai masa hadapan:

=XNPV(E1, A2:A5, B2:B5)

NPV positif menunjukkan bahawa projek itu menguntungkan:

Sekarang, mari cari kadar diskaun yang akan menjadikan nilai kini bersih sifar. Untuk ini, kami menggunakan fungsi XIRR:

=XIRR(A2:A5, B2:B5)

Untuk menyemak sama ada kadar yang dihasilkan oleh XIRR benar-benar membawa kepada NPV sifar, letakkannya dalam hujah kadar bagi XNPV andaformula:

=XNPV(E4, A2:A5, B2:B5)

Atau benamkan keseluruhan fungsi XIRR:

=XNPV(XIRR(A2:A5, B2:B5), A2:A5, B2:B5)

Ya, XNPV yang dibundarkan kepada 2 tempat perpuluhan adalah sama dengan sifar:

Untuk memaparkan nilai NPV yang tepat, pilih untuk menunjukkan lebih banyak tempat perpuluhan atau gunakan format Saintifik pada sel XNPV. Itu akan menghasilkan hasil yang serupa dengan ini:

Jika anda tidak biasa dengan tatatanda saintifik, lakukan pengiraan berikut untuk menukarnya kepada nombor perpuluhan:

1.11E-05 = 1.11*10^-5 = 0.0000111

Fungsi Excel XIRR tidak berfungsi

Jika anda menghadapi masalah dengan fungsi XNPV dalam Excel, di bawah ialah perkara utama untuk diperiksa.

#NUM ! ralat

Ralat #NUM mungkin berlaku kerana sebab berikut:

• Julat nilai dan tarikh mempunyai panjang yang berbeza (berbeza bilangan lajur atau baris).
• Tatasusunan nilai tidak mengandungi sekurang-kurangnya satu nilai positif dan satu negatif.
• Mana-mana tarikh berikutnya adalah lebih awal daripada yang pertama tarikh.
• Hasil tidak ditemui selepas 100 lelaran. Dalam kes ini, cuba tekaan yang berbeza.

#VALUE! ralat

Ralat #VALUE mungkin disebabkan oleh perkara berikut:

• Mana-mana nilai yang dibekalkan bukan angka.
• Sesetengahnya daripada tarikh yang dibekalkan tidak boleh dikenal pasti sebagai tarikh Excel yang sah.

Begitulah anda mengira XIRR dalam Excel. Untuk melihat dengan lebih dekat formula yang dibincangkan dalam tutorial ini, anda dialu-alukan untuk memuat turun sampel kamibuku kerja di bawah. Saya mengucapkan terima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan!

Berlatih buku kerja untuk memuat turun

Templat XIRR Excel (fail.xlsx)