Bu eğitimde, Excel'de belirli bir metne sahip hücrelerin sayısının nasıl sayılacağı gösterilmektedir. Tam eşleşme, kısmi eşleşme ve filtrelenmiş hücreler için formül örnekleri bulacaksınız.

Geçen hafta Excel'de metin içeren hücreleri, yani herhangi bir metin içeren tüm hücreleri nasıl sayacağımızı inceledik. Büyük bilgi yığınlarını analiz ederken, kaç hücrenin belirli bir metin içerdiğini de bilmek isteyebilirsiniz. Bu eğitimde bunun basit bir şekilde nasıl yapılacağı açıklanmaktadır.

Excel'de belirli metin içeren hücreler nasıl sayılır

Microsoft Excel'in hücreleri koşullu olarak saymak için özel bir işlevi vardır: COUNTIF işlevi. Tek yapmanız gereken hedef metin dizesini Kriterler Tartışma.

İşte belirli bir metni içeren hücrelerin sayısını saymak için genel bir Excel formülü:

Aşağıdaki örnekte bu işlem gösterilmektedir. Diyelim ki A2:A10'da öğe kimliklerinin bir listesi var ve belirli bir kimliğe sahip hücrelerin sayısını saymak istiyorsunuz, örneğin "AA-01". Bu dizeyi ikinci bağımsız değişkene yazdığınızda bu basit formülü elde edersiniz:

=COUNTIF(A2:A10, "AA-01")

Kullanıcılarınızın formülü değiştirmeye gerek kalmadan belirli bir metne sahip hücreleri saymasını sağlamak için, metni önceden tanımlanmış bir hücreye, örneğin D1'e girin ve hücre başvurusunu sağlayın:

=COUNTIF(A2:A10, D1)

Not: Excel COUNTIF işlevi büyük/küçük harf duyarsız yani harf büyüklüğünü ayırt etmez. Büyük ve küçük harf karakterlerini farklı şekilde ele almak için bu büyük/küçük harfe duyarlı formülü kullanın.

Belirli metne sahip hücreler nasıl sayılır (kısmi eşleşme)

Önceki örnekte ele alınan formül, ölçütlerle tam olarak eşleşir. Bir hücrede en az bir farklı karakter varsa, örneğin sonunda fazladan bir boşluk varsa, bu tam bir eşleşme olmaz ve böyle bir hücre sayılmaz.

İçeriklerinin bir parçası olarak belirli bir metin içeren hücrelerin sayısını bulmak için, ölçütlerinizde joker karakterleri, yani herhangi bir diziyi veya karakteri temsil eden yıldız işaretini (*) kullanın. Hedefinize bağlı olarak, bir formül aşağıdakilerden birine benzeyebilir.

'de belirli bir metin içeren hücreleri sayın. çok başlangıç :

içinde belirli metinleri içeren hücreleri sayın herhangi bir pozisyon :

Örneğin, A2:A10 aralığındaki kaç hücrenin "AA" ile başladığını bulmak için şu formülü kullanın:

=COUNTIF(A2:A10, "AA*")

Herhangi bir konumda "AA" içeren hücrelerin sayısını almak için bunu kullanın:

=COUNTIF(A2:A10, "*AA*")

Formülleri daha dinamik hale getirmek için, sabit kodlanmış dizeleri hücre referanslarıyla değiştirin.

Belirli bir metinle başlayan hücreleri saymak için:

=COUNTIF(A2:A10, D1& "*")

İçinde herhangi bir yerde belirli bir metin bulunan hücreleri saymak için:

=COUNTIF(A2:A10, "*"&D1&"*")

Aşağıdaki ekran görüntüsü sonuçları göstermektedir:

Belirli bir metin içeren hücreleri sayma (büyük/küçük harfe duyarlı)

Büyük ve küçük harf karakterlerini ayırt etmeniz gereken durumlarda COUNTIF işlevi çalışmayacaktır. Tam veya kısmi eşleşme aramanıza bağlı olarak, farklı bir formül oluşturmanız gerekecektir.

Belirli metne sahip hücreleri saymak için büyük/küçük harfe duyarlı formül (tam eşleşme)

Metin durumunu tanıyan belirli metne sahip hücrelerin sayısını saymak için, SUMPRODUCT ve EXACT fonksiyonlarının bir kombinasyonunu kullanacağız:

Bu formül nasıl çalışır?

• EXACT aralıktaki her hücreyi örnek metinle karşılaştırır ve DOĞRU ve YANLIŞ değerlerinden oluşan bir dizi döndürür; DOĞRU tam eşleşmeleri, YANLIŞ ise diğer tüm hücreleri temsil eder. çift tekli ) TRUE ve FALSE değerlerini 1'lere ve 0'lara zorlar.
• SUMPRODUCT, dizinin tüm öğelerini toplar. Bu toplam, eşleşme sayısı olan 1'lerin sayısıdır.

Örneğin, A2:A10'da D1'deki metni içeren ve büyük ve küçük harfleri farklı karakterler olarak işleyen hücre sayısını elde etmek için şu formülü kullanın:

=SUMPRODUCT(--EXACT(D1, A2:A10))

Belirli metne sahip hücreleri saymak için büyük/küçük harfe duyarlı formül (kısmi eşleşme)

Bir hücrenin herhangi bir yerinde ilgilenilen bir metin dizesini bulabilen büyük/küçük harfe duyarlı bir formül oluşturmak için 3 farklı işlev kullanıyoruz:

Bu formül nasıl çalışır?

• Büyük/küçük harfe duyarlı FIND işlevi, aralığın her bir hücresinde hedef metni arar. Başarılı olursa, işlev ilk karakterin konumunu döndürür, aksi takdirde #VALUE! hatası verir. Açıklık sağlamak için, tam konumu bilmemiz gerekmez, herhangi bir sayı (hatanın aksine) hücrenin hedef metni içerdiği anlamına gelir.
• ISNUMBER işlevi, FIND tarafından döndürülen sayı ve hata dizisini işler ve sayıları DOĞRU'ya, diğerlerini YANLIŞ'a dönüştürür. Çift tekli (--), mantıksal değerleri birlere ve sıfırlara zorlar.
• SUMPRODUCT, 1'ler ve 0'lar dizisini toplar ve içeriklerinin bir parçası olarak belirtilen metni içeren hücrelerin sayısını döndürür.

Formülü gerçek hayat verileri üzerinde test etmek için A2:A10'daki kaç hücrenin D1'deki alt dize girişini içerdiğini bulalım:

=SUMPRODUCT(--(ISNUMBER(FIND(D1, A2:A10))))

Bu da 3 sayısını döndürür (A2, A3 ve A6 hücreleri):

Belirli metne sahip filtrelenmiş hücreler nasıl sayılır

Saymak için görünür öğeler Filtrelenmiş bir listede, tam veya kısmi eşleşme isteyip istemediğinize bağlı olarak 4 veya daha fazla fonksiyonun bir kombinasyonunu kullanmanız gerekecektir. Örnekleri takip etmeyi kolaylaştırmak için önce kaynak verilere hızlıca bir göz atalım.

Şunları içeren bir tablonuz olduğunu varsayalım Sipariş Kimlikleri B sütununda ve Miktar Şu an için yalnızca 1'den büyük miktarlarla ilgileniyorsunuz ve tablonuzu buna göre filtrelediniz. Soru şu: Belirli bir kimliğe sahip filtrelenmiş hücreleri nasıl sayarsınız?

Belirli metne sahip filtrelenmiş hücreleri saymak için formül (tam eşleşme)

İçeriği örnek metin dizesiyle tam olarak eşleşen filtrelenmiş hücreleri saymak için aşağıdaki formüllerden birini kullanın:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10)), --(B2:B10=F1))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(B2:B10=F1))

Burada F1 örnek metin ve B2:B10 sayılacak hücrelerdir.

Bu formüller nasıl çalışır?

Her iki formülün özünde 2 kontrol gerçekleştirirsiniz:

1. Görünür ve gizli satırları belirleyin. Bunun için SUBTOTAL fonksiyonunu function_num SUBTOTAL'e tüm bireysel hücre referanslarını sağlamak için INDIRECT (ilk formülde) veya OFFSET, ROW ve MIN (ikinci formülde) kombinasyonunu kullanın. Görünür ve gizli satırları bulmayı amaçladığımızdan, hangi sütuna başvurulacağı gerçekten önemli değildir (örneğimizde A). Bu işlemin sonucu, birlerin görünür satırları temsil ettiği 1'ler ve 0'lardan oluşan bir dizidir.satırlar ve sıfırlar - gizli satırlar.
2. Verilen metni içeren hücreleri bulun. Bunun için, örnek metni (F1) hücre aralığıyla (B2:B10) karşılaştırın. Bu işlemin sonucu, çift tekli işleç yardımıyla 1'lere ve 0'lara zorlanan DOĞRU ve YANLIŞ değerlerinden oluşan bir dizidir.

Son olarak, SUMPRODUCT işlevi iki dizinin aynı konumlardaki öğelerini çarpar ve ardından elde edilen diziyi toplar. Sıfırla çarpma sıfır verdiğinden, yalnızca her iki dizide de 1 olan hücreler son dizide 1'e sahiptir. 1'lerin toplamı, belirtilen metni içeren filtrelenmiş hücrelerin sayısıdır.

Belirli metne sahip filtrelenmiş hücreleri saymak için formül (kısmi eşleşme)

Hücre içeriğinin bir parçası olarak belirli bir metni içeren filtrelenmiş hücreleri saymak için yukarıdaki formülleri aşağıdaki şekilde değiştirin. Örnek metni hücre aralığıyla karşılaştırmak yerine, önceki örneklerden birinde açıklandığı gibi ISNUMBER ve FIND kullanarak hedef metni arayın:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISNUMBER(FIND(F1, B2:B10))))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(ISNUMBER(FIND(F1, B2:B10))))

Sonuç olarak, formüller belirli bir metin dizesini bir hücredeki herhangi bir konumda bulacaktır:

Not. 103 ile ALTTOPLAM işlevi function_num argümanı, manuel olarak filtrelenen ve gizlenen tüm gizli hücreleri tanımlar. Sonuç olarak, yukarıdaki formüller yalnızca görünür hücreler görünmez hücrelerin nasıl gizlendiğine bakılmaksızın. Yalnızca filtrelenmiş hücreleri hariç tutmak, ancak manuel olarak gizlenmiş olanları dahil etmek için function_num .

Excel'de belirli bir metne sahip hücrelerin sayısını bu şekilde sayabilirsiniz. Okuduğunuz için teşekkür eder, gelecek hafta blogumuzda görüşmek dileğiyle!

Mevcut indirmeler

Belirli metne sahip hücreleri saymak için Excel formülleri