Tutorial ini menunjukkan cara menggunakan XIRR di Excel untuk menghitung tingkat pengembalian internal (IRR) untuk arus kas dengan waktu yang tidak teratur dan cara membuat kalkulator XIRR Anda sendiri.

Ketika Anda dihadapkan pada keputusan yang padat modal, menghitung tingkat pengembalian internal adalah hal yang diinginkan karena memungkinkan Anda membandingkan hasil yang diproyeksikan untuk investasi yang berbeda dan memberikan dasar kuantitatif untuk membuat keputusan.

Dalam tutorial kami sebelumnya, kami melihat cara menghitung tingkat pengembalian internal dengan fungsi IRR Excel. Metode itu cepat dan mudah, tetapi memiliki batasan penting - fungsi IRR mengasumsikan bahwa semua arus kas terjadi pada interval waktu yang sama seperti bulanan atau tahunan. Dalam situasi kehidupan nyata, bagaimanapun, arus kas masuk dan keluar sering terjadi pada interval yang tidak teratur.Untungnya, Microsoft Excel memiliki fungsi lain untuk menemukan IRR dalam kasus seperti itu, dan tutorial ini akan mengajarkan Anda cara menggunakannya.

Fungsi XIRR di Excel

Fungsi Excel XIRR mengembalikan tingkat pengembalian internal untuk serangkaian arus kas yang mungkin atau mungkin tidak periodik.

Fungsi ini diperkenalkan di Excel 2007 dan tersedia di semua versi Excel 2010, Excel 2013, Excel 2016, Excel 2019, dan Excel untuk Office 365 yang lebih baru.

Sintaks fungsi XIRR adalah sebagai berikut:

Di mana:

• Nilai-nilai (wajib) - larik atau rentang sel yang mewakili serangkaian arus masuk dan arus keluar.
• Tanggal (wajib) - tanggal yang berhubungan dengan arus kas. Tanggal dapat terjadi dalam urutan apa pun, tetapi tanggal investasi awal harus menjadi yang pertama dalam array.
• Tebak (opsional) - IRR yang diharapkan diberikan sebagai persentase atau angka desimal. Jika dihilangkan, Excel menggunakan tingkat default 0,1 (10%).

Misalnya, untuk menghitung IRR untuk rangkaian arus kas di A2:A5 dan tanggal di B2:B5, Anda akan menggunakan rumus ini:

=XIRR(A2:A5, B2:B5)

Tip. Agar hasilnya ditampilkan dengan benar, pastikan bahwa Persentase format diatur untuk sel formula.

6 hal yang harus Anda ketahui tentang fungsi XIRR

Catatan berikut ini akan membantu Anda lebih memahami mekanisme bagian dalam fungsi XIRR dan menggunakannya dalam lembar kerja Anda secara paling efisien.

1. XIRR di Excel dirancang untuk menghitung tingkat pengembalian internal untuk arus kas dengan waktu yang tidak sama. Untuk arus kas periodik dengan tanggal pembayaran pasti tidak diketahui, Anda dapat menggunakan fungsi IRR.
2. Kisaran nilai harus mengandung sekurang-kurangnya satu nilai positif (pendapatan) dan satu nilai negatif (pembayaran keluar).
3. Jika nilai pertama adalah pengeluaran (investasi awal), maka harus diwakili oleh angka negatif. Investasi awal tidak didiskontokan; pembayaran selanjutnya dibawa kembali ke tanggal arus kas pertama dan didiskontokan berdasarkan tahun 365 hari.
4. Semua tanggal dipotong menjadi bilangan bulat, yang berarti bahwa bagian pecahan dari tanggal yang mewakili waktu dihilangkan.
5. Tanggal harus berupa tanggal Excel yang valid yang dimasukkan sebagai referensi ke sel yang berisi tanggal atau hasil rumus seperti fungsi DATE. Jika tanggal dimasukkan dalam format teks, masalah bisa terjadi.
6. XIRR di Excel selalu mengembalikan IRR yang disetahunkan bahkan ketika menghitung arus kas bulanan atau mingguan.

Perhitungan XIRR di Excel

Fungsi XIRR di Excel menggunakan pendekatan trial and error untuk menemukan tingkat yang memenuhi persamaan ini:

Di mana:

• P - arus kas (pembayaran)
• d - tanggal
• i - nomor periode
• n - periode total

Dimulai dengan tebakan jika disediakan atau dengan default 10% jika tidak, Excel melewati iterasi untuk sampai pada hasil dengan akurasi 0.000001%. Jika setelah 100 upaya tingkat akurat tidak ditemukan, kesalahan #NUM! dikembalikan.

Untuk memeriksa validitas persamaan ini, mari kita uji terhadap hasil rumus XIRR. Untuk menyederhanakan perhitungan kita, kita akan menggunakan rumus array berikut (harap diingat bahwa rumus array apa pun harus diselesaikan dengan menekan Ctrl + Shift + Enter ):

=SUM(A2:A5/((1+$E$1)^((B2:B5-$B$2)/365)))

Di mana:

• A2:A5 adalah arus kas
• B2:B5 adalah tanggal
• E1 adalah tingkat yang dikembalikan oleh XIRR

Seperti yang ditunjukkan dalam tangkapan layar di bawah ini, hasilnya sangat mendekati nol. Q.E.D. :)

Cara menghitung XIRR di Excel - contoh rumus

Di bawah ini adalah beberapa contoh yang menunjukkan penggunaan umum fungsi XIRR di Excel.

Rumus dasar XIRR di Excel

Misalkan Anda menginvestasikan $1.000 pada tahun 2017 dan berharap untuk menerima sejumlah keuntungan dalam 6 tahun ke depan. Untuk menemukan tingkat pengembalian internal untuk investasi ini, gunakan rumus ini:

=XIRR(A2:A8, B2:B8)

Di mana A2:A8 adalah arus kas dan B2:B8 adalah tanggal yang sesuai dengan arus kas:

Untuk menilai profitabilitas investasi ini, bandingkan output XIRR dengan biaya modal rata-rata tertimbang atau tingkat rintangan Jika tingkat pengembalian lebih tinggi dari biaya modal, proyek dapat dianggap sebagai investasi yang baik.

Ketika membandingkan beberapa pilihan investasi, harap diingat bahwa tingkat pengembalian yang diproyeksikan hanyalah salah satu faktor yang harus Anda perkirakan sebelum membuat keputusan. Untuk informasi lebih lanjut, silakan lihat Apa itu tingkat pengembalian internal (IRR)?

Bentuk lengkap fungsi Excel XIRR

Jika Anda tahu jenis pengembalian yang Anda harapkan dari investasi ini atau itu, Anda bisa menggunakan ekspektasi Anda sebagai tebakan. Ini sangat membantu ketika rumus XIRR yang jelas-jelas benar menghasilkan kesalahan #NUM!

Untuk input data yang ditunjukkan di bawah ini, rumus XIRR tanpa tebakan menghasilkan error:

=XIRR(A2:A7, B2:B7)

Tingkat pengembalian yang diantisipasi (-20%) dimasukkan ke dalam tebak argumen membantu Excel sampai pada hasilnya:

=XIRR(A2:A7, B2:B7, -20%)

Cara menghitung XIRR untuk arus kas bulanan

Sebagai permulaan, harap ingat ini - apa pun arus kas yang Anda hitung, fungsi Excel XIRR menghasilkan tingkat pengembalian tahunan .

Untuk memastikan hal ini, mari kita cari IRR untuk rangkaian arus kas yang sama (A2:A8) yang terjadi setiap bulan dan setiap tahun (tanggalnya ada di B2:B8):

=XIRR(A2:A8, B2:B8)

Seperti yang dapat Anda lihat pada tangkapan layar di bawah ini, IRR berubah dari 7,68% dalam kasus arus kas tahunan menjadi sekitar 145% untuk arus kas bulanan! Perbedaannya tampaknya terlalu tinggi untuk dibenarkan oleh faktor nilai waktu uang saja:

Untuk menemukan perkiraan XIRR bulanan Anda dapat menggunakan perhitungan di bawah ini, di mana E1 adalah hasil dari rumus XIRR biasa:

=(1+E1)^(1/12)-1

Atau Anda bisa menyematkan XIRR secara langsung dalam persamaan:

=(1+XIRR(A2:A8,B2:B8))^(1/12)-1

Sebagai pemeriksaan tambahan, mari kita gunakan fungsi IRR pada arus kas yang sama. Harap diingat bahwa IRR juga akan menghitung tingkat perkiraan karena mengasumsikan semua periode waktu sama:

=IRR(A2:A8)

Sebagai hasil dari perhitungan ini, kami mendapatkan XIRR bulanan sebesar 7,77%, yang sangat dekat dengan 7,68% yang dihasilkan oleh rumus IRR:

Kesimpulan Jika Anda mencari IRR tahunan untuk arus kas bulanan, gunakan fungsi XIRR dalam bentuk murni; untuk mendapatkan IRR bulanan, terapkan penyesuaian yang dijelaskan di atas.

Templat XIRR Excel

Untuk mendapatkan tingkat pengembalian internal dengan cepat untuk berbagai proyek, Anda dapat membuat kalkulator XIRR serbaguna untuk Excel. Begini caranya:

1. Masukkan arus kas dan tanggal dalam dua kolom individual (A dan B dalam contoh ini).
2. Buat dua dynamic defined range, bernama Arus_Kas dan Tanggal Secara teknis, itu akan dinamai formula:

   Cash_flows:

   =OFFSET(Sheet1!$A$2,0,0,0,COUNT(Sheet1!$A:$A),1)

   Tanggal:

   =OFFSET(Sheet1!$B$2,0,0,0,COUNT(Sheet1!$B:$B),1)

   Di mana Sheet1 adalah nama lembar kerja Anda, A2 adalah arus kas pertama, dan B2 adalah tanggal pertama.

   Untuk petunjuk langkah demi langkah mendetail, silakan lihat Cara membuat rentang bernama dinamis di Excel.

3. Berikan nama-nama dinamis yang telah Anda buat ke rumus XIRR:

=XIRR(Arus_Kas, Tanggal)

Selesai! Anda sekarang dapat menambahkan atau menghapus arus kas sebanyak yang Anda inginkan, dan rumus XIRR dinamis Anda akan menghitung ulang sesuai dengan itu:

XIRR vs IRR di Excel

Perbedaan utama antara fungsi Excel XIRR dan IRR adalah ini:

• IRR Anda menggunakan fungsi ini untuk menemukan tingkat pengembalian internal untuk arus kas periodik seperti bulanan, triwulanan atau tahunan.
• XIRR memungkinkan Anda untuk menetapkan tanggal untuk setiap arus kas individu. Jadi, gunakan fungsi ini untuk menghitung IRR untuk arus kas yang tidak harus periodik.

Umumnya, jika Anda mengetahui tanggal pasti pembayaran, disarankan untuk menggunakan XIRR karena memberikan akurasi perhitungan yang lebih baik.

Sebagai contoh, mari kita bandingkan hasil IRR dan XIRR untuk arus kas yang sama:

Jika semua pembayaran terjadi pada interval reguler , fungsi-fungsi tersebut memberikan hasil yang sangat dekat:

Jika waktu arus kas adalah tidak setara perbedaan di antara hasil-hasil tersebut cukup signifikan:

XIRR dan XNPV di Excel

XIRR terkait erat dengan fungsi XNPV karena hasil XIRR adalah tingkat diskonto yang mengarah ke nilai sekarang bersih nol. Dengan kata lain, XIRR adalah XNPV = 0. Contoh berikut menunjukkan hubungan antara XIRR dan XNPV di Excel.

Katakanlah Anda sedang mempertimbangkan beberapa peluang investasi dan ingin memeriksa nilai sekarang bersih dan tingkat pengembalian internal atas investasi ini.

Dengan arus kas di A2: A5, tanggal di B2: B5 dan tingkat diskonto di E1, rumus XNPV berikut akan memberi Anda nilai sekarang bersih dari arus kas masa depan:

=XNPV(E1, A2:A5, B2:B5)

NPV positif menunjukkan bahwa proyek tersebut menguntungkan:

Sekarang, mari kita cari tingkat diskonto yang akan membuat nilai sekarang bersih menjadi nol. Untuk ini, kita menggunakan fungsi XIRR:

=XIRR(A2:A5, B2:B5)

Untuk memeriksa apakah tingkat yang dihasilkan oleh XIRR benar-benar mengarah ke NPV nol, masukkan ke dalam tingkat argumen dari rumus XNPV Anda:

=XNPV(E4, A2:A5, B2:B5)

Atau menyematkan seluruh fungsi XIRR:

=XNPV(XIRR(A2:A5, B2:B5), A2:A5, B2:B5)

Ya, XNPV yang dibulatkan ke 2 tempat desimal memang sama dengan nol:

Untuk menampilkan nilai NPV yang tepat, pilih untuk menampilkan lebih banyak tempat desimal atau terapkan format Ilmiah ke sel XNPV. Itu akan menghasilkan hasil yang mirip dengan ini:

Jika Anda tidak terbiasa dengan notasi ilmiah, lakukan kalkulasi berikut ini untuk mengubahnya menjadi angka desimal:

1.11E-05 = 1.11*10^-5 = 0.0000111

Fungsi Excel XIRR tidak berfungsi

Jika Anda mengalami masalah dengan fungsi XNPV di Excel, di bawah ini adalah poin-poin utama untuk diperiksa.

#NUM! kesalahan

Kesalahan #NUM bisa terjadi karena alasan-alasan berikut ini:

• The nilai dan tanggal rentang memiliki panjang yang berbeda (jumlah kolom atau baris yang berbeda).
• The nilai array tidak mengandung setidaknya satu nilai positif dan satu nilai negatif.
• Tanggal-tanggal berikutnya lebih awal daripada tanggal pertama.
• Sebuah hasil tidak ditemukan setelah 100 iterasi. Dalam hal ini, cobalah tebakan yang berbeda.

#VALUE! kesalahan

Error #VALUE bisa disebabkan oleh hal-hal berikut ini:

• Salah satu dari yang disediakan nilai adalah non-numerik.
• Sebagian tanggal yang diberikan tidak bisa diidentifikasi sebagai tanggal Excel yang valid.

Untuk melihat lebih dekat rumus-rumus yang dibahas dalam tutorial ini, Anda dipersilakan untuk mengunduh buku kerja sampel kami di bawah ini. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

Buku kerja latihan untuk diunduh

Templat XIRR Excel (file .xlsx)