W tym krótkim tutorialu porozmawiamy o funkcji Excel SMALL, jak działa i jak jej używać, aby znaleźć N-tą najmniejszą liczbę, datę lub czas.

Potrzebujesz znaleźć kilka najniższych liczb w arkuszu? Jest to dość łatwe do zrobienia dzięki funkcji Excel Sort. Nie chcesz tracić czasu na ponowne sortowanie danych przy każdej zmianie? Funkcja SMALL pomoże Ci szybko znaleźć najniższą wartość, drugą najmniejszą, trzecią najmniejszą itd.

Funkcja SMALL w programie Excel

SMALL jest funkcją statystyczną, która zwraca n-tą najmniejszą wartość w zbiorze danych.

Składnia funkcji SMALL zawiera dwa argumenty, z których oba są wymagane.

SMALL(tablica, k)

Gdzie:

• Array - tablicę lub zakres komórek, z których należy wyodrębnić najmniejszą wartość.
• K - liczba całkowita, która wskazuje pozycję od najniższej wartości do zwrotu, czyli k-tej najmniejszej.

Funkcja jest dostępna we wszystkich wersjach programu Excel dla Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010 i wcześniejszych.

Wskazówka. aby znaleźć k-tą najniższą wartość z kryteriami, należy użyć formuły Excel SMALL IF.

Podstawowa formuła SMALL w Excelu

Formuła SMALL w swojej podstawowej formie jest bardzo prosta do zbudowania - wystarczy podać zakres i pozycję od najmniejszej pozycji do zwrotu.

Na liście liczb w B2:B10, załóżmy, że chcesz wyodrębnić 3. najmniejszą wartość. Formuła jest tak prosta jak:

=SMALL(B2:B10, 3)

Aby ułatwić sobie sprawdzenie wyniku, kolumna B jest posortowana w porządku rosnącym:

4 rzeczy, które powinieneś wiedzieć o funkcji SMALL

Poniższe uwagi dotyczące użytkowania pomogą Ci lepiej zrozumieć zachowanie funkcji SMALL i uniknąć pomyłek podczas budowania własnych formuł.

1. Każdy puste komórki , tekst wartości, oraz logiczne wartości TRUE i FALSE w macierz argumentu są ignorowane.
2. Jeśli macierz zawiera jeden lub więcej błędy , zwracany jest błąd.
3. W przypadku, gdy są duplikaty w macierz , twoja formuła może spowodować "remisy". Na przykład, jeśli dwie komórki zawierają liczbę 1, a funkcja SMALL jest skonfigurowana tak, aby zwrócić najmniejszą i 2. najmniejszą wartość, otrzymasz 1 w obu przypadkach.
4. Zakładając, że n jest liczbą wartości w macierz , SMALL(tablica,1) zwróci najniższą wartość, a SMALL(tablica,n) wybierze najwyższą wartość.

Jak wykorzystać funkcję SMALL w Excelu - przykłady formuł

A teraz przyjrzyjmy się jeszcze kilku przykładom użycia funkcji SMALL w Excelu, które wykraczają poza jej podstawowe zastosowanie.

Znajdź wartości dolne 3, 5, 10 itd.

Jak już wiesz, funkcja SMALL ma za zadanie obliczyć n-tą najmniejszą wartość. Ten przykład pokazuje, jak to zrobić najbardziej efektywnie.

W poniższej tabeli załóżmy, że chcesz znaleźć dolne 3 wartości. W tym celu wpisz liczby 1, 2 i 3 w osobnych komórkach (D3, D4 i D5 w naszym przypadku). Następnie wpisz następującą formułę w komórce E3 i przeciągnij ją w dół przez E5:

=SMALL($B$2:$B$10, D3)

W E3 formuła wyciąga najmniejszą wartość, używając liczby w D3 dla k Kluczową sprawą jest podanie odpowiednich odwołań do komórek, dzięki którym formuła będzie się poprawnie kopiować w innych komórkach: absolute for macierz i względny dla k .

Nie chcesz się męczyć z ręcznym wpisywaniem szeregów? Użyj funkcji ROWS z etykietą rozszerzający się zakres odniesienie, aby zapewnić k W tym celu wykonujemy odwołanie bezwzględne dla pierwszej komórki (lub tylko blokujemy współrzędną wiersza jak B$2) i odwołanie względne dla ostatniej komórki:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

W rezultacie, odwołanie do zakresu rozszerza się w miarę kopiowania formuły w dół kolumny. W D2, ROWS(B$2:B2) daje 1 dla k W D3, ROWS(B$2:B3) daje 2, a my otrzymujemy 2. najniższy koszt, i tak dalej.

Wystarczy skopiować formułę przez 5 komórek, a otrzymasz dolne 5 wartości:

Suma wartości dolnych N

Chcesz znaleźć sumę najmniejszych n wartości w zbiorze danych? Jeśli już wyodrębniłeś wartości jak pokazano w poprzednim przykładzie, najprostszym rozwiązaniem byłaby formuła SUM jak:

=SUM(E3:E5)

Możesz też stworzyć niezależny wzór, używając funkcji SMALL wraz z SUMPRODUCT:

Aby uzyskać sumę 3 dolnych wartości w naszym zestawie danych, wzór przyjmuje taki kształt:

=SUMPRODUKT(SMALL(B2:B10, {1,2,3}))

Funkcja SUM da ten sam wynik:

=SUMA(SMALL(B2:B10, {1,2,3}))

Uwaga. Jeśli używasz odniesienia do komórek zamiast stałej tablicowej dla k , musisz nacisnąć Ctrl + Shift + Enter, aby uczynić go formułą tablicową. W programie Excel 365, który obsługuje dynamiczne tablice, SUM SMALL działa jako zwykła formuła w obu przypadkach.

Jak działa ta formuła:

W zwykłej formule, SMALL zwraca pojedynczą k-tą najmniejszą wartość w zakresie. W tym przypadku, dostarczamy stałą tablicową taką jak {1,2,3} dla argumentu k, zmuszając ją do zwrócenia tablicy najmniejszych 3 wartości:

{29240, 43610, 58860}

Funkcja SUMPRODUCT lub SUM sumuje liczby w tablicy i wypisuje sumę. To wszystko!

INDEX MATCH SMALL formuła pozwalająca uzyskać najmniejsze dopasowania

W sytuacji, gdy chcemy pobrać jakieś dane związane z najmniejszą wartością, należy użyć klasycznej kombinacji INDEX MATCH z SMALL jako wartością lookup:

Gdzie:

• Return_array jest zakresem, z którego należy wyodrębnić powiązane dane.
• Lookup_array jest zakresem, w którym należy szukać najniższej n-tej wartości.
• N to pozycja najmniejszej interesującej nas wartości.

Na przykład, aby uzyskać nazwę projektu, który ma najniższy koszt, wzór w E3 to:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Gdzie A2:A10 to nazwy projektów, B2:B10 to koszty, a D3 to ranga od najmniejszej.

Skopiuj formułę do poniższych komórek (E4 i E5), a otrzymasz nazwy 3 najtańszych projektów:

Uwagi:

• To rozwiązanie działa dobrze dla zbioru danych, który nie ma duplikatów. Jednak dwie lub więcej zduplikowanych wartości w kolumnie numerycznej może tworzyć "krawaty" w rankingu, co doprowadzi do błędnych wyników. W tym przypadku proszę użyć nieco bardziej wyrafinowanej formuły, aby złamać krawaty.
• W Excelu 365 zadanie to można zrealizować za pomocą nowych funkcji tablic dynamicznych. Oprócz tego, że takie podejście jest znacznie prostsze, automatycznie rozwiązuje problem więzów. Pełne informacje na ten temat znajdziesz w artykule Jak filtrować dolne wartości N w Excelu.

Sortuj liczby od najniższej do najwyższej za pomocą formuły

Chyba każdy wie jak uporządkować liczby za pomocą funkcji Excel Sort. Ale czy wiesz jak wykonać sortowanie za pomocą formuły? Użytkownicy Excela 365 mogą to zrobić w prosty sposób dzięki nowej funkcji SORT. W Excelu 2019, 2016 i wcześniejszych wersjach SORT nie działa, niestety. Ale miej trochę wiary, a SORT przyjdzie na ratunek :)

Podobnie jak w pierwszym przykładzie, używamy funkcji ROWS z rozszerzającym odwołaniem do zakresu w celu inkrementacji k o 1 w każdym wierszu, w którym formuła jest kopiowana:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Wprowadź formułę w pierwszej komórce, a następnie przeciągnij ją w dół do tylu komórek, ile jest wartości w oryginalnym zestawie danych (C2:C10 w tym przykładzie):

Wskazówka. Aby posortować zstępujący , użyj funkcji LARGE zamiast SMALL.

Formuła Excel SMALL dla dat i godzin

Ponieważ daty i czasy są również wartościami liczbowymi (w wewnętrznym systemie Excela daty są przechowywane jako liczby porządkowe, a czasy jako ułamki dziesiętne), funkcja SMALL może je również obsłużyć bez dodatkowego wysiłku z Twojej strony.

Jak widać na zrzutach ekranu poniżej, podstawowa formuła, której używaliśmy dla liczb, działa pięknie również dla dat i godzin:

=SMALL($B$2:$B$10, D2)

MAŁA formuła pozwalająca znaleźć najwcześniejsze 3 daty:

MAŁY wzór do uzyskania najkrótszego 3 razy:

Kolejny przykład pokazuje, jak funkcja SMALL może pomóc w realizacji bardziej konkretnego zadania związanego z datami.

Znajdź poprzednią datę najbardziej zbliżoną do dzisiejszej lub określonej daty

Na liście dat załóżmy, że chcemy znaleźć najbliższą datę przed określoną datą. Można to zrobić za pomocą funkcji SMALL w połączeniu z COUNTIF.

Mając listę dat w B2:B10 i datę docelową w E1, poniższa formuła zwróci datę wcześniejszą najbliższą dacie docelowej:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

Aby wyodrębnić datę, która jest o dwie daty wcześniejsza od daty w E1, czyli wcześniejsza, ale o jedną datę, formuła to:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

Aby znaleźć datę przeszłą najbliższy dziś , użyj funkcji TODAY dla kryteriów COUNTIF:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

Wskazówka. aby zapobiec błędom w sytuacji, gdy nie zostanie znaleziona data pasująca do Twoich kryteriów, możesz owinąć funkcję IFERROR wokół swojej formuły, jak np:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

Jak działają te formuły:

Ogólną ideą jest policzenie liczby dat mniejszych niż data docelowa za pomocą COUNTIF. I ta liczba jest dokładnie tym, czego potrzebuje funkcja SMALL dla k argument.

Aby lepiej zrozumieć tę koncepcję, spójrzmy na nią z innej strony:

Gdyby w naszym zbiorze danych pojawiła się data 1 sierpnia 2020 (data docelowa w E1), byłaby to siódma co do wielkości data na liście. W związku z tym istnieje sześć dat mniejszych od niej. Oznacza to, że szósta najmniejsza data jest poprzednią datą najbliższą dacie docelowej.

Najpierw więc obliczamy, ile dat jest mniejszych od daty w E1 (wynik to 6):

COUNTIF(B2:B10, "<"&E1)

A następnie podłącz liczbę do 2. argumentu SMALL:

=SMALL(B2:B10, 6)

Aby uzyskać przedostatnią datę (czyli w naszym przypadku 5. najmniejszą), od wyniku COUNTIF odejmujemy 1.

Jak podświetlić dolne wartości w programie Excel

Aby wyróżnić najmniejsze wartości n w tabeli za pomocą formatowania warunkowego programu Excel, można użyć wbudowanej opcji Góra/Dół lub skonfigurować własną regułę opartą na formule SMALL. Pierwsza metoda jest szybsza i łatwiejsza do zastosowania, natomiast druga zapewnia większą kontrolę i elastyczność. Poniższe kroki przeprowadzą Cię przez tworzenie niestandardowej reguły:

1. Wybierz zakres, w którym chcesz podświetlić dolne wartości. W naszym przypadku liczby znajdują się w B2:B10, więc wybieramy go. Jeśli chciałbyś podświetlić całe wiersze, to wybierz A2:B10.
2. Na Strona główna zakładka, w Style grupa, kliknij Formatowanie warunkowe > Nowa zasada .
3. W Nowa zasada formatowania okno dialogowe, wybierz Użyj formuły, aby określić, które komórki mają być sformatowane.
4. W Formatuj wartości, w których ta formuła jest prawdziwa pole, wprowadź formułę taką jak ta:

   =B2<=SMALL($B$2:$B$10, 3)

   Gdzie B2 jest najbardziej wysuniętą na lewo komórką sprawdzanego zakresu liczbowego, $B$2:$B$10 jest całym zakresem, a 3 jest wartością n wartości dolne do podświetlenia.

   W swojej formule pamiętaj o typach referencji: lewa komórka jest referencją względną (B2), natomiast zakres jest referencją bezwzględną ($B$2:$B$10).

5. Kliknij przycisk Format i wybrać dowolny format.
6. Kliknij dwukrotnie przycisk OK, aby zamknąć oba okna dialogowe.

Gotowe! Dolne 3 wartości w kolumnie B są podświetlone:

Więcej informacji znajdziesz w rozdziale Formatowanie warunkowe w Excelu na podstawie formuły.

Funkcja SMALL w programie Excel nie działa

Jak właśnie zobaczyłeś na naszych przykładach, używanie funkcji MAŁA w Excelu jest dość łatwe i raczej nie będziesz miał z nią żadnych trudności. Jeśli Twoja formuła nie zadziała, najprawdopodobniej będzie to błąd #LICZBA!, który może wystąpić z następujących powodów:

• Array jest pusta lub nie zawiera pojedynczej wartości liczbowej.
• Na stronie k wartość jest mniejsza od zera (głupia literówka może kosztować Cię wiele godzin rozwiązywania problemów!) lub przekracza liczbę wartości w tablicy.

Oto jak wykorzystać formułę SMALL w Excelu do znalezienia i podkreślenia dolnych liczb w zestawie danych. Jeśli znasz jakieś inne scenariusze, w których funkcja się przydaje, to serdecznie zapraszam do podzielenia się w komentarzach. Dziękuję za przeczytanie i mam nadzieję, że zobaczymy się na naszym blogu za tydzień!

Zeszyt ćwiczeń do pobrania

Przykłady formuły Excel SMALL (plik .xlsx)