Mendapatkan banyak error #N/A di lembar kerjamu dan ingin tahu apakah ada cara untuk menampilkan teks kustom sebagai gantinya? Formula IFNA adalah solusi yang kamu butuhkan.

Ketika rumus Excel tidak dapat mengidentifikasi atau menemukan sesuatu, ia melempar kesalahan # N / A. Untuk menangkap kesalahan seperti itu dan menggantinya dengan pesan yang ramah pengguna, Anda dapat menggunakan fungsi IFNA. Dengan kata lain, # N / A adalah cara Excel untuk mengatakan bahwa nilai yang Anda cari tidak ada dalam dataset yang direferensikan. IFNA adalah cara Anda menjebak dan menangani kesalahan itu.

Fungsi IFNA di Excel

Fungsi IFNA Excel dimaksudkan untuk menangkap dan menangani kesalahan # N / A. Jika rumus dievaluasi menjadi # N / A, IFNA menjebak kesalahan itu dan menggantinya dengan nilai kustom yang Anda tentukan; jika tidak, mengembalikan hasil normal dari rumus.

Sintaks IFNA

Sintaks fungsi IFNA adalah sebagai berikut:

Di mana:

Nilai (wajib) - formula, nilai, atau referensi untuk memeriksa kesalahan #N/A.

Value_if_na (wajib) - nilai yang akan dikembalikan jika kesalahan #N/A terdeteksi.

Catatan penggunaan

• Fungsi IFNA hanya menangani #N/A tanpa menekan kesalahan lainnya.
• Jika nilai argumen adalah sebuah rumus larik IFNA mengembalikan array hasil, satu per sel, seperti yang ditunjukkan dalam contoh ini.

Ketersediaan IFNA

Fungsi IFNA diperkenalkan di Excel 2013 dan tersedia di semua versi berikutnya termasuk Excel 2016, Excel 2019, Excel 2021, dan Microsoft 365.

Dalam versi sebelumnya, Anda bisa menangkap error #N/A dengan menggunakan fungsi IF dan ISNA bersama-sama.

Cara menggunakan fungsi IFNA di Excel

Untuk menggunakan IFNA di Excel secara efektif, ikuti pendekatan umum ini:

1. Pada argumen pertama ( nilai ), masukkan rumus yang dipengaruhi oleh kesalahan #N/A.
2. Pada argumen kedua ( value_if_na ), ketik teks yang ingin Anda kembalikan, bukan notasi kesalahan standar. Untuk mengembalikan sel kosong ketika tidak ada yang ditemukan, berikan string kosong ('"").

Untuk kembali teks khusus , rumus umumnya adalah:

Untuk mengembalikan sel kosong , rumus umumnya adalah:

Mari kita lihat bagaimana cara kerjanya pada contoh sederhana. Pada tabel di bawah ini, misalkan Anda ingin mengetahui bagaimana nilai seorang siswa tertentu berada di antara siswa yang lain. Skor kolom dari tertinggi ke terendah, peringkat akan cocok dengan posisi relatif siswa dalam tabel. Dan untuk mendapatkan posisi, Anda dapat menggunakan fungsi MATCH dalam bentuk yang paling sederhana:

=MATCH(E1, A2:A10, 0)

Karena nilai pencarian (Neal) tidak tersedia dalam larik pencarian (A2:A10), kesalahan #N/A terjadi.

Jika mengalami kesalahan ini, pengguna yang tidak berpengalaman mungkin berpikir ada yang salah dengan rumusnya, dan Anda sebagai pembuat buku kerja akan menerima banyak pertanyaan. Untuk menghindarinya, Anda dapat secara eksplisit menunjukkan bahwa rumusnya benar, hanya saja tidak dapat menemukan nilai yang diminta untuk dicari. Jadi, Anda menyarangkan rumus MATCH di argumen pertama IFNA dan, di argumen kedua, ketik kustom Andateks, "Tidak ditemukan" dalam kasus kami:

=IFNA(MATCH(E1, A2:A10, 0), "Tidak ditemukan")

Sekarang, alih-alih notasi kesalahan standar, teks Anda sendiri ditampilkan dalam sel, menginformasikan pengguna bahwa nilai pencarian tidak ada dalam dataset:

Cara menggunakan IFNA dengan VLOOKUP

Paling sering error #N/A terjadi pada fungsi yang mencari sesuatu seperti VLOOKUP, HLOOKUP, LOOKUP, dan MATCH. Contoh-contoh di bawah ini mencakup beberapa kasus penggunaan yang umum.

Contoh 1. Rumus dasar IFNA VLOOKUP

Untuk menjebak error #N/A yang terjadi ketika VLOOKUP tidak dapat menemukan kecocokan, periksa hasilnya menggunakan IFNA dan tentukan nilai yang akan ditampilkan sebagai ganti error. Praktik yang umum dilakukan adalah membungkus fungsi IFNA di sekitar rumus VLOOKUP yang ada menggunakan sintaks ini:

Dalam tabel contoh kita, misalkan kamu ingin mengambil nilai dari siswa tertentu (E1). Untuk ini, kamu menggunakan rumus VLOOKUP klasik ini:

=VLOOKUP(E1, A2:B10, 2, FALSE)

Masalahnya adalah Neal tidak mengikuti ujian, oleh karena itu namanya tidak ada dalam daftar, dan jelas VLOOKUP gagal menemukan kecocokan.

Untuk menyembunyikan error, kita membungkus VLOOKUP dalam IFNA seperti ini:

=IFNA(VLOOKUP(E1, A2:B10, 2, FALSE), "Tidak mengikuti ujian")

Sekarang, hasilnya tidak terlihat begitu mengintimidasi pengguna dan jauh lebih informatif:

Contoh 2. IFNA VLOOKUP untuk mencari di beberapa lembar

Fungsi IFNA juga berguna untuk melakukan apa yang disebut berurutan atau dirantai Idenya adalah Anda menyarangkan beberapa rumus IFNA (VLOOKUP (....)) yang berbeda satu sama lain dengan cara ini:

Jika VLOOKUP utama tidak menemukan apa pun, fungsi IFNA-nya menjalankan VLOOKUP berikutnya hingga nilai yang diinginkan ditemukan. Jika semua pencarian gagal, rumus akan mengembalikan teks yang ditentukan.

Seandainya Anda memiliki nilai dari kelas-kelas yang berbeda yang terdaftar dalam lembaran-lembaran yang berbeda (dinamai Kelas A , Kelas B dan Kelas C Tujuanmu adalah untuk mendapatkan nilai dari siswa tertentu, yang namanya dimasukkan dalam cell B1 di lembar kerjamu saat ini. Untuk memenuhi tugas tersebut, gunakan rumus ini:

=IFNA(VLOOKUP(B1, 'Kelas A'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Kelas B'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Kelas C'!A2:B5, 2, FALSE), "Tidak ditemukan")))

Rumus ini secara berurutan mencari nama yang ditentukan dalam tiga lembar berbeda dalam urutan VLOOKUP bersarang dan membawa kecocokan yang pertama kali ditemukan:

Contoh 3. IFNA dengan INDEX MATCH

Dengan cara yang sama, IFNA dapat menangkap error #N/A yang dihasilkan oleh fungsi pencarian lainnya. Sebagai contoh, mari kita gunakan bersama dengan rumus INDEX MATCH:

=IFNA(INDEX(B2:B10, MATCH(E1, A2:A10, 0)), "Tidak ditemukan")

Inti dari rumus ini sama seperti pada semua contoh sebelumnya - INDEX MATCH melakukan pencarian, dan IFNA mengevaluasi hasilnya dan menangkap error #N/A jika nilai yang direferensikan tidak ditemukan.

IFNA untuk mengembalikan beberapa hasil

Jika fungsi dalam (yaitu, formula yang ditempatkan di dalam nilai argumen) mengembalikan beberapa nilai, IFNA akan menguji setiap nilai yang dikembalikan satu per satu dan mengeluarkan larik hasil. Sebagai contoh:

=IFNA(VLOOKUP(D2:D4, A2:B10, 2, FALSE), "Tidak ditemukan")

Dalam Dynamic Array Excel (Microsoft 365 dan Excel 2021), formula reguler di sel paling atas (E2) menumpahkan semua hasil di sel tetangga secara otomatis (dalam istilah Excel, ini disebut rentang tumpahan).

Dalam versi pra-dinamis (Excel 2019 dan yang lebih rendah), efek serupa dapat dicapai dengan menggunakan rumus array multi-sel, yang dilengkapi dengan pintasan Ctrl + Shift + Enter.

Apa perbedaan antara IFNA dan IFERROR?

Bergantung pada akar penyebab masalahnya, rumus Excel dapat memicu kesalahan yang berbeda seperti # N / A, # NAME, # VALUE, #REF, # DIV / 0, # NUM, dan lainnya. Fungsi IFERROR menangkap semua kesalahan tersebut sementara IFNA hanya terbatas pada # N / A. Mana yang lebih baik untuk dipilih? Itu tergantung situasinya.

Jika Anda ingin menekan segala jenis kesalahan Ini sangat berguna dalam perhitungan yang kompleks ketika rumus mencakup beberapa fungsi yang dapat menghasilkan kesalahan yang berbeda.

Dengan fungsi pencarian , Anda sebaiknya menggunakan IFNA karena ini menampilkan hasil kustom hanya ketika nilai pencarian tidak ditemukan dan tidak menyembunyikan masalah mendasar dengan rumus itu sendiri.

Untuk mengilustrasikan perbedaannya, mari kita kembalikan rumus dasar IFNA VLOOKUP kita dan "secara tidak sengaja" salah mengeja nama fungsinya (VLOKUP, bukan VLOOKUP).

=IFNA(VLOKUP(E1, A2:B10, 2, FALSE), "Tidak mengikuti ujian")

IFNA tidak menekan error ini, sehingga anda bisa melihat dengan jelas bahwa ada yang salah dengan salah satu nama fungsi:

Sekarang, mari kita lihat apa yang terjadi jika kamu menggunakan IFERROR:

=IFERROR(VLOKUP(E1, A2:B10, 2, FALSE), "Tidak mengikuti ujian")

Hmm... dikatakan bahwa Olivia tidak mengikuti ujian, yang mana itu tidak benar! Hal ini karena fungsi IFERROR menjebak #NAME? error dan mengembalikan teks kustom sebagai gantinya. Dalam situasi ini, tidak hanya mengembalikan informasi yang salah tetapi juga mengaburkan masalah dengan rumus.

Itulah cara menggunakan rumus IFNA di Excel. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

Unduhan yang tersedia

Contoh rumus IFNA Excel (file .xlsx)