Dans ce court tutoriel, nous allons parler de la fonction SMALL d'Excel, de son fonctionnement et de la manière de l'utiliser pour trouver le Nième plus petit nombre, date ou heure.

Vous avez besoin de trouver quelques chiffres les plus bas dans une feuille de calcul ? C'est assez facile à faire avec la fonction de tri d'Excel. Vous ne voulez pas perdre de temps à reclasser vos données à chaque changement ? La fonction SMALL vous aidera à trouver rapidement la valeur la plus basse, la deuxième plus petite, la troisième plus petite, et ainsi de suite.

Fonction SMALL d'Excel

SMALL est une fonction statistique qui renvoie la n-ième plus petite valeur dans un ensemble de données.

La syntaxe de la fonction SMALL comprend deux arguments, tous deux obligatoires.

SMALL(tableau, k)

Où :

• Array - un tableau ou une plage de cellules dont on veut extraire la plus petite valeur.
• K - un nombre entier qui indique la position de la valeur la plus basse à retourner, c'est-à-dire la k-ième plus petite.

Cette fonction est disponible dans toutes les versions d'Excel pour Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010 et antérieures.

Astuce : pour trouver la k-ième valeur la plus basse avec les critères, utilisez la formule Excel SMALL IF.

Formule de base SMALL dans Excel

Une formule SMALL dans sa forme de base est très facile à construire - il suffit de spécifier la plage et la position du plus petit élément à retourner.

Dans la liste de nombres B2:B10, supposons que vous vouliez extraire la 3ème plus petite valeur. La formule est aussi simple que cela :

=SMALL(B2:B10, 3)

Pour vous permettre de vérifier plus facilement le résultat, la colonne B est triée par ordre croissant :

4 choses que vous devez savoir sur la fonction SMALL

Les notes d'utilisation suivantes vous aideront à mieux comprendre le comportement de la fonction SMALL et à éviter toute confusion lors de l'élaboration de vos propres formules.

1. Tout cellules vides , texte et logique les valeurs TRUE et FALSE dans la tableau sont ignorés.
2. Si tableau contient un ou plusieurs erreurs une erreur est renvoyée.
3. Au cas où il y aurait doublons sur tableau Par exemple, si deux cellules contiennent le nombre 1, et que la fonction SMALL est configurée pour renvoyer la plus petite et la deuxième plus petite valeur, vous obtiendrez 1 dans les deux cas.
4. En supposant que n est le nombre de valeurs dans tableau SMALL(array,1) retournera la valeur la plus basse, et SMALL(array,n) prendra la valeur la plus haute.

Comment utiliser la fonction SMALL dans Excel - exemples de formules

Voyons maintenant d'autres exemples de la fonction SMALL d'Excel qui vont au-delà de son utilisation de base.

Trouver les valeurs inférieures de 3, 5, 10, etc.

Comme vous le savez déjà, la fonction SMALL est conçue pour calculer la n-ième valeur la plus basse. Cet exemple montre comment le faire le plus efficacement possible.

Dans le tableau ci-dessous, supposons que vous souhaitiez trouver les 3 valeurs inférieures. Pour cela, saisissez les chiffres 1, 2 et 3 dans des cellules distinctes (D3, D4 et D5 dans notre cas). Ensuite, saisissez la formule suivante dans E3 et faites-la glisser vers le bas jusqu'à E5 :

=SMALL($B$2:$B$10, D3)

En E3, la formule extrait la plus petite valeur en utilisant le nombre en D3 pour le paramètre k L'essentiel est de fournir des références de cellule correctes pour que la formule soit copiée correctement dans d'autres cellules : absolue pour tableau et relative pour k .

Si vous ne voulez pas vous embêter à taper les rangs manuellement, utilisez la fonction ROWS avec un numéro d'ordre. gamme croissante référence pour fournir le k Pour cela, nous faisons une référence absolue pour la première cellule (ou nous verrouillons uniquement la coordonnée de la ligne comme B$2) et une référence relative pour la dernière cellule :

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Par conséquent, la référence de la plage s'étend à mesure que la formule est copiée vers le bas de la colonne. En D2, ROWS(B$2:B2) produit 1 pour k En D3, ROWS(B$2:B3) donne 2, et nous obtenons le deuxième coût le plus bas, et ainsi de suite.

Il suffit de copier la formule dans 5 cellules, et vous obtiendrez les 5 valeurs inférieures :

Somme des valeurs N inférieures

Si vous avez déjà extrait les valeurs comme dans l'exemple précédent, la solution la plus simple est d'utiliser la formule SUM :

=SUM(E3:E5)

Vous pouvez également créer une formule indépendante en utilisant la fonction SMALL avec la fonction SUMPRODUCT :

Pour obtenir la somme des 3 valeurs inférieures dans notre ensemble de données, la formule prend cette forme :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

La fonction SUM produira le même résultat :

=SOMME(SMALL(B2:B10, {1,2,3}))

Remarque : si vous utilisez références de cellules plutôt qu'une constante de tableau pour k Dans Excel 365 qui prend en charge les tableaux dynamiques, SOMME PETITE fonctionne comme une formule normale dans les deux cas.

Comment fonctionne cette formule :

Dans une formule régulière, SMALL renvoie une seule k-ième plus petite valeur dans une plage. Dans ce cas, nous fournissons une constante de tableau comme {1,2,3} pour l'argument k, le forçant à renvoyer un tableau des 3 plus petites valeurs :

{29240, 43610, 58860}

La fonction SUMPRODUCT ou SUM additionne les chiffres du tableau et donne le total. C'est tout !

Formule INDEX MATCH SMALL pour obtenir les correspondances les plus petites

Lorsque vous souhaitez récupérer des données associées à la plus petite valeur, utilisez la combinaison classique INDEX MATCH avec SMALL comme valeur de recherche :

Où :

• Tableau de retour est une plage à partir de laquelle on peut extraire les données associées.
• Tableau de recherche est un intervalle dans lequel il faut chercher la n-ième valeur la plus basse.
• N est la position de la plus petite valeur d'intérêt.

Par exemple, pour obtenir le nom du projet qui a le coût le plus bas, la formule dans E3 est :

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Où A2:A10 sont les noms des projets, B2:B10 sont les coûts et D3 est le rang du plus petit.

Copiez la formule dans les cellules ci-dessous (E4 et E5), et vous obtiendrez les noms des 3 projets les moins chers :

Notes :

• Cette solution fonctionne bien pour un ensemble de données qui n'a pas de doublons. Cependant, deux ou plusieurs valeurs en double dans une colonne numérique peuvent créer des "égalités" dans le classement, ce qui entraînera des résultats erronés. Dans ce cas, veuillez utiliser une formule un peu plus sophistiquée pour briser les égalités.
• Dans Excel 365, cette tâche peut être accomplie à l'aide des nouvelles fonctions de tableau dynamique. En plus d'être beaucoup plus simple, cette approche résout automatiquement le problème des égalités. Pour plus de détails, veuillez consulter Comment filtrer les N valeurs inférieures dans Excel.

Trier les nombres du plus petit au plus grand à l'aide d'une formule

Je crois que tout le monde sait comment mettre des nombres en ordre avec la fonction de tri d'Excel. Mais savez-vous comment effectuer un tri avec une formule ? Les utilisateurs d'Excel 365 peuvent le faire facilement avec la nouvelle fonction SORT. Dans Excel 2019, 2016 et les versions antérieures, SORT ne fonctionne pas, hélas. Mais ayez un peu de foi, et SMALL viendra à la rescousse :)

Comme dans le premier exemple, nous utilisons la fonction ROWS avec une référence de plage étendue pour incrémenter k par 1 dans chaque ligne où la formule est copiée :

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Saisissez la formule dans la première cellule, puis faites-la glisser vers le bas dans autant de cellules qu'il y a de valeurs dans l'ensemble de données d'origine (C2:C10 dans cet exemple) :

Conseil. Pour trier descendant Dans le cas de l'utilisation d'une carte de crédit, utilisez la fonction LARGE au lieu de SMALL.

Formule Excel SMALL pour les dates et les heures

Les dates et les heures étant également des valeurs numériques (dans le système interne d'Excel, les dates sont stockées sous forme de nombres séquentiels et les heures sous forme de fractions décimales), la fonction SMALL peut également les traiter sans effort supplémentaire de votre part.

Comme vous pouvez le voir dans les captures d'écran ci-dessous, la formule de base que nous avons utilisée pour les chiffres fonctionne parfaitement pour les dates et les heures :

=SMALL($B$2:$B$10, D2)

Petite formule pour trouver les 3 dates les plus anciennes :

Petite formule pour obtenir le plus court 3 fois :

L'exemple suivant montre comment la fonction SMALL peut vous aider à accomplir une tâche plus spécifique concernant les dates.

Trouver une date antérieure la plus proche d'aujourd'hui ou d'une date spécifiée

Dans une liste de dates, supposons que vous souhaitiez trouver la date la plus proche d'une date donnée, en utilisant la fonction SMALL en combinaison avec COUNTIF.

Avec la liste des dates dans B2:B10 et la date cible dans E1, la formule suivante renverra une date antérieure la plus proche de la date cible :

=SMALL(B2:B10, COUNTIF(B2:B10, "<;"&E1))

Pour extraire une date qui précède de deux dates la date en E1, c'est-à-dire une date antérieure mais unique, la formule est la suivante :

=SMALL(B2:B10, COUNTIF(B2:B10, "<;"&E1)-1)

Pour trouver une date passée le plus proche d'aujourd'hui Pour les critères du COUNTIF, utilisez la fonction TODAY :

=SMALL(B2:B10, COUNTIF(B2:B10, "<;"&TODAY()))

Conseil : pour éviter les erreurs lorsqu'une date correspondant à vos critères n'est pas trouvée, vous pouvez utiliser la fonction IFERROR autour de votre formule, comme ceci :

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<;"&E1)-1), "Not Found")

Comment ces formules fonctionnent :

L'idée générale est de compter le nombre de dates inférieures à la date cible avec COUNTIF. Et ce compte est exactement ce dont la fonction SMALL a besoin pour la fonction de calcul de la date. k argument.

Pour mieux comprendre le concept, examinons-le sous un autre angle :

Si le 1er août 2020 (la date cible en E1) apparaissait dans notre ensemble de données, il s'agirait de la 7e plus grande date de la liste. Par conséquent, il existe six dates plus petites que celle-ci. Autrement dit, la 6e plus petite date est la date précédente la plus proche de la date cible.

Donc, nous calculons d'abord combien de dates sont plus petites que la date en E1 (le résultat est 6) :

COUNTIF(B2:B10, "<;"&E1)

Et ensuite, on introduit le nombre dans le deuxième argument de SMALL :

=SMALL(B2:B10, 6)

Pour obtenir l'avant-dernière date (qui est la 5ème plus petite date dans notre cas), nous soustrayons 1 du résultat de COUNTIF.

Comment mettre en évidence les valeurs inférieures dans Excel

Pour mettre en évidence les valeurs n les plus petites de votre tableau à l'aide de la mise en forme conditionnelle d'Excel, vous pouvez utiliser l'option intégrée Haut/Bas ou créer votre propre règle basée sur une formule SMALL. La première méthode est plus rapide et plus facile à appliquer, tandis que la seconde offre plus de contrôle et de flexibilité. Les étapes ci-dessous vous guideront dans la création d'une règle personnalisée :

1. Sélectionnez la plage dans laquelle vous souhaitez mettre en évidence les valeurs inférieures. Dans notre cas, les chiffres se trouvent dans B2:B10, nous les sélectionnons donc. Si vous souhaitez mettre en évidence des lignes entières, sélectionnez A2:B10.
2. Sur le Accueil dans l'onglet Styles cliquez sur Formatage conditionnel > ; Nouvelle règle .
3. Dans le Nouvelle règle de formatage sélectionnez Utilisez une formule pour déterminer les cellules à mettre en forme.
4. Dans le Formatez les valeurs pour lesquelles cette formule est vraie entrez une formule comme celle-ci :

   =B2<=SMALL($B$2:$B$10, 3)

   Où B2 est la cellule la plus à gauche de la plage numérique à vérifier, $B$2:$B$10 est la plage entière, et 3 est la valeur de n les valeurs inférieures à mettre en évidence.

   Dans votre formule, tenez compte des types de référence : la cellule la plus à gauche est une référence relative (B2) tandis que la plage est une référence absolue ($B$2:$B$10).

5. Cliquez sur le bouton Format et choisissez le format qui vous convient.
6. Cliquez deux fois sur OK pour fermer les deux fenêtres de dialogue.

Les 3 dernières valeurs de la colonne B sont mises en évidence :

Pour plus d'informations, veuillez consulter la rubrique Mise en forme conditionnelle d'Excel basée sur une formule.

La fonction SMALL d'Excel ne fonctionne pas

Comme vous venez de le voir dans nos exemples, l'utilisation de la fonction SMALL dans Excel est assez simple, et il est peu probable que vous rencontriez des difficultés avec elle. Si votre formule ne fonctionne pas, il s'agira très probablement d'une erreur #NUM ! qui peut se produire pour les raisons suivantes :

• Array est vide ou ne contient pas une seule valeur numérique.
• Le site k est inférieure à zéro (une simple faute de frappe peut vous coûter des heures de dépannage !) ou dépasse le nombre de valeurs dans le tableau.

Voilà comment utiliser une formule SMALL dans Excel pour trouver et mettre en évidence les chiffres les plus bas dans un ensemble de données. Si vous connaissez d'autres scénarios où la fonction est utile, vous êtes invités à les partager dans les commentaires. Je vous remercie de votre lecture et j'espère vous voir sur notre blog la semaine prochaine !

Cahier d'exercices à télécharger

Exemples de formules Excel SMALL (fichier .xlsx)