У гэтым кароткім падручніку мы пагаворым пра функцыю Excel SMALL, пра тое, як яна працуе і як яе выкарыстоўваць для пошуку найменшага N-га ліку, даты або часу.

Патрэба каб знайсці некалькі найменшых лікаў на аркушы? Гэта даволі лёгка зрабіць з дапамогай функцыі Excel Sort. Не жадаеце марнаваць час на перасарціроўку даных з кожным змяненнем? Функцыя МАЛЫ дапаможа вам хутка знайсці найменшае значэнне, другое найменшае, трэцяе найменшае і гэтак далей.

Функцыя МАЛЫ Excel

МАЛЫ — гэта статыстычная функцыя, якая вяртае n-е найменшае значэнне ў наборы даных.

Сінтаксіс функцыі SMALL уключае два аргументы, абодва з якіх абавязковыя.

SMALL(масіў, k)

Дзе:

• Масіў - масіў або дыяпазон ячэек, з якіх трэба атрымаць найменшае значэнне.
• K - цэлае лік, якое паказвае пазіцыю ад найменшага значэння для вяртання, г.зн. k-е найменшае.

Функцыя даступная ва ўсіх версіях Excel для Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010 і больш раннія версіі.

Парада. Каб знайсці k-е найменшае значэнне з дапамогай крытэрыяў, выкарыстоўвайце формулу Excel SMALL IF.

Асноўная формула SMALL у Excel

Формулу SMALL у яе базавай форме вельмі проста стварыць - вы проста ўказваеце дыяпазон і пазіцыя ад найменшага элемента, які трэба вярнуць.

У спісе лікаў у B2:B10, выкажам здагадку, што вы хочаце атрымаць трэцяе найменшае значэнне. Формула якпроста як:

=SMALL(B2:B10, 3)

Каб вам было прасцей праверыць вынік, слупок B адсартаваны ў парадку ўзрастання:

4 рэчы, якія вы павінны ведаць пра функцыю SMALL

Наступныя заўвагі па выкарыстанні дапамогуць вам лепш зразумець паводзіны функцыі SMALL і пазбегнуць блытаніны пры стварэнні ўласных формул.

1. Любая пустыя ячэйкі , тэкставыя значэнні і лагічныя значэнні TRUE і FALSE у масіве аргументу ігнаруюцца.
2. Калі масіў змяшчае адну ці некалькі памылак , вяртаецца памылка.
3. У выпадку, калі ў масіўе ёсць дублікаты , ваша формула можа прывесці да «сувязяў». Напрыклад, калі дзве ячэйкі ўтрымліваюць лік 1, а функцыя SMALL настроена на вяртанне найменшага і другога найменшага значэнняў, вы атрымаеце 1 у абодвух выпадках.
4. Калі n з'яўляецца колькасцю значэнняў у масіў , SMALL(масіў,1) верне найменшае значэнне, а SMALL(масіў,n) выбярэ найбольшае значэнне.

Як выкарыстоўваць функцыю SMALL у Excel - прыклады формул

А цяпер давайце паглядзім яшчэ некалькі прыкладаў функцыі Excel SMALL, якія выходзяць за рамкі яе базавага выкарыстання.

Знайдзіце ніжнія значэнні 3, 5, 10 і г.д.

Як вы ўжо ведаеце, функцыя SMALL прызначана для вылічэння n-га найменшага значэння. Гэты прыклад паказвае, як зрабіць гэта найбольш эфектыўна.

Выкажам здагадку, што ў табліцы ніжэй вы хочаце знайсці 3 ніжнія значэнні. Для гэтага ўвядзіцелічбы 1, 2 і 3 у асобныя клеткі (у нашым выпадку D3, D4 і D5). Затым увядзіце наступную формулу ў E3 і перацягніце яе ўніз праз E5:

=SMALL($B$2:$B$10, D3)

У E3 формула здабывае найменшае значэнне, выкарыстоўваючы лік у D3 для k аргумент. Галоўнае — падаць правільныя спасылкі на ячэйкі, дзякуючы якім формула карэктна капіюецца ў іншыя ячэйкі: абсалютныя для масіў і адносныя для k .

Не жадаеце ўводзіць рангі ўручную? Выкарыстоўвайце функцыю ROWS са спасылкай пашыраючы дыяпазон , каб атрымаць значэнне k . Для гэтага мы робім абсалютную спасылку для першай ячэйкі (або толькі фіксуем каардынаты радка, як B$2) і адносную спасылку для апошняй ячэйкі:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

У выніку дыяпазон спасылка пашыраецца, калі формула капіюецца ўніз па слупку. У D2 ROWS(B$2:B2) дае 1 для k , а формула вяртае найменшы кошт. У D3 ROWS(B$2:B3) дае 2, і мы атрымліваем 2-і самы нізкі кошт, і гэтак далей.

Проста скапіруйце формулу праз 5 вочак, і вы атрымаеце 5 ніжніх значэнняў:

Сума ніжніх N значэнняў

Хочаце знайсці агульную колькасць найменшых n значэнняў у наборы даных? Калі вы ўжо здабылі значэнні, як паказана ў папярэднім прыкладзе, самым простым рашэннем будзе формула СУММА:

=SUM(E3:E5)

Або вы можаце зрабіць незалежную формулу, выкарыстоўваючы функцыю SMALL разам з SUMPRODUCT:

Каб атрымаць суму 3 апошніх значэнняў у нашым наборы даных, формула прымае такую ​​форму :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

Функцыя SUM дасць той самы вынік:

=SUM(SMALL(B2:B10, {1,2,3}))

Заўвага. Калі вы выкарыстоўваеце спасылкі на ячэйкі замест канстанты масіва для k , вам трэба націснуць Ctrl + Shift + Enter, каб зрабіць гэта формулай масіву. У Excel 365, які падтрымлівае дынамічныя масівы, SUM SMALL працуе як звычайная формула ў любым выпадку.

Як працуе гэтая формула:

У звычайнай формуле SMALL вяртае адно k-е найменшае значэнне ў дыяпазоне. У гэтым выпадку мы даем канстанту масіва накшталт {1,2,3} для аргумента k, прымушаючы яго вяртаць масіў з 3 найменшых значэнняў:

{29240, 43610, 58860}

SUMPRODUCT або Функцыя SUM складае лікі ў масіве і выводзіць агульную суму. Вось і ўсё!

Формула INDEX MATCH SMALL для атрымання найменшых супадзенняў

У сітуацыі, калі вы хочаце атрымаць некаторыя даныя, звязаныя з найменшым значэннем, выкарыстоўвайце класічную камбінацыю INDEX MATCH з SMALL для значэння пошуку. :

Дзе :

• Return_array - гэта дыяпазон, з якога трэба здабываць звязаныя даныя.
• Lookup_array - гэта дыяпазон, у якім трэба шукаць найменшы n -е значэнне.
• N - пазіцыя найменшага цікавага значэння.

Длянапрыклад, каб атрымаць назву праекта, які мае самы нізкі кошт, формула ў E3:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Дзе A2:A10 - гэта назвы праектаў, B2:B10 - гэта выдаткі і D3 - гэта ранг ад найменшага.

Скапіруйце формулу ў ячэйкі ніжэй (E4 і E5), і вы атрымаеце назвы 3 самых танных праектаў:

Заўвагі:

• Гэта рашэнне добра працуе для набору даных, які не мае дублікатаў. Аднак два або больш паўтаральных значэнняў у лікавым слупку могуць стварыць "сувязі" ў рэйтынгу, што прывядзе да няправільных вынікаў. У гэтым выпадку выкарыстоўвайце крыху больш складаную формулу, каб разарваць сувязі.
• У Excel 365 гэта задача можа быць выканана з дапамогай новых функцый дынамічнага масіву. Гэты падыход не толькі нашмат прасцей, але і аўтаматычна вырашае праблему сувязяў. Для атрымання больш падрабязнай інфармацыі, калі ласка, гл. Як адфільтраваць ніжнія значэнні N у Excel.

Сартаванне лікаў ад найменшага да высокага з дапамогай формулы

Я лічу, што кожны ведае, як упарадкаваць лічбы з дапамогай Функцыя сартавання Excel. Але ці ведаеце вы, як выканаць сартаванне па формуле? Карыстальнікі Excel 365 могуць зрабіць гэта простым спосабам з дапамогай новай функцыі SORT. У Excel 2019, 2016 і больш ранніх версіях SORT не працуе, нажаль. Але паверце крыху, і SMALL прыйдзе на дапамогу :)

Як і ў першым прыкладзе, мы выкарыстоўваем функцыю ROWS са спасылкай на пашыраны дыяпазон, каб павялічваць k на 1 у кожным радок, дзе формулакапіюецца:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Увядзіце формулу ў першую ячэйку, а затым перацягніце яе ўніз да такой колькасці ячэек, колькі значэнняў у зыходным наборы даных (C2:C10 у гэтым прыкладзе) :

Савет. Для сартавання па змяншэнні выкарыстоўвайце функцыю LARGE замест SMALL.

Формула Excel SMALL для дат і часу

Паколькі даты і час таксама з'яўляюцца лікавымі значэннямі (ва ўнутранай сістэме Excel даты захоўваюцца як паслядоўныя лікі, а час як дзесятковыя дробы), функцыя SMALL можа іх апрацоўваць а таксама без якіх-небудзь дадатковых намаганняў з вашага боку.

Як вы можаце бачыць на скрыншотах ніжэй, асноўная формула, якую мы выкарыстоўвалі для лікаў, выдатна працуе таксама для дат і часу:

=SMALL($B$2:$B$10, D2)

МАЛАЯ формула, каб знайсці 3 самыя раннія даты:

МАЛАЯ формула, каб знайсці самыя кароткія 3 даты:

У наступным прыкладзе паказана, як функцыя SMALL можа дапамагчы вам выканаць больш канкрэтную задачу, звязаную з датамі.

Знайдзіце папярэднюю дату, бліжэйшую да сённяшняй або вызначанай даты

У спісе дат , выкажам здагадку, што вы хочаце знайсці бліжэйшую дату да вызначанай даты. Гэта можна зрабіць з дапамогай функцыі SMALL у спалучэнні з COUNTIF.

Са спісам дат у B2:B10 і мэтавай датай у E1 наступная формула верне папярэднюю дату, бліжэйшую да мэтавай:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

Каб атрымаць дату, якая на дзве даты папярэднічае даце ў E1, г.зн. даце, папярэдняй перад адной,формула:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

Каб знайсці мінулую дату найбліжэйшую да сённяшняй , выкарыстоўвайце функцыю СЁННЯ для крытэрыяў COUNTIF:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

Савет. Каб прадухіліць памылкі ў сітуацыі, калі дата, якая адпавядае вашым крытэрам, не знойдзена, вы можаце абгарнуць функцыю IFERROR вакол вашай формулы, як гэта:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

Як працуюць гэтыя формулы:

Агульная ідэя складаецца ў тым, каб падлічыць колькасць дат, меншых за мэтавую, з дапамогай COUNTIF. І гэты лік якраз і патрэбны функцыі SMALL для аргумента k .

Каб лепш зразумець канцэпцыю, давайце паглядзім на яе з іншага боку:

Калі 1- Жнівень 2020 г. (запланаваная дата ў E1) з'явіўся ў нашым наборы даных, гэта будзе 7-я па велічыні дата ў спісе. Такім чынам, ёсць шэсць дат, меншых за яго. Гэта азначае, што 6-я найменшая дата - гэта папярэдняя дата, бліжэйшая да мэтавай даты.

Такім чынам, спачатку мы падлічым, колькі дат меншых за дату ў E1 (вынік 6):

COUNTIF(B2:B10, "<"&E1)

І затым падключыце лік да 2-га аргумента SMALL:

=SMALL(B2:B10, 6)

Каб атрымаць дату перад адной (у нашым выпадку гэта 5-я найменшая дата) , мы адымаем 1 з выніку COUNTIF.

Як вылучыць ніжнія значэнні ў Excel

Каб вылучыць найменшыя n значэнняў у вашай табліцы з дапамогай умоўнага фарматавання Excel, вы можаце выкарыстаць альбо ўбудаваны Top /Ніжняя опцыя або наладзьце ўласнае правіла на аснове МАЛОЙ формулы. Першы спосаб больш хуткіі лягчэй прымяняць, у той час як другі забяспечвае больш кантролю і гнуткасці. Наступныя крокі правядуць вас праз стварэнне ўласнага правіла:

1. Выберыце дыяпазон, у якім вы хочаце вылучыць ніжнія значэнні. У нашым выпадку лічбы знаходзяцца ў B2:B10, таму мы выбіраем яго. Калі вы хочаце вылучыць цэлыя радкі, абярыце A2:B10.
2. На ўкладцы Галоўная ў групе Стылі націсніце Умоўнае фарматаванне > Новае правіла .
3. У дыялогавым акне Новае правіла фарматавання выберыце Выкарыстоўваць формулу, каб вызначыць, якія ячэйкі фарматаваць.
4. У полі Фарматаваць значэнні, дзе гэтая формула праўдзівая , увядзіце формулу накшталт гэтай:

   =B2<=SMALL($B$2:$B$10, 3)

   Дзе B2 — крайняя левая лічбавая ячэйка дыяпазон, які трэба праверыць, $B$2:$B$10 - гэта ўвесь дыяпазон, а 3 - гэта n ніжнія значэнні, якія трэба вылучыць.

   У сваёй формуле звярніце ўвагу на тыпы спасылак: крайняя левая ячэйка з'яўляецца адноснай спасылкай (B2), а дыяпазон - абсалютнай спасылкай ($B$2:$B$10).

5. Націсніце кнопку Фарматаваць і абярыце любы фармат, які вам падабаецца.
6. Націсніце ОК двойчы, каб закрыць абодва дыялогавыя вокны.

Гатова! 3 ніжнія значэнні ў слупку B вылучаны:

Для атрымання дадатковай інфармацыі, калі ласка, гл. Умоўнае фарматаванне Excel на аснове формулы.

Функцыя Excel SMALL не працуе

Як вы толькі што бачылі з нашых прыкладаў, выкарыстоўваць функцыю SMALL у Excel даволі проста, і вынаўрад ці ўзнікнуць з гэтым якія-небудзь цяжкасці. Калі ваша формула не працуе, хутчэй за ўсё, гэта будзе #NUM! памылка, якая можа адбыцца па наступных прычынах:

• Масіў пусты або не змяшчае ніводнага лікавага значэння.
• k значэнне меншае за нуль (дурная памылка друку можа каштаваць вам гадзін пошуку і ліквідацыі непаладак!) або перавышае колькасць значэнняў у масіве.

Вось як выкарыстоўваць МАЛЕНЬКУЮ формулу ў Excel, каб знайсці і вылучыць ніжнія лічбы ў наборы даных. Калі вы ведаеце якія-небудзь іншыя сцэнарыі, калі гэтая функцыя спатрэбіцца, вы можаце падзяліцца імі ў каментарах. Я дзякую вам за чытанне і спадзяюся ўбачыць вас у нашым блогу на наступным тыдні!

Практычны сшытак для спампоўкі

Прыклады невялікай формулы Excel (файл .xlsx)