Vejledningen viser, hvordan du bruger XIRR i Excel til at beregne den interne rente for pengestrømme med uregelmæssig timing, og hvordan du laver din egen XIRR-beregner.

Når du står over for en kapitalintensiv beslutning, er det ønskeligt at beregne den interne rente, fordi det giver dig mulighed for at sammenligne det forventede afkast for forskellige investeringer og giver dig et kvantitativt grundlag for at træffe beslutningen.

I vores tidligere vejledning så vi på, hvordan man beregner den interne rente med Excel IRR-funktionen. Den metode er hurtig og ligetil, men den har en væsentlig begrænsning - IRR-funktionen forudsætter, at alle pengestrømme forekommer med lige store tidsintervaller, f.eks. månedligt eller årligt. I virkelige situationer sker ind- og udbetalinger af penge imidlertid ofte med uregelmæssige intervaller.Heldigvis har Microsoft Excel en anden funktion til at finde IRR i sådanne tilfælde, og i denne vejledning lærer du, hvordan du bruger den.

XIRR-funktionen i Excel

Excel XIRR-funktionen returnerer den interne rente for en række pengestrømme, som kan være periodiske eller ikke periodiske.

Funktionen blev introduceret i Excel 2007 og er tilgængelig i alle senere versioner af Excel 2010, Excel 2013, Excel 2016, Excel 2019 og Excel for Office 365.

Syntaksen for XIRR-funktionen er som følger:

Hvor:

• Værdier (påkrævet) - et array eller en række celler, der repræsenterer en række ind- og udstrømninger.
• Datoer (påkrævet) - datoer, der svarer til pengestrømme. Datoerne kan forekomme i vilkårlig rækkefølge, men datoen for den første investering skal være den første i arrayet.
• Gæt (valgfrit) - en forventet IRR angivet som en procentdel eller et decimaltal. Hvis den udelades, bruger Excel standardprocenten 0,1 (10 %).

Hvis du f.eks. vil beregne IRR for serierne af pengestrømme i A2:A5 og datoer i B2:B5, skal du bruge denne formel:

=XIRR(A2:A5, B2:B5)

Tip. For at resultatet vises korrekt, skal du sikre dig, at Procentdel formatet er indstillet for formelcellen.

6 ting, du bør vide om XIRR-funktionen

De følgende noter vil hjælpe dig med at forstå XIRR-funktionens indre mekanik bedre og bruge den mest effektivt i dine regneark.

1. XIRR i Excel er beregnet til at beregne den interne rente for pengestrømme med ulige timing. For periodiske pengestrømme med ukendte nøjagtige betalingsdatoer kan du bruge IRR-funktionen.
2. Værdiintervallet skal indeholde mindst én positiv værdi (indkomst) og én negativ værdi (udgående betaling).
3. Hvis den første værdi er en udgift (initialinvestering), skal den repræsenteres med et negativt tal. Den første investering diskonteres ikke; efterfølgende betalinger bringes tilbage til datoen for den første pengestrøm og diskonteres på grundlag af et år med 365 dage.
4. Alle datoer er afkortet til hele tal, hvilket betyder, at den del af datoen, der repræsenterer tid, er fjernet.
5. Datoer skal være gyldige Excel-datoer, der er indtastet som referencer til celler, der indeholder datoer, eller som resultater af formler som f.eks. funktionen DATO. Hvis datoer indtastes i tekstformat, kan der opstå problemer.
6. XIRR i Excel returnerer altid et annualiseret IRR selv ved beregning af månedlige eller ugentlige pengestrømme.

XIRR-beregning i Excel

XIRR-funktionen i Excel bruger en trial and error-metode til at finde den sats, der opfylder denne ligning:

Hvor:

• P - pengestrøm (betaling)
• d - dato
• i - periode nummer
• n - perioder i alt

Excel starter med gættet, hvis det er angivet, eller med standard 10 %, hvis det ikke er angivet, og går gennem iterationer for at nå frem til et resultat med 0,000001 % nøjagtighed. Hvis der efter 100 forsøg ikke er fundet en nøjagtig sats, returneres fejlen #NUM!

For at kontrollere gyldigheden af denne ligning skal vi teste den mod resultatet af XIRR-formlen. For at forenkle vores beregning bruger vi følgende matrixformel (husk, at enhver matrixformel skal afsluttes ved at trykke på Ctrl + Shift + Enter ):

=SUM(A2:A5/((1+$E$1)^((B2:B5-$B$2)/365)))

Hvor:

• A2:A5 er pengestrømme
• B2:B5 er datoerne
• E1 er den sats, som XIRR giver

Som det fremgår af nedenstående skærmbillede, er resultatet meget tæt på nul. Q.E.D. :)

Sådan beregner du XIRR i Excel - eksempler på formler

Nedenfor er der nogle få eksempler, der viser de almindelige anvendelser af XIRR-funktionen i Excel.

Grundlæggende XIRR-formel i Excel

Antag, at du investerede 1.000 USD i 2017 og forventer at få en vis fortjeneste i løbet af de næste 6 år. For at finde den interne rente for denne investering skal du bruge denne formel for at finde det interne afkast:

=XIRR(A2:A8, B2:B8)

Hvor A2:A8 er pengestrømme, og B2:B8 er de datoer, der svarer til pengestrømmene:

For at bedømme rentabiliteten af denne investering skal du sammenligne XIRR-udbyttet med din virksomheds vægtede gennemsnitlige kapitalomkostninger eller hurdle rate Hvis afkastet er højere end kapitalomkostningerne, kan projektet anses for at være en god investering.

Når du sammenligner flere investeringsmuligheder, skal du huske, at en forventet afkastningsgrad kun er en af de faktorer, du bør vurdere, før du træffer en beslutning. For yderligere oplysninger, se Hvad er den interne rente (IRR)?

Komplet form af Excel XIRR-funktionen

Hvis du ved, hvilket afkast du forventer af denne eller hin investering, kan du bruge din forventning som et gæt. Det er især nyttigt, når en åbenlyst korrekt XIRR-formel giver en #NUM! fejl.

For de data, der er vist nedenfor, giver en XIRR-formel uden gæt en fejl:

=XIRR(A2:A7, B2:B7)

Den forventede afkastprocent (-20 %), der er sat i gæt argumentet hjælper Excel med at nå frem til resultatet:

=XIRR(A2:A7, B2:B7, -20%)

Sådan beregnes XIRR for månedlige pengestrømme

Til at begynde med skal du huske dette - uanset hvilke pengestrømme du beregner, producerer Excel XIRR-funktionen en årlig afkastningsgrad .

For at sikre os dette, skal vi finde IRR for den samme serie af pengestrømme (A2:A8), der forekommer hver måned og hvert år (datoerne er i B2:B8):

=XIRR(A2:A8, B2:B8)

Som du kan se på nedenstående skærmbillede, går IRR'en fra 7,68 % ved årlige pengestrømme til ca. 145 % ved månedlige pengestrømme! Forskellen synes for stor til at kunne retfærdiggøres alene af tidsværdien af pengefaktoren:

For at finde et omtrentligt månedlig XIRR kan du bruge nedenstående beregning, hvor E1 er resultatet af den almindelige XIRR-formel:

=(1+E1)^(1/12)-1

Eller du kan indlejre XIRR direkte i ligningen:

=(1+XIRR(A2:A8,B2:B8))^(1/12)-1

Som en yderligere kontrol kan vi bruge IRR-funktionen på de samme pengestrømme. Husk, at IRR også beregner en tilnærmelsesvis sats, fordi den antager, at alle tidsperioder er lige lange:

=IRR(A2:A8)

Resultatet af disse beregninger er en månedlig XIRR på 7,77 %, hvilket er meget tæt på de 7,68 %, der fremkommer ved hjælp af IRR-formlen:

Konklusionen : hvis du søger en årlig IRR for månedlige pengestrømme, skal du bruge XIRR-funktionen i sin rene form; for at få en månedlig IRR skal du anvende den ovenfor beskrevne justering.

Excel XIRR-skabelon

For hurtigt at få den interne rente for forskellige projekter kan du oprette en alsidig XIRR-beregner til Excel for hurtigt at få den interne rente for forskellige projekter:

1. Indtast pengestrømmene og datoerne i to individuelle kolonner (A og B i dette eksempel).
2. Opret to dynamiske definerede områder, der hedder Cash_flows og Datoer Teknisk set vil der være tale om navngivne formler:

   Cash_flows:

   =OFFSET(Sheet1!$A$2,0,0,0,COUNT(Sheet1!$A:$A),1)

   Datoer:

   =OFFSET(Sheet1!$B$2,0,0,0,COUNT(Sheet1!$B:$B),1)

   Hvor Ark1 er navnet på dit regneark, A2 er den første pengestrøm, og B2 er den første dato.

   Du kan finde en detaljeret trin-for-trin-vejledning i Sådan opretter du et dynamisk navngivet område i Excel.

3. Angiv de dynamiske definerede navne, som du har oprettet, til XIRR-formlen:

=XIRR(Cash_flows, Datoer)

Færdig! Du kan nu tilføje eller fjerne så mange pengestrømme, som du vil, og din dynamiske XIRR-formel vil blive genberegnet i overensstemmelse hermed:

XIRR vs. IRR i Excel

Den væsentligste forskel mellem Excel XIRR- og IRR-funktionerne er følgende:

• IRR antager, at alle perioder i en række pengestrømme er lige store. Du bruger denne funktion til at finde den interne rente for periodiske pengestrømme, f.eks. månedlige, kvartalsvise eller årlige.
• XIRR giver dig mulighed for at tildele en dato til hver enkelt pengestrøm. Brug derfor denne funktion til at beregne IRR for pengestrømme, der ikke nødvendigvis er periodiske.

Hvis du kender de nøjagtige datoer for betalingerne, er det generelt tilrådeligt at bruge XIRR, fordi det giver en bedre beregningsnøjagtighed.

Lad os som et eksempel sammenligne resultaterne af IRR og XIRR for de samme pengestrømme:

Hvis alle betalinger sker på regelmæssige intervaller , giver funktionerne meget ensartede resultater:

Hvis tidspunktet for pengestrømme er ulige er forskellen mellem resultaterne ganske betydelig:

XIRR og XNPV i Excel

XIRR er tæt forbundet med XNPV-funktionen, fordi resultatet af XIRR er den diskonteringssats, der fører til en nettonutidsværdi på nul. Med andre ord er XIRR lig med XNPV = 0. Følgende eksempel viser forholdet mellem XIRR og XNPV i Excel.

Lad os sige, at du overvejer en investeringsmulighed og ønsker at undersøge både nettonutidsværdien og den interne rente på denne investering.

Med pengestrømmene i A2:A5, datoerne i B2:B5 og diskonteringssatsen i E1 giver følgende XNPV-formel nettonutidsværdien af de fremtidige pengestrømme:

=XNPV(E1, A2:A5, B2:B5)

En positiv NPV viser, at projektet er rentabelt:

Lad os nu finde ud af, hvilken diskonteringsrente der vil få nettonutidsværdien til at være nul. Til dette formål bruger vi XIRR-funktionen:

=XIRR(A2:A5, B2:B5)

For at kontrollere, om den sats, der fremkommer ved hjælp af XIRR, virkelig fører til en NPV på nul, skal du sætte den ind i sats argument i din XNPV-formel:

=XNPV(E4, A2:A5, B2:B5)

Eller indlejre hele XIRR-funktionen:

=XNPV(XIRR(A2:A5, B2:B5), A2:A5, B2:B5)

Ja, XNPV afrundet til to decimaler er lig med nul:

Hvis du vil vise den nøjagtige NPV-værdi, skal du vælge at vise flere decimaler eller anvende det videnskabelige format på XNPV-cellen. Det vil give et resultat, der ligner dette:

Hvis du ikke er bekendt med den videnskabelige notation, skal du foretage følgende beregning for at omregne det til et decimaltal:

1.11E-05 = 1.11*10^-5 = 0.0000111

Excel XIRR-funktionen fungerer ikke

Hvis du er stødt på et problem med XNPV-funktionen i Excel, kan du nedenfor se de vigtigste punkter, du skal kontrollere.

#NUM! fejl

En #NUM-fejl kan opstå af følgende årsager:

• værdier og datoer intervaller har forskellige længder (forskelligt antal kolonner eller rækker).
• værdier arrayet ikke indeholder mindst én positiv og én negativ værdi.
• Enhver af de efterfølgende datoer er tidligere end den første dato.
• Der er ikke fundet et resultat efter 100 gentagelser. I så fald skal du prøve et andet gæt.

#VALUE! fejl

En #VALUE-fejl kan skyldes følgende:

• Enhver af de leverede værdier er ikke-numeriske.
• Nogle af de angivne datoer kan ikke identificeres som gyldige Excel-datoer.

Sådan beregner du XIRR i Excel. Hvis du vil se nærmere på formlerne i denne vejledning, er du velkommen til at downloade vores prøvearbejdsmappe nedenfor. Tak fordi du læste med og håber at se dig på vores blog i næste uge!

Arbejdsbog til download

XIRR Excel-skabelon (.xlsx-fil)