په دې لنډ ټیوټوریل کې، موږ به د Excel SMALL فنکشن په اړه وغږیږو، چې دا څنګه کار کوي او څنګه یې د Nth ترټولو کوچنۍ شمیره، نیټه، یا وخت موندلو لپاره کارول کیږي.

اړتیا په یوه کاري پاڼه کې د څو ټیټو شمیرو موندلو لپاره؟ دا د ایکسل ترتیب ځانګړتیا سره ترسره کول خورا اسانه دي. نه غواړئ د هر بدلون سره ستاسو د معلوماتو بیا تنظیم کولو کې وخت ضایع کړئ؟ SMALL فنکشن به تاسو سره په چټکۍ سره د ټیټ ارزښت په موندلو کې مرسته وکړي، دویم کوچنی، دریم کوچنی، او داسې نور.

د ایکسل سمال فنکشن

SMALL یو احصایوي فعالیت دی چې بیرته راګرځي. په ډیټا سیټ کې د n-th تر ټولو کوچنی ارزښت.

د SMALL فنکشن ترکیب کې دوه دلیلونه شامل دي، چې دواړه اړین دي.

SMALL(array, k)

• Array - یو سرې یا د حجرو لړۍ چې له هغې څخه ترټولو کوچنی ارزښت استخراج شي.
• K - یو انټیجر چې د بیرته راستنیدو لپاره د ټیټ ارزښت څخه موقعیت په ګوته کوي ، د بیلګې په توګه k-th تر ټولو کوچنی.

فنکشن د Office 365 ، Excel 2021 ، Excel 2019 ، Excel 2016 ، Excel لپاره د Excel په ټولو نسخو کې شتون لري 2013، Excel 2010، او پخوا.

لارښوونه. د معیارونو سره د k-th ټیټ ارزښت موندلو لپاره، د Excel SMALL IF فارمول وکاروئ.

په Excel کې بنسټیز کوچنی فارمول

یو کوچنی فارمول په خپل لومړني شکل کې رامینځته کول خورا اسانه دي - تاسو یوازې مشخص کړئ حد او موقعیت د بیرته راستنیدو لپاره ترټولو کوچني توکي څخه.

په B2:B10 کې د شمیرو په لیست کې، فرض کړئ چې تاسو غواړئ دریم کوچنی ارزښت استخراج کړئ. فورمول داسې دیساده لکه:

=SMALL(B2:B10, 3)

د دې لپاره چې تاسو ته د نتیجې کتل اسانه کړي، B کالم په پورته ترتیب سره ترتیب شوی دی:

12>

4 شیان چې تاسو باید د کوچني فعالیت په اړه پوه شئ

لاندې کارونې یادښتونه به تاسو سره د کوچني فعالیت چلند په ښه پوهیدو کې مرسته وکړي او د خپل فارمولونو په جوړولو کې د ګډوډۍ مخه ونیسي.

1. کوم خالي حجرې ، متن ارزښتونه، او منطقي ارزښتونه سم او غلط په ارې دلیل له پامه غورځول شوي دي.
2. که array یو یا ډیرو غلطۍ لري، یوه تیروتنه بیرته راګرځي.
3. که چیرې نقلونه په ارې کې وي، ستاسو فورمول کیدای شي د "تړون" پایله ولري. د مثال په توګه، که دوه حجرې 1 شمیره ولري، او د SMALL فنکشن د ترټولو کوچنی او دوهم کوچنی ارزښت بیرته راګرځولو لپاره ترتیب شوی وي، تاسو به په دواړو حالتونو کې 1 ترلاسه کړئ.
4. فرض کړئ n د ارزښتونو شمیره ده array ، SMALL(array,1) به تر ټولو ټیټ ارزښت راوباسي، او SMALL(array,n) به تر ټولو لوړ ارزښت غوره کړي.

په Excel کې د SMALL فنکشن کارولو څرنګوالی - د فورمول مثالونه

او اوس، راځئ چې د Excel SMALL فنکشن ځینې نور مثالونه وګورو چې د دې بنسټیز کارونې څخه بهر ځي.

لاندې 3، 5، 10، او نور ارزښتونه ومومئ

لکه څنګه چې تاسو دمخه پوهیږئ، کوچنی فعالیت د n-th ټیټ ارزښت محاسبه کولو لپاره ډیزاین شوی. دا مثال ښیې چې دا څنګه په خورا مؤثره توګه ترسره کیدی شي.

په لاندې جدول کې، فرض کړئ چې تاسو غواړئ لاندې 3 ارزښتونه ومومئ. د دې لپاره، ټایپ کړئشمیرې 1، 2 او 3 په جلا حجرو کې (زموږ په قضیه کې D3، D4 او D5). بیا، لاندې فورمول په E3 کې دننه کړئ او د E5 له لارې یې ښکته کړئ:

=SMALL($B$2:$B$10, D3)

په E3 کې، فورمول د k<2 لپاره د D3 شمیرې په کارولو سره ترټولو کوچنی ارزښت استخراجوي> استدلال. اصلي شی د مناسب حجرو حوالې چمتو کول دي چې له امله یې فورمول په نورو حجرو کې په سمه توګه کاپي کیږي: د ارې لپاره مطلق او د k لپاره اړوند.

17>

ایا نه غواړئ په لاسي ډول د رتبو ټایپ کولو کې زحمت وکړئ؟ د ROWS فنکشن د پراخیدو سلسلې حوالې سره د k ارزښت چمتو کولو لپاره وکاروئ. د دې لپاره، موږ د لومړي حجرې لپاره مطلق حواله ورکوو (یا یوازې د قطار همغږي بند کړئ لکه B$2) او د وروستي حجرې لپاره اړونده حواله:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

د پایلې په توګه، حد حواله پراخه کیږي کله چې فورمول د کالم لاندې کاپي کیږي. په D2 کې، ROWS(B$2:B2) د k لپاره 1 تولیدوي، او فورمول تر ټولو ټیټ لګښت راګرځوي. په D3 کې، ROWS(B$2:B3) د 2 حاصل ورکوي، او موږ دوهم ټیټ لګښت ترلاسه کوو، او داسې نور.

یوازې د 5 حجرو له لارې فورمول کاپي کړئ، او تاسو به لاندې 5 ارزښتونه ترلاسه کړئ:

د لاندې N ارزښتونو مجموعه

غواړئ چې په ډیټاسیټ کې د ټولو کوچنیو n ارزښتونه ومومئ؟ که تاسو دمخه هغه ارزښتونه استخراج کړي لکه څنګه چې په تیرو مثال کې ښودل شوي ، ترټولو اسانه حل به د SUM فورمول وي لکه:

=SUM(E3:E5)

19>

یا تاسو کولی شئ د SUMPRODUCT:

زموږ د ډاټا په سیټ کې د لاندې 3 ارزښتونو مجموعې ترلاسه کولو لپاره، فورمول دا شکل اخلي :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

د SUM فعالیت به ورته پایله تولید کړي:

=SUM(SMALL(B2:B10, {1,2,3}))

یادونه. که تاسو د k لپاره د سري ثابت پر ځای حجري حوالې کاروئ، نو تاسو اړتیا لرئ چې Ctrl + Shift + Enter فشار ورکړئ ترڅو دا د صف فورمول جوړ کړي. په Excel 365 کې چې د متحرک صفونو ملاتړ کوي، SUM SMALL په هر حالت کې د منظم فارمول په توګه کار کوي.

دا فورمول څنګه کار کوي:

په یوه منظم فورمول کې، SMALL په یوه سلسله کې یو واحد k-th کوچنی ارزښت راګرځوي. په دې حالت کې، موږ د k استدلال لپاره د {1,2,3} په څیر یو سرې ثابته ورکوو، چې دا مجبوروي چې د 3 کوچنیو ارزښتونو لړۍ بیرته راولي:

{29240, 43610, 58860}

SUMPRODUCT یا د SUM فنکشن په صف کې شمیرې اضافه کوي او مجموعه تولیدوي. بس!

د وړو میچونو ترلاسه کولو لپاره INDEX MATCH وړوکی فورمول

په هغه حالت کې چې تاسو غواړئ ځینې ډیټا ترلاسه کړئ چې د کوچني ارزښت سره تړاو لري، د کتلو ارزښت لپاره د SMALL سره د کلاسیک INDEX MATCH ترکیب وکاروئ :

چیرته :

• Return_array هغه سلسله ده چې له هغې څخه تړلې ډاټا را ایستل کیږي.
• Lookup_array یو سلسله ده چیرې چې د ټیټ n لټون کول -th ارزښت.
• N د ګټو ترټولو کوچنی ارزښت موقعیت دی.

د دې لپارهد بیلګې په توګه، د پروژې نوم ترلاسه کولو لپاره چې ترټولو ټیټ لګښت لري، په E3 کې فورمول دا دی:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

چیرته چې A2:A10 د پروژې نومونه دي، B2:B10 لګښتونه دي او D3 تر ټولو کوچنۍ درجه ده.

فورمول لاندې حجرو (E4 او E5) ته کاپي کړئ، او تاسو به د 3 ارزانه پروژو نومونه ترلاسه کړئ:

یادښتونه:

• دا حل د ډیټا سیټ لپاره ښه کار کوي چې هیڅ نقل نلري. په هرصورت، په شمیري کالم کې دوه یا ډیر نقل شوي ارزښتونه کیدای شي په درجه بندي کې "تعلق" رامینځته کړي، کوم چې به د غلط پایلو المل شي. په دې حالت کې، مهرباني وکړئ د اړیکو ماتولو لپاره یو څه نور پیچلي فورمول وکاروئ.
• په Excel 365 کې، دا کار د نوي متحرک صفونو په مرسته ترسره کیدی شي. د ډیر ساده کیدو سربیره، دا طریقه په اتوماتيک ډول د اړیکو ستونزه حل کوي. د بشپړو جزیاتو لپاره، مهرباني وکړئ وګورئ چې څنګه په Excel کې د لاندې N ارزښتونه فلټر کړئ.

شمیرې له ټیټ څخه تر لوړې پورې د فورمول سره ترتیب کړئ

زه باور لرم چې هرڅوک پوهیږي چې څنګه شمیرې په ترتیب سره تنظیم کړي. د ایکسل ترتیب ځانګړتیا. مګر ایا تاسو پوهیږئ چې څنګه د فارمول سره ترتیب کول ترسره کړئ؟ د ایکسل 365 کاروونکي کولی شي دا د نوي SORT فعالیت سره په اسانۍ سره ترسره کړي. په Excel 2019، 2016 او پخوانیو نسخو کې، SORT کار نه کوي، افسوس. مګر لږ باور ولرئ، او سمال به د ژغورنې لپاره راشي :)

لکه د لومړي مثال په څیر، موږ د ROWS فنکشن د پراخیدونکي رینج حوالې سره کاروو چې په هر کې د 1 لخوا k زیاتیږي. قطار چیرته چې فورمولکاپي شوی دی:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

په لومړي حجره کې فورمول دننه کړئ، او بیا یې د ډیرو حجرو ته ښکته کړئ لکه څنګه چې په اصلي ډاټا سیټ کې ارزښتونه شتون لري (C2:C10 په دې مثال کې) :

لارښوونه. د ترتیب کولو لپاره ښکته کیدل ، د SMALL پرځای لوی فعالیت وکاروئ.

د نیټو او وختونو لپاره د ایکسل وړوکی فورمول

ځکه چې نیټې او وختونه هم عددي ارزښتونه دي (په داخلي Excel سیسټم کې، نیټې د ترتیبي شمیرو په توګه ساتل کیږي او وختونه د لسیزو برخو په توګه ساتل کیږي)، وړوکی فعالیت کولی شي دوی اداره کړي. همدارنګه پرته له کومې اضافي هڅې ستاسو په لوري.

لکه څنګه چې تاسو په لاندې سکرین شاټونو کې لیدلی شئ، یو اساسي فورمول چې موږ د شمیرو لپاره کارولی د نیټې او وختونو لپاره هم په ښه توګه کار کوي:

=SMALL($B$2:$B$10, D2)

کوچنی فورمول د لومړنیو 3 نیټو موندلو لپاره:

23>

کوچنی فورمول تر ټولو لنډ 3 ځله ترلاسه کول:

24>

راتلونکې بیلګه ښیي چې څنګه سمال فنکشن کولی شي تاسو سره د نیټې پورې اړوند یو ډیر مشخص کار سرته رسولو کې مرسته وکړي.

نن یا ټاکل شوې نیټې ته نږدې پخوانۍ نیټه ومومئ

د نیټو په لیست کې ، که تاسو غواړئ چې د ټاکلې نیټې دمخه نږدې نیټه ومومئ. دا د COUNTIF سره په ترکیب کې د کوچني فعالیت په کارولو سره ترسره کیدی شي.

په B2:B10 کې د نیټې لیست او په E1 کې د هدف نیټې سره، لاندې فورمول به د هدف نیټې ته نږدې پخوانۍ نیټه بیرته راولي:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

د یوې نیټې د استخراج لپاره چې په E1 کې د نیټې څخه دوه نیټې دمخه وي، د بیلګې په توګه پخوانۍ مګر یوه نیټه،فورمول دا دی:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

د تیرې نیټې موندلو لپاره نن ته نږدې ، د COUNTIF د معیارونو لپاره د TODAY فعالیت وکاروئ:<3

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

26>

لارښوونه. په داسې حالت کې د غلطیو د مخنیوي لپاره کله چې ستاسو د معیارونو سره سمون لرونکې نیټه ونه موندل شي، تاسو کولی شئ د خپل فارمول په شاوخوا کې د IFERROR فعالیت وپلټئ، لکه:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

دا فورمول څنګه کار کوي:

عمومي نظر دا دی چې د COUNTIF سره د هدف نیټې څخه کوچني نیټې شمیرل کیږي. او دا شمیره په سمه توګه هغه څه ده چې د k دلیل لپاره کوچني فعالیت ته اړتیا لري.

د مفهوم د ښه پوهیدو لپاره، راځئ چې له بلې زاویې وګورو:

که 1- Aug-2020 (په E1 کې د هدف نیټه) زموږ په ډیټاسیټ کې راښکاره شوه، دا به په لیست کې اووم لوی نیټه وي. په پایله کې، شپږ نیټې له هغې څخه کوچنۍ دي. په دې معنی، شپږمه کوچنۍ نیټه د هدف نیټې ته نږدې پخوانۍ نیټه ده.

نو، لومړی موږ محاسبه کوو چې څومره نیټې په E1 کې د نیټې څخه کوچنۍ دي (نتیجه 6):

COUNTIF(B2:B10, "<"&E1)

او بیا، شمیره د SMALL په دوهم دلیل کې ولګوئ:

=SMALL(B2:B10, 6)

د مخکینۍ مګر یوه نیټه ترلاسه کولو لپاره (کوم چې زموږ په قضیه کې پنځمه کوچنۍ نیټه ده) ، موږ د COUNTIF پایلې څخه 1 کموو.

په Excel کې د لاندې ارزښتونو روښانه کولو څرنګوالی

د Excel مشروط فارمیټینګ سره ستاسو په جدول کې د کوچني n ارزښتونو روښانه کولو لپاره ، تاسو کولی شئ یو جوړ شوی ټاپ وکاروئ / لاندې اختیار یا د کوچني فارمول پراساس خپل قانون تنظیم کړئ. لومړی میتود ګړندی دیاو د پلي کولو لپاره اسانه ، پداسې حال کې چې دوهم ډیر کنټرول او انعطاف چمتو کوي. لاندې مرحلې به تاسو د دودیز قواعد رامینځته کولو له لارې پرمخ بوځي:

1. هغه سلسله غوره کړئ په کوم کې چې تاسو غواړئ لاندې ارزښتونه روښانه کړئ. زموږ په قضیه کې، شمیرې په B2 کې دي: B10، نو موږ یې غوره کوو. که تاسو غواړئ ټول قطارونه روښانه کړئ، نو A2 غوره کړئ: B10.
2. په کور ټب کې، په ډولونو ګروپ کې، مشروط فارمیټ کلیک وکړئ > نوی قاعده .
3. په نوی فارمیټینګ قاعده ډیالوګ بکس کې، غوره کړئ یو فارمول وکاروئ ترڅو معلومه کړئ چې کوم حجرې فارمیټ کوي.
4. په د بڼې ارزښتونو کې چیرې چې دا فورمول ریښتیا وي بکس، د دې په څیر یو فورمول داخل کړئ:

   =B2<=SMALL($B$2:$B$10, 3)

   چیرې چې B2 د شمیرې ترټولو کیڼ حجره ده د کتلو لپاره حد، $B$2:$B$10 ټوله سلسله ده، او 3 د n لاندې ارزښتونه دي چې روښانه شي.

   په خپل فورمول کې، مهرباني وکړئ د حوالې ډولونه په پام کې ونیسئ: کیڼ اړخه حجره یو نسبي حواله ده (B2) پداسې حال کې چې حد مطلق حواله ده ($B$2:$B$10).

5. د فارمټ تڼۍ کلیک وکړئ او هر هغه شکل چې تاسو یې خوښوئ غوره کړئ.
6. دوه ځله د ډیالوګ وینډوز بندولو لپاره په سمه توګه کلیک وکړئ.

وشول! په B کالم کې لاندې 3 ارزښتونه په ګوته شوي:

د لا زیاتو معلوماتو لپاره، مهرباني وکړئ د فورمول پر بنسټ د Excel مشروط فارمیټ وګورئ.

د ایکسل کوچني فعالیت کار نه کوي

لکه څنګه چې تاسو زموږ د مثالونو څخه لیدلي، په Excel کې د کوچني فعالیت کارول خورا اسانه دي، او تاسو یې یاستامکان نلري چې پدې کې کومه ستونزه شتون ولري. که ستاسو فورمول کار ونکړي، ډیری احتمال به دا #NUM وي! تېروتنه، چې کېدای شي د لاندې دلایلو له امله رامنځته شي:

• Array خالي دی یا یو واحد عددي ارزښت نلري.
• د k ارزښت له صفر څخه کم دی (یو احمقانه ټایپو کولی شي تاسو ته د ستونزو حل کولو ساعتونه مصرف کړي!) یا په صف کې د ارزښتونو شمیر څخه ډیر دی.

دا د موندلو او موندلو لپاره په Excel کې د وړو فارمول کارولو څرنګوالی دی. د معلوماتو په سیټ کې لاندې شمیرې روښانه کړئ. که تاسو کوم بل سناریو وپیژنئ چیرې چې فنکشن په لاس کې راځي، تاسو په نظرونو کې د شریکولو لپاره خورا ښه راغلاست یاست. زه ستاسو د لوستلو لپاره مننه کوم او هیله لرم چې تاسو راتلونکې اونۍ زموږ په بلاګ کې وګورم!

د ډاونلوډ لپاره د تمرین کاري کتاب

د ایکسل کوچني فارمول مثالونه (.xlsx فایل)