في هذا البرنامج التعليمي القصير ، سنتحدث عن وظيفة Excel SMALL ، وكيف تعمل وكيفية استخدامها للعثور على الرقم الأصغر أو التاريخ أو الوقت.

Need للعثور على أقل عدد من الأرقام في ورقة العمل؟ من السهل جدًا القيام بذلك باستخدام ميزة Excel Sort. لا تريد تضييع الوقت في إعادة فرز بياناتك مع كل تغيير؟ ستساعدك وظيفة SMALL في العثور بسرعة على أدنى قيمة ، وثاني أصغرها ، وثالث أصغرها ، وهكذا.

دالة Excel الصغيرة

SMALL هي دالة إحصائية ترجع أصغر قيمة من رقم n في مجموعة البيانات.

تشتمل صيغة الدالة SMALL على وسيطين ، وكلاهما مطلوب.

SMALL (array، k)

حيث:

• Array - صفيف أو نطاق من الخلايا يتم منه استخراج أصغر قيمة.
• K - an عدد صحيح يشير إلى الموضع من أدنى قيمة يتم إرجاعها ، أي أصغر k-th.

تتوفر الوظيفة في جميع إصدارات Excel لـ Office 365 و Excel 2021 و Excel 2019 و Excel 2016 و Excel 2013 و Excel 2010 والإصدارات السابقة.

نصيحة. للعثور على أدنى قيمة k-th مع المعايير ، استخدم صيغة Excel SMALL IF.

الصيغة الأساسية الصغيرة في Excel

من السهل جدًا إنشاء صيغة صغيرة في شكلها الأساسي - ما عليك سوى تحديد النطاق والموضع من أصغر عنصر لإرجاعه.

في قائمة الأرقام في B2: B10 ، بافتراض أنك تريد استخراج ثالث أصغر قيمة. الصيغة هيبسيطة مثل:

=SMALL(B2:B10, 3)

لتسهيل التحقق من النتيجة ، يتم فرز العمود B بترتيب تصاعدي:

4 أشياء يجب أن تعرفها عن وظيفة SMALL

ستساعدك ملاحظات الاستخدام التالية على فهم سلوك وظيفة SMALL بشكل أفضل وتجنب الالتباس عند إنشاء الصيغ الخاصة بك.

1. أي الخلايا الفارغة ، النص القيم ، و القيم المنطقية القيم TRUE و FALSE في الصفيف الوسيطة يتم تجاهلها.
2. إذا المصفوفة تحتوي على خطأ أو أكثر ، يتم إرجاع خطأ.
3. في حالة وجود مكررات في المصفوفة ، الصيغة قد يؤدي إلى "العلاقات". على سبيل المثال ، إذا احتوت خليتان على الرقم 1 ، وتم تكوين الدالة الصغيرة لإرجاع أصغر قيمة وثاني أصغر قيمة ، فستحصل على 1 في كلتا الحالتين.
4. بافتراض أن n هو عدد القيم في المصفوفة ، SMALL (المصفوفة ، 1) ستعيد أدنى قيمة ، وستختار SMALL (المصفوفة ، n) أعلى قيمة.

كيفية استخدام الدالة الصغيرة في Excel - أمثلة على الصيغ

والآن ، دعنا نلقي نظرة على بعض الأمثلة الأخرى لوظيفة Excel SMALL التي تتجاوز استخدامها الأساسي.

ابحث عن القيم السفلية 3 و 5 و 10 وما إلى ذلك

كما تعلم بالفعل ، تم تصميم الدالة الصغيرة لحساب أدنى قيمة من رقم n. يوضح هذا المثال كيفية القيام بذلك بشكل أكثر فاعلية.

في الجدول أدناه ، افترض أنك ترغب في العثور على القيم الثلاث السفلية. لهذا ، اكتبالأرقام 1 و 2 و 3 في خلايا منفصلة (D3 و D4 و D5 في حالتنا). بعد ذلك ، أدخل الصيغة التالية في E3 واسحبها لأسفل عبر E5:

=SMALL($B$2:$B$10, D3)

في E3 ، تستخرج الصيغة أصغر قيمة باستخدام الرقم في D3 لـ k حجة. الشيء الأساسي هو توفير مراجع الخلية المناسبة بسبب نسخ الصيغة بشكل صحيح في الخلايا الأخرى: مطلق لـ المصفوفة والنسبية لـ ك .

لا تريد عناء كتابة الرتب يدويًا؟ استخدم الدالة ROWS مع مرجع نطاق موسع لتوفير قيمة k . لهذا ، نقوم بعمل مرجع مطلق للخلية الأولى (أو فقط قفل إحداثي الصف مثل B $ 2) والمرجع النسبي للخلية الأخيرة:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

ونتيجة لذلك ، النطاق يتم توسيع المرجع أثناء نسخ الصيغة أسفل العمود. في D2 ، ينتج ROWS (B $ 2: B2) 1 لـ k ، وتعيد الصيغة أقل تكلفة. في D3 ، ينتج ROWS (B $ 2: B3) 2 ، ونحصل على ثاني أقل تكلفة ، وهكذا.

فقط انسخ الصيغة من خلال 5 خلايا ، وستحصل على أدنى 5 قيم:

جمع قيم N السفلية

هل تريد العثور على إجمالي قيم n الأصغر في مجموعة البيانات؟ إذا كنت قد قمت بالفعل باستخراج القيم كما هو موضح في المثال السابق ، فسيكون الحل الأسهل هو صيغة SUM مثل:

=SUM(E3:E5)

أو يمكنك قم بعمل صيغة مستقلة باستخدام الدالة SMALL مع SUMPRODUCT:

للحصول على مجموع القيم الثلاث السفلية في مجموعة البيانات لدينا ، تأخذ الصيغة هذا الشكل :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

ستنتج الدالة SUM نفس النتيجة:

=SUM(SMALL(B2:B10, {1,2,3}))

ملاحظة. إذا كنت تستخدم مراجع الخلية بدلاً من ثابت الصفيف لـ k ، فأنت بحاجة إلى الضغط على Ctrl + Shift + Enter لجعلها صيغة صفيف. في Excel 365 الذي يدعم المصفوفات الديناميكية ، يعمل SUM SMALL كصيغة عادية في كلتا الحالتين.

كيف تعمل هذه الصيغة:

في صيغة عادية ، تُرجع SMALL أصغر قيمة k-th واحدة في النطاق. في هذه الحالة ، نوفر ثابت صفيف مثل {1،2،3} للوسيطة k ، مما يجبره على إرجاع مصفوفة من أصغر 3 قيم:

{29240, 43610, 58860}

SUMPRODUCT أو تجمع الدالة SUM الأرقام الموجودة في المصفوفة وتخرج الإجمالي. هذا كل شيء!

صيغة INDEX MATCH الصغيرة للحصول على أصغر التطابقات

في الحالة التي ترغب فيها في استرداد بعض البيانات المرتبطة بأصغر قيمة ، استخدم تركيبة INDEX MATCH الكلاسيكية مع SMALL لقيمة البحث :

أين :

• Return_array هو نطاق يتم من خلاله استخراج البيانات المرتبطة.
• Lookup_array هو نطاق يتم فيه البحث عن أدنى عدد n -th value.
• N هو موضع أصغر قيمة للفائدة.

بالنسبة إلىعلى سبيل المثال ، للحصول على اسم المشروع الأقل تكلفة ، تكون الصيغة في E3 هي:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

حيث A2: A10 هي أسماء المشروع ، B2: B10 هي التكاليف و D3 هو الترتيب من الأصغر.

انسخ الصيغة إلى الخلايا أدناه (E4 و E5) ، وستحصل على أسماء المشاريع الثلاثة الأرخص:

ملاحظات:

• يعمل هذا الحل بشكل جيد لمجموعة بيانات لا تحتوي على تكرارات. ومع ذلك ، قد تؤدي قيمتان مكررتان أو أكثر في عمود رقمي إلى إنشاء "روابط" في الترتيب ، مما يؤدي إلى نتائج خاطئة. في هذه الحالة ، يرجى استخدام صيغة أكثر تعقيدًا لكسر الروابط.
• في Excel 365 ، يمكن إنجاز هذه المهمة بمساعدة وظائف الصفيف الديناميكية الجديدة. بصرف النظر عن كونه أبسط بكثير ، فإن هذا النهج يحل تلقائيًا مشكلة العلاقات. للحصول على التفاصيل الكاملة ، يرجى الاطلاع على كيفية تصفية القيم السفلية في Excel.

فرز الأرقام من الأدنى إلى الأعلى باستخدام صيغة

أعتقد أن الجميع يعرف كيفية ترتيب الأرقام بالترتيب مع ميزة Excel Sort. لكن هل تعرف كيفية إجراء الفرز باستخدام صيغة؟ يمكن لمستخدمي Excel 365 القيام بذلك بطريقة سهلة باستخدام وظيفة SORT الجديدة. في Excel 2019 و 2016 والإصدارات السابقة ، لا يعمل SORT ، للأسف. لكن تحلى ببعض الإيمان ، وسيأتي SMALL للإنقاذ :)

كما في المثال الأول ، نستخدم وظيفة ROWS مع مرجع نطاق موسع لزيادة k بمقدار 1 في كل صف حيث الصيغةتم نسخه:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

أدخل الصيغة في الخلية الأولى ، ثم اسحبها لأسفل إلى أكبر عدد ممكن من الخلايا حيث توجد قيم في مجموعة البيانات الأصلية (C2: C10 في هذا المثال) :

نصيحة. لفرز تنازليًا ، استخدم الدالة LARGE بدلاً من SMALL.

صيغة Excel الصغيرة للتواريخ والأوقات

نظرًا لأن التواريخ والأوقات هي أيضًا قيم رقمية (في نظام Excel الداخلي ، يتم تخزين التواريخ كأرقام متسلسلة وأوقات كسور عشرية) ، يمكن للدالة الصغيرة التعامل معها أيضًا دون بذل أي جهد إضافي من جانبك.

كما ترى في لقطات الشاشة أدناه ، تعمل الصيغة الأساسية التي استخدمناها للأرقام بشكل جميل مع التواريخ والأوقات أيضًا:

=SMALL($B$2:$B$10, D2)

صيغة صغيرة للعثور على أقدم 3 تواريخ:

صيغة صغيرة للحصول على أقصر 3 مرات:

يوضح المثال التالي كيف يمكن أن تساعدك الدالة الصغيرة في إنجاز مهمة أكثر تحديدًا تتعلق بالتواريخ.

ابحث عن تاريخ سابق أقرب إلى اليوم أو تاريخ محدد

في قائمة التواريخ ، بافتراض أنك تريد البحث عن أقرب تاريخ قبل تاريخ محدد. يمكن القيام بذلك باستخدام الدالة SMALL بالاشتراك مع COUNTIF.

مع قائمة التواريخ في B2: B10 والتاريخ المستهدف في E1 ، ستُرجع الصيغة التالية تاريخًا سابقًا أقرب إلى التاريخ المستهدف:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

لاستخراج تاريخ قبل التاريخ في E1 ، أي تاريخ سابق ولكن تاريخ واحد ،الصيغة هي:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

للعثور على تاريخ سابق الأقرب إلى اليوم ، استخدم الدالة TODAY لمعايير COUNTIF:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

نصيحة. لمنع حدوث أخطاء في الموقف عندما لا يتم العثور على تاريخ يطابق المعايير الخاصة بك ، يمكنك التفاف الدالة IFERROR حول الصيغة الخاصة بك ، مثل هذا:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

كيف تعمل هذه الصيغ:

الفكرة العامة هي حساب عدد التواريخ أصغر من التاريخ المستهدف باستخدام COUNTIF. وهذا العدد هو بالضبط ما تحتاجه الدالة الصغيرة للوسيطة k .

لفهم المفهوم بشكل أفضل ، دعنا ننظر إليه من زاوية أخرى:

إذا كان 1- ظهر Aug-2020 (التاريخ المستهدف في E1) في مجموعة البيانات الخاصة بنا ، وسيكون هذا هو سابع أكبر تاريخ في القائمة. وبالتالي ، هناك ستة تواريخ أصغر منه. بمعنى ، التاريخ السادس الأصغر هو التاريخ السابق الأقرب للتاريخ المستهدف.

لذلك ، نحسب أولاً عدد التواريخ الأصغر من التاريخ في E1 (النتيجة هي 6):

COUNTIF(B2:B10, "<"&E1)

وبعد ذلك ، أدخل العدد في الوسيطة الثانية من SMALL:

=SMALL(B2:B10, 6)

للحصول على التاريخ السابق ولكن واحد (وهو خامس أصغر تاريخ في حالتنا) ، نطرح 1 من نتيجة COUNTIF.

كيفية تمييز القيم السفلية في Excel

لتمييز أصغر قيم n في جدولك باستخدام تنسيق Excel الشرطي ، يمكنك استخدام إما الجزء العلوي المدمج / الخيار السفلي أو إعداد القاعدة الخاصة بك على أساس صيغة صغيرة. الطريقة الأولى أسرعوأسهل في التطبيق ، بينما يوفر الثاني مزيدًا من التحكم والمرونة. ستوجهك الخطوات التالية خلال إنشاء قاعدة مخصصة:

1. حدد النطاق الذي تريد تمييز القيم السفلية فيه. في حالتنا ، الأرقام موجودة في B2: B10 ، لذلك نختارها. إذا كنت ترغب في تمييز الصفوف بأكملها ، فحدد A2: B10.
2. في علامة التبويب الصفحة الرئيسية ، في مجموعة الأنماط ، انقر فوق تنسيق شرطي & gt؛ New Rule .
3. في مربع الحوار New Formatting Rule ، اختر استخدم صيغة لتحديد الخلايا المراد تنسيقها.
4. في المربع تنسيق القيم حيث تكون هذه الصيغة صحيحة ، أدخل صيغة مثل هذه:

   =B2<=SMALL($B$2:$B$10, 3)

   حيث تكون B2 هي الخلية الموجودة في أقصى يسار الرقم النطاق المراد التحقق منه ، $ B $ 2: $ B $ 10 هو النطاق الكامل ، و 3 هو n القيم السفلية المراد تمييزها.

   في الصيغة ، يرجى مراعاة أنواع المراجع: الخلية الموجودة في أقصى اليسار هي مرجع نسبي (B2) بينما النطاق هو المرجع المطلق ($ B $ 2: $ B $ 10).

5. انقر فوق الزر تنسيق واختر أي تنسيق تريده.
6. انقر فوق موافق مرتين لإغلاق نافذتي الحوار.

فعله! تم تمييز القيم الثلاث السفلية في العمود B:

لمزيد من المعلومات ، يرجى الاطلاع على تنسيق Excel الشرطي استنادًا إلى الصيغة.

وظيفة Excel الصغيرة لا تعمل

كما رأيت للتو من الأمثلة لدينا ، فإن استخدام وظيفة SMALL في Excel أمر سهل للغاية ، وأنت كذلكمن غير المحتمل أن تواجه أي صعوبات في ذلك. إذا لم تعمل الصيغة الخاصة بك ، فمن المرجح أن تكون #NUM! الخطأ الذي قد يحدث للأسباب التالية:

• المصفوفة فارغة أو لا تحتوي على قيمة رقمية واحدة.
• k القيمة أقل من الصفر (قد يكلفك خطأ إملائي سخيف ساعات من استكشاف الأخطاء وإصلاحها!) أو يتجاوز عدد القيم في المصفوفة.

هذه هي كيفية استخدام صيغة صغيرة في Excel للبحث عن و تسليط الضوء على الأرقام السفلية في مجموعة من البيانات. إذا كنت تعرف أي سيناريوهات أخرى حيث تكون الوظيفة مفيدة ، فنحن نرحب بك للمشاركة في التعليقات. أشكرك على القراءة وآمل أن أراك على مدونتنا الأسبوع المقبل!

تدرب على المصنف للتنزيل

أمثلة على صيغ Excel الصغيرة (ملف .xlsx)