Dina tutorial pondok ieu, urang bakal ngobrol ngeunaan pungsi Excel SMALL, cara gawéna jeung cara ngagunakeunana pikeun manggihan nomer Nth pangleutikna, tanggal, atawa waktu.

Peryogi pikeun manggihan sababaraha angka panghandapna dina LKS a? Ieu rada gampang dilakukeun sareng fitur Excel Sort. Naha anjeun henteu hoyong miceunan waktos pikeun nyusun ulang data anjeun kalayan unggal parobihan? Fungsi SMALL bakal ngabantosan anjeun gancang mendakan nilai panghandapna, pangleutikna kadua, pangleutikna katilu, sareng saterasna.

Fungsi Excel SMALL

SMALL mangrupikeun fungsi statistik anu mulih. nilai n-th pangleutikna dina set data.

Sintaksis tina fungsi SMALL ngawengku dua argumen, duanana diperlukeun.

SMALL(array, k)

Dimana:

• Asép Sunandar Sunarya - susunan atawa rentang sél pikeun nimba nilai pangleutikna.
• K - hiji integer anu nuduhkeun posisi tina nilai panghandapna pikeun mulang, nyaéta k-th pangleutikna.

Pungsi ieu sadia dina sadaya vérsi Excel pikeun Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010, jeung saméméhna.

Tip. Pikeun manggihan nilai k-th panghandapna kalawan kriteria, make rumus Excel SMALL IF.

Rumus SMALL Dasar dina Excel

Rumus SMALL dina bentuk dasarna gampang pisan pikeun ngawangun - anjeun ngan nangtukeun rentang jeung posisi ti item pangleutikna pikeun mulang.

Dina daptar angka dina B2:B10, anggap anjeun hoyong nimba nilai 3 pangleutikna. Rumusna nyaéta salakubasajan saperti:

=SMALL(B2:B10, 3)

Pikeun leuwih gampang mariksa hasilna, kolom B diurutkeun dina urutan naek:

4 hal anu anjeun kedah terang ngeunaan fungsi LEUTIK

Catatan pamakean di handap ieu bakal ngabantosan anjeun langkung ngartos paripolah fungsi LEUTIK sareng ngahindarkeun kabingungan nalika ngawangun rumus anjeun nyalira.

1. Sakur sél kosong , nilai text , jeung nilai logical BENER jeung SALAH dina argumen array teu dipalire.
2. Lamun array ngandung hiji atawa leuwih kasalahan , kasalahan dipulangkeun.
3. Upami aya duplikat dina array , rumus anjeun bisa ngakibatkeun "tali". Contona, lamun dua sél ngandung angka 1, sarta fungsi SMALL dikonpigurasikeun pikeun mulangkeun nilai pangleutikna jeung 2nd, anjeun bakal meunang 1 dina duanana kasus.
4. Anggap n nyaéta jumlah nilai dina array , SMALL(array,1) bakal ngabalikeun nilai panghandapna, sareng SMALL(array,n) bakal milih nilai anu pangluhurna.

Kumaha cara ngagunakeun fungsi SMALL dina Excel - conto rumus

Sareng ayeuna, hayu urang tingali sababaraha conto deui pungsi Excel SMALL anu ngalangkungan pamakean dasarna.

Teangan nilai handap 3, 5, 10, jsb

Sakumaha anjeun terang, fungsi SMALL dirancang pikeun ngitung nilai panghandapna n-th. Conto ieu nunjukkeun kumaha cara ngalakukeun ieu paling efektif.

Dina tabel di handap, anggap anjeun hoyong mendakan 3 nilai panghandapna. Jang ngalampahkeun ieu, ngetikangka 1, 2 jeung 3 dina sél misah (D3, D4 jeung D5 bisi urang). Teras, lebetkeun rumus di handap ieu dina E3 sareng sered ka handap ngalangkungan E5:

=SMALL($B$2:$B$10, D3)

Dina E3, rumus ékstrak nilai pangleutikna nganggo angka dina D3 pikeun k argumen. Hal utama nyaéta nyadiakeun référénsi sél anu bener ku sabab éta rumus nyalin leres dina sél anu sanés: mutlak pikeun array sareng relatif pikeun k .

Rek repot ngetik jajaran sacara manual? Anggo pungsi ROWS kalayan rujukan rentang ngembangna pikeun masihan nilai k . Pikeun ieu, urang nyieun rujukan mutlak pikeun sél kahiji (atawa ngan konci koordinat baris kawas B$2) jeung rujukan relatif pikeun sél panungtungan:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Kusabab hasilna, rentang rujukan expands sakumaha rumus ieu disalin ka handap kolom. Dina D2, ROWS(B$2:B2) ngahasilkeun 1 pikeun k , sarta rumusna ngabalikeun biaya panghandapna. Dina D3, ROWS(B$2:B3) ngahasilkeun 2, sarta kami meunang 2nd ongkos panghandapna, jeung saterusna.

Cukup nyalin rumus ngaliwatan 5 sél, tur Anjeun bakal meunang 5 nilai handap:

Jumlah nilai N panghandapna

Hoyong milarian total nilai n pangleutikna dina set data? Upami anjeun parantos nimba nilai sapertos anu dipidangkeun dina conto sateuacana, solusi anu paling gampang nyaéta rumus SUM sapertos:

=SUM(E3:E5)

Atawa anjeun tiasa nyieun rumus mandiri ku ngagunakeun fungsi SMALL babarengan jeung SUMPRODUCT:

Pikeun meunangkeun jumlah tina 3 nilai handap dina susunan data urang, rumus nyokot bentuk kieu :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

Pungsi SUM bakal ngahasilkeun hasil anu sarua:

=SUM(SMALL(B2:B10, {1,2,3}))

Catetan. Lamun make referensi sél tinimbang array constant pikeun k , anjeun kudu mencet Ctrl + Shift + Enter pikeun nyieun rumus array. Dina Excel 365 anu ngadukung susunan dinamis, SUM SMALL tiasa dianggo salaku rumus biasa dina dua kasus.

Kumaha rumus ieu jalanna:

Dina rumus biasa, SMALL ngabalikeun hiji k-th nilai pangleutikna dina rentang. Dina hal ieu, kami nyayogikeun konstanta array sapertos {1,2,3} pikeun argumen k, maksakeun éta ngabalikeun array tina 3 nilai pangleutikna:

{29240, 43610, 58860}

SUMPRODUCT atanapi Fungsi SUM nambihan angka dina Asép Sunandar Sunarya jeung outputs total. Éta!

Rumus LEUTIK INDEX MATCH pikeun meunangkeun patandingan anu pangleutikna

Dina kaayaan nalika anjeun badé nyandak sababaraha data anu aya hubunganana sareng nilai pangleutikna, paké kombinasi INDEX MATCH klasik sareng SMALL pikeun niléy panéangan. :

Dimana :

• Return_array mangrupa rentang ti mana nimba data nu pakait.
• Lookup_array nyaeta rentang dimana neangan n panghandapna. -Nilai ka-.
• N nyaeta posisi nilai nu pangleutikna dipikaresep.

PikeunContona, pikeun meunangkeun ngaran proyék nu boga biaya panghandapna, rumus dina E3 nyaéta:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Dimana A2:A10 mangrupakeun ngaran proyék, B2:B10 nyaéta waragad jeung D3 nyaéta pangkat ti pangleutikna.

Salin rumus ka sél di handap (E4 sareng E5), sareng anjeun bakal nampi nami 3 proyék anu paling murah:

Catetan:

• Solusi ieu hade pikeun susunan data nu teu boga duplikat. Sanajan kitu, dua atawa leuwih nilai duplikat dina kolom numerik bisa nyieun "tali" dina ranking, nu bakal ngakibatkeun hasil salah. Dina hal ieu, mangga paké rumus anu leuwih canggih pikeun megatkeun hubungan.
• Dina Excel 365, tugas ieu bisa dilaksanakeun kalayan bantuan fungsi array dinamis anyar. Salian ti langkung saderhana, pendekatan ieu sacara otomatis ngarengsekeun masalah hubungan. Pikeun detil lengkepna, mangga tingali Cara nyaring nilai N panghandapna dina Excel.

Urutkeun angka ti panghandapna nepi ka pangluhurna make rumus

Kuring yakin sarerea weruh kumaha carana nempatkeun angka dina urutan jeung Fitur Urut Excel. Tapi naha anjeun terang kumaha ngalakukeun asihan nganggo rumus? Pamaké Excel 365 tiasa ngalakukeun éta kalayan gampang kalayan fungsi SORT anyar. Dina Excel 2019, 2016 sareng versi sateuacana, SORT henteu jalan, sayangna. Tapi boga iman saeutik, sarta LEUTIK bakal datang ka nyalametkeun teh :)

Sapertos dina conto kahiji, urang ngagunakeun fungsi ROWS kalawan rujukan rentang ngembangna kana increment k ku 1 dina unggal. baris mana rumusdisalin:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Asupkeun rumus dina sél kahiji, teras sered ka handap ka saloba sél sakumaha aya niléy dina kumpulan data aslina (C2:C10 dina conto ieu) :

Tip. Pikeun nyortir turun , paké fungsi LARGE tinimbang SMALL.

Rumus Excel SMALL pikeun kaping sareng waktos

Kusabab kaping sareng waktos ogé mangrupikeun nilai numerik (dina sistem Excel internal, kaping disimpen salaku nomer urut sareng waktos salaku pecahan desimal), fungsi SMALL tiasa nanganan aranjeunna. ogé tanpa usaha tambahan di sisi anjeun.

Sakumaha anjeun tiasa tingali dina screenshot di handap ieu, rumus dasar anu kami dianggo pikeun angka tiasa dianggo ogé pikeun kaping sareng waktos:

=SMALL($B$2:$B$10, D2)

Rumus LEUTIK pikeun manggihan 3 tanggal pangheubeulna:

Rumus LEUTIK pikeun meunangkeun pangpendek 3 kali:

Conto salajengna nunjukkeun kumaha fungsi SMALL tiasa ngabantosan anjeun ngalaksanakeun tugas anu langkung spésifik anu aya hubunganana sareng kaping.

Teangan tanggal sateuacana anu paling caket sareng dinten ayeuna atanapi tanggal anu ditangtukeun

Dina daptar tanggal. , upami anjeun hoyong milarian tanggal pangcaketna sateuacan tanggal anu ditangtukeun. Ieu bisa dilakukeun ku cara make fungsi SMALL dina kombinasi jeung COUNTIF.

Kalayan daptar tanggal dina B2:B10 jeung tanggal udagan dina E1, rumus ieu bakal mulangkeun tanggal saméméhna pangdeukeutna ka tanggal target:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

Pikeun nimba tanggal anu dua tanggal samemeh tanggal dina E1, nyaéta tanggal samemehna tapi hiji,rumusna nyaéta:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

Pikeun manggihan tanggal kaliwat pangcaketna ka kiwari , paké fungsi TODAY pikeun kriteria COUNTIF:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

Tip. Pikeun nyegah kasalahan dina kaayaan nalika tanggal anu cocog sareng kriteria anjeun henteu kapendak, anjeun tiasa ngabungkus fungsi IFERROR kana rumus anjeun, sapertos kieu:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

Kumaha rumus ieu jalan:

Gagasan umum nyaéta ngitung jumlah tanggal anu langkung alit tibatan tanggal target nganggo COUNTIF. Sareng cacah ieu mangrupikeun naon anu dibutuhkeun ku fungsi SMALL pikeun argumen k .

Pikeun langkung ngartos konsép, hayu urang tingali tina sudut anu sanés:

Upami 1- Aug-2020 (tanggal target dina E1) muncul dina set data urang, éta bakal janten tanggal 7 pangbadagna dina daptar. Akibatna, aya genep tanggal leuwih leutik ti eta. Hartina, tanggal pangleutikna ka-6 nyaéta tanggal saméméhna pangdeukeutna tanggal udagan.

Ku kituna, mimitina urang ngitung sabaraha tanggal anu leuwih leutik batan tanggal dina E1 (hasilna 6):

COUNTIF(B2:B10, "<"&E1)

Salajengna, colokkeun itungan kana argumen 2nd of SMALL:

=SMALL(B2:B10, 6)

Pikeun meunangkeun tanggal samemehna tapi hiji (anu mangrupa tanggal pangleutikna ka-5 dina kasus urang) , urang kurangan 1 tina hasil COUNTIF.

Kumaha cara nyorot nilai handap dina Excel

Pikeun nyorot nilai n pangleutikna dina tabel anjeun sareng pormat kondisional Excel, anjeun tiasa nganggo Top anu diwangun. / Pilihan handap atawa nyetél aturan sorangan dumasar kana rumus LEUTIK. Metodeu kahiji langkung gancangsarta gampang panawaran, sedengkeun nu kadua nyadiakeun leuwih kontrol jeung kalenturan. Léngkah-léngkah di handap ieu bakal dipandu ku anjeun dina nyieun aturan khusus:

1. Pilih rentang anu anjeun hoyong nyorot niléy handap. Dina kasus urang, jumlahna aya dina B2: B10, janten urang pilih éta. Upami anjeun hoyong nyorot sadayana baris, teras pilih A2:B10.
2. Dina tab Home , dina grup Styles , klik Format kondisional > Aturan Anyar .
3. Dina kotak dialog Aturan Format Anyar , pilih Paké rumus pikeun nangtukeun sél mana nu rék diformat.
4. Dina kotak Format dimana rumus ieu leres , lebetkeun rumus sapertos kieu:

   =B2<=SMALL($B$2:$B$10, 3)

   Dimana B2 mangrupikeun sél numerik paling kénca. rentang pikeun dipariksa, $B$2:$B$10 sakabeh rentang, jeung 3 nyaeta n nilai handap pikeun disorot.

   Dina rumus anjeun, mangga inget tipe rujukan: sél paling kénca mangrupa rujukan relatif (B2) sedengkeun rentang mangrupa rujukan mutlak ($B$2:$B$10).

5. Klik tombol Format jeung pilih format nu mana wae nu Anjeun pikaresep.
6. Klik OK dua kali pikeun nutup kadua jandela dialog.

Réngsé! 3 nilai handap dina kolom B disorot:

Pikeun inpormasi lengkep, mangga tingali pormat kondisional Excel dumasar kana rumus.

Pungsi Excel SMALL teu jalan

Sakumaha anu anjeun tingali tina conto kami, ngagunakeun fungsi SMALL dina Excel cukup gampang, sareng anjeunjigana teu aya kasusah jeung eta. Upami rumus anjeun henteu tiasa dianggo, kamungkinan éta bakal janten #NUM! kasalahan, nu bisa lumangsung alatan alesan ieu:

• Array kosong atawa teu ngandung hiji nilai numerik.
• Nu k nilai kirang ti nol (salah ketik konyol bisa ngarugikeun anjeun jam ngungkulan!) Atawa ngaleuwihan jumlah nilai dina array.

Kitu cara ngagunakeun rumus LEUTIK dina Excel pikeun manggihan tur nyorot angka handap dina susunan data. Upami anjeun terang skenario anu sanés dimana fungsina tiasa dianggo, anjeun wilujeng sumping pikeun dibagikeun dina koméntar. Hatur nuhun pikeun maca sareng ngarepkeun anjeun tiasa ningali dina blog urang minggu payun!

Buku latihan pikeun diunduh

Conto rumus Excel LEUTIK (file .xlsx)