Opplæringen viser hvordan du bruker XIRR i Excel til å beregne internrenten (IRR) for kontantstrømmer med uregelmessig timing og hvordan du lager din egen XIRR-kalkulator.

Når du står overfor en kapitalintensiv beslutning, er det ønskelig å beregne internrenten fordi den lar deg sammenligne forventet avkastning for ulike investeringer og gir et kvantitativt grunnlag for å ta beslutningen.

I vår forrige veiledning, vi så på hvordan man beregner internrenten med Excel IRR-funksjonen. Denne metoden er rask og enkel, men den har en vesentlig begrensning – IRR-funksjonen forutsetter at alle kontantstrømmer skjer med like tidsintervaller som månedlig eller årlig. I virkelige situasjoner skjer imidlertid inn- og utstrømmer kontanter med ujevne mellomrom. Heldigvis har Microsoft Excel en annen funksjon for å finne IRR i slike tilfeller, og denne veiledningen vil lære deg hvordan du bruker den.

XIRR-funksjon i Excel

Excel XIRR funksjonen returnerer den interne avkastningen for en serie kontantstrømmer som kan være periodiske eller ikke.

Funksjonen ble introdusert i Excel 2007 og er tilgjengelig i alle senere versjoner av Excel 2010, Excel 2013, Excel 2016 , Excel 2019 og Excel for Office 365.

Syntaksen til XIRR-funksjonen er som følger:

Hvor:

• Verdier (påkrevd) – enmatrise eller et celleområde som representerer en serie av inn- og utstrømmer.
• Datoer (påkrevd) – datoer som tilsvarer kontantstrømmer. Datoer kan forekomme i hvilken som helst rekkefølge, men datoen for den første investeringen må være først i rekken.
• Gjett (valgfritt) – en forventet IRR oppgitt som en prosentandel eller et desimaltall. Hvis utelatt, bruker Excel standardsatsen på 0,1 (10%).

For å beregne IRR for serien med kontantstrømmer i A2:A5 og datoer i B2:B5, ville du for eksempel bruk denne formelen:

=XIRR(A2:A5, B2:B5)

Tips. For at resultatet skal vises riktig, sørg for at formatet Prosent er angitt for formelcellen.

6 ting du bør vite om XIRR-funksjonen

De følgende merknadene vil hjelpe deg å bedre forstå den indre mekanikken til XIRR-funksjonen og bruke den mest effektivt i regnearkene dine.

1. XIRR i Excel er designet for å beregne internrenten for kontantstrømmer med ulik timing. For periodiske kontantstrømmer med eksakte betalingsdatoer ukjent, kan du bruke IRR-funksjonen.
2. Verdiområdet må inneholde minst én positiv (inntekt) og én negativ (utgående betaling) verdi.
3. Hvis den første verdien er et utlegg (startinvestering), må den representeres med et negativt tall. Den første investeringen er ikke diskontert; påfølgende betalinger bringes tilbake til datoen for den første kontantstrømmen og diskonteres basertpå et 365-dagers år.
4. Alle datoer avkortes til heltall, noe som betyr at brøkdelen av en dato som representerer tid fjernes.
5. Datoer må være gyldige Excel-datoer oppgitt som referanser til celler som inneholder datoer eller resultater av formler som DATE-funksjonen. Hvis datoer legges inn i tekstformatet, kan det oppstå problemer.
6. XIRR i Excel returnerer alltid en årlig IRR selv ved beregning av månedlige eller ukentlige kontantstrømmer.

XIRR-beregning i Excel

XIRR-funksjonen i Excel bruker en prøve- og feiltilnærming for å finne hastigheten som tilfredsstiller denne ligningen:

Hvor:

• P - kontantstrøm (betaling)
• d - dato
• i - periodenummer
• n - perioder totalt

Begynner med gjetning hvis gitt eller med standard 10% hvis ikke, Excel går gjennom iterasjoner for å komme frem til resultatet med 0,000001% nøyaktighet. Hvis en nøyaktig rate ikke blir funnet etter 100 forsøk, vil #NUM! feilen returneres.

For å sjekke gyldigheten til denne ligningen, la oss teste den mot resultatet av XIRR-formelen. For å forenkle beregningen vår vil vi bruke følgende matriseformel (husk at enhver matriseformel må fullføres ved å trykke Ctrl + Shift + Enter ):

=SUM(A2:A5/((1+$E$1)^((B2:B5-$B$2)/365)))

Hvor:

• A2:A5 er kontantstrømmene
• B2:B5 er datoene
• E1 er kursen returnert av XIRR

Som vist i skjermbildet nedenfor, er resultatet veldig nærttil null. Q.E.D. :)

Hvordan beregne XIRR i Excel – formeleksempler

Nedenfor er noen få eksempler som viser de vanlige bruken av XIRR-funksjonen i Excel.

Grunnleggende XIRR-formel i Excel

Anta at du investerte $1 000 i 2017 og forventer å få noe overskudd i løpet av de neste 6 årene. For å finne internrenten for denne investeringen, bruk denne formelen:

=XIRR(A2:A8, B2:B8)

Hvor A2:A8 er kontantstrømmer og B2:B8 er datoene som tilsvarer kontantstrømmene:

For å bedømme lønnsomheten til denne investeringen, sammenligne XIRR-resultatet med bedriftens veide gjennomsnittlige kapitalkostnad eller grensesats . Hvis avkastningen er høyere enn kapitalkostnaden, kan prosjektet betraktes som en god investering.

Når du sammenligner flere investeringsalternativer, husk at en anslått avkastningsrate bare er en av faktorene du bør estimere før du tar en beslutning. For mer informasjon, se Hva er internrenten (IRR)?

Fullstendig form for Excel XIRR-funksjon

Hvis du vet hva slags avkastning du forventer fra dette eller hint investering, kan du bruke forventningene dine som en gjetning. Det er spesielt nyttig når en åpenbart korrekt XIRR-formel gir et #NUM! feil.

For datainndataene vist nedenfor, returnerer en XIRR-formel uten gjetning en feil:

=XIRR(A2:A7, B2:B7)

Den forventede returraten(-20%) satt inn gjetning -argumentet hjelper Excel med å komme frem til resultatet:

=XIRR(A2:A7, B2:B7, -20%)

Hvordan beregne XIRR for månedlige kontantstrømmer

For det første, husk dette – uansett hvilken kontantstrøm du beregner, produserer Excel XIRR-funksjonen en årlig avkastning .

For å sikre at dette, la oss finne IRR for samme serie med kontantstrømmer (A2:A8) som oppstår månedlig og årlig (datoene er i B2:B8):

=XIRR(A2:A8, B2:B8)

Som du kan se i skjermbildet nedenfor går IRR fra 7,68 % ved årlige kontantstrømmer til omtrent 145 % for månedlige kontantstrømmer! Forskjellen virker for høy til å kunne rettferdiggjøres av tidsverdien til pengefaktoren alene:

For å finne en omtrentlig månedlig XIRR , kan du bruke følgende beregning, hvor E1 er resultatet av den vanlige XIRR-formelen:

=(1+E1)^(1/12)-1

Eller du kan legge inn XIRR direkte i ligningen:

=(1+XIRR(A2:A8,B2:B8))^(1/12)-1

Som en ekstra sjekk, la oss bruke IRR-funksjonen på de samme kontantstrømmene. Vær oppmerksom på at IRR også vil beregne en omtrentlig rate fordi den antar at alle tidsperiodene er like:

=IRR(A2:A8)

Som et resultat av disse beregningene får vi en månedlig XIRR på 7,77 %, som er veldig nær 7,68 % produsert av IRR-formelen:

Konklusjonen : hvis du ser etter en årlig IRR for månedlige kontanter flyter, bruk XIRR-funksjonen i sin rene form; for å få en månedlig IRR, søkjusteringen beskrevet ovenfor.

Excel XIRR-mal

For raskt å få internrenten for ulike prosjekter kan du lage en allsidig XIRR-kalkulator for Excel. Slik gjør du:

1. Skriv inn kontantstrømmene og datoene i to individuelle kolonner (A og B i dette eksemplet).
2. Opprett to dynamisk definerte områder, kalt Kontantstrømmer og Datoer . Teknisk sett vil det bli kalt formler:

   Cash_flows:

   =OFFSET(Sheet1!$A$2,0,0,COUNT(Sheet1!$A:$A),1)

   Datoer:

   =OFFSET(Sheet1!$B$2,0,0,COUNT(Sheet1!$B:$B),1)

   Hvor Sheet1 er navnet på regnearket ditt, A2 er den første kontantstrømmen, og B2 er den første datoen.

   For detaljerte trinnvise instruksjoner, se Hvordan lage et dynamisk navngitt område i Excel.

3. Oppgi de dynamisk definerte navnene du har opprettet til XIRR-formelen:

=XIRR(Cash_flows, Dates)

Ferdig! Du kan nå legge til eller fjerne så mange kontantstrømmer du vil, og din dynamiske XIRR-formel vil beregnes på nytt tilsvarende:

XIRR vs. IRR i Excel

Hovedforskjellen mellom Excel XIRR- og IRR-funksjoner er denne:

• IRR forutsetter at alle periodene i en serie med kontantstrømmer er like. Du bruker denne funksjonen til å finne internrenten for periodiske kontantstrømmer som månedlig, kvartalsvis eller årlig.
• XIRR lar deg tilordne en dato til hver enkelt kontantstrøm. Så bruk denne funksjonen til å beregne IRR for kontantstrømmer som ikke nødvendigvis er periodiske.

Generelt,hvis du vet de nøyaktige datoene for betalingene, er det tilrådelig å bruke XIRR fordi det gir bedre beregningsnøyaktighet.

La oss som et eksempel sammenligne resultatene av IRR og XIRR for de samme kontantstrømmene:

Hvis alle betalinger skjer med regelmessige intervaller , gir funksjonene svært nære resultater:

Hvis tidspunktet for kontantstrømmer er ulik , er forskjellen mellom resultatene ganske betydelig:

XIRR og XNPV i Excel

XIRR er nært knyttet til XNPV-funksjonen fordi resultatet av XIRR er diskonteringsrenten som fører til null netto nåverdi. Med andre ord, XIRR er XNPV = 0. Følgende eksempel viser forholdet mellom XIRR og XNPV i Excel.

La oss si at du vurderer en investeringsmulighet og ønsker å undersøke både netto nåverdi og internrente av avkastning på denne investeringen.

Med kontantstrømmene i A2:A5, datoer i B2:B5 og diskonteringsrenten i E1, vil følgende XNPV-formel gi deg netto nåverdi av fremtidige kontantstrømmer:

=XNPV(E1, A2:A5, B2:B5)

En positiv NPV indikerer at prosjektet er lønnsomt:

Nå, la oss finne hvilken diskonteringsrente som vil gjøre netto nåverdi null. Til dette bruker vi XIRR-funksjonen:

=XIRR(A2:A5, B2:B5)

For å sjekke om hastigheten produsert av XIRR virkelig fører til en null NPV, legg den inn i rate -argumentet til din XNPVformel:

=XNPV(E4, A2:A5, B2:B5)

Eller bygg inn hele XIRR-funksjonen:

=XNPV(XIRR(A2:A5, B2:B5), A2:A5, B2:B5)

Ja, XNPV avrundet til 2 desimaler er lik null:

For å vise den nøyaktige NPV-verdien, velg å vise flere desimaler eller bruk det vitenskapelige formatet på XNPV-cellen. Det vil gi et resultat som ligner på dette:

Hvis du ikke er kjent med den vitenskapelige notasjonen, utfør følgende beregning for å konvertere den til et desimaltall:

1.11E-05 = 1.11*10^-5 = 0.0000111

Excel XIRR-funksjonen fungerer ikke

Hvis du har støtt på et problem med XNPV-funksjonen i Excel, er hovedpunktene nedenfor du bør sjekke.

#NUM ! feil

En #NUM-feil kan oppstå på grunn av følgende årsaker:

• verdiene og datoer har forskjellige lengder (forskjellig antall kolonner eller rader).
• verdier -matrisen inneholder ikke minst én positiv og én negativ verdi.
• Enhver av de påfølgende datoene er tidligere enn den første dato.
• Et resultat ble ikke funnet etter 100 iterasjoner. I dette tilfellet, prøv en annen gjetning.

#VERDI! feil

En #VALUE-feil kan være forårsaket av følgende:

• Enhver av de oppgitte verdiene er ikke-numeriske.
• Noen av av de oppgitte datoene kan ikke identifiseres som gyldige Excel-datoer.

Det er slik du beregner XIRR i Excel. For å se nærmere på formlene som er diskutert i denne opplæringen, er du velkommen til å laste ned prøven vårarbeidsbok nedenfor. Jeg takker for at du leser og håper å se deg på bloggen vår neste uke!

Øvningsarbeidsbok for nedlasting

XIRR Excel-mal (.xlsx-fil)