V učbeniku je prikazano, kako v Excelu uporabiti XIRR za izračun notranje stopnje donosa (IRR) za denarne tokove z neenakomernim časovnim razporedom in kako izdelati svoj kalkulator XIRR.

Ko se soočate s kapitalsko intenzivno odločitvijo, je izračun notranje stopnje donosnosti zaželen, saj vam omogoča primerjavo predvidenih donosov za različne naložbe in daje kvantitativno podlago za sprejemanje odločitev.

V prejšnjem učbeniku smo si ogledali, kako izračunati notranjo stopnjo donosa s pomočjo Excelove funkcije IRR. Ta metoda je hitra in preprosta, vendar ima bistveno omejitev - funkcija IRR predpostavlja, da vsi denarni tokovi potekajo v enakih časovnih intervalih, na primer mesečno ali letno. Vendar se v resničnih življenjskih razmerah denarni prilivi in odlivi pogosto pojavljajo v neenakomernih časovnih intervalih.K sreči ima Microsoft Excel še eno funkcijo za iskanje IRR v takšnih primerih in v tem vodniku se boste naučili, kako jo uporabiti.

Funkcija XIRR v programu Excel

Excelova funkcija XIRR vrne notranjo stopnjo donosa za vrsto denarnih tokov, ki so lahko periodični ali ne.

Funkcija je bila uvedena v Excelu 2007 in je na voljo v vseh poznejših različicah programov Excel 2010, Excel 2013, Excel 2016, Excel 2019 in Excel za Office 365.

Sintaksa funkcije XIRR je naslednja:

Kje:

• Vrednosti (obvezno) - polje ali niz celic, ki predstavljajo vrsto prilivov in odlivov.
• Datumi (obvezno) - datumi, ki ustrezajo denarnim tokovom. Datumi so lahko v poljubnem vrstnem redu, vendar mora biti datum začetne naložbe prvi v polju.
• Ugani (neobvezno) - pričakovana interna stopnja donosa, ki je podana v odstotkih ali decimalnem številu. Če je izpuščena, Excel uporabi privzeto stopnjo 0,1 (10 %).

Za izračun IRR za niz denarnih tokov v A2:A5 in datume v B2:B5 na primer uporabite to formulo:

=XIRR(A2:A5, B2:B5)

Nasvet. Če želite, da se rezultat prikaže pravilno, se prepričajte, da je Odstotek za celico formule je nastavljena oblika.

6 stvari, ki jih morate vedeti o funkciji XIRR

Naslednje opombe vam bodo pomagale bolje razumeti notranjo mehaniko funkcije XIRR in jo čim učinkoviteje uporabljati v delovnih listih.

1. Funkcija XIRR v Excelu je zasnovana za izračun notranje stopnje donosa za denarne tokove z neenakomernim časovnim razporedom. Za periodične denarne tokove z neznanimi točnimi datumi plačil lahko uporabite funkcijo IRR.
2. Razpon vrednosti mora vsebovati vsaj eno pozitivno (prihodek) in eno negativno (odhodno plačilo) vrednost.
3. Če je prva vrednost izdatek (začetna naložba), jo je treba prikazati z negativnim številom. Začetna naložba se ne diskontira; nadaljnja plačila se prenesejo na datum prvega denarnega toka in se diskontirajo na podlagi 365-dnevnega leta.
4. Vsi datumi so skrajšani na cela števila, kar pomeni, da je delni del datuma, ki predstavlja čas, odstranjen.
5. Datumi morajo biti veljavni datumi programa Excel, vneseni kot sklici na celice z datumi ali rezultati formul, kot je funkcija DATUM. Če so datumi vneseni v obliki besedila, lahko pride do težav.
6. XIRR v Excelu vedno vrne letna interna stopnja donosnosti tudi pri izračunu mesečnih ali tedenskih denarnih tokov.

Izračun XIRR v Excelu

Funkcija XIRR v Excelu uporablja pristop poskusov in napak, da bi našla stopnjo, ki ustreza tej enačbi:

Kje:

• P - denarni tok (plačilo)
• d - datum
• i - številka obdobja
• n - obdobja skupaj

Excel začne z ugibanjem, če je bilo podano, ali s privzetim 10 %, če ni bilo podano, z iteracijami, da bi prišel do rezultata z natančnostjo 0,000001 %. Če po 100 poskusih ne najde natančne stopnje, vrne napako #NUM!.

Da bi preverili veljavnost te enačbe, jo preizkusimo z rezultatom formule XIRR. Da bi poenostavili naš izračun, bomo uporabili naslednjo matrično formulo (ne pozabite, da je treba vsako matrično formulo dokončati s pritiskom tipk Ctrl + Shift + Enter ):

=SUM(A2:A5/((1+$E$1)^((B2:B5-$B$2)/365)))

Kje:

• A2:A5 so denarni tokovi
• B2:B5 so datumi
• E1 je stopnja, ki jo vrne stopnja XIRR

Kot je prikazano na spodnji sliki zaslona, je rezultat zelo blizu nič. Q.E.D. :)

Kako izračunati XIRR v Excelu - primeri formul

Spodaj je nekaj primerov, ki prikazujejo pogoste uporabe funkcije XIRR v Excelu.

Osnovna formula XIRR v Excelu

Predpostavimo, da ste leta 2017 vložili 1.000 USD in pričakujete, da boste v naslednjih šestih letih prejeli nekaj dobička. Da bi ugotovili notranjo stopnjo donosa za to naložbo, uporabite to formulo:

=XIRR(A2:A8, B2:B8)

Pri čemer so A2:A8 denarni tokovi, B2:B8 pa datumi, ki ustrezajo denarnim tokovom:

Da bi ocenili donosnost te naložbe, primerjajte donosnost XIRR z donosnostjo vašega podjetja tehtani povprečni stroški kapitala ali mejna obrestna mera Če je stopnja donosa višja od stroškov kapitala, se projekt lahko šteje za dobro naložbo.

Ko primerjate več naložbenih možnosti, ne pozabite, da je predvidena stopnja donosa le eden od dejavnikov, ki jih morate oceniti, preden se odločite. Za več informacij glejte Kaj je interna stopnja donosa (IRR)?

Popolna oblika Excelove funkcije XIRR

Če veste, kakšen donos pričakujete od te ali one naložbe, lahko svoje pričakovanje uporabite kot ugibanje. To je še posebej koristno, kadar očitno pravilna formula XIRR vrže napako #NUM!

Pri spodaj prikazanem vnosu podatkov formula XIRR brez ugibanja vrne napako:

=XIRR(A2:A7, B2:B7)

Predvidena stopnja donosa (-20 %), ki je bila določena v uganiti argument pomaga Excelu priti do rezultata:

=XIRR(A2:A7, B2:B7, -20%)

Kako izračunati XIRR za mesečne denarne tokove

Za začetek si zapomnite naslednje - ne glede na denarne tokove, ki jih izračunavate, Excelova funkcija XIRR ustvari letna stopnja donosa .

Da bi se o tem prepričali, poiščimo IRR za isto serijo denarnih tokov (A2:A8), ki se pojavljajo mesečno in letno (datumi so v B2:B8):

=XIRR(A2:A8, B2:B8)

Kot lahko vidite na spodnji sliki zaslona, se interna stopnja donosnosti poveča s 7,68 % pri letnih denarnih tokovih na približno 145 % pri mesečnih denarnih tokovih! Razlika se zdi prevelika, da bi jo lahko upravičil samo dejavnik časovne vrednosti denarja:

Za določitev približnega mesečna XIRR , lahko uporabite spodnji izračun, kjer je E1 rezultat običajne formule XIRR:

=(1+E1)^(1/12)-1

Lahko pa v enačbo neposredno vnesete stopnjo XIRR:

=(1+XIRR(A2:A8,B2:B8))^(1/12)-1

Za dodatno preverjanje uporabimo funkcijo IRR za iste denarne tokove. Upoštevajte, da bo IRR prav tako izračunala približno stopnjo, ker predpostavlja, da so vsa časovna obdobja enaka:

=IRR(A2:A8)

Na podlagi teh izračunov dobimo mesečno stopnjo XIRR v višini 7,77 %, ki je zelo blizu 7,68 %, izračunani s formulo IRR:

Zaključek : če iščete letno IRR za mesečne denarne tokove, uporabite funkcijo XIRR v njeni čisti obliki; če želite dobiti mesečno IRR, uporabite zgoraj opisano prilagoditev.

Excelova predloga XIRR

Če želite hitro pridobiti notranjo stopnjo donosa za različne projekte, lahko ustvarite vsestranski kalkulator XIRR za Excel:

1. Denarne tokove in datume vnesite v dva posamezna stolpca (A in B v tem primeru).
2. Ustvarite dva dinamično definirana območja z imeni Denarni_toki in . Datumi . Tehnično gledano so to poimenovane formule:

   Denarni_toki:

   =OFFSET(Sheet1!$A$2,0,0,COUNT(Sheet1!$A:$A),1)

   Datumi:

   =OFFSET(List1!$B$2,0,0,COUNT(List1!$B:$B),1)

   Kje: List1 je ime delovnega lista, A2 je prvi denarni tok, B2 pa prvi datum.

   Za podrobna navodila po korakih glejte Kako ustvariti dinamično poimenovano območje v Excelu.

3. V formulo XIRR vnesite dinamično opredeljena imena, ki ste jih ustvarili:

=XIRR(Denarni_toki, Datumi)

Zdaj lahko dodate ali odstranite poljubno število denarnih tokov in vaša dinamična formula XIRR se bo ustrezno preračunala:

XIRR proti IRR v Excelu

Glavna razlika med funkcijama Excel XIRR in IRR je naslednja:

• IRR predpostavlja, da so vsa obdobja v nizu denarnih tokov enaka. S to funkcijo najdete notranjo stopnjo donosnosti za periodične denarne tokove, kot so mesečni, četrtletni ali letni.
• XIRR vam omogoča, da vsakemu posameznemu denarnemu toku pripišete datum. To funkcijo torej uporabite za izračun IRR za denarne tokove, ki niso nujno periodični.

Če poznate natančne datume izplačil, je na splošno priporočljivo uporabiti XIRR, saj zagotavlja večjo natančnost izračuna.

Primerjajmo rezultate IRR in XIRR za iste denarne tokove:

Če se vsa plačila izvedejo ob v rednih časovnih presledkih , funkciji dajeta zelo podobne rezultate:

Če je časovna razporeditev denarnih tokov neenakopravno , je razlika med rezultati precej velika:

XIRR in XNPV v Excelu

XIRR je tesno povezana s funkcijo XNPV, saj je rezultat funkcije XIRR diskontna stopnja, ki vodi do ničelne neto sedanje vrednosti. Z drugimi besedami, XIRR je XNPV = 0. Naslednji primer prikazuje povezavo med XIRR in XNPV v programu Excel.

Recimo, da razmišljate o neki naložbeni priložnosti in želite preučiti neto sedanjo vrednost in notranjo stopnjo donosa te naložbe.

Z denarnimi tokovi v A2:A5, datumi v B2:B5 in diskontno stopnjo v E1 boste z naslednjo formulo XNPV dobili neto sedanjo vrednost prihodnjih denarnih tokov:

=XNPV(E1, A2:A5, B2:B5)

Pozitivna neto sedanja vrednost pomeni, da je projekt donosen:

Zdaj poiščimo diskontno stopnjo, s katero bo neto sedanja vrednost enaka nič. Za to uporabimo funkcijo XIRR:

=XIRR(A2:A5, B2:B5)

Če želite preveriti, ali obrestna mera, izračunana z metodo XIRR, res vodi do ničelne neto sedanje vrednosti, jo vstavite v stopnja argumenta vaše formule XNPV:

=XNPV(E4, A2:A5, B2:B5)

Ali pa vgradite celotno funkcijo XIRR:

=XNPV(XIRR(A2:A5, B2:B5), A2:A5, B2:B5)

Ja, vrednost XNPV, zaokrožena na dve decimalni mesti, je enaka nič:

Če želite prikazati natančno vrednost NPV, izberite prikaz več decimalnih mest ali uporabite znanstveni format za celico XNPV. Tako bo rezultat podoben temu:

Če ne poznate znanstvenega zapisa, izvedite naslednji izračun za pretvorbo v decimalno število:

1.11E-05 = 1.11*10^-5 = 0.0000111

Excelova funkcija XIRR ne deluje

Če ste naleteli na težavo s funkcijo XNPV v Excelu, so spodaj navedene glavne točke, ki jih je treba preveriti.

#NUM! napaka

Napaka #NUM se lahko pojavi zaradi naslednjih razlogov:

• Spletna stran vrednosti in . datumi razponi so različno dolgi (različno število stolpcev ali vrstic).
• Spletna stran vrednosti polje ne vsebuje vsaj ene pozitivne in ene negativne vrednosti.
• Vsak naslednji datum je zgodnejši od prvega datuma.
• Po 100 iteracijah ni mogoče najti rezultata. V tem primeru poskusite z drugo domnevo.

#VALUE! napaka

Napaka #VALUE je lahko posledica naslednjih dejavnikov:

• Katera koli od priloženih vrednosti so neštevilčni.
• Nekaterih navedenih datumov ni mogoče prepoznati kot veljavnih datumov programa Excel.

Če si želite natančneje ogledati formule, obravnavane v tem učbeniku, si lahko spodaj prenesete naš vzorčni delovni zvezek. Zahvaljujem se vam za branje in upam, da se naslednji teden vidimo na našem blogu!

Praktični delovni zvezek za prenos

Excelova predloga XIRR (.xlsx datoteka)