Aínda que o reconto de palabras e caracteres en Follas de cálculo de Google úsase en casos raros, aínda é a funcionalidade que algúns esperamos ver directamente no menú. Pero a diferenza de Google Docs, para Google Sheets, é a función LEN a que fai iso.

Aínda que hai moitas formas diferentes de contar os caracteres nas follas de cálculo, a publicación de hoxe no blog cubrirá a función LEN como a súa función. O obxectivo principal das táboas é contar :) Porén, case nunca se usa por si só. A continuación, aprenderá a utilizar Google Sheets LEN correctamente e atopar as fórmulas máis buscadas para calcular caracteres en follas de cálculo.

Función LEN de Google Sheets: uso e sintaxe

O principal e o único propósito da función LEN en Follas de cálculo de Google é obter a lonxitude da cadea. É tan sinxelo que mesmo require só 1 argumento:

• pode levar o propio texto entre comiñas dobres:

  =LEN("Yggdrasil")

• ou unha referencia a unha cela co texto de interese:

  =LEN(A2)

A ver se hai algunha peculiaridade no uso da función en follas de cálculo.

Caracter contar en Follas de cálculo de Google

Empezarei coa operación máis sinxela: facer un reconto de caracteres en Follas de cálculo de Google da forma máis común: facendo referencia a unha cela co texto mediante a función LEN.

I introduza a fórmula en B2 e cópiaa en toda a columna para contar os caracteres de cada fila:

=LEN(A2)

Nota. A función LENcalcula todos os caracteres: letras, números, espazos, signos de puntuación, etc.

Pode pensar que dun xeito similar podería facer un reconto de caracteres para todo o intervalo de celas, como este: LEN(A2:A6) . Pero, como por estraño que sexa, non funciona simplemente deste xeito.

Para totalizar caracteres en varias celas, debes envolver o teu LEN en SUMPRODUCT: a función que calcula os números dos intervalos introducidos. No meu caso, o rango é devolto pola función LEN:

=SUMPRODUCT(LEN(A2:A6))

Por suposto, podes incorporar a función SUMA no seu lugar. Pero SUM en Follas de cálculo de Google non procesa matrices doutras funcións. Para que funcione, terás que engadir outra función: ArrayFormula:

=ArrayFormula(SUM(LEN(A2:A6)))

Como contar caracteres sen espazos en Follas de cálculo de Google

Como indiquei anteriormente, Follas de cálculo de Google A función LEN conta todos e cada un dos caracteres que ve, incluídos os espazos.

Pero e se hai espazos adicionais engadidos por erro e non queres consideralos para o resultado?

Para casos como isto, está a función TRIM en Google Sheets. Comproba que o texto non teña espazos intermedios, ao final e ao final. Cando TRIM se emparella con LEN, este último non conta todos eses espazos impares.

Aquí tes un exemplo. Engadín espazos en diferentes posicións na columna A. Como podes ver, cando é só, Google Sheets LEN conta todos:

=LEN(A2)

Pero en canto integras TRIM, todo extra os espazos sonignorado:

=LEN(TRIM(A2))

Podes ir máis alá e facer que a túa fórmula non teña en conta nin sequera eses espazos únicos entre as palabras. A función SUBSTITUTE asistirá. Aínda que o seu propósito principal é substituír un carácter por outro, hai un truco para que reduza completamente os espazos:

• text_to_search é o intervalo co que traballas: columna A ou A2 para ser exactos.
• buscar_por debe ser un espazo entre comiñas dobres: " "
• substituír_con debe conter comiñas dobres baleiras. Se vai ignorar espazos, debe substituílos por literalmente nada (cadea baleira): ""
• occurrence_number úsase normalmente para especificar a instancia para substituír. Pero dado que estou describindo como contar os caracteres sen todos os espazos, suxíroche que omitas este argumento xa que é opcional.

Agora tenta reunir todos estes en Google Sheets LEN e verás que non se ten en conta ningún espazo:

=LEN(SUBSTITUTE(A2, " ", ""))

Follas de Google: contar caracteres específicos

Usase o mesmo tándem de Follas de cálculo LEN e SUBSTITUTE sempre que necesite contar caracteres específicos , letras ou números.

Nos meus exemplos, vou descubrir o número de aparicións da letra 's'. E esta vez, comezarei cunha fórmula xa preparada:

=LEN(A2)-LEN(SUBSTITUTE(A2, "s", ""))

Imos descomprimila en anacos para entender comofunciona:

1. SUBSTITUTE(A2, "s", "") busca a letra 's' en A2 e substitúe todas as ocorrencias por "nada" ou unha cadea baleira ( "")).
2. LEN(SUBSTITUTE(A2, "s", "") calcula o número de todos os caracteres excepto as 's' en A2.
3. LEN(A2) conta todos os caracteres en A2.
4. Finalmente, resta un do outro.

A diferenza do resultado mostra cantos 's' hai na cela:

Nota. Podes preguntar por que B1 di que só hai 1 's' en A2 mentres que podes ver 3?

O caso é que a función SUBSTITUTE distingue entre maiúsculas e minúsculas. Pedinlle que tomase todas as instancias de 's' en minúsculas e así o fixo.

Para que ignore o texto e procese letras en minúsculas e maiúsculas, terás que chamar a unha función máis de Follas de cálculo de Google para obter axuda: BAIXA.

Consello. Consulta outras formas de cambiar as maiúsculas e minúsculas do texto en Follas de cálculo de Google.

É tan sinxelo coma LEN e TRIM de Follas de cálculo de Google porque o único que precisa é o texto:

=LOWER(text)

E o único que fai é converter a cadea de texto enteira int o minúscula. Este truco é exactamente o que necesitas para que Follas de cálculo de Google conte caracteres específicos sen importar as mayúsculas e minúsculas:

=LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "s", ""))

Consello. E como antes, para contar o total de caracteres específicos do intervalo, envolve o teu LEN en SUMPRODUCT:

=SUMPRODUCT(LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "s", "")))

Conta palabras en Google Sheets

Cando hai hai varias palabras nas celas, é probable que teñas que ter o seu número en vez dea lonxitude da cadea de follas de cálculo de Google.

E aínda que hai varias formas de facelo, hoxe mencionarei como fai o traballo de LEN de follas de cálculo de Google.

Lembra a fórmula que usei para contar caracteres específicos en Follas de cálculo de Google? De feito, aquí tamén será útil. Porque non vou contar literalmente palabras. En vez diso, vou contar o número de espazos entre as palabras e despois engadirei 1. Bótalle un ollo:

=LEN(A2)-LEN(SUBSTITUTE((A2), " ", ""))+1

1. LEN(A2) conta o número de todos os caracteres da cela.
2. LEN(SUBSTITUTE((A2)," ","")) elimina todos os espazos da cadea de texto e conta os caracteres restantes.
3. Despois resta un do outro, e a diferenza que obtén é o número de espazos na cela.
4. Xa que as palabras sempre superan os espazos nunha frase por un, engádese 1 ao final.

Follas de Google: contar palabras específicas

Por último, gustaríame compartir unha fórmula de Follas de cálculo de Google que podes usar para contar palabras específicas.

Aquí teño The Mock Turtle's Song de Alice's Adventures in Wonderland:

Quero saber cantas veces aparece a palabra "will" en cada fila. Creo que non che sorprenderá se che digo que a fórmula que necesito consta das mesmas funcións que antes: Google Sheets LEN, SUBSTITUTE e LOWER:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2), "will", "")))/LEN("will")

A fórmula pode parece asustado, pero podo asegurarche que é fácil de comprender, así que ten paciencia comigo :)

1. Xa que o texto non éimporta para min, uso MINIÑO(A2) para poñer todo en minúsculas.
2. Entón vai SUBSTITUTO(MINIÑO(A2), "vai",""))) : elimina todas as ocorrencias de 'will' substituíndoas por cadeas baleiras ("").
3. Despois diso, resto o número de caracteres sen a palabra 'will' da lonxitude total da cadea. . O número que recibo conta todos os caracteres en todas as ocorrencias de "will" en cada fila.

   Así, se aparece 'will' unha vez, o número é 4 xa que hai 4 letras na palabra. Se aparece dúas veces, o número é 8, etc.

4. Finalmente, divido este número pola lonxitude da única palabra "will".

Consello. E, de novo, se prefire obter o número total de todas as aparicións da palabra 'will', só tes que incluír a fórmula completa por SUMPRODUCT:

=SUMPRODUCT((LEN(A2:A7)-LEN(SUBSTITUTE(LOWER(A2:A7), "will", "")))/LEN("will"))

Como podes ver , todos estes casos de reconto de caracteres resólvense cos mesmos patróns das mesmas funcións para Google Sheets: LEN, SUBSTITUTE, LOWER e SUMPRODUCT.

Se algunhas fórmulas aínda che confunden ou non o estás seguro de como aplicalo todo á túa tarefa particular, non sexas tímido e pregunta na sección de comentarios a continuación!