V tomto krátkom návode si povieme o funkcii Excel SMALL, ako funguje a ako ju použiť na nájdenie N-tého najmenšieho čísla, dátumu alebo času.

Potrebujete nájsť niekoľko najnižších čísel v pracovnom hárku? Pomocou funkcie Excel Sort (Zoradiť) to zvládnete celkom jednoducho. Nechcete strácať čas opätovným triedením údajov pri každej zmene? Funkcia SMALL vám pomôže rýchlo nájsť najnižšiu hodnotu, druhú najmenšiu, tretiu najmenšiu atď.

Funkcia Excel SMALL

SMALL je štatistická funkcia, ktorá vracia n-tú najmenšiu hodnotu v súbore údajov.

Syntax funkcie SMALL obsahuje dva argumenty, pričom oba sú povinné.

SMALL(pole, k)

Kde:

• Pole - pole alebo rozsah buniek, z ktorých sa má získať najmenšia hodnota.
• K - celé číslo, ktoré označuje pozíciu od najnižšej hodnoty, ktorá sa má vrátiť, t. j. k-tá najmenšia.

Funkcia je k dispozícii vo všetkých verziách aplikácie Excel pre Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010 a starších.

Tip. Ak chcete nájsť k-tú najnižšiu hodnotu s kritériami, použite vzorec Excel SMALL IF.

Základný vzorec SMALL v programe Excel

Vzorec SMALL sa v základnej podobe zostavuje veľmi jednoducho - stačí zadať rozsah a pozíciu od najmenšej položky, ktorá sa má vrátiť.

Predpokladajme, že v zozname čísel v B2:B10 chcete získať tretiu najmenšiu hodnotu. Vzorec je jednoduchý:

=SMALL(B2:B10, 3)

Aby sa vám výsledok ľahšie kontroloval, stĺpec B je zoradený vzostupne:

4 veci, ktoré by ste mali vedieť o funkcii SMALL

Nasledujúce poznámky k použitiu vám pomôžu lepšie pochopiť správanie funkcie SMALL a vyhnúť sa zmätkom pri vytváraní vlastných vzorcov.

1. Akékoľvek prázdne bunky , text hodnoty a logické hodnoty TRUE a FALSE v pole sú ignorované.
2. Ak pole obsahuje jeden alebo viac chyby , vráti sa chyba.
3. V prípade, že existujú duplikáty na stránke pole Ak napríklad dve bunky obsahujú číslo 1 a funkcia SMALL je nakonfigurovaná tak, aby vrátila najmenšiu a druhú najmenšiu hodnotu, v oboch prípadoch dostanete 1.
4. Za predpokladu, že n je počet hodnôt v pole , SMALL(array,1) vráti najnižšiu hodnotu a SMALL(array,n) vyberie najvyššiu hodnotu.

Ako používať funkciu SMALL v programe Excel - príklady vzorcov

A teraz sa pozrime na ďalšie príklady funkcie Excel SMALL, ktoré presahujú jej základné použitie.

Nájdite spodné hodnoty 3, 5, 10 atď.

Ako už viete, funkcia SMALL je určená na výpočet n-tej najnižšej hodnoty. Tento príklad ukazuje, ako to urobiť čo najefektívnejšie.

Predpokladajme, že v nasledujúcej tabuľke chcete nájsť dolné 3 hodnoty. Na tento účel zadajte čísla 1, 2 a 3 do samostatných buniek (v našom prípade D3, D4 a D5). Potom zadajte nasledujúci vzorec do bunky E3 a potiahnite ho nadol cez E5:

=SMALL($B$2:$B$10, D3)

V E3 vzorec vyberie najmenšiu hodnotu pomocou čísla v D3 pre k Kľúčové je uviesť správne odkazy na bunky, vďaka ktorým sa vzorec správne skopíruje do iných buniek: absolútne pre pole a relatívne pre k .

Nechcete sa zdržiavať ručným zadávaním hodností? Použite funkciu ROWS s rozširujúci sa sortiment odkaz na poskytnutie k Na tento účel vytvoríme absolútny odkaz pre prvú bunku (alebo len uzamkneme súradnicu riadku ako B$2) a relatívny odkaz pre poslednú bunku:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Výsledkom je, že odkaz na rozsah sa rozšíri, keď sa vzorec skopíruje do stĺpca. V D2, ROWS(B$2:B2) vytvorí 1 pre k , a vzorec vráti najnižšiu cenu. V D3, ROWS(B$2:B3) dáva 2, a dostaneme 2. najnižšiu cenu, a tak ďalej.

Stačí vzorec skopírovať cez 5 buniek a získate spodných 5 hodnôt:

Súčet dolných hodnôt N

Ak chcete zistiť súčet najmenších n hodnôt v súbore údajov? Ak ste už extrahovali hodnoty, ako je uvedené v predchádzajúcom príklade, najjednoduchším riešením by bol vzorec SUM, ako napríklad:

=SUM(E3:E5)

Alebo môžete vytvoriť nezávislý vzorec pomocou funkcie SMALL spolu s funkciou SUMPRODUCT:

Ak chcete získať súčet spodných 3 hodnôt v našom súbore údajov, vzorec má tento tvar:

=SUMPRODUKT(SMALL(B2:B10, {1,2,3})

Funkcia SUM poskytne rovnaký výsledok:

=SUM(SMALL(B2:B10, {1,2,3})

Poznámka: Ak používate odkazy na bunky namiesto konštanty poľa pre k , musíte stlačiť klávesovú skratku Ctrl + Shift + Enter, aby sa z neho stal vzorec pre pole. V programe Excel 365, ktorý podporuje dynamické polia, funguje SUM SMALL v oboch prípadoch ako bežný vzorec.

Ako tento vzorec funguje:

V regulárnom vzorci SMALL vracia jednu k-tu najmenšiu hodnotu v rozsahu. V tomto prípade zadáme ako argument k konštantu poľa typu {1,2,3}, čím ho prinútime vrátiť pole troch najmenších hodnôt:

{29240, 43610, 58860}

Funkcia SUMPRODUCT alebo SUM sčíta čísla v poli a vypíše celkový súčet. To je všetko!

Vzorec INDEX MATCH SMALL na získanie najmenších zhod

V situácii, keď chcete získať nejaké údaje spojené s najmenšou hodnotou, použite klasickú kombináciu INDEX MATCH s hodnotou SMALL pre vyhľadávanie:

Kde:

• Return_array je rozsah, z ktorého sa majú získať súvisiace údaje.
• Lookup_array je rozsah, v ktorom sa má hľadať najnižšia n-tá hodnota.
• N je poloha najmenšej hodnoty záujmu.

Ak chcete napríklad získať názov projektu s najnižšími nákladmi, vzorec v E3 je:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Kde A2:A10 sú názvy projektov, B2:B10 sú náklady a D3 je poradie od najmenšieho.

Skopírujte vzorec do nasledujúcich buniek (E4 a E5) a získate názvy 3 najlacnejších projektov:

Poznámky:

• Toto riešenie funguje dobre v prípade súboru údajov, ktorý neobsahuje žiadne duplikáty. Dve alebo viac duplicitných hodnôt v číselnom stĺpci však môže vytvoriť "väzby" v poradí, čo povedie k nesprávnym výsledkom. V takom prípade použite trochu zložitejší vzorec na prerušenie väzieb.
• V aplikácii Excel 365 možno túto úlohu vykonať pomocou nových funkcií dynamického poľa. Okrem toho, že je tento prístup oveľa jednoduchší, automaticky rieši problém väzieb. Podrobné informácie nájdete v časti Ako filtrovať dolných N hodnôt v aplikácii Excel.

Zoradenie čísel od najnižšieho po najvyššie pomocou vzorca

Verím, že každý vie, ako zoradiť čísla pomocou funkcie Excel Sort. Viete však, ako vykonať triedenie pomocou vzorca? Používatelia Excelu 365 to môžu urobiť jednoduchým spôsobom pomocou novej funkcie SORT. V Exceli 2019, 2016 a starších verziách SORT bohužiaľ nefunguje. Ale majte trochu viery a SMALL príde na pomoc :)

Podobne ako v prvom príklade použijeme funkciu ROWS s rozširujúcim sa odkazom na rozsah na inkrementáciu k o 1 v každom riadku, do ktorého je vzorec skopírovaný:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Zadajte vzorec do prvej bunky a potom ho potiahnite do toľkých buniek, koľko je hodnôt v pôvodnom súbore údajov (v tomto príklade C2:C10):

Tip. Triedenie zostupne , namiesto funkcie SMALL použite funkciu LARGE.

Vzorec Excel SMALL pre dátumy a časy

Keďže dátumy a časy sú tiež číselné hodnoty (v internom systéme Excel sú dátumy uložené ako poradové čísla a časy ako desatinné zlomky), funkcia SMALL ich dokáže spracovať aj bez dodatočného úsilia na vašej strane.

Ako môžete vidieť na snímkach nižšie, základný vzorec, ktorý sme použili pre čísla, funguje výborne aj pre dátumy a časy:

=SMALL($B$2:$B$10, D2)

MALÝ vzorec na vyhľadanie 3 najskorších dátumov:

MALÝ vzorec na získanie najkratšieho 3-násobku:

Ďalší príklad ukazuje, ako vám funkcia SMALL môže pomôcť splniť konkrétnejšiu úlohu týkajúcu sa dátumov.

Vyhľadanie predchádzajúceho dátumu, ktorý je najbližšie k dnešnému alebo zadanému dátumu

Predpokladajme, že v zozname dátumov chcete nájsť najbližší dátum pred zadaným dátumom. To môžete urobiť pomocou funkcie SMALL v kombinácii s funkciou COUNTIF.

Ak máte zoznam dátumov v B2:B10 a cieľový dátum v E1, nasledujúci vzorec vráti predchádzajúci dátum, ktorý je najbližšie k cieľovému dátumu:

=SMALL(B2:B10, COUNTIF(B2:B10,"<"&E1))

Ak chcete získať dátum, ktorý je dva dátumy pred dátumom v E1, t. j. predchádzajúci, ale jeden dátum, vzorec je:

=SMALL(B2:B10, COUNTIF(B2:B10,"<"&E1)-1)

Vyhľadanie minulého dátumu najbližšie k dnešnému dňu , použite funkciu TODAY pre kritériá COUNTIF:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY())

Tip. Ak chcete zabrániť chybám v situácii, keď sa nenájde dátum zodpovedajúci vašim kritériám, môžete vzorec obaliť funkciou IFERROR, napríklad takto:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10,"<"&E1)-1), "Not Found")

Ako tieto vzorce fungujú:

Všeobecnou myšlienkou je spočítať počet dátumov menších ako cieľový dátum pomocou COUNTIF. A tento počet je presne to, čo funkcia SMALL potrebuje pre k argument.

Aby sme lepšie pochopili tento koncept, pozrime sa naň z iného uhla:

Ak by sa v našom súbore údajov objavil dátum 1. august 2020 (cieľový dátum v E1), bol by siedmym najväčším dátumom v zozname. Následne je šesť dátumov menších ako on. To znamená, že šiesty najmenší dátum je predchádzajúci dátum najbližší cieľovému dátumu.

Najprv teda vypočítame, koľko dátumov je menších ako dátum v E1 (výsledok je 6):

COUNTIF(B2:B10, "<"&E1)

A potom tento počet vložte do druhého argumentu príkazu SMALL:

=SMALL(B2:B10, 6)

Ak chceme získať predposledný dátum (čo je v našom prípade piaty najmenší dátum), od výsledku COUNTIF odčítame 1.

Ako zvýrazniť spodné hodnoty v programe Excel

Ak chcete zvýrazniť najmenšie n hodnôt v tabuľke pomocou podmieneného formátovania programu Excel, môžete použiť buď vstavanú možnosť Top/Bottom, alebo si nastaviť vlastné pravidlo založené na vzorci SMALL. Prvá metóda je rýchlejšia a jednoduchšia na použitie, zatiaľ čo druhá poskytuje väčšiu kontrolu a flexibilitu. Nasledujúce kroky vás prevedú vytvorením vlastného pravidla:

1. Vyberte rozsah, v ktorom chcete zvýrazniť spodné hodnoty. V našom prípade sú čísla v B2:B10, takže ho vyberieme. Ak chcete zvýrazniť celé riadky, vyberte A2:B10.
2. Na Domov na karte Štýly kliknite na položku Podmienené formátovanie > Nové pravidlo .
3. V Nové pravidlo formátovania dialógové okno, vyberte Pomocou vzorca určíte, ktoré bunky sa majú formátovať.
4. V Formátovanie hodnôt, pri ktorých je tento vzorec pravdivý zadajte vzorec, ako je tento:

   =B2<=SMALL($B$2:$B$10, 3)

   Kde B2 je najľavejšia bunka číselného rozsahu, ktorý sa má skontrolovať, $B$2:$B$10 je celý rozsah a 3 je n spodné hodnoty na zvýraznenie.

   Vo vašom vzorci dbajte na typy odkazov: bunka úplne vľavo je relatívny odkaz (B2), zatiaľ čo rozsah je absolútny odkaz ($B$2:$B$10).

5. Kliknite na tlačidlo Formát a vyberte si ľubovoľný formát.
6. Kliknutím na tlačidlo OK dvakrát zatvorte obe dialógové okná.

Hotovo! Spodné 3 hodnoty v stĺpci B sú zvýraznené:

Ďalšie informácie nájdete v časti Podmienené formátovanie programu Excel na základe vzorca.

Nefunguje funkcia Excel SMALL

Ako ste práve videli na našich príkladoch, používanie funkcie SMALL v programe Excel je pomerne jednoduché a pravdepodobne s ním nebudete mať žiadne ťažkosti. Ak váš vzorec nefunguje, s najväčšou pravdepodobnosťou to bude chyba #NUM!, ktorá môže nastať z nasledujúcich dôvodov:

• Pole je prázdny alebo neobsahuje ani jednu číselnú hodnotu.
• Stránka k je menšia ako nula (hlúpy preklep vás môže stáť hodiny riešenia problémov!) alebo presahuje počet hodnôt v poli.

Takto sa dá použiť vzorec SMALL v programe Excel na nájdenie a zvýraznenie spodných čísel v súbore údajov. Ak poznáte ďalšie scenáre, v ktorých sa táto funkcia hodí, môžete sa o ne podeliť v komentároch. Ďakujem za prečítanie a dúfam, že sa na našom blogu uvidíme budúci týždeň!

Cvičebnica na stiahnutie

Príklady vzorcov Excel SMALL (.xlsx súbor)