આ ટુંકા ટ્યુટોરીયલમાં, અમે Excel SMALL ફંક્શન વિશે વાત કરીશું, તે કેવી રીતે કાર્ય કરે છે અને Nth સૌથી નાની સંખ્યા, તારીખ અથવા સમય શોધવા માટે તેનો ઉપયોગ કેવી રીતે કરવો.

જરૂર છે. વર્કશીટમાં થોડા ઓછા નંબરો શોધવા માટે? એક્સેલ સૉર્ટ સુવિધા સાથે આ કરવું એકદમ સરળ છે. દરેક ફેરફાર સાથે તમારા ડેટાને ફરીથી સૉર્ટ કરવામાં સમય બગાડવા નથી માંગતા? SMALL ફંક્શન તમને સૌથી નીચું મૂલ્ય, બીજું સૌથી નાનું, ત્રીજું સૌથી નાનું, વગેરે શોધવામાં મદદ કરશે.

Excel SMALL ફંક્શન

SMALL એ આંકડાકીય કાર્ય છે જે પરત કરે છે. ડેટા સેટમાં n-મું સૌથી નાનું મૂલ્ય.

SMALL ફંક્શનના સિન્ટેક્સમાં બે દલીલોનો સમાવેશ થાય છે, જે બંને જરૂરી છે.

SMALL(એરે, k)

ક્યાં:

• એરે - એક એરે અથવા કોષોની શ્રેણી જેમાંથી સૌથી નાનું મૂલ્ય કાઢવાનું છે.
• K - એક પૂર્ણાંક જે પરત કરવા માટે સૌથી નીચા મૂલ્યથી સ્થિતિ સૂચવે છે, એટલે કે k-th સૌથી નાનું.

આ ફંક્શન Office 365, Excel 2021, Excel 2019, Excel 2016, Excel માટે Excel ના તમામ સંસ્કરણોમાં ઉપલબ્ધ છે. 2013, એક્સેલ 2010 અને તે પહેલાનું.

ટીપ. માપદંડ સાથે k-th સૌથી નીચું મૂલ્ય શોધવા માટે, Excel SMALL IF સૂત્રનો ઉપયોગ કરો.

એક્સેલમાં મૂળભૂત સ્મોલ ફોર્મ્યુલા

એક નાનું સૂત્ર તેના મૂળભૂત સ્વરૂપમાં ખૂબ જ સરળ છે - તમે ફક્ત સ્પષ્ટ કરો શ્રેણી અને પરત કરવા માટેની સૌથી નાની વસ્તુમાંથી સ્થિતિ.

B2:B10 માં સંખ્યાઓની સૂચિમાં, ધારો કે તમે 3જી સૌથી નાની કિંમત કાઢવા માંગો છો. સૂત્ર આ પ્રમાણે છેઆ રીતે સરળ છે:

=SMALL(B2:B10, 3)

તમારા માટે પરિણામ તપાસવાનું સરળ બનાવવા માટે, કૉલમ B ને ચડતા ક્રમમાં ગોઠવવામાં આવે છે:

SMALL ફંક્શન વિશે તમારે 4 વસ્તુઓ જાણવી જોઈએ

નીચેની ઉપયોગ નોંધો તમને નાના કાર્યની વર્તણૂકને વધુ સારી રીતે સમજવામાં અને તમારા પોતાના સૂત્રો બનાવતી વખતે મૂંઝવણ ટાળવામાં મદદ કરશે.

1. કોઈપણ ખાલી કોષો , ટેક્સ્ટ મૂલ્યો, અને એરે દલીલમાં તાર્કિક મૂલ્યો TRUE અને FALSE અવગણવામાં આવે છે.
2. જો એરે માં એક અથવા વધુ ભૂલો હોય છે, એક ભૂલ પરત કરવામાં આવે છે.
3. જો એરે માં ડુપ્લિકેટ્સ હોય, તો તમારું સૂત્ર "સંબંધો" માં પરિણમી શકે છે. ઉદાહરણ તરીકે, જો બે કોષોમાં નંબર 1 હોય, અને SMALL ફંક્શન સૌથી નાનું અને 2જી સૌથી નાનું મૂલ્ય પરત કરવા માટે ગોઠવેલું હોય, તો તમને બંને કિસ્સાઓમાં 1 મળશે.
4. માનીએ છીએ કે n એ <માં મૂલ્યોની સંખ્યા છે 1>એરે , SMALL(એરે,1) સૌથી નીચું મૂલ્ય આપશે, અને SMALL(એરે,n) સૌથી વધુ મૂલ્ય પસંદ કરશે.

એક્સેલમાં SMALL ફંક્શનનો ઉપયોગ કેવી રીતે કરવો - ફોર્મ્યુલા ઉદાહરણો

અને હવે, ચાલો Excel SMALL ફંક્શનના કેટલાક વધુ ઉદાહરણો જોઈએ જે તેના મૂળભૂત વપરાશથી આગળ વધે છે.

તળિયે 3, 5, 10, વગેરે મૂલ્યો શોધો

જેમ તમે પહેલાથી જ જાણો છો, SMALL ફંક્શન n-th સૌથી નીચી કિંમતની ગણતરી કરવા માટે રચાયેલ છે. આ ઉદાહરણ બતાવે છે કે આ સૌથી અસરકારક રીતે કેવી રીતે કરવું.

નીચેના કોષ્ટકમાં, ધારો કે તમે નીચેના 3 મૂલ્યો શોધવા માંગો છો. આ માટે, ટાઈપ કરોઅલગ કોષોમાં નંબર 1, 2 અને 3 (અમારા કિસ્સામાં D3, D4 અને D5). પછી, E3 માં નીચેનું સૂત્ર દાખલ કરો અને તેને E5 દ્વારા નીચે ખેંચો:

=SMALL($B$2:$B$10, D3)

E3 માં, ફોર્મ્યુલા k<2 માટે D3 માં નંબરનો ઉપયોગ કરીને સૌથી નાનું મૂલ્ય કાઢે છે> દલીલ. મુખ્ય બાબત એ છે કે યોગ્ય કોષ સંદર્ભો પૂરા પાડવાનું છે જેના કારણે સૂત્ર અન્ય કોષોમાં યોગ્ય રીતે નકલ કરે છે: એરે માટે સંપૂર્ણ અને k માટે સંબંધિત.

રેન્ક મેન્યુઅલી ટાઇપ કરવાની તસ્દી લેવા માંગતા નથી? k મૂલ્ય પ્રદાન કરવા માટે વિસ્તરણ શ્રેણી સંદર્ભ સાથે ROWS ફંક્શનનો ઉપયોગ કરો. આ માટે, અમે પ્રથમ કોષ માટે સંપૂર્ણ સંદર્ભ બનાવીએ છીએ (અથવા ફક્ત B$2 જેવા પંક્તિ સંકલનને લૉક કરીએ છીએ) અને છેલ્લા કોષ માટે સંબંધિત સંદર્ભ:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

પરિણામે, શ્રેણી સંદર્ભ વિસ્તૃત થાય છે કારણ કે ફોર્મ્યુલા કૉલમ નીચે કૉપિ કરવામાં આવે છે. D2 માં, ROWS(B$2:B2) k માટે 1 ઉત્પન્ન કરે છે, અને ફોર્મ્યુલા સૌથી ઓછી કિંમત આપે છે. D3 માં, ROWS(B$2:B3) 2 ઉપજ આપે છે, અને અમને 2જી સૌથી ઓછી કિંમત મળે છે, વગેરે.

ફક્ત 5 કોષો દ્વારા ફોર્મ્યુલાની નકલ કરો, અને તમને નીચેના 5 મૂલ્યો મળશે:

સમ બોટમ N મૂલ્યો

ડેટાસેટમાં કુલ સૌથી નાના n મૂલ્યો શોધવા માંગો છો? જો તમે પહેલાનાં ઉદાહરણમાં બતાવેલ મૂલ્યો પહેલેથી જ એક્સટ્રેક્ટ કરી લીધા હોય, તો સૌથી સરળ ઉકેલ એ SUM ફોર્મ્યુલા હશે જેમ કે:

=SUM(E3:E5)

અથવા તમે SUMPRODUCT:

આપણા ડેટાના સેટમાં નીચેના 3 મૂલ્યોનો સરવાળો મેળવવા માટે, સૂત્ર આ આકાર લે છે :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

SUM ફંક્શન સમાન પરિણામ આપશે:

=SUM(SMALL(B2:B10, {1,2,3}))

નોંધ. જો તમે k માટે એરે કોન્સ્ટન્ટને બદલે સેલ સંદર્ભો નો ઉપયોગ કરો છો, તો તમારે તેને એરે ફોર્મ્યુલા બનાવવા માટે Ctrl + Shift + Enter દબાવવાની જરૂર છે. એક્સેલ 365 માં કે જે ડાયનેમિક એરેને સપોર્ટ કરે છે, SUM SMALL બંને કિસ્સામાં નિયમિત ફોર્મ્યુલા તરીકે કામ કરે છે.

આ ફોર્મ્યુલા કેવી રીતે કામ કરે છે:

નિયમિત ફોર્મ્યુલામાં, SMALL શ્રેણીમાં એક k-th સૌથી નાની કિંમત આપે છે. આ કિસ્સામાં, અમે k દલીલ માટે {1,2,3} જેવો એરે કોન્સ્ટન્ટ સપ્લાય કરીએ છીએ, તેને સૌથી નાની 3 મૂલ્યોની એરે પરત કરવાની ફરજ પાડીએ છીએ:

{29240, 43610, 58860}

SUMPRODUCT અથવા SUM ફંક્શન એરેમાં સંખ્યાઓ ઉમેરે છે અને કુલ આઉટપુટ કરે છે. બસ!

સૌથી નાની મેચો મેળવવા માટે INDEX MATCH સ્મોલ ફોર્મ્યુલા

જ્યારે તમે સૌથી નાની કિંમત સાથે સંકળાયેલ કેટલાક ડેટાને પુનઃપ્રાપ્ત કરવા માંગતા હો ત્યારે લુકઅપ મૂલ્ય માટે SMALL સાથે ક્લાસિક INDEX MATCH સંયોજનનો ઉપયોગ કરો. :

ક્યાં :

• Return_array એ એક શ્રેણી છે જેમાંથી સંકળાયેલ ડેટા કાઢવાનો છે.
• Lookup_array એ એક શ્રેણી છે જ્યાં સૌથી ઓછા n માટે શોધ કરવી -મું મૂલ્ય.
• N એ વ્યાજના સૌથી નાના મૂલ્યની સ્થિતિ છે.

માટેઉદાહરણ તરીકે, સૌથી ઓછી કિંમત ધરાવતા પ્રોજેક્ટનું નામ મેળવવા માટે, E3 માં સૂત્ર છે:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

જ્યાં A2:A10 એ પ્રોજેક્ટના નામ છે, B2:B10 એ ખર્ચ છે અને D3 એ સૌથી નાનો ક્રમ છે.

નીચેના કોષો (E4 અને E5) પર સૂત્રની નકલ કરો, અને તમને 3 સૌથી સસ્તા પ્રોજેક્ટના નામ મળશે:

નોંધો:

• આ સોલ્યુશન એવા ડેટાસેટ માટે સારું કામ કરે છે જેમાં કોઈ ડુપ્લિકેટ નથી. જો કે, આંકડાકીય કૉલમમાં બે અથવા વધુ ડુપ્લિકેટ મૂલ્યો રેન્કિંગમાં "ટાઈ" બનાવી શકે છે, જે ખોટા પરિણામો તરફ દોરી જશે. આ કિસ્સામાં, કૃપા કરીને સંબંધો તોડવા માટે થોડી વધુ અત્યાધુનિક ફોર્મ્યુલાનો ઉપયોગ કરો.
• એક્સેલ 365માં, આ કાર્ય નવા ડાયનેમિક એરે ફંક્શન્સની મદદથી પૂર્ણ કરી શકાય છે. વધુ સરળ હોવા ઉપરાંત, આ અભિગમ આપમેળે સંબંધોની સમસ્યાને હલ કરે છે. સંપૂર્ણ વિગતો માટે, મહેરબાની કરીને જુઓ કે એક્સેલમાં નીચેના N મૂલ્યોને કેવી રીતે ફિલ્ટર કરવું.

સૂત્ર વડે સૌથી નીચાથી ઉચ્ચતમ સુધી નંબરોને સૉર્ટ કરો

હું માનું છું કે દરેક વ્યક્તિ જાણે છે કે નંબરોને ક્રમમાં કેવી રીતે મૂકવો એક્સેલ સૉર્ટ સુવિધા. પરંતુ શું તમે જાણો છો કે ફોર્મ્યુલા સાથે સોર્ટિંગ કેવી રીતે કરવું? એક્સેલ 365 ના વપરાશકર્તાઓ તેને નવા SORT ફંક્શન સાથે સરળ રીતે કરી શકે છે. એક્સેલ 2019, 2016 અને પહેલાનાં વર્ઝનમાં, SORT કામ કરતું નથી, અરે. પરંતુ થોડો વિશ્વાસ રાખો, અને SMALL બચાવમાં આવશે :)

પ્રથમ ઉદાહરણની જેમ, અમે ROWS ફંક્શનનો ઉપયોગ વિસ્તરતી રેન્જ સંદર્ભ સાથે k પ્રત્યેક 1 દ્વારા વધારો કરવા માટે કરીએ છીએ પંક્તિ જ્યાં સૂત્રકોપી કરેલ છે:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

પ્રથમ કોષમાં ફોર્મ્યુલા દાખલ કરો, અને પછી મૂળ ડેટા સેટમાં જેટલા મૂલ્યો છે તેટલા કોષો સુધી તેને નીચે ખેંચો (આ ઉદાહરણમાં C2:C10) :

ટીપ. ઉતરતા ને સૉર્ટ કરવા માટે, SMALL ને બદલે LARGE ફંક્શનનો ઉપયોગ કરો. 13 તેમજ તમારી બાજુના કોઈપણ વધારાના પ્રયત્નો વિના.

જેમ તમે નીચેના સ્ક્રીનશૉટ્સમાં જોઈ શકો છો, એક મૂળભૂત સૂત્ર જેનો અમે નંબરો માટે ઉપયોગ કર્યો છે તે તારીખો અને સમય માટે પણ સુંદર રીતે કાર્ય કરે છે:

=SMALL($B$2:$B$10, D2)

સૌથી વહેલી 3 તારીખો શોધવા માટે નાનું સૂત્ર:

સૌથી ટૂંકી 3 વખત મેળવવા માટે નાનું સૂત્ર:

આગલું ઉદાહરણ બતાવે છે કે કેવી રીતે SMALL ફંક્શન તમને તારીખો સંબંધિત વધુ ચોક્કસ કાર્ય પૂર્ણ કરવામાં મદદ કરી શકે છે.

આજની સૌથી નજીકની અગાઉની તારીખ અથવા ઉલ્લેખિત તારીખ શોધો

તારીખોની સૂચિમાં , ધારો કે તમે નિર્દિષ્ટ તારીખ પહેલા નજીકની તારીખ શોધવા માંગો છો. આ COUNTIF સાથે સંયોજનમાં SMALL ફંક્શનનો ઉપયોગ કરીને કરી શકાય છે.

B2:B10 માં તારીખોની સૂચિ અને E1 માં લક્ષ્ય તારીખ સાથે, નીચેનું સૂત્ર લક્ષ્ય તારીખની સૌથી નજીકની અગાઉની તારીખ આપશે:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

એક તારીખ કાઢવા માટે કે જે E1 માં તારીખ પહેલાંની બે તારીખ હોય, એટલે કે અગાઉની પરંતુ એક તારીખ,ફોર્મ્યુલા છે:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

પાછલી તારીખ શોધવા માટે આજની સૌથી નજીક , COUNTIF ના માપદંડ માટે TODAY ફંક્શનનો ઉપયોગ કરો:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

ટીપ. તમારા માપદંડ સાથે મેળ ખાતી તારીખ ન મળે ત્યારે પરિસ્થિતિમાં ભૂલોને રોકવા માટે, તમે તમારા ફોર્મ્યુલાની આસપાસ IFERROR ફંક્શનને લપેટી શકો છો, જેમ કે:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

આ ફોર્મ્યુલા કેવી રીતે કાર્ય કરે છે:

સામાન્ય વિચાર એ છે કે COUNTIF સાથે લક્ષિત તારીખ કરતાં નાની તારીખોની સંખ્યા ગણવી. અને આ ગણતરી એ જ છે જે નાના ફંક્શનને k દલીલ માટે જરૂરી છે.

વિભાવનાને વધુ સારી રીતે સમજવા માટે, ચાલો તેને બીજા ખૂણાથી જોઈએ:

જો 1- ઑગસ્ટ-2020 (E1 માં લક્ષ્યાંક તારીખ) અમારા ડેટાસેટમાં દેખાય છે, તે સૂચિમાં 7મી સૌથી મોટી તારીખ હશે. પરિણામે, તેના કરતાં છ તારીખો નાની છે. મતલબ, 6ઠ્ઠી સૌથી નાની તારીખ એ લક્ષ્ય તારીખની સૌથી નજીકની પાછલી તારીખ છે.

તેથી, પહેલા આપણે ગણતરી કરીએ છીએ કે E1 ની તારીખ કરતાં કેટલી તારીખો નાની છે (પરિણામ 6 છે):

COUNTIF(B2:B10, "<"&E1)

અને પછી, ગણતરીને SMALL ની 2જી દલીલમાં પ્લગ કરો:

=SMALL(B2:B10, 6)

પહેલી પણ એક તારીખ મેળવવા માટે (જે અમારા કિસ્સામાં 5મી સૌથી નાની તારીખ છે) , અમે COUNTIF ના પરિણામમાંથી 1 બાદ કરીએ છીએ.

એક્સેલમાં નીચેના મૂલ્યોને કેવી રીતે હાઇલાઇટ કરવું

તમારા કોષ્ટકમાં સૌથી નાના n મૂલ્યોને એક્સેલ કંડીશનલ ફોર્મેટિંગ સાથે હાઇલાઇટ કરવા માટે, તમે બિલ્ટ-ઇન ટોપનો ઉપયોગ કરી શકો છો. /બોટમ વિકલ્પ અથવા નાના ફોર્મ્યુલાના આધારે તમારો પોતાનો નિયમ સેટ કરો. પ્રથમ પદ્ધતિ ઝડપી છેઅને લાગુ કરવા માટે સરળ છે, જ્યારે બીજું વધુ નિયંત્રણ અને સુગમતા પ્રદાન કરે છે. નીચેના પગલાં તમને કસ્ટમ નિયમ બનાવવા તરફ લઈ જશે:

1. તમે નીચેનાં મૂલ્યોને હાઇલાઇટ કરવા માંગો છો તે શ્રેણી પસંદ કરો. અમારા કિસ્સામાં, સંખ્યાઓ B2:B10 માં છે, તેથી અમે તેને પસંદ કરીએ છીએ. જો તમે સમગ્ર પંક્તિઓને પ્રકાશિત કરવા માંગતા હો, તો પછી A2:B10 પસંદ કરો.
2. Home ટેબ પર, શૈલીઓ જૂથમાં, શરતી ફોર્મેટિંગ પર ક્લિક કરો > નવો નિયમ .
3. નવો ફોર્મેટિંગ નિયમ સંવાદ બોક્સમાં, કયા કોષોને ફોર્મેટ કરવા તે નક્કી કરવા માટે ફોર્મ્યુલાનો ઉપયોગ કરો.
4. ફોર્મેટ મૂલ્યો જ્યાં આ સૂત્ર સાચું છે બોક્સમાં, આના જેવું એક સૂત્ર દાખલ કરો:

   =B2<=SMALL($B$2:$B$10, 3)

   જ્યાં B2 એ આંકડાકીયનો સૌથી ડાબો કોષ છે ચકાસવાની શ્રેણી, $B$2:$B$10 એ સમગ્ર શ્રેણી છે, અને 3 એ n નીચેની કિંમતો છે જે હાઇલાઇટ કરવા માટે છે.

   તમારા ફોર્મ્યુલામાં, કૃપા કરીને સંદર્ભ પ્રકારોને ધ્યાનમાં રાખો: ડાબી બાજુનો કોષ એ સંબંધિત સંદર્ભ (B2) છે જ્યારે શ્રેણી સંપૂર્ણ સંદર્ભ છે ($B$2:$B$10).

5. ફોર્મેટ બટન પર ક્લિક કરો અને તમને ગમે તે ફોર્મેટ પસંદ કરો.
6. બંને સંવાદ વિન્ડો બંધ કરવા માટે ઓકે બે વાર ક્લિક કરો.

થઈ ગયું! કૉલમ B માં નીચેના 3 મૂલ્યો હાઇલાઇટ કરવામાં આવ્યા છે:

વધુ માહિતી માટે, કૃપા કરીને ફોર્મ્યુલાના આધારે એક્સેલ શરતી ફોર્મેટિંગ જુઓ.

Excel SMALL ફંક્શન કામ કરતું નથી

તમે હમણાં જ અમારા ઉદાહરણોમાંથી જોયું તેમ, Excel માં SMALL ફંક્શનનો ઉપયોગ કરવો એકદમ સરળ છે, અને તમેતેની સાથે કોઈ મુશ્કેલીઓ થવાની શક્યતા નથી. જો તમારું સૂત્ર કામ કરતું નથી, તો મોટા ભાગે તે #NUM હશે! ભૂલ, જે નીચેના કારણોસર થઈ શકે છે:

• એરે ખાલી છે અથવા તેમાં એક પણ આંકડાકીય મૂલ્ય નથી.
• ધ કે મૂલ્ય શૂન્ય કરતાં ઓછું છે (એક મૂર્ખ ટાઈપો તમને મુશ્કેલીનિવારણના કલાકો ખર્ચી શકે છે!) અથવા એરેમાં મૂલ્યોની સંખ્યા કરતાં વધી જાય છે.

તે શોધવા માટે એક્સેલમાં નાના ફોર્મ્યુલાનો ઉપયોગ કેવી રીતે કરવો અને ડેટાના સમૂહમાં નીચેની સંખ્યાઓ પ્રકાશિત કરો. જો તમે કોઈ અન્ય દૃશ્યો જાણો છો જ્યાં ફંક્શન હાથમાં આવે છે, તો ટિપ્પણીઓમાં શેર કરવા માટે તમારું સ્વાગત છે. હું વાંચવા બદલ તમારો આભાર માનું છું અને આગામી અઠવાડિયે તમને અમારા બ્લોગ પર મળવાની આશા રાખું છું!

ડાઉનલોડ માટે પ્રેક્ટિસ વર્કબુક

Excel નાના ફોર્મ્યુલા ઉદાહરણો (.xlsx ફાઇલ)