I mitt tidigare blogginlägg beskrev jag olika sätt att hitta och bearbeta dubbletter i kalkylbladet. Men för att upptäcka dem direkt är det bäst att markera dem med färg.

Och idag ska jag försöka täcka de mest populära fallen för dig. Du ska markera dubbletter i Google Sheets med hjälp av inte bara villkorlig formatering (det finns olika formler som baseras på hur många dubbletter som finns i din tabell) utan också ett speciellt tillägg.

Markera dubbla celler i en enda Google Sheets-kolumn

Låt oss börja med det grundläggande exemplet, dvs. när du bara har en kolumn med upprepade värden:

Tips: Jag kommer att använda villkorlig formatering i alla utom det sista fallet i dag. Om du inte känner till det kan du bekanta dig med det i det här blogginlägget.

Om du vill markera dubbla celler i en Google Sheets-kolumn öppnar du villkorlig formatering och ställer in följande alternativ:

1. tillämpa regeln på din rad av celler - A2:A10 i mitt exempel
2. välj Anpassad formel från rullgardinsmenyn med villkoret och ange följande formel:

   =COUNTIF($A$2:$A$10,$A2)>1

   Observera att det finns ett dollartecken bredvid bokstaven för A2 Det är avsiktligt så att formeln kan räkna varje cell från kolumn A. Du kommer att lära dig mer om cellreferenser i den här artikeln.

3. välja en valfri färg från Formateringsstil för att markera dessa dubbletter
4. Klicka på Klart

Formeln COUNTIF kommer att skanna kolumn A och tala om för regeln vilka poster som förekommer mer än en gång. Alla dessa dubbla celler kommer att färgas enligt dina inställningar:

Tips: Se hur du räknar celler efter färg i Google Sheets i den här artikeln.

Markera dubbletter i flera kolumner i Google Sheets

Det kan hända att upprepade värden finns i mer än en kolumn:

Hur skannar och markerar du dubbletter i alla 3 kolumnerna i Google Sheets? Du använder även villkorlig formatering. Övningen är densamma som ovan med några små justeringar:

1. Välj A2:C10 som ett intervall för att färga upprepade celler inom
2. ändra intervallet för Anpassad formel också:

   =COUNTIF($A$2:$C$10,A2)>1

   Observera: Denna gång tar du bort dollartecknet från A2. Detta gör att formeln kan räkna alla förekomster av varje cell i tabellen, inte bara i kolumn A.

   Tips: Läs den här artikeln om du vill veta mer om relativa, absoluta, & blandade cellreferenser.

3. välja en färg i Formateringsstil avsnittet och tryck på Klart

Till skillnad från den tidigare nämnda COUNTIF skannar den här metoden alla tre kolumnerna och räknar hur många gånger varje värde från tabellen förekommer i alla kolumnerna. Om det förekommer mer än en gång kommer villkorlig formatering att markera dessa dubblettceller i din Google Sheets-tabell.

Markera hela raden om dubbletter finns i en kolumn

Nästa exempel är när din tabell innehåller olika poster i varje kolumn, men hela raden i tabellen betraktas som en enda post, en enda information:

Som du kan se finns det dubbletter i kolumn B: pasta & kryddor sektionerna förekommer två gånger vardera.

I sådana här fall kan det vara lämpligt att behandla hela dessa rader som dubbletter och att markera dessa dubblettrader i Google-kalkylbladet.

Om det är precis vad du är ute efter, se till att ställa in dessa för din villkorliga formatering:

1. Tillämpa regeln på intervallet A2:C10
2. Och här är formeln:

   =COUNTIF($B$2:$B$10,$B2)>1

Denna COUNTIF räknar poster från kolumn B, ja, i kolumn B :) Och sedan markerar regeln för villkorlig formatering inte bara dubbletter i kolumn B, utan även relaterade poster i andra kolumner.

Markera fullständiga raddubbleringar i kalkylblad

Vad händer om hela raden med poster i alla kolumner förekommer flera gånger i tabellen?

Hur kontrollerar du alla tre kolumnerna i tabellen och markerar absolut dubbla rader i ditt Google-ark?

Använd den här formeln i villkorlig formatering:

=COUNTIF(ArrayFormula($A$2:$A$10&$B$2:$B$10&$C$2:$C$10),$A2&$B2&$C2)>1

Låt oss dela upp det i olika delar för att förstå hur det fungerar:

1. ArrayFormula($A$2:$A$10&$B$2:$B$10&$C$2:$C$10) sammanfogar alla tre celler från varje rad till en textsträng som ser ut så här: SpaghettiPasta9-RQQ-24

   I mitt exempel finns det alltså 9 sådana strängar - en per rad.

2. Därefter tar COUNTIFS varje sträng (med början från den första: $A2&$B2&$C2 ) och letar efter den bland dessa nio strängar.
3. Om det finns mer än en sträng ( >1 ), markeras dessa dubbletter.

Tips: Du kan läsa mer om COUNTIF och concatenation i Google Sheets i relaterade artiklar.

Markera faktiska dubbletter - 2n, 3d osv.

Låt oss anta att du vill behålla de första posterna i dubbla rader intakta och se alla andra förekomster om det finns några.

Med bara en ändring i formeln kan du markera dessa "riktiga" dubbla rader - inte de första posterna, utan deras andra, tredje, fjärde osv.

Så här är formeln som jag föreslog ovan för alla dubbla rader:

=COUNTIF(ArrayFormula($A$2:$A$10&$B$2:$B$10&$C$2:$C$10),$A2&$B2&$C2)>1

Det här är formeln du behöver för att markera endast dubbletter i Google Sheets:

=COUNTIF(ArrayFormula($A$2:$A2&$B$2:$B2&$C$2:$C2),$A2&$B2&$C2)>1

Kan du se skillnaden i formeln?

Det finns i det första COUNTIF-argumentet:

$A$2:$A2&$B$2:$B2&$C$2:$C2

Istället för att nämna alla rader som i den första formeln använder jag bara den första cellen i varje kolumn.

Det gör att varje rad endast kan titta ovanför för att se om det finns samma rader. Om så är fallet kommer varje aktuell rad att behandlas som en annan instans eller, med andra ord, som en faktisk dubblett som kommer att färgas.

Formelfritt sätt att markera dubbletter - tilläggsmodul Ta bort dubbletter för Google Sheets

Du kanske har ett annat användningsområde som kräver en annan formel. Men alla formler och villkorlig formatering kräver en inlärningskurva. Om du inte är redo att ägna din tid åt dem finns det en enklare lösning.

Tillägget Remove Duplicates för Google Sheets markerar dubbletter åt dig.

Det tar bara några få klick i fyra steg, och alternativet för att markera hittade dubbletter är bara en radioknapp med en färgpalett:

Tillägget erbjuder ett intuitivt sätt att välja data och kolumner som du vill kontrollera för dubbletter. Det finns ett separat steg för varje åtgärd så att du inte blir förvirrad:

Dessutom vet den hur man markerar inte bara dubbletter utan även unika exemplar, och det finns ett alternativ för att ignorera första instanserna också:

Tips: Här är en video som visar tillägget i praktiken. Den kan vara lite gammal eftersom tillägget för närvarande har mer att erbjuda, men det är fortfarande samma tillägg:

Markera dubbletter i schemat med hjälp av tillägget

Alla steg och inställningar som du väljer i tillägget kan sparas och återanvändas med ett klick senare eller till och med schemaläggas till en viss tid för autostart.

Här är en 2-minuters demovideo för att styrka mina ord (eller se nedan för ett par animerade bilder):

Och här är en kort animerad bild som visar hur du sparar och kör scenarier när dina data ändras:

Ännu bättre är att du kan schemalägga dessa scenarier så att de startar automatiskt några gånger om dagen:

Ingen fara, det finns ett särskilt loggblad där du kan registrera alla automatiska körningar & för att se till att de fungerar korrekt:

Installera bara Remove Duplicates från Google Sheets-butiken, prova det på dina data och du kommer att se hur mycket tid och nerver du kommer att spara på att få dessa poster korrekt färgade. Ja, utan formler och med bara några få klick ;)

Video: Hur du markerar dubbletter i Google Sheets

Den här videon på 1,5 minuter visar de tre snabbaste sätten (med och utan formler) att hitta & markera dubbletter i Google Sheets. Du kommer att se hur du kan färga en kolumn eller hela rader baserat på dubbletter, till och med automatiskt.

Kalkylblad med exempel på formler

Markera dubbletter i Google Sheets - exempel på villkorlig formatering (gör en kopia av filen)