Tutorial labur honetan, Excel SMALL funtzioari buruz hitz egingo dugu, nola funtzionatzen duen eta nola erabili N-garren zenbaki, data edo ordurik txikiena aurkitzeko.

Beharrezkoa lan-orri batean zenbaki txikien batzuk aurkitzeko? Hau nahiko erraza da Excel Sort funtzioarekin. Ez al duzu denbora galdu nahi zure datuak berriro ordenatzen aldaketa bakoitzean? SMALL funtzioak balio txikiena, bigarren txikiena, hirugarren txikiena eta abar azkar aurkitzen lagunduko dizu.

Excel SMALL funtzioa

SMALL itzultzen duen funtzio estatistikoa da. datu multzo bateko n-garren baliorik txikiena.

SMALL funtzioaren sintaxiak bi argumentu biltzen ditu, biak beharrezkoak.

SMALL(array, k)

Non:

• Matrizea - balio txikiena ateratzeko matrizea edo gelaxka sorta bat.
• K - an Balio baxuenetik itzulerara dagoen posizioa adierazten duen osokoa, hau da, k-garren txikiena.

Funtzioa Office 365, Excel 2021, Excel 2019, Excel 2016, Excel-en Excel bertsio guztietan dago eskuragarri. 2013, Excel 2010 eta aurrekoak.

Aholkua. Irizpideekin k-garren baliorik baxuena aurkitzeko, erabili Excel SMALL IF formula.

Oinarrizko formula TXIKIA Excel-en

Oinarrizko formula TXIKIA oso erraza da eraikitzen; besterik ez duzu zehaztu. barrutia eta itzultzeko elementu txikienetik posizioa.

B2:B10 zenbakien zerrendan, 3. balio txikiena atera nahi duzula suposatuz. Formula bezala daerraza da:

=SMALL(B2:B10, 3)

Emaitza egiaztatzea errazteko, B zutabea goranzko ordenan dago ordenatuta:

SMALL funtzioari buruz jakin behar dituzun 4 gauza

Ondoko erabilera-ohar hauek SMALL funtzioaren portaera hobeto ulertzen lagunduko dizute eta nahasmena saihestuko duzu zure formulak eraikitzean.

1. Edozein gelaxka hutsak , testua balioak eta logikoak balioak EGIA eta GEZURRA matrizea argumentuan ez ikusi egiten dira.
2. <1 bada> array k errore bat edo gehiago ditu, errore bat itzultzen da.
3. bikoiztuak badaude array n, zure formula "loturak" eragin ditzake. Adibidez, bi gelaxkek 1 zenbakia badute eta TXIKIA funtzioa txikiena eta 2. txikiena itzultzeko konfiguratuta badago, 1 lortuko duzu bi kasuetan.
4. N <-ko balio kopurua dela suposatuz. 1>array , SMALL(array,1) balio txikiena itzuliko du eta SMALL(array,n) baliorik altuena aukeratuko du.

Nola erabili SMALL funtzioa Excel-en - formula-adibideak

Eta orain, ikus ditzagun Excel SMALL funtzioaren adibide gehiago, oinarrizko erabileratik haratago doazenak.

Bilatu beheko 3, 5, 10 eta abar balioak

Dagoeneko dakizunez, SMALL funtzioa n-garren baliorik baxuena kalkulatzeko diseinatuta dago. Adibide honek modu eraginkorrenean nola egin erakusten du.

Beheko taulan, demagun beheko 3 balioak aurkitu nahi dituzula. Horretarako, idatzi1, 2 eta 3 zenbakiak gelaxka bereizietan (D3, D4 eta D5 gure kasuan). Ondoren, sartu formula hau E3-n eta arrastatu behera E5-n:

=SMALL($B$2:$B$10, D3)

E3-n, formulak baliorik txikiena ateratzen du k<2-ko D3 zenbakia erabiliz> argumentua. Funtsezkoa da gelaxka-erreferentzia egokiak hornitzea, eta, ondorioz, formulak behar bezala kopiatzen ditu beste gelaxketan: absolutua array rentzat eta erlatiboa k rentzat.

Ez al duzu nahi sailkapenak eskuz idazten? Erabili ROWS funtzioa barruti hedagarria erreferentzia batekin k balioa emateko. Horretarako, erreferentzia absolutua egiten dugu lehen gelaxkarentzat (edo errenkada koordenatua B$2 bezala bakarrik blokeatu) eta erreferentzia erlatiboa azken gelaxkarentzat:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Ondorioz, barrutia erreferentzia zabaltzen da formula zutabean behera kopiatzen den heinean. D2-n, ROWS(B$2:B2) 1 sortzen du k , eta formulak kostu txikiena itzultzen du. D3-n, ROWS(B$2:B3) 2 ematen du, eta 2. kostu baxuena lortuko dugu, eta abar.

Kopiatu formula 5 gelaxkatik eta beheko 5 balioak lortuko dituzu:

Beheko N balioen batura

Datu multzo bateko n balio txikienen guztirakoa aurkitu nahi duzu? Aurreko adibidean erakutsitako balioak lehendik atera badituzu, irtenbiderik errazena SUM formula bat izango litzateke:

=SUM(E3:E5)

Edo dezakezu egin formula independente bat SUMPRODUCT:

Gure datu multzoko beheko 3 balioen batura lortzeko, formulak forma hau hartzen du. :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

SUM funtzioak emaitza bera emango du:

=SUM(SMALL(B2:B10, {1,2,3}))

Oharra. zelula-erreferentziak erabiltzen badituzu k -rako array konstantea baino, Ctrl + Shift + Sartu sakatu behar duzu matrize formula izan dadin. Matrize dinamikoak onartzen dituen Excel 365-en, SUM SMALL-ek formula arrunt gisa funtzionatzen du kasu batean zein bestean.

Formula honek nola funtzionatzen duen:

Formula arrunt batean, SMALL-ek barruti bateko k-garren baliorik txikiena ematen du. Kasu honetan, {1,2,3} bezalako matrize-konstante bat hornitzen dugu k argumenturako, 3 balio txikienetako array bat itzultzera behartuz:

{29240, 43610, 58860}

SUMPRODUCT edo SUM funtzioak matrizeko zenbakiak batzen ditu eta guztira ateratzen du. Hori da!

INDEX MATCH SMALL formula parekatze txikienak lortzeko

Balio txikienarekin lotutako datu batzuk berreskuratu nahi dituzunean, erabili INDEX MATCH konbinazio klasikoa SMALL eta bilaketa-balioa lortzeko. :

Non :

• Return_array erlazionatutako datuak ateratzeko tartea da.
• Lookup_array n txikiena bilatzeko tartea da. -garren balioa.
• N interes-balio txikienaren posizioa da.

ForuAdibidez, kostu txikiena duen proiektuaren izena lortzeko, E3-ko formula hau da:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Non A2:A10 proiektuaren izenak diren, B2:B10 kostuak eta D3 txikieneko maila da.

Kopiatu formula beheko gelaxketan (E4 eta E5), eta 3 proiektu merkeenen izenak jasoko dituzu:

Oharrak:

• Konponbide honek ondo funtzionatzen du bikoizturik ez duen datu multzo batean. Hala ere, zenbakizko zutabe bateko bi balio bikoiztu edo gehiagok "loturak" sor ditzakete sailkapenean, eta horrek emaitza okerrak ekarriko ditu. Kasu honetan, mesedez, erabili formula apur bat sofistikatuagoa loturak hausteko.
• Excel 365-en, zeregin hau matrize dinamikoen funtzio berrien laguntzarekin egin daiteke. Askoz sinpleagoa izateaz gain, hurbilketa honek automatikoki konpontzen du loturen arazoa. Xehetasun osoetarako, ikus Nola iragazi beheko N balioak Excel-en.

Ordenatu zenbakiak txikienetik handienera formula batekin

Uste dut denek dakiela zenbakiak ordenan jartzen. Excel ordenatzeko funtzioa. Baina ba al dakizu nola egiten den ordenaketa formula batekin? Excel 365 erabiltzaileek modu errazean egin dezakete SORT funtzio berriarekin. Excel 2019, 2016 eta aurreko bertsioetan SORT-ek ez du funtzionatzen, ai. Baina izan fede pixka bat, eta TXIKIA erreskatatzera etorriko da :)

Lehenengo adibidean bezala, ROWS funtzioa erabiltzen dugu zabaltzen den barrutiaren erreferentzia batekin k bakoitzean 1 handitzeko. errenkada non formulakopiatzen da:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Idatzi formula lehenengo gelaxkan, eta arrastatu behera jatorrizko datu multzoan balio adina gelaxkatara (C2:C10 adibide honetan) :

Aholkua. beheranzko ordenatzeko, erabili HANDIA funtzioa TXIKIA beharrean.

Excel SMALL data eta orduetarako formula

Datak eta orduak ere zenbakizko balioak direnez (Excel barneko sisteman, datak zenbaki sekuentzial gisa gordetzen dira eta denborak frakzio hamartar gisa), SMALL funtzioak kudea ditzake. baita zure alde aparteko ahaleginik egin gabe.

Beheko pantaila-argazkietan ikus dezakezun bezala, zenbakietarako erabiltzen dugun oinarrizko formula batek ederki funtzionatzen du data eta orduetarako ere:

=SMALL($B$2:$B$10, D2)

Formula TXIKIA 3 data goiztiarrenak aurkitzeko:

Formula TXIKIA 3 aldiz laburrenak lortzeko:

Hurrengo adibideak erakusten du SMALL funtzioak nola lagun diezazukeen datei lotutako zeregin zehatzago bat burutzen.

Bilatu aurreko data bat gaur edo zehaztutako datatik hurbilen dagoena

Daten zerrenda batean , demagun data zehatz baten aurretik hurbilen dagoen data aurkitu nahi duzula. Hau egin daiteke TXIKIA funtzioa COUNTIF-rekin konbinatuta.

B2:B10-ko daten zerrendarekin eta xede-data E1-n, formula honek xede-datatik hurbilen dagoen aurreko data itzuliko du:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

E1eko data baino bi data baino lehenagokoa den data bat ateratzeko, hau da, aurreko baina data bakarra,formula hau da:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

Iraganeko data bat aurkitzeko gaurtik hurbilen dagoen , erabili GAUR funtzioa COUNTIF-en irizpideetarako:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

Aholkua. Zure irizpideekin bat datorren data aurkitzen ez den egoeran akatsak saihesteko, IFERROR funtzioa bil dezakezu zure formularen inguruan, honela:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

Nola funtzionatzen duten formula hauek:

Ideia orokorra da xede-data baino data txikiagoa zenbatzea COUNTIF-rekin. Eta zenbaketa hau da TXIKIA funtzioak k argumenturako behar duena.

Kontzeptua hobeto ulertzeko, ikus dezagun beste angelu batetik:

1- bada. 2020ko abuztua (helmuga-data E1ean) gure datu multzoan agertu zen, zerrendako 7. datarik handiena izango litzateke. Ondorioz, sei data txikiagoak daude. Hau da, 6. data txikiena xede-datatik hurbilen dagoen aurreko data da.

Beraz, lehenik eta behin kalkulatuko dugu zenbat data diren E1eko data baino txikiagoa (emaitza 6 da):

COUNTIF(B2:B10, "<"&E1)

Eta gero, konektatu zenbaketa SMALL-en 2. argumentuan:

=SMALL(B2:B10, 6)

Aurreko data bat lortzeko (gure kasuan 5. data txikiena da) , COUNTIF-en emaitzatik 1 kentzen dugu.

Nola nabarmendu beheko balioak Excel-en

Zure taulako n baliorik txikienak Excel baldintzazko formatuarekin nabarmentzeko, Goiko barnean erabil dezakezu. /Beheko aukera edo ezarri zure araua formula TXIKI batean oinarrituta. Lehenengo metodoa azkarragoa daeta aplikatzeko errazago, bigarrenak kontrol eta malgutasun gehiago ematen duen bitartean. Beheko pausoek arau pertsonalizatu bat sortzen lagunduko dizute:

1. Hautatu beheko balioak nabarmendu nahi dituzun barrutia. Gure kasuan, zenbakiak B2:B10-n daude, beraz, hautatzen dugu. Errenkada osoak nabarmendu nahi badituzu, hautatu A2:B10.
2. Hasiera fitxan, Estiloak taldean, sakatu Baldintzazko formatua. > Arau berria .
3. Formatu-arau berria elkarrizketa-koadroan, aukeratu Erabili formula bat formateatu behar den zehazteko.
4. Formatu balioak non formula hau egia den koadroan, idatzi honelako formula bat:

   =B2<=SMALL($B$2:$B$10, 3)

   Non B2 zenbakiko ezkerreko gelaxka den. egiaztatu beharreko barrutia, $B$2:$B$10 barruti osoa da, eta 3 azpimarratzeko n beheko balioak.

   Zure formulan, kontuan izan erreferentzia motak: Ezkerreko gelaxka erreferentzia erlatiboa da (B2), tartea erreferentzia absolutua den bitartean ($B$2:$B$10).

5. Sakatu Formatua botoian eta aukeratu nahi duzun formatua.
6. Sakatu Ados bi aldiz elkarrizketa-leiho biak ixteko.

Eginda! B zutabeko beheko 3 balioak nabarmentzen dira:

Informazio gehiago lortzeko, ikus Excel baldintzazko formatua formulan oinarrituta.

Excel SMALL funtzioa ez dabil

Gure adibideetatik ikusi berri duzun bezala, Excel-en TXIKIA funtzioa erabiltzea nahiko erraza da, etanekez izango du zailtasunik. Zure formulak ez badu funtzionatzen, ziurrenik #NUM bat izango da! errorea, arrazoi hauengatik gerta daitekeena:

• Matrizea hutsik dago edo ez du zenbakizko balio bakar bat.
• k balioa zero baino txikiagoa da (ordo ortografia ergel batek arazoak konpontzeko orduak kosta diezazkizuke!) edo matrizeko balio kopurua gainditzen du.

Horrela erabili Excel-en formula TXIKI bat aurkitzeko eta aurkitzeko. nabarmendu beheko zenbakiak datu multzo batean. Funtzioa erabilgarria den beste eszenatokiren bat ezagutzen baduzu, ongi etorria izango zara iruzkinetan partekatzea. Eskerrik asko irakurtzeagatik eta datorren astean gure blogean ikustea espero dut!

Lan koadernoa deskargatzeko

Excel SMALL formula adibideak (.xlsx fitxategia)