Dnes sa pozrieme na to, ako používať VLOOKUP v programe Excel s mnohými podrobnými príkladmi krok za krokom. Naučíte sa, ako VLOOKUP z iného hárku a iného zošita, vyhľadávať pomocou zástupných znakov a mnoho ďalšieho.

Týmto článkom začíname seriál venovaný funkcii VLOOKUP, jednej z najužitočnejších funkcií programu Excel a zároveň jednej z najzložitejších a najmenej zrozumiteľných. Budeme sa snažiť vysvetliť základy veľmi jednoduchým jazykom, aby sme neskúseným používateľom čo najviac uľahčili učenie. Budeme tiež uvádzať príklady vzorcov, ktoré pokrývajú najtypickejšie spôsoby použitia funkcie VLOOKUP v programe Excel, a pokúsime sasú poučné aj zábavné.

Funkcia Excel VLOOKUP

Čo je to VLOOKUP? Na začiatok treba povedať, že je to funkcia programu Excel :) Čo robí? Vyhľadá zadanú hodnotu a vráti zodpovedajúcu hodnotu z iného stĺpca. Technicky povedané, funkcia VLOOKUP vyhľadá hodnotu v prvom stĺpci daného rozsahu a vráti hodnotu v rovnakom riadku z iného stĺpca.

Pri bežnom používaní VLOOKUP v programe Excel prehľadáva súbor údajov na základe jedinečného identifikátora a prináša časť informácií spojených s týmto jedinečným identifikátorom.

Písmeno "V" znamená "vertikálny" a používa sa na odlíšenie funkcie VLOOKUP od funkcie HLOOKUP, ktorá vyhľadáva hodnotu v riadku a nie v stĺpci (H znamená "horizontálny").

Táto funkcia je k dispozícii vo všetkých verziách programu Excel 365 až Excel 2007.

Tip. V aplikáciách Excel 365 a Excel 2021 môžete používať funkciu XLOOKUP, ktorá je flexibilnejším a výkonnejším nástupcom funkcie VLOOKUP.

Syntax VLOOKUP

Syntax funkcie VLOOKUP je nasledujúca:

Kde:

• Lookup_value (povinné) - je hodnota, ktorá sa má vyhľadať.

  Môže to byť hodnota (číslo, dátum alebo text), odkaz na bunku (odkaz na bunku obsahujúcu vyhľadávaciu hodnotu) alebo hodnota vrátená inou funkciou. Na rozdiel od čísel a odkazov na bunky by textové hodnoty mali byť vždy uzavreté v dvojitých úvodzovkách.

• Table_array (povinné) - je rozsah buniek, v ktorých sa má hľadať hodnota vyhľadávania a z ktorých sa má získať zhoda. Funkcia VLOOKUP vždy hľadá v prvom stĺpci tabuľkového poľa , ktoré môžu obsahovať rôzne textové hodnoty, čísla, dátumy a logické hodnoty.
• Col_index_num (povinné) - je číslo stĺpca, z ktorého sa má vrátiť hodnota. Počítanie sa začína od stĺpca, ktorý je v poli tabuľky najviac vľavo, čo je 1.
• Range_lookup (nepovinné) - určuje, či sa má hľadať približná alebo presná zhoda:
  • TRUE alebo vynechať (predvolené) - približná zhoda. Ak sa nenájde presná zhoda, vzorec hľadá najväčšiu hodnotu, ktorá je menšia ako hodnota vyhľadávania. Vyžaduje zoradenie stĺpca vyhľadávania vzostupne.
  • FALSE - presná zhoda. Vzorec hľadá hodnotu, ktorá sa presne rovná hodnote vyhľadávania. Ak sa presná zhoda nenájde, vráti sa hodnota #N/A.

Základný vzorec VLOOKUP

Tu je príklad vzorca Excel VLOOKUP v jeho najjednoduchšej podobe. Pozrite sa na nasledujúci vzorec a pokúste sa ho "preložiť" do slovenčiny:

=VLOOKUP("lev", A2:B11, 2, FALSE)

• 1. argument ( lookup_value ) jasne naznačuje, že vzorec hľadá slovo "lev".
• Druhý argument ( table_array ) je A2:B11. Majúc na pamäti, že vyhľadávanie sa vykonáva v stĺpci najviac vľavo, môžete vyššie uvedený vzorec čítať trochu ďalej: vyhľadajte "lev" v rozsahu A2:A11. Zatiaľ je to dobré, však?
• Tretí argument col_index_num je 2. To znamená, že chceme vrátiť zhodnú hodnotu zo stĺpca B, ktorý je druhý v tabuľkovom poli.
• Štvrtý argument range_lookup je FALSE, čo znamená, že hľadáme presnú zhodu.

Po stanovení všetkých argumentov by ste nemali mať problém s načítaním celého vzorca: vyhľadajte "lev" v A2:A11, nájdite presnú zhodu a vráťte hodnotu zo stĺpca B v tom istom riadku.

Pre väčšie pohodlie môžete do niektorej bunky, napríklad E1, zadať hodnotu, ktorá vás zaujíma, nahradiť "natvrdo" zadaný text odkazom na bunku a vzorec vyhľadá akúkoľvek hodnotu, ktorú zadáte do E1:

=VLOOKUP(E1, A2:B11, 2, FALSE)

Zostáva niečo nejasné? Skúste sa na to pozrieť takto:

Ako vykonať Vlookup v programe Excel

Pri používaní vzorcov VLOOKUP v reálnych pracovných listoch platí toto hlavné pravidlo: pole uzamykacích tabuliek s absolútnymi odkazmi na bunky (napríklad $A$2:$C$11), aby sa zabránilo ich zmene pri kopírovaní vzorca do iných buniek.

Stránka vyhľadávacia hodnota vo väčšine prípadov by mal byť relatívny odkaz (ako E2) alebo môžete uzamknúť iba súradnicu stĺpca ($E2). Keď sa vzorec skopíruje do stĺpca, odkaz sa automaticky prispôsobí pre každý riadok.

Aby ste videli, ako to funguje v praxi, vezmite do úvahy nasledujúci príklad. Do našej vzorovej tabuľky sme pridali ešte jeden stĺpec, ktorý zoraďuje zvieratá podľa rýchlosti (stĺpec A), a chceme nájsť 1., 5. a 10. najrýchlejšieho šprintéra na svete. Na tento účel zadajte do niektorých buniek (E2:E4 na obrázku nižšie) vyhľadávacie rebríčky a použite nasledujúce vzorce:

Vytiahnutie názvov zvierat zo stĺpca B:

=VLOOKUP($E2, $A$2:$C$11, 2, FALSE)

Výber rýchlosti zo stĺpca C:

=VLOOKUP($E2, $A$2:$C$11, 3, FALSE)

Zadajte vyššie uvedené vzorce do buniek F2 a G2, vyberte tieto bunky a pretiahnite vzorce do nasledujúcich riadkov:

Ak preskúmate vzorec v nižšom riadku, zistíte, že odkaz na vyhľadávaciu hodnotu sa pre tento konkrétny riadok upravil, zatiaľ čo pole tabuľky sa nezmenilo:

Nižšie nájdete niekoľko ďalších užitočných tipov, ktoré vám ušetria veľa bolesti hlavy a času na riešenie problémov.

Excel VLOOKUP - 5 vecí, ktoré si treba zapamätať!

1. Funkcia VLOOKUP sa nemôže pozrieť na svoju ľavú stranu Vždy sa vyhľadáva v krajný ľavý stĺpec tabuľkového poľa a vráti hodnotu zo stĺpca vpravo. Ak potrebujete vytiahnuť hodnoty zľava, použite kombináciu INDEX MATCH (alebo INDEX XMATCH v Exceli 365), ktorá sa nemôže starať o umiestnenie vyhľadávacích a návratových stĺpcov.
2. Pri funkcii VLOOKUP sa nerozlišujú veľké a malé písmená , čo znamená, že veľké a malé písmená sa považujú za rovnocenné. Ak chcete rozlišovať veľkosť písmen, použite vzorce VLOOKUP, ktoré rozlišujú veľkosť písmen.
3. Nezabudnite na dôležitosť posledného parametra. Pre približnú zhodu použite TRUE a pre presnú zhodu FALSE. Všetky podrobnosti nájdete v časti VLOOKUP TRUE vs. FALSE.
4. Pri hľadaní približnej zhody sa uistite, že údaje v stĺpci vyhľadávania sú zoradené vzostupne.
5. Ak sa hodnota vyhľadávania nenájde, vráti sa chyba #N/A. Informácie o ďalších chybách nájdete v časti Prečo Excel VLOOKUP nefunguje.

Príklady Excel VLOOKUP

Dúfam, že vertikálne vyhľadávanie vám začína byť trochu známejšie. Aby ste si svoje vedomosti upevnili, vytvorme si niekoľko ďalších vzorcov VLOOKUP.

Ako Vlookup z iného hárku v programe Excel

V praxi sa funkcia Excel VLOOKUP používa len zriedkavo s údajmi v tom istom hárku. Najčastejšie budete musieť vytiahnuť zodpovedajúce údaje z iného hárku.

Ak chcete vyhľadávať z iného hárku programu Excel, vložte názov hárku, za ktorým nasleduje výkričník, do table_array napríklad na vyhľadávanie v rozsahu A2:B10 na hárku 2 použite tento vzorec:

=VLOOKUP("Product1", Sheet2!A2:B10, 2)

Samozrejme, nemusíte zadávať názov hárku ručne. Jednoducho začnite písať vzorec a keď príde na table_array prepnite na hárok vyhľadávania a vyberte rozsah pomocou myši.

Takto môžete napríklad vyhľadať hodnotu A2 v rozsahu A2:A9 na Ceny a vrátiť zodpovedajúcu hodnotu zo stĺpca C:

=VLOOKUP(A2, Ceny!$A$2:$C$9, 3, FALSE)

Poznámky:

• Ak názov tabuľky obsahuje medzery alebo iné ako abecedné znaky , musí byť uzavretý v jednoduchých úvodzovkách, napr. "Cenník"!$A$2:$C$9.
• Ak použijete vzorec VLOOKUP pre viacero buniek, nezabudnite lock table_array so znakom $, napríklad $A$2:$C$9.

Ako Vlookup z iného zošita v programe Excel

Ak chcete Vlookup z iného zošita programu Excel, vložte názov zošita uzavretý v hranatých zátvorkách pred názov pracovného hárka.

Tu je napríklad vzorec na vyhľadanie hodnoty A2 na liste s názvom Ceny v Price_List.xlsx pracovný zošit:

=VLOOKUP(A2, [Price_List.xlsx]Ceny!$A$2:$C$9, 3, FALSE)

Ak názov zošita alebo názov pracovného hárka obsahuje medzery alebo iné ako abecedné znaky, mali by ste ich uzavrieť do jednoduchých úvodzoviek takto:

=VLOOKUP(A2, '[Cenník.xlsx]Ceny'!$A$2:$C$9, 3, FALSE)

Najjednoduchší spôsob, ako vytvoriť vzorec VLOOKUP, ktorý odkazuje na iný zošit, je tento:

1. Otvorte oba súbory.
2. Začnite písať vzorec, prepnite sa do druhého zošita a myšou vyberte tabuľkové pole.
3. Zadajte zostávajúce argumenty a stlačením tlačidla Enter dokončite vzorec.

Výsledok bude vyzerať podobne ako na obrázku nižšie:

Keď zavrieť súbor s vyhľadávacou tabuľkou, vzorec VLOOKUP bude naďalej fungovať, ale teraz sa zobrazí celá cesta k zatvorenému zošitu:

Ďalšie informácie nájdete v časti Ako sa odvolať na iný hárok alebo zošit programu Excel.

Ako vyhľadávať z pomenovaného rozsahu v inom hárku

V prípade, že plánujete používať ten istý rozsah vyhľadávania vo viacerých vzorcoch, môžete preň vytvoriť pomenovaný rozsah a zadať názov priamo do table_array argument.

Ak chcete vytvoriť pomenovaný rozsah, jednoducho vyberte bunky a zadajte požadovaný názov do Názov vľavo od panela vzorcov. Podrobný postup nájdete v časti Ako pomenovať rozsah v programe Excel.

Pre tento príklad sme dali názov Ceny_2020 do buniek údajov (A2:C9) v hárku vyhľadávania a získate tento kompaktný vzorec:

=VLOOKUP(A2, Prices_2020, 3, FALSE)

Väčšina názvov v programe Excel sa vzťahuje na celý zošit , takže pri použití pomenovaných rozsahov nemusíte zadávať názov pracovného hárka.

Ak je pomenovaný rozsah v ďalší zošit , vložte názov zošita pred názov rozsahu, napríklad:

=VLOOKUP(A2, 'Cenník.xlsx'!Ceny_2020, 3, FALSE)

Takéto vzorce sú oveľa zrozumiteľnejšie, však? Okrem toho môže byť použitie pomenovaných rozsahov dobrou alternatívou k absolútnym odkazom. Keďže pomenovaný rozsah sa nemení, môžete si byť istí, že vaše tabuľkové pole zostane uzamknuté bez ohľadu na to, kam sa vzorec presunie alebo skopíruje.

Ak ste previedli rozsah vyhľadávania na plne funkčnú tabuľku programu Excel, potom môžete vykonať Vlookup na základe názvu tabuľky, napr. Cenová_tabuľka v nasledujúcom vzorci:

=VLOOKUP(A2, Cenová_tabuľka, 3, FALSE)

Referencie na tabuľky, nazývané aj štruktúrované referencie, sú odolné a imúnne voči mnohým manipuláciám s údajmi. Môžete napríklad odstrániť alebo pridať nové riadky do vyhľadávacej tabuľky bez toho, aby ste sa museli obávať aktualizácie referencií.

Používanie zástupných znakov vo vzorci VLOOKUP

Podobne ako mnohé iné vzorce, aj funkcia VLOOKUP aplikácie Excel akceptuje nasledujúce zástupné znaky:

• Otáznik (?) na porovnanie s ľubovoľným jedným znakom.
• Hviezdička (*) na porovnanie ľubovoľnej postupnosti znakov.

Zástupné znaky sú v mnohých situáciách naozaj užitočné:

• Keď si nepamätáte presný text, ktorý hľadáte.
• Ak hľadáte textový reťazec, ktorý je súčasťou obsahu bunky.
• Keď stĺpec vyhľadávania obsahuje úvodné alebo koncové medzery. V takom prípade si môžete lámať hlavu a snažiť sa zistiť, prečo bežný vzorec nefunguje.

Príklad 1. Vyhľadajte text začínajúci alebo končiaci určitými znakmi

Predpokladajme, že chcete nájsť určitého zákazníka v nižšie uvedenej databáze. Nepamätáte si jeho priezvisko, ale ste si istí, že začína na "ack".

Ak chcete vrátiť priezvisko zo stĺpca A, použite nasledujúci vzorec Vlookup so zástupným znakom:

=VLOOKUP("ack*", $A$2:$B$10, 1, FALSE)

Ak chcete získať licenčný kľúč zo stĺpca B, použite tento kľúč (rozdiel je len v indexovom čísle stĺpca):

=VLOOKUP("ack*", $A$2:$B$10, 2, FALSE)

Môžete tiež zadať známu časť názvu do niektorej bunky, napríklad E1, a skombinovať zástupný znak s odkazom na bunku:

=VLOOKUP(E1& "*", $A$2:$B$10, 1, FALSE)

Na nasledujúcom obrázku sú zobrazené výsledky:

Nižšie je uvedených niekoľko ďalších vzorcov VLOOKUP so zástupnými znakmi.

Nájdite priezvisko končiace na "son":

=VLOOKUP("*son", $A$2:$B$10, 1, FALSE)

Získajte meno, ktoré sa začína na "joh" a končí na "son":

=VLOOKUP("joh*son", $A$2:$B$10, 1, FALSE)

Vytiahnite 5-miestne priezvisko:

=VLOOKUP("?????", $A$2:$B$10, 1, FALSE)

Príklad 2. Zástupný znak VLOOKUP na základe hodnoty bunky

Z predchádzajúceho príkladu už viete, že je možné spojiť ampersand (&) a odkaz na bunku a vytvoriť tak vyhľadávací reťazec. Ak chcete nájsť hodnotu, ktorá obsahuje daný znak (znaky) na ľubovoľnej pozícii, vložte ampersand pred a za odkaz na bunku.

Povedzme, že chcete získať názov zodpovedajúci určitému licenčnému kľúču, ale nepoznáte celý kľúč, iba niekoľko znakov. S kľúčmi v stĺpci A, názvami v stĺpci B a časťou cieľového kľúča v E1 môžete takto vykonať Vlookup so zástupným znakom:

Výpis kľúča:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 1, FALSE)

Výpis názvu:

=VLOOKUP("*"&E1& "*", $A$2:$B$10, 2, FALSE)

Poznámky:

• Aby vzorec VLOOKUP so zástupným znakom fungoval správne, použite presnú zhodu (posledný argument je FALSE).
• Ak sa nájde viac ako jedna zhoda, vráti sa prvá z nich .

VLOOKUP TRUE vs FALSE

A teraz je čas pozrieť sa bližšie na posledný argument funkcie Excel VLOOKUP. Hoci je voliteľný, je range_lookup V závislosti od toho, či vyberiete TRUE alebo FALSE, môže váš vzorec priniesť rôzne výsledky.

Excel VLOOKUP presná zhoda (FALSE)

Ak range_lookup je nastavená na FALSE, vzorec Vlookup hľadá hodnotu, ktorá sa presne rovná hodnote vyhľadávania. Ak sa nájdu dve alebo viac zhody, vráti sa 1. Ak sa presná zhoda nenájde, nastane chyba #N/A.

Excel VLOOKUP približná zhoda (TRUE)

Ak range_lookup je nastavená na TRUE alebo vynechaná (predvolené nastavenie), vzorec vyhľadá najbližšiu zhodu. Presnejšie, najprv hľadá presnú zhodu, a ak presnú zhodu nenájde, hľadá ďalšiu najväčšiu hodnotu, ktorá je menšia ako hodnota vyhľadávania.

Približná zhoda Vlookup funguje s nasledujúcimi výhradami:

• Stĺpec vyhľadávania musí byť zoradený v vzostupné poradie od najmenšej po najväčšiu, inak sa nemusí nájsť správna hodnota.
• Ak je hodnota vyhľadávania menšia ako najmenšia hodnota v poli vyhľadávania, vráti sa chyba #N/A.

Nasledujúce príklady vám pomôžu lepšie pochopiť rozdiel medzi presnou a približnou zhodou Vlookup a kedy je najlepšie použiť jednotlivé vzorce.

Príklad 1. Ako vykonať presnú zhodu Vlookup

Ak chcete vyhľadať presnú zhodu, stačí do posledného argumentu vložiť FALSE.

Pre tento príklad vezmeme tabuľku rýchlosti zvierat, vymeníme stĺpce a pokúsime sa nájsť zvieratá, ktoré dokážu bežať rýchlosťou 80, 50 a 30 míľ za hodinu. S vyhľadávacími hodnotami v D2, D3 a D4 zadajte do E2 nasledujúci vzorec a potom ho skopírujte do ďalších dvoch buniek:

=VLOOKUP(D2, $A$2:$B$12, 2, FALSE)

Ako vidíte, vzorec vráti hodnotu "Lion" v položke E3, pretože ich za hodinu prebehne presne 50. Pre ostatné dve hodnoty vyhľadávania sa presná zhoda nenájde a objavia sa chyby #N/A.

Príklad 2. Ako použiť Vlookup na približnú zhodu

Ak chcete vyhľadať približnú zhodu, musíte urobiť dve základné veci:

• Zoradiť prvý stĺpec table_array od najmenšieho po najväčší.
• Použite TRUE pre range_lookup argument alebo ho vynechať.

Zoradenie stĺpca vyhľadávania je veľmi dôležité, pretože funkcia VLOOKUP prestane vyhľadávať hneď, ako nájde blízku zhodu menšiu ako hodnota vyhľadávania. Ak údaje nie sú správne zoradené, môže sa stať, že budete mať naozaj čudné výsledky alebo množstvo chýb #N/A.

Pre našu vzorku údajov je približná zhoda vzorca Vlookup nasledovná:

=VLOOKUP(D2, $A$2:$B$12, 2, TRUE)

A vráti nasledujúce výsledky:

• Pre vyhľadávaciu hodnotu "80" sa vráti "Cheetah", pretože jeho rýchlosť (70) je najbližšia zhoda, ktorá je menšia ako vyhľadávacia hodnota.
• V prípade hodnoty vyhľadávania "50" sa vráti presná zhoda (Lion).
• V prípade hodnoty vyhľadávania "30" sa vráti chyba #N/A, pretože hodnota vyhľadávania je menšia ako najmenšia hodnota v stĺpci vyhľadávania.

Špeciálne nástroje pre Vlookup v programe Excel

VLOOKUP je nepochybne jednou z najvýkonnejších a najužitočnejších funkcií programu Excel, ale zároveň aj jednou z najzamotanejších. Aby krivka učenia nebola taká strmá a skúsenosti boli príjemnejšie, do nášho balíka Ultimate Suite for Excel sme zahrnuli niekoľko nástrojov, ktoré vám ušetria čas.

Sprievodca VLOOKUP - jednoduchý spôsob písania zložitých vzorcov

Interaktívny sprievodca VLOOKUP vás prevedie možnosťami konfigurácie, aby ste vytvorili dokonalý vzorec pre zadané kritériá. V závislosti od štruktúry údajov použije štandardnú funkciu VLOOKUP alebo vzorec INDEX MATCH, ktorý môže ťahať hodnoty zľava.

Ak chcete získať vzorec na mieru, musíte urobiť toto:

1. Spustite sprievodcu VLOOKUP.

1. Vyberte hlavnú tabuľku a vyhľadávaciu tabuľku.
2. Zadajte nasledujúce stĺpce (v mnohých prípadoch sa vyberú automaticky):
   • Kľúčový stĺpec - stĺpec v hlavnej tabuľke, ktorý obsahuje hodnoty, ktoré sa majú vyhľadať.
   • Stĺpec vyhľadávania - stĺpec, proti ktorému sa má pozerať.
   • Návratový stĺpec - stĺpec, z ktorého sa majú načítať hodnoty.
3. Kliknite na tlačidlo Vložte tlačidlo.

Nasledujúce príklady ukazujú sprievodcu v akcii.

Štandardné vyhľadávanie

Keď sa stĺpec vyhľadávania ( Zviera ) je najľavejší stĺpec v tabuľke vyhľadávania, vloží sa normálny vzorec VLOOKUP pre presnú zhodu:

Vlookup doľava

Keď sa stĺpec vyhľadávania ( Zviera ) sa nachádza na pravej strane stĺpca pre návrat ( Rýchlosť ), sprievodca vloží vzorec INDEX MATCH do Vlookup sprava doľava:

Extra bonus! Vďaka šikovnému použitiu odkazov na bunky možno vzorce kopírovať alebo presúvať do ľubovoľného stĺpca bez toho, aby ste museli aktualizovať odkazy.

Zlúčenie dvoch tabuliek - alternatíva programu Excel VLOOKUP bez vzorcov

Ak sú vaše súbory programu Excel nesmierne veľké a zložité, termín ukončenia projektu sa blíži a hľadáte niekoho, kto vám podá pomocnú ruku, vyskúšajte Sprievodcu zlúčením tabuliek.

Tento nástroj je našou vizuálnou a bezstresovou alternatívou funkcie VLOOKUP programu Excel, ktorá funguje týmto spôsobom:

1. Vyberte hlavný stôl.
2. Vyberte vyhľadávaciu tabuľku.
3. Ako jedinečný identifikátor (identifikátory) vyberte jeden alebo niekoľko spoločných stĺpcov.
4. Zadajte, ktoré stĺpce sa majú aktualizovať.
5. Voliteľne vyberte stĺpce, ktoré chcete pridať.
6. Nechajte Sprievodcovi zlúčením tabuliek niekoľko sekúnd na spracovanie... a užite si výsledky :)

To je spôsob, ako používať VLOOKUP v programe Excel na základnej úrovni. V ďalšej časti nášho návodu sa budeme venovať pokročilým príkladom VLOOKUP, ktoré vás naučia, ako VLOOKUP používať pri viacerých kritériách, vracať všetky zhody alebo N-ty výskyt, vykonávať dvojitý VLOOKUP, vyhľadávať vo viacerých hárkoch pomocou jedného vzorca a podobne. Ďakujem vám za prečítanie a dúfam, že sa uvidíme budúci týždeň!

Dostupné súbory na stiahnutie

Príklady vzorcov Excel VLOOKUP (.xlsx súbor)

14-dňová plne funkčná verzia balíka Ultimate Suite (.exe súbor)