Tutorialak XIRR Excel-en nola erabili erakusten du denbora irregularreko kutxa-fluxuen barne etekin-tasa (IRR) kalkulatzeko eta zure XIRR kalkulagailua nola egin.

Noiz kapital intentsiboko erabaki baten aurrean zaude, barne-errendimendu-tasa kalkulatzea komeni da, inbertsio desberdinetarako aurreikusitako etekinak alderatzen uzten dizulako eta erabakia hartzeko oinarri kuantitatibo bat ematen duelako.

Gure aurreko tutorialean, Excel IRR funtzioarekin barne etekin-tasa nola kalkulatu aztertu dugu. Metodo hori azkarra eta zuzena da, baina ezinbesteko muga bat du: IRR funtzioak suposatzen du kutxa-fluxu guztiak denbora-tarte berdinetan gertatzen direla, hala nola hilero edo urtero. Bizitza errealeko egoeretan, ordea, diru-sarrerak eta irteerak tarte irregularrean gertatzen dira. Zorionez, Microsoft Excel-ek beste funtzio bat dauka horrelako kasuetan IRR aurkitzeko, eta tutorial honek nola erabili irakatsiko dizu.

XIRR funtzioa Excel-en

Excel XIRR funtzioak aldian-aldian izan daitezkeen ala ez izan daitezkeen diru-fluxu batzuen barne-errendimendu-tasa itzultzen du.

Funtzioa Excel 2007-n sartu zen eta Excel 2010, Excel 2013, Excel 2016-en ondorengo bertsio guztietan dago eskuragarri. , Excel 2019 eta Excel for Office 365.

XIRR funtzioaren sintaxia hau da:

Non:

• Balioak (beharrezkoa) – anarray edo gelaxka sorta bat, sarrera eta irteera sorta bat adierazten dutenak.
• Datak (beharrezkoa) – kutxa-fluxuei dagozkien datak. Datak edozein ordenatan ager daitezke, baina hasierako inbertsioaren datak lehena izan behar du matrizean.
• Asmatu (aukerakoa) – espero den IRR bat ehuneko edo zenbaki hamartar gisa ematen da. Salbatuz gero, Excel-ek 0,1 (% 10) tasa lehenetsia erabiltzen du.

Adibidez, A2:A5-ko kutxa-fluxuen eta B2:B5-ko daten serierako IRR kalkulatzeko, egin beharko zenuke. erabili formula hau:

=XIRR(A2:A5, B2:B5)

Aholkua. Emaitza behar bezala bistaratzeko, ziurtatu Ehunekoa formatua formula-gelaxketarako ezarrita dagoela.

XIRR funtzioari buruz jakin behar dituzun 6 gauza

Ondoko ohar hauek XIRR funtzioaren barruko mekanika hobeto ulertzen lagunduko dizute eta zure lan-orrietan modu eraginkorrenean erabiltzen.

1. Excel-en XIRR kutxa-fluxuen barne-errendimendu-tasa kalkulatzeko diseinatuta dago, denbora desberdinarekin. Ordainketa-data zehatzak ezezagunak dituzten aldizkako kutxa-fluxuetarako, IRR funtzioa erabil dezakezu.
2. Balioen barrutiak balio positibo (sarrera) eta negatibo bat (irteerako ordainketa) izan behar du gutxienez.
3. Lehenengo balioa gastu bat bada (hasierako inbertsioa), zenbaki negatibo batekin irudikatu behar da. Hasierako inbertsioa ez da deskontatzen; ondorengo ordainketak lehen kutxa-fluxuaren datara itzultzen dira eta deskontatu egiten dira365 eguneko urtean.
4. Data guztiak zenbaki osoetara mozten dira, hau da, denbora adierazten duen data baten zati zatia kentzen da.
5. Datek erreferentzia gisa sartutako Excel datak baliozkoak izan behar dira. datak edo DATA funtzioa bezalako formulen emaitzak dituzten gelaxkak. Datak testu-formatuan sartzen badira, arazoak gerta daitezke.
6. Excel-en XIRR-k urteko IRR itzultzen du beti, hileko edo asteko diru-fluxuak kalkulatzean ere.

XIRR kalkulua Excel-en

Excel-en XIRR funtzioak saiakuntza eta erroreen ikuspegia erabiltzen du ekuazio hau betetzen duen tasa aurkitzeko:

Non:

• P - diru-fluxua (ordainketa)
• d - data
• i - aldiaren zenbakia
• n - aldien guztizkoa

Ematen bada asmatzen hasita edo lehenetsitako % 10ekoa ez bada, Excel-ek iterazioak egiten ditu emaitzara % 0,000001eko zehaztasunarekin iristeko. 100 saiakeraren ondoren tasa zehatza aurkitzen ez bada, #NUM! errorea itzultzen da.

Ekuazio honen baliozkotasuna egiaztatzeko, proba dezagun XIRR formularen emaitzarekin. Gure kalkulua sinplifikatzeko, honako array formula hau erabiliko dugu (gogoratu edozein array formula osatu behar dela Ctrl + Shift + Sartu sakatuz):

=SUM(A2:A5/((1+$E$1)^((B2:B5-$B$2)/365)))

Non:

• A2:A5 diru-fluxuak dira
• B2:B5 datak dira
• E1 XIRR-ek itzultzen duen tasa da

Ikusiko den bezala. beheko pantaila-argazkia, emaitza oso hurbil dagozerora. Q.E.D. :)

Nola kalkulatu XIRR Excel-en - formula adibideak

Jarraian XIRR funtzioaren erabilera arruntak Excel-en erakusten dituzten adibide batzuk daude.

Excel-en XIRR oinarrizko formula

Demagun 2017an 1.000 dolar inbertitu dituzula eta datozen 6 urteetan irabazien bat jasotzea espero duzula. Inbertsio honen barneko etekin-tasa aurkitzeko, erabili formula hau:

=XIRR(A2:A8, B2:B8)

Non A2:A8 diru-fluxuak diren eta B2:B8 diru-fluxuei dagozkien datak diren:

Inbertsio honen errentagarritasuna epaitzeko, konparatu XIRR irteera zure enpresaren kapitalaren batez besteko kostu haztatuarekin edo oztopo-tasa rekin. Itzulitako tasa kapitalaren kostua baino handiagoa bada, proiektua inbertsio ontzat jo daiteke.

Hainbat inbertsio aukera alderatzean, gogoratu aurreikusitako itzulera-tasa estimatu beharko zenukeen faktoreetako bat besterik ez dela. erabakia hartu aurretik. Informazio gehiago lortzeko, ikusi Zein da barne-errentamendu-tasa (IRR)?

Excel XIRR funtzioaren inprimaki osoa

Badakizu zer nolako etekina espero duzun honetatik edo hartatik. inbertsioa, zure itxaropena asmakizun gisa erabil dezakezu. Bereziki lagungarria da XIRR formula zuzenak #NUM bat botatzen duenean! errorea.

Behean agertzen den datuen sarrerarako, asmakizunik gabeko XIRR formula batek errore bat ematen du:

=XIRR(A2:A7, B2:B7)

Aurreikusitako itzulera-tasa(%-20) asmatu argumentua jarriz gero, Excel-ek emaitzara iristen laguntzen du:

=XIRR(A2:A7, B2:B7, -20%)

Nola kalkulatu XIRR-rako hileko kutxa-fluxuak

Hasteko, gogoratu hau: kalkulatzen ari zaren eskudiru-fluxuak edozein direla ere, Excel XIRR funtzioak urteko etekin-tasa sortzen du.

Ziurtatzeko. hau, aurki ditzagun hilero eta urtero gertatzen diren kutxa-fluxuen (A2:A8) serie bereko IRR (datak B2:B8an daude):

=XIRR(A2:A8, B2:B8)

Ikus dezakezun bezala. beheko pantaila-argazkian, IRR% 7,68tik urteko kutxa-fluxuen kasuan% 145 ingurura doa hileroko kutxa-fluxuetarako! Aldea handiegia dirudi diruaren denbora-balioaren faktoreak bakarrik justifikatzeko:

Gutxi gorabeherako hilabeteko XIRR aurkitzeko, beheko hau erabil dezakezu kalkulua, non E1 XIRR formula erregularraren emaitza den:

=(1+E1)^(1/12)-1

Edo XIRR zuzenean txerta dezakezu ekuazioan:

=(1+XIRR(A2:A8,B2:B8))^(1/12)-1

Bezala txeke gehigarri bat, erabil dezagun IRR funtzioa kutxa-fluxu berdinetan. Kontuan izan IRRk ere gutxi gorabeherako tasa bat kalkulatuko duela, denbora-tarte guztiak berdinak direla suposatzen duelako:

=IRR(A2:A8)

Kalkulu hauen ondorioz, hileko XIRR 7,77 lortzen dugu. %, hau da, IRR formulak sortutako % 7,68tik oso gertu dagoena:

Ondorioa : hileko dirua lortzeko urteko IRR baten bila bazabiltza. fluxuak, erabili XIRR funtzioa bere forma hutsean; hileko IRR bat lortzeko, eskatugoian deskribatutako doikuntza.

Excel XIRR txantiloia

Proiektu ezberdinen barne-errentagarritasuna azkar lortzeko, Excel-erako XIRR kalkulagailu polifazetikoa sor dezakezu. Hona hemen nola:

1. Idatzi diru-fluxuak eta datak bi zutabe indibidualetan (A eta B adibide honetan).
2. Sortu definitutako bi barruti dinamiko, Diru-fluxuak<2 izenekoak> eta Datak . Teknikoki, formulak izendatuko dira:

   Kutxa_fluxuak:

   =OFFSET(Sheet1!$A$2,0,0,COUNT(Sheet1!$A:$A),1)

   Datak:

   =OFFSET(Sheet1!$B$2,0,0,COUNT(Sheet1!$B:$B),1)

   Non Orria1 den zure lan-orriaren izena, A2 lehen diru-fluxua da eta B2 lehenengo data.

   Urratsez urratseko argibide zehatzak lortzeko, ikus Nola sortu izen-barruti dinamiko bat Excel-en.

3. Eman XIRR formulari sortu dituzun definitutako izen dinamikoak:

=XIRR(Cash_flows, Dates)

Bukatu! Orain nahi adina kutxa-fluxu gehitu edo kendu ditzakezu, eta zure XIRR formula dinamikoa horren arabera kalkulatuko da:

XIRR vs. IRR Excel-en

Excel XIRR eta IRR funtzioen arteko desberdintasun nagusia hau da:

• IRR -k kutxa-fluxuen serie bateko aldi guztiak berdinak direla suposatzen du. Funtzio hau erabiltzen duzu aldizkako kutxa-fluxuen barne-errentamendu-tasa aurkitzeko, hala nola hilero, hiruhileko edo urteko.
• XIRR -k data bat esleitzeko aukera ematen dizu diru-fluxu bakoitzari. Beraz, erabili funtzio hau IRR kalkulatzeko nahitaez periodikoak ez diren kutxa-fluxuetarako.

Oro har,ordainketen data zehatzak ezagutzen badituzu, komeni da XIRR erabiltzea, kalkuluaren zehaztasun hobea ematen duelako.

Adibide gisa, konparatu ditzagun IRR eta XIRRren emaitzak kutxa-fluxu berdinetarako:

Ordainketa guztiak tarte erregularretan gertatzen badira, funtzioek emaitza oso hurbilak ematen dituzte:

Diru-fluxuen denbora bada. desberdina , emaitzen arteko aldea nahiko esanguratsua da:

XIRR eta XNPV Excel-en

XIRR estuki lotuta dago XNPV funtzioarekin, zeren eta XIRRren emaitza zero egungo balio garbira eramaten duen deskontu-tasa da. Beste era batera esanda, XIRR XNPV = 0 da. Ondorengo adibide honek Excel-en XIRR eta XNPVren arteko erlazioa erakusten du.

Demagun inbertsio-aukera bat aztertzen ari zarela eta egungo balio garbia eta barne-tasa aztertu nahi dituzula. inbertsio honen errentagarritasuna.

A2:A5 ataleko kutxa-fluxuekin, B2:B5-ko datek eta E1-ko deskontu-tasarekin, hurrengo XNPV formula honek etorkizuneko kutxa-fluxuen egungo balio garbia emango dizu:

=XNPV(E1, A2:A5, B2:B5)

NPV positibo batek proiektua errentagarria dela adierazten du:

Orain, aurki dezagun zer deskontu-tasa izango duen balio uneko garbia. zero. Horretarako, XIRR funtzioa erabiltzen dugu:

=XIRR(A2:A5, B2:B5)

XIRR-k sortutako tasak benetan zero NPVra eramaten duen egiaztatzeko, jarri tasa argumentuan. zure XNPVformula:

=XNPV(E4, A2:A5, B2:B5)

Edo txertatu XIRR funtzio osoa:

=XNPV(XIRR(A2:A5, B2:B5), A2:A5, B2:B5)

Bai, 2 zifra hamartartara biribildutako XNPV zero berdina da:

NPV balio zehatza bistaratzeko, aukeratu hamartar gehiago erakustea edo formatu zientifikoa aplikatu XNPV gelaxkan. Honen antzeko emaitza emango du:

Notazio zientifikoa ezagutzen ez baduzu, egin kalkulu hau zenbaki hamartar bihurtzeko:

1.11E-05 = 1.11*10^-5 = 0.0000111

Excel XIRR funtzioa ez dabil

Excel-en XNPV funtzioarekin arazoren bat aurkitu baduzu, behean egiaztatu beharreko puntu nagusiak daude.

#NUM ! error

#NUM errore bat gerta daiteke arrazoi hauengatik:

• balioak eta data barrutiek luzera desberdinak dituzte (desberdinak). zutabe edo errenkada kopurua).
• balioak matrizeak ez du balio positibo bat eta negatibo bat gutxienez.
• Ondorengo datak lehenengoa baino lehenagokoak dira. data.
• Ez da emaitzarik aurkitzen 100 iterazioren ondoren. Kasu honetan, saiatu beste asmakizun batekin.

#BALIOA! error

#VALUE errorea honako hauengatik izan daiteke:

• Emandako balio edozein zenbakizkoak ez dira.
• Batzuk hornitutako daten artean ezin da baliozko Excel data gisa identifikatu.

Horrela kalkulatzen duzu XIRR Excel-en. Tutorial honetan eztabaidatutako formulak gertutik ikusteko, gure lagina deskargatu dezakezulan-koadernoa behean. Eskerrik asko irakurtzeagatik eta datorren astean gure blogean ikustea espero dut!

Lan koadernoa deskargatzeko

XIRR Excel txantiloia (.xlsx fitxategia)