Udžbenik pokazuje kako koristiti XIRR u Excelu za izračunavanje interne stope povrata (IRR) za novčane tokove s nepravilnim vremenskim rasporedom i kako napraviti vlastiti XIRR kalkulator.

Kada suočeni ste s kapitalno intenzivnom odlukom, izračun interne stope povrata je poželjan jer vam omogućuje usporedbu predviđenih povrata za različita ulaganja i daje kvantitativnu osnovu za donošenje odluke.

U našem prethodnom vodiču, pogledali smo kako izračunati internu stopu povrata s Excel IRR funkcijom. Ta je metoda brza i jednostavna, ali ima bitno ograničenje – IRR funkcija pretpostavlja da se svi novčani tokovi odvijaju u jednakim vremenskim intervalima, primjerice mjesečno ili godišnje. U stvarnim životnim situacijama, međutim, novčani priljevi i odljevi često se događaju u nepravilnim intervalima. Srećom, Microsoft Excel ima još jednu funkciju za pronalaženje IRR-a u takvim slučajevima, a ovaj vodič će vas naučiti kako je koristiti.

XIRR funkcija u Excelu

Excel XIRR funkcija vraća internu stopu povrata za niz novčanih tokova koji mogu, ali ne moraju biti periodični.

Funkcija je uvedena u programu Excel 2007 i dostupna je u svim kasnijim verzijama programa Excel 2010, Excel 2013, Excel 2016 , Excel 2019 i Excel za Office 365.

Sintaksa funkcije XIRR je sljedeća:

Gdje:

• Vrijednosti (obavezno) – anniz ili niz ćelija koje predstavljaju niz priljeva i odljeva.
• Datumi (obavezno) – datumi koji odgovaraju novčanim tokovima. Datumi se mogu pojavljivati ​​bilo kojim redoslijedom, ali datum početnog ulaganja mora biti prvi u nizu.
• Pogodi (neobavezno) – očekivani IRR naveden kao postotak ili decimalni broj. Ako se izostavi, Excel koristi zadanu stopu od 0,1 (10%).

Na primjer, da biste izračunali IRR za niz novčanih tokova u A2:A5 i datume u B2:B5, trebali biste koristite ovu formulu:

=XIRR(A2:A5, B2:B5)

Savjet. Kako bi se rezultat ispravno prikazao, provjerite je li format Postotak postavljen za ćeliju formule.

6 stvari koje biste trebali znati o funkciji XIRR

Sljedeće napomene pomoći će vam da bolje razumijete unutarnju mehaniku funkcije XIRR i da je najučinkovitije koristite u svojim radnim listovima.

1. XIRR u Excelu dizajniran je za izračun interne stope povrata za novčane tokove s nejednakim vremenskim rasporedom. Za periodične novčane tijekove s nepoznatim točnim datumima plaćanja možete koristiti IRR funkciju.
2. Raspon vrijednosti mora sadržavati najmanje jednu pozitivnu (prihod) i jednu negativnu (odlazna plaćanja) vrijednost.
3. Ako je prva vrijednost izdatak (početno ulaganje), ona mora biti predstavljena negativnim brojem. Početna investicija nije diskontirana; naknadna plaćanja vraćaju se na datum prvog novčanog toka i diskontirajuu godini od 365 dana.
4. Svi datumi su skraćeni na cijele brojeve, što znači da je razlomački dio datuma koji predstavlja vrijeme uklonjen.
5. Datumi moraju biti valjani Excel datumi uneseni kao reference na ćelije koje sadrže datume ili rezultate formula kao što je funkcija DATE. Ako se datumi unose u tekstualnom formatu, može doći do problema.
6. XIRR u Excelu uvijek vraća godišnju IRR čak i kada izračunava mjesečne ili tjedne novčane tokove.

Izračun XIRR u Excelu

Funkcija XIRR u Excelu koristi se metodom pokušaja i pogrešaka kako bi pronašla stopu koja zadovoljava ovu jednadžbu:

Gdje:

• P - novčani tok (plaćanje)
• d - datum
• i - broj razdoblja
• n - ukupno razdoblja

Počevši od pretpostavke ako je navedena ili sa zadanih 10% ako nije, Excel prolazi kroz iteracije kako bi došao do rezultata s 0,000001% točnosti. Ako se nakon 100 pokušaja ne pronađe točna stopa, #NUM! vraća se pogreška.

Da provjerimo valjanost ove jednadžbe, testirajmo je u odnosu na rezultat formule XIRR. Kako bismo pojednostavili naš izračun, koristit ćemo sljedeću formulu polja (molimo zapamtite da se svaka formula polja mora dovršiti pritiskom na Ctrl + Shift + Enter):

=SUM(A2:A5/((1+$E$1)^((B2:B5-$B$2)/365)))

Gdje:

• A2:A5 su novčani tokovi
• B2:B5 su datumi
• E1 je stopa koju vraća XIRR

Kao što je prikazano u na slici ispod, rezultat je vrlo blizuna nulu. Q.E.D. :)

Kako izračunati XIRR u Excelu – primjeri formula

U nastavku je nekoliko primjera koji pokazuju uobičajenu upotrebu funkcije XIRR u Excelu.

Osnovna XIRR formula u Excelu

Pretpostavimo da ste uložili 1000 dolara u 2017. godini i očekujete da ćete dobiti neku zaradu u sljedećih 6 godina. Da biste pronašli internu stopu povrata za ovu investiciju, upotrijebite ovu formulu:

=XIRR(A2:A8, B2:B8)

Gdje su A2:A8 novčani tokovi, a B2:B8 datumi koji odgovaraju novčanim tokovima:

Da biste procijenili isplativost ove investicije, usporedite XIRR output s ponderiranim prosječnim troškom kapitala ili stopom prepreke vaše tvrtke. Ako je stopa povrata viša od cijene kapitala, projekt se može smatrati dobrom investicijom.

Kada uspoređujete nekoliko opcija ulaganja, imajte na umu da je predviđena stopa povrata samo jedan od faktora koje trebate procijeniti prije donošenja odluke. Za više informacija pogledajte Koja je interna stopa povrata (IRR)?

Kompletan oblik funkcije Excel XIRR

U slučaju da znate kakav povrat očekujete od ovoga ili onoga ulaganja, možete koristiti svoje očekivanje kao pretpostavku. Posebno je korisno kada očito ispravna XIRR formula daje #NUM! pogreška.

Za unos podataka prikazan u nastavku, XIRR formula bez pogađanja vraća pogrešku:

=XIRR(A2:A7, B2:B7)

Očekivana stopa povrata(-20%) stavljen u argument pogodi pomaže Excelu da dođe do rezultata:

=XIRR(A2:A7, B2:B7, -20%)

Kako izračunati XIRR za mjesečni novčani tokovi

Za početak, zapamtite ovo – bez obzira na novčane tokove koje izračunavate, funkcija Excel XIRR proizvodi godišnju stopu povrata .

Kako biste bili sigurni ovo, pronađimo IRR za isti niz novčanih tokova (A2:A8) koji se događaju mjesečno i godišnje (datumi su u B2:B8):

=XIRR(A2:A8, B2:B8)

Kao što možete vidjeti u na slici ispod, IRR ide od 7,68% u slučaju godišnjih novčanih tokova do oko 145% za mjesečne novčane tokove! Čini se da je razlika prevelika da bi se opravdala samo faktorom vremenske vrijednosti novca:

Da biste pronašli približan mjesečni XIRR , možete koristiti dolje izračun, gdje je E1 rezultat regularne XIRR formule:

=(1+E1)^(1/12)-1

Ili možete ugraditi XIRR izravno u jednadžbu:

=(1+XIRR(A2:A8,B2:B8))^(1/12)-1

As dodatnu provjeru, upotrijebimo IRR funkciju na istim novčanim tokovima. Imajte na umu da će IRR također izračunati približnu stopu jer pretpostavlja da su sva vremenska razdoblja jednaka:

=IRR(A2:A8)

Kao rezultat ovih izračuna, dobivamo mjesečni XIRR od 7,77 %, što je vrlo blizu 7,68% proizvedeno formulom IRR-a:

Zaključak : ako tražite godišnji IRR za mjesečni novac tokovi, koristite funkciju XIRR u svom čistom obliku; da biste dobili mjesečnu IRR, prijavite segore opisanu prilagodbu.

Excel XIRR predložak

Da biste brzo dobili internu stopu povrata za različite projekte, možete stvoriti svestrani XIRR kalkulator za Excel. Evo kako:

1. Unesite novčane tijekove i datume u dva pojedinačna stupca (A i B u ovom primjeru).
2. Stvorite dva dinamički definirana raspona pod nazivom Novčani_tokovi i Datumi . Tehnički, to će biti imenovane formule:

   Cash_flows:

   =OFFSET(Sheet1!$A$2,0,0,COUNT(Sheet1!$A:$A),1)

   Datumi:

   =OFFSET(Sheet1!$B$2,0,0,COUNT(Sheet1!$B:$B),1)

   Gdje je Sheet1 naziv vašeg radnog lista, A2 je prvi novčani tok, a B2 je prvi datum.

   Vidi također: VLOOKUP u Google tablicama s primjerima formula

   Za detaljne upute korak po korak pogledajte Kako stvoriti dinamički imenovani raspon u programu Excel.

3. Dodajte dinamički definirana imena koja ste stvorili formuli XIRR:

=XIRR(Cash_flows, Dates)

Gotovo! Sada možete dodati ili ukloniti onoliko novčanih tokova koliko želite, a vaša će se dinamička XIRR formula ponovno izračunati u skladu s tim:

XIRR u odnosu na IRR u Excelu

Glavna razlika između funkcija Excel XIRR i IRR je sljedeća:

• IRR pretpostavlja da su sva razdoblja u nizu novčanih tokova jednaka. Ovu funkciju koristite za pronalaženje interne stope povrata za periodične novčane tokove kao što su mjesečni, tromjesečni ili godišnji.
• XIRR omogućuje vam dodjeljivanje datuma svakom pojedinačnom novčanom toku. Dakle, koristite ovu funkciju za izračun IRR-a za novčane tokove koji nisu nužno periodični.

Općenito,ako znate točne datume plaćanja, preporučljivo je koristiti XIRR jer pruža bolju točnost izračuna.

Kao primjer, usporedimo rezultate IRR i XIRR za iste novčane tokove:

Ako se sva plaćanja odvijaju u redovitim intervalima , funkcije vraćaju vrlo slične rezultate:

Ako je vrijeme novčanih tokova nejednak , razlika između rezultata je prilično značajna:

XIRR i XNPV u Excelu

XIRR je usko povezan s funkcijom XNPV jer rezultat XIRR je diskontna stopa koja dovodi do nulte neto sadašnje vrijednosti. Drugim riječima, XIRR je XNPV = 0. Sljedeći primjer pokazuje odnos između XIRR i XNPV u Excelu.

Recimo da razmatrate neku priliku za ulaganje i želite ispitati i neto sadašnju vrijednost i internu stopu povrata ovog ulaganja.

S novčanim tokovima u A2:A5, datumima u B2:B5 i diskontnom stopom u E1, sljedeća XNPV formula će vam dati neto sadašnju vrijednost budućih novčanih tokova:

=XNPV(E1, A2:A5, B2:B5)

Pozitivan NPV označava da je projekt isplativ:

Sada, saznajmo koja će diskontna stopa činiti neto sadašnju vrijednost nula. Za ovo koristimo funkciju XIRR:

=XIRR(A2:A5, B2:B5)

Da biste provjerili dovodi li stopa koju proizvodi XIRR doista do nulte NPV, stavite je u argument rate od vaš XNPVformula:

=XNPV(E4, A2:A5, B2:B5)

Ili ugradite cijelu funkciju XIRR:

=XNPV(XIRR(A2:A5, B2:B5), A2:A5, B2:B5)

Da, XNPV zaokružen na 2 decimalna mjesta jednak je nuli:

Za prikaz točne NPV vrijednosti odaberite prikaz više decimalnih mjesta ili primijenite znanstveni format na ćeliju XNPV. To će proizvesti rezultat sličan ovome:

Ako niste upoznati sa znanstvenim zapisom, izvršite sljedeći izračun da biste ga pretvorili u decimalni broj:

1.11E-05 = 1.11*10^-5 = 0.0000111

Excel XIRR funkcija ne radi

Ako ste naišli na problem s XNPV funkcijom u Excelu, u nastavku su glavne točke koje treba provjeriti.

#NUM ! greška

Pogreška #NUM može se pojaviti zbog sljedećih razloga:

• Rasponi vrijednosti i datumi imaju različite duljine (različite broj stupaca ili redaka).
• Niz vrijednosti ne sadrži barem jednu pozitivnu i jednu negativnu vrijednost.
• Bilo koji od sljedećih datuma raniji je od prvog datum.
• Rezultat nije pronađen nakon 100 ponavljanja. U ovom slučaju pokušajte drugačije pogoditi.

#VALUE! pogreška

Pogreška #VALUE može biti uzrokovana sljedećim:

• Bilo koja od navedenih vrijednosti nije numerička.
• Neke navedenih datuma ne može se identificirati kao važeći Excel datumi.

Tako izračunavate XIRR u Excelu. Kako biste pobliže pogledali formule o kojima se govori u ovom vodiču, slobodno možete preuzeti naš uzorakradna bilježnica u nastavku. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeći tjedan!

Radna bilježnica za vježbe za preuzimanje

XIRR Excel predložak (.xlsx datoteka)