Bu kısa eğitimde, Excel SMALL fonksiyonundan, nasıl çalıştığından ve N'inci en küçük sayıyı, tarihi veya saati bulmak için nasıl kullanılacağından bahsedeceğiz.

Bir çalışma sayfasında en düşük birkaç sayıyı mı bulmanız gerekiyor? Excel Sıralama özelliği ile bunu yapmak oldukça kolaydır. Her değişiklikte verilerinizi yeniden sıralamak için zaman kaybetmek istemiyor musunuz? SMALL işlevi en düşük değeri, ikinci en küçük değeri, üçüncü en küçük değeri vb. hızlı bir şekilde bulmanıza yardımcı olacaktır.

Excel KÜÇÜK işlevi

SMALL, bir veri kümesindeki n'inci en küçük değeri döndüren istatistiksel bir fonksiyondur.

SMALL fonksiyonunun sözdizimi, her ikisi de gerekli olan iki argüman içerir.

KÜÇÜK(dizi, k)

Nerede?

• Dizi - en küçük değerin çıkarılacağı bir dizi veya hücre aralığı.
• K - döndürülecek en düşük değerden itibaren konumu belirten bir tamsayı, yani k-inci en küçük.

İşlev, Office 365 için Excel, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010 ve önceki Excel sürümlerinin tümünde kullanılabilir.

İpucu. k-inci en düşük değeri ölçütlerle bulmak için Excel KÜÇÜK EĞER formülünü kullanın.

Excel'de temel KÜÇÜK formülü

Temel haliyle bir SMALL formülü oluşturmak çok kolaydır - sadece aralığı ve döndürülecek en küçük öğeden itibaren konumu belirtirsiniz.

B2:B10'daki sayılar listesinde, en küçük 3. değeri çıkarmak istediğinizi varsayalım. Formül şu kadar basittir:

=KÜÇÜK(B2:B10, 3)

Sonucu kontrol etmenizi kolaylaştırmak için B sütunu artan sırada sıralanmıştır:

KÜÇÜK işlev hakkında bilmeniz gereken 4 şey

Aşağıdaki kullanım notları, SMALL fonksiyonunun davranışını daha iyi anlamanıza ve kendi formüllerinizi oluştururken karışıklığı önlemenize yardımcı olacaktır.

1. Herhangi bir boş hücreler , Metin değerleri ve mantıksal içinde TRUE ve FALSE değerleri dizi argümanı göz ardı edilir.
2. Eğer dizi bir veya daha fazla hatalar 'de bir hata döndürülür.
3. Olması durumunda kopyalar içinde dizi Örneğin, iki hücre 1 sayısını içeriyorsa ve SMALL işlevi en küçük ve 2. en küçük değeri döndürecek şekilde yapılandırılmışsa, her iki durumda da 1 elde edersiniz.
4. n'nin aşağıdaki değerlerin sayısı olduğunu varsayarsak dizi , SMALL(dizi,1) en düşük değeri döndürecek ve SMALL(dizi,n) en yüksek değeri seçecektir.

Excel'de SMALL işlevi nasıl kullanılır - formül örnekleri

Şimdi de Excel SMALL fonksiyonunun temel kullanımının ötesine geçen birkaç örneğe daha bakalım.

Alttaki 3, 5, 10, vb. değerleri bulun

Bildiğiniz gibi, SMALL fonksiyonu n'inci en düşük değeri hesaplamak için tasarlanmıştır. Bu örnek, bunun en etkili şekilde nasıl yapılacağını göstermektedir.

Aşağıdaki tabloda, en alttaki 3 değeri bulmak istediğinizi varsayalım. Bunun için, 1, 2 ve 3 sayılarını ayrı hücrelere yazın (bizim durumumuzda D3, D4 ve D5). Ardından, aşağıdaki formülü E3'e girin ve E5'e doğru sürükleyin:

=KÜÇÜK($B$2:$B$10, D3)

E3'te formül, D3'teki sayıyı kullanarak en küçük değeri çıkarır. k argümanı. Önemli olan, formülün diğer hücrelerde doğru şekilde kopyalanması için uygun hücre referanslarını sağlamaktır: absolute for dizi ve göreceli olarak k .

Sıraları elle yazmakla uğraşmak istemiyor musunuz? ROWS işlevini bir genişleyen ürün yelpazesi sağlamak için referans k Bunun için, ilk hücre için mutlak bir referans (veya B$2 gibi yalnızca satır koordinatını kilitleyin) ve son hücre için göreli referans yaparız:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Sonuç olarak, formül sütundan aşağı kopyalandıkça aralık referansı genişler. D2'de, SATIRLAR(B$2:B2) aşağıdakiler için 1 üretir k ve formül en düşük maliyeti döndürür. D3'te, SATIRLAR(B$2:B3) 2 verir ve 2. en düşük maliyeti elde ederiz ve bu böyle devam eder.

Formülü 5 hücreye kopyaladığınızda en alttaki 5 değeri elde edersiniz:

Toplam alt N değerleri

Bir veri kümesindeki en küçük n değerin toplamını mı bulmak istiyorsunuz? Önceki örnekte gösterildiği gibi değerleri zaten ayıkladıysanız, en kolay çözüm aşağıdaki gibi bir SUM formülü olacaktır:

=TOPLA(E3:E5)

Veya SUMPRODUCT ile birlikte SMALL işlevini kullanarak bağımsız bir formül oluşturabilirsiniz:

Veri setimizdeki en alttaki 3 değerin toplamını elde etmek için formül bu şekli alır:

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

SUM işlevi de aynı sonucu üretecektir:

=TOPLAM(SMALL(B2:B10, {1,2,3}))

Not: Eğer kullanıyorsanız hücre referansları için dizi sabiti yerine k 'yi bir dizi formülü yapmak için Ctrl + Shift + Enter tuşlarına basmanız gerekir. Dinamik dizileri destekleyen Excel 365'te, KÜÇÜK TOPLA her iki durumda da normal bir formül olarak çalışır.

Bu formül nasıl çalışır?

Normal bir formülde, SMALL bir aralıktaki tek bir k-inci en küçük değeri döndürür. Bu durumda, k bağımsız değişkeni için {1,2,3} gibi bir dizi sabiti sağlayarak, en küçük 3 değerden oluşan bir dizi döndürmeye zorlarız:

{29240, 43610, 58860}

SUMPRODUCT veya SUM işlevi dizideki sayıları toplar ve toplamı verir. İşte bu kadar!

En küçük eşleşmeleri almak için INDEX MATCH SMALL formülü

En küçük değerle ilişkili bazı verileri almak istediğinizde, arama değeri için SMALL ile klasik INDEX MATCH kombinasyonunu kullanın:

Nerede?

• Return_array ilişkili verilerin çıkarılacağı bir aralıktır.
• Lookup_array en düşük n'inci değerin aranacağı bir aralıktır.
• N ilgilenilen en küçük değerin konumudur.

Örneğin, en düşük maliyete sahip projenin adını elde etmek için E3'teki formül şöyledir:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Burada A2:A10 proje adları, B2:B10 maliyetler ve D3 en küçükten en büyüğe doğru sıralamadır.

Formülü aşağıdaki hücrelere (E4 ve E5) kopyaladığınızda en ucuz 3 projenin adını elde edeceksiniz:

Notlar:

• Bu çözüm, kopyası olmayan bir veri kümesi için iyi çalışır. Ancak, sayısal bir sütunda iki veya daha fazla yinelenen değer sıralamada "bağlar" oluşturabilir ve bu da yanlış sonuçlara yol açar. Bu durumda, lütfen bağları kırmak için biraz daha karmaşık bir formül kullanın.
• Excel 365'te bu görev, yeni dinamik dizi işlevlerinin yardımıyla gerçekleştirilebilir. Çok daha basit olmasının yanı sıra, bu yaklaşım bağ sorununu otomatik olarak çözer. Tüm ayrıntılar için lütfen Excel'de alt N değerlerini filtreleme bölümüne bakın.

Sayıları bir formülle en düşükten en yükseğe doğru sıralama

Excel Sıralama özelliği ile sayıları nasıl sıralayacağınızı herkesin bildiğine inanıyorum. Peki bir formülle nasıl sıralama yapacağınızı biliyor musunuz? Excel 365 kullanıcıları yeni SORT işlevi ile bunu kolay bir şekilde yapabilirler. Excel 2019, 2016 ve önceki sürümlerde SORT ne yazık ki çalışmıyor. Ancak biraz inancınız olsun ve SMALL imdadınıza yetişecek :)

İlk örnekte olduğu gibi, artırmak için genişleyen bir aralık referansıyla birlikte ROWS işlevini kullanırız k formülün kopyalandığı her satırda 1 azalır:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Formülü ilk hücreye girin ve ardından orijinal veri kümesindeki değer sayısı kadar hücreye sürükleyin (bu örnekte C2:C10):

İpucu. Sıralamak için azalan , KÜÇÜK yerine BÜYÜK işlevini kullanın.

Tarihler ve saatler için Excel KÜÇÜK formülü

Tarihler ve saatler de sayısal değerler olduğundan (dahili Excel sisteminde, tarihler sıralı sayılar ve saatler ondalık kesirler olarak saklanır), SMALL işlevi bunları da sizin tarafınızdan fazladan çaba sarf etmeden işleyebilir.

Aşağıdaki ekran görüntülerinde de görebileceğiniz gibi, sayılar için kullandığımız temel formül, tarihler ve saatler için de güzel bir şekilde çalışıyor:

=KÜÇÜK($B$2:$B$10, D2)

En erken 3 tarihi bulmak için KÜÇÜK formül:

En kısa 3 katı elde etmek için KÜÇÜK formül:

Bir sonraki örnek, SMALL fonksiyonunun tarihlerle ilgili daha spesifik bir görevi yerine getirmenize nasıl yardımcı olabileceğini göstermektedir.

Bugüne veya belirtilen tarihe en yakın önceki bir tarihi bulun

Bir tarih listesinde, belirli bir tarihten önceki en yakın tarihi bulmak istediğinizi varsayalım. Bu, SMALL işlevini COUNTIF ile birlikte kullanarak yapılabilir.

B2:B10'daki tarih listesi ve E1'deki hedef tarih ile, aşağıdaki formül hedef tarihe en yakın önceki tarihi döndürür:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

E1'deki tarihten iki tarih önce olan, yani önceki ama bir tarih olan bir tarihi çıkarmak için formül şöyledir:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

Geçmiş bir tarihi bulmak için bugüne en yakın , COUNTIF kriterleri için TODAY işlevini kullanın:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY())

İpucu: Ölçütlerinizle eşleşen bir tarihin bulunamadığı durumlarda hataları önlemek için, IFERROR işlevini formülünüzün etrafına şu şekilde sarabilirsiniz:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Bulunamadı")

Bu formüller nasıl çalışır?

Genel fikir, COUNTIF ile hedef tarihten daha küçük tarihlerin sayısını saymaktır. Ve bu sayı tam olarak SMALL fonksiyonunun k Tartışma.

Bu kavramı daha iyi kavrayabilmek için konuya başka bir açıdan bakalım:

Eğer 1-Ağustos-2020 (E1'deki hedef tarih) veri setimizde yer alsaydı, listedeki en büyük 7. tarih olacaktı. Sonuç olarak, ondan daha küçük altı tarih vardır. Yani, en küçük 6. tarih, hedef tarihe en yakın olan bir önceki tarihtir.

Bu nedenle, ilk olarak E1'deki tarihten kaç tarihin daha küçük olduğunu hesaplarız (sonuç 6'dır):

COUNTIF(B2:B10, "<"&E1)

Ardından, sayıyı SMALL'un 2. bağımsız değişkenine ekleyin:

=KÜÇÜK(B2:B10, 6)

Bir tarih hariç önceki tarihi (bizim durumumuzda 5. en küçük tarih) elde etmek için COUNTIF'in sonucundan 1'i çıkarırız.

Excel'de alt değerler nasıl vurgulanır

Excel koşullu biçimlendirme ile tablonuzdaki en küçük n değerlerini vurgulamak için, yerleşik Üst/Alt seçeneğini kullanabilir veya bir KÜÇÜK formülüne dayalı olarak kendi kuralınızı oluşturabilirsiniz. İlk yöntem daha hızlı ve uygulaması daha kolayken, ikincisi daha fazla kontrol ve esneklik sağlar. Aşağıdaki adımlar, özel bir kural oluşturma konusunda size yol gösterecektir:

1. Alt değerleri vurgulamak istediğiniz aralığı seçin. Bizim durumumuzda, sayılar B2:B10'da, bu yüzden onu seçiyoruz. Tüm satırları vurgulamak istiyorsanız, A2:B10'u seçin.
2. Üzerinde Ev sekmesinde Stiller grubunu seçin, tıklayın Koşullu biçimlendirme > Yeni Kural .
3. İçinde Yeni Biçimlendirme Kuralı iletişim kutusunu seçin, ardından Hangi hücrelerin biçimlendirileceğini belirlemek için bir formül kullanın.
4. İçinde Bu formülün doğru olduğu değerleri biçimlendirin kutusuna bunun gibi bir formül girin:

   =B2<=SMALL($B$2:$B$10, 3)

   Burada B2 kontrol edilecek sayısal aralığın en soldaki hücresi, $B$2:$B$10 aralığın tamamı ve 3 n vurgulamak için alt değerler.

   Formülünüzde, lütfen başvuru türlerine dikkat edin: en soldaki hücre göreli bir başvuru (B2), aralık ise mutlak başvurudur ($B$2:$B$10).

5. Tıklayınız Biçim düğmesine basın ve istediğiniz biçimi seçin.
6. Her iki iletişim penceresini kapatmak için iki kez Tamam'a tıklayın.

Bitti! B sütunundaki en alttaki 3 değer vurgulanır:

Daha fazla bilgi için lütfen formüle dayalı Excel koşullu biçimlendirme bölümüne bakın.

Excel KÜÇÜK işlevi çalışmıyor

Örneklerimizde gördüğünüz gibi, Excel'de SMALL işlevini kullanmak oldukça kolaydır ve bu konuda herhangi bir zorluk yaşamanız olası değildir. Formülünüz çalışmazsa, büyük olasılıkla aşağıdaki nedenlerden dolayı oluşabilecek bir #NUM! hatası olacaktır:

• Dizi boşsa veya tek bir sayısal değer içermiyorsa.
• Bu k değerinin sıfırdan küçük olması (aptalca bir yazım hatası size saatlerce sorun giderme işlemine mal olabilir!) veya dizideki değer sayısını aşması.

Bir veri kümesindeki alt sayıları bulmak ve vurgulamak için Excel'de KÜÇÜK formülü bu şekilde kullanabilirsiniz. İşlevin kullanışlı olduğu başka senaryolar biliyorsanız, yorumlarda paylaşabilirsiniz. Okuduğunuz için teşekkür eder, gelecek hafta blogumuzda görüşmek dileğiyle!

İndirmek için pratik çalışma kitabı

Excel KÜÇÜK formül örnekleri (.xlsx dosyası)