U ovom kratkom vodiču ćemo govoriti o Excel SMALL funkciji, kako funkcionira i kako je koristiti za pronalaženje N-og najmanjeg broja, datuma ili vremena.

Potrebno pronaći nekoliko najnižih brojeva na radnom listu? Ovo je prilično lako učiniti pomoću funkcije Excel Sortiranje. Ne želite gubiti vrijeme na ponovno sortiranje podataka sa svakom promjenom? Funkcija SMALL će vam pomoći da brzo pronađete najnižu vrijednost, drugu najmanju, treću najmanju i tako dalje.

Excel SMALL funkcija

SMALL je statistička funkcija koja vraća n-ta najmanja vrijednost u skupu podataka.

Sintaksa funkcije SMALL uključuje dva argumenta, od kojih su oba obavezna.

SMALL(niz, k)

Gdje:

• Niz - niz ili raspon ćelija iz kojih se izdvaja najmanja vrijednost.
• K - cijeli broj koji označava poziciju od najniže vrijednosti koju treba vratiti, tj. k-tu najmanju.

Funkcija je dostupna u svim verzijama Excela za Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010 i ranije.

Savjet. Da biste pronašli k-tu najnižu vrijednost s kriterijima, koristite formulu Excel SMALL IF.

Osnovna SMALL formula u Excelu

MALA formula u svom osnovnom obliku je vrlo lako izgraditi - samo navedite raspon i poziciju od najmanje stavke koju treba vratiti.

Na listi brojeva u B2:B10, pod pretpostavkom da želite izvući treću najmanju vrijednost. Formula je kaojednostavno kao:

=SMALL(B2:B10, 3)

Da bi vam olakšali provjeru rezultata, stupac B je sortiran uzlaznim redoslijedom:

4 stvari koje biste trebali znati o SMALL funkciji

Sljedeće napomene o upotrebi pomoći će vam da bolje razumijete ponašanje SMALL funkcije i izbjegnete zabunu prilikom izrade vlastitih formula.

1. Bilo koji prazne ćelije , tekst vrijednosti i logičke vrijednosti TRUE i FALSE u argumentu array se zanemaruju.
2. Ako niz sadrži jednu ili više grešaka , vraća se greška.
3. U slučaju da postoje duplikati u nizu , vaša formula može rezultirati "vezama". Na primjer, ako dvije ćelije sadrže broj 1, a funkcija SMALL je konfigurirana da vraća najmanju i drugu najmanju vrijednost, dobićete 1 u oba slučaja.
4. Pod pretpostavkom da je n broj vrijednosti u array , SMALL(array,1) će vratiti najnižu vrijednost, a SMALL(array,n) će odabrati najveću vrijednost.

Kako koristiti SMALL funkciju u Excelu - primjeri formule

A sada, pogledajmo još nekoliko primjera funkcije Excel SMALL koji prevazilaze njenu osnovnu upotrebu.

Pronađi donje vrijednosti 3, 5, 10, itd.

Kao što već znate, funkcija SMALL je dizajnirana da izračuna n-tu najnižu vrijednost. Ovaj primjer pokazuje kako to učiniti najefikasnije.

U tabeli ispod, pretpostavimo da želite pronaći donje 3 vrijednosti. Za ovo ukucajtebrojevi 1, 2 i 3 u odvojenim ćelijama (u našem slučaju D3, D4 i D5). Zatim unesite sljedeću formulu u E3 i povucite je dolje kroz E5:

=SMALL($B$2:$B$10, D3)

U E3, formula izdvaja najmanju vrijednost koristeći broj u D3 za k argument. Ključna stvar je osigurati ispravne reference ćelije zbog kojih se formula ispravno kopira u druge ćelije: apsolutna za array i relativna za k .

Ne želite da se trudite da ručno upisujete činove? Koristite funkciju ROWS sa proširujućim rasponom referencom da osigurate vrijednost k . Za ovo pravimo apsolutnu referencu za prvu ćeliju (ili zaključavamo samo koordinate reda kao B$2) i relativnu referencu za posljednju ćeliju:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Kao rezultat, raspon referenca se proširuje kako se formula kopira niz kolonu. U D2, ROWS(B$2:B2) proizvodi 1 za k , a formula vraća najnižu cijenu. U D3, ROWS(B$2:B3) daje 2, a mi dobijamo 2. najnižu cijenu, i tako dalje.

Samo kopirajte formulu kroz 5 ćelija, i dobićete donjih 5 vrijednosti:

Zbroj donjih N vrijednosti

Želite pronaći ukupno najmanjih n vrijednosti u skupu podataka? Ako ste već izdvojili vrijednosti kao što je prikazano u prethodnom primjeru, najlakše rješenje bi bila formula ZUM kao:

=SUM(E3:E5)

Ili možete napravite nezavisnu formulu koristeći funkciju SMALL zajedno sa SUMPRODUCT:

Da bismo dobili zbir donje 3 vrijednosti u našem skupu podataka, formula poprima ovaj oblik :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

Funkcija SUM će dati isti rezultat:

=SUM(SMALL(B2:B10, {1,2,3}))

Napomena. Ako koristite reference ćelije umjesto konstante niza za k , trebate pritisnuti Ctrl + Shift + Enter da to postane formula niza. U programu Excel 365 koji podržava dinamičke nizove, SUM SMALL radi kao redovna formula u oba slučaja.

Kako ova formula funkcionira:

U redovnoj formuli, SMALL vraća jednu k-tu najmanju vrijednost u rasponu. U ovom slučaju, dobavljamo konstantu niza kao što je {1,2,3} za argument k, prisiljavajući ga da vrati niz od najmanje 3 vrijednosti:

{29240, 43610, 58860}

SUMPRODUCT ili Funkcija SUM zbraja brojeve u nizu i daje zbir. To je to!

INDEX MATCH MALE formula za dobivanje najmanjih podudaranja

U situaciji kada želite dohvatiti neke podatke povezane s najmanjom vrijednošću, koristite klasičnu INDEX MATCH kombinaciju sa SMALL za traženu vrijednost :

Gdje :

• Return_array je raspon iz kojeg se izdvajaju povezani podaci.
• Lookup_array je raspon u kojem se traži najniži n -th vrijednost.
• N je pozicija najmanje vrijednosti od interesa.

Zana primjer, da biste dobili naziv projekta koji ima najnižu cijenu, formula u E3 je:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Gdje su A2:A10 nazivi projekta, B2:B10 su troškovi i D3 je rang od najmanjeg.

Kopirajte formulu u ćelije ispod (E4 i E5) i dobićete imena 3 najjeftinija projekta:

Napomene:

• Ovo rješenje radi dobro za skup podataka koji nema duplikate. Međutim, dvije ili više dupliranih vrijednosti u numeričkoj koloni mogu stvoriti "veze" u rangiranju, što će dovesti do pogrešnih rezultata. U ovom slučaju, koristite malo sofisticiraniju formulu da biste prekinuli veze.
• U Excelu 365, ovaj zadatak se može postići uz pomoć novih funkcija dinamičkog niza. Osim što je mnogo jednostavniji, ovaj pristup automatski rješava problem veza. Za potpune detalje, pogledajte Kako filtrirati donje N vrijednosti u Excelu.

Sortirajte brojeve od najnižeg do najvišeg pomoću formule

Vjerujem da svi znaju kako da slože brojeve sa Excel funkcija sortiranja. Ali znate li kako izvršiti sortiranje pomoću formule? Korisnici programa Excel 365 mogu to učiniti na jednostavan način s novom funkcijom SORT. U Excelu 2019, 2016 i starijim verzijama, SORT ne radi, nažalost. Ali imajte malo vjere i SMALL će priskočiti u pomoć :)

Kao u prvom primjeru, koristimo funkciju ROWS sa proširenjem raspona reference na povećanje k za 1 u svakom red u kojem je formulaje kopirano:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Unesite formulu u prvu ćeliju, a zatim je povucite dolje na onoliko ćelija koliko ima vrijednosti u izvornom skupu podataka (C2:C10 u ovom primjeru) :

Savjet. Za sortiranje opadajuće , koristite funkciju LARGE umjesto SMALL.

Excel MALA formula za datume i vremena

Pošto su datumi i vremena također numeričke vrijednosti (u internom Excel sistemu datumi se pohranjuju kao sekvencijalni brojevi, a vremena kao decimalni razlomci), funkcija SMALL može njima upravljati kao i bez dodatnog napora sa vaše strane.

Kao što možete vidjeti na snimcima ekrana ispod, osnovna formula koju smo koristili za brojeve odlično funkcionira i za datume i vrijeme:

=SMALL($B$2:$B$10, D2)

MALA formula za pronalaženje najranija 3 datuma:

MALA formula da dobijete najkraća 3 puta:

Sljedeći primjer pokazuje kako vam funkcija SMALL može pomoći da izvršite konkretniji zadatak koji se odnosi na datume.

Pronađite prethodni datum najbliži današnjem ili određenom datumu

Na listi datuma , pod pretpostavkom da želite pronaći najbliži datum prije određenog datuma. Ovo se može učiniti korištenjem funkcije SMALL u kombinaciji sa COUNTIF.

Sa listom datuma u B2:B10 i ciljnim datumom u E1, sljedeća formula će vratiti prethodni datum najbliži ciljnom datumu:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

Da biste izdvojili datum koji je dva datuma prije datuma u E1, tj. prethodni ali jedan datum,formula je:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

Da biste pronašli prošli datum najbliži današnjem , koristite funkciju DANAS za kriterije COUNTIF-a:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

Savjet. Da biste spriječili greške u situaciji kada datum koji odgovara vašim kriterijima nije pronađen, možete obaviti funkciju IFERROR oko vaše formule, ovako:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

Kako ove formule funkcioniraju:

Opća ideja je da se broj datuma manji od ciljnog datuma sa COUNTIF. A ovaj broj je upravo ono što SMALL funkcija treba za argument k .

Da bismo bolje shvatili koncept, pogledajmo ga iz drugog ugla:

Ako je 1- Avg-2020 (ciljni datum u E1) pojavio se u našem skupu podataka, to bi bio 7. najveći datum na listi. Shodno tome, postoji šest datuma manjih od njega. Što znači, 6. najmanji datum je prethodni datum najbliži ciljnom datumu.

Dakle, prvo izračunamo koliko je datuma manje od datuma u E1 (rezultat je 6):

COUNTIF(B2:B10, "<"&E1)

A zatim, uključite brojač u 2. argument SMALL:

=SMALL(B2:B10, 6)

Da dobijete prethodni, ali jedan datum (što je 5. najmanji datum u našem slučaju) , oduzimamo 1 od rezultata COUNTIF-a.

Kako istaknuti donje vrijednosti u Excelu

Da biste istakli najmanjih n vrijednosti u vašoj tablici s Excel uslovnim formatiranjem, možete koristiti ili ugrađeni vrh /Donja opcija ili postavite svoje pravilo na osnovu MALE formule. Prva metoda je bržai lakši za primjenu, dok drugi pruža veću kontrolu i fleksibilnost. Koraci u nastavku će vas provesti kroz kreiranje prilagođenog pravila:

1. Odaberite raspon u kojem želite istaknuti donje vrijednosti. U našem slučaju, brojevi su u B2:B10, pa ga biramo. Ako želite istaknuti cijele redove, odaberite A2:B10.
2. Na kartici Početna , u grupi Stilovi kliknite Uvjetno oblikovanje > Novo pravilo .
3. U dijaloškom okviru Novo pravilo oblikovanja odaberite Koristite formulu da odredite koje ćelije želite formatirati.
4. U polje Format vrijednosti gdje je ova formula tačna unesite formulu poput ove:

   =B2<=SMALL($B$2:$B$10, 3)

   Gdje je B2 krajnja lijeva ćelija numeričkog raspon koji treba provjeriti, $B$2:$B$10 je cijeli raspon, a 3 je n donje vrijednosti koje treba istaknuti.

   U vašoj formuli, obratite pažnju na tipove referenci: krajnja lijeva ćelija je relativna referenca (B2) dok je raspon apsolutna referenca ($B$2:$B$10).

5. Kliknite na dugme Format i odaberite bilo koji format koji želite.
6. Kliknite dvaput OK da zatvorite oba dijaloška prozora.

Gotovo! Donje 3 vrijednosti u koloni B su istaknute:

Za više informacija, pogledajte Excel uvjetno formatiranje zasnovano na formuli.

Mala Excel funkcija ne radi

Kao što ste upravo vidjeli iz naših primjera, korištenje SMALL funkcije u Excelu je prilično jednostavno, a vi stemalo je vjerovatno da ćete imati ikakvih poteškoća s tim. Ako vaša formula ne radi, najvjerovatnije će to biti #NUM! greška, koja se može pojaviti iz sljedećih razloga:

• Niz je prazan ili ne sadrži jednu numeričku vrijednost.
• k vrijednost je manja od nule (glupa tipkarska greška može vas koštati satima rješavanja problema!) ili premašuje broj vrijednosti u nizu.

Eto kako koristiti MALE formulu u Excelu da pronađete i označite donje brojeve u skupu podataka. Ako znate još neke scenarije u kojima ova funkcija dobro dođe, slobodno ih podijelite u komentarima. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeće sedmice!

Vježbanje za preuzimanje

MALI primjeri formule Excel (.xlsx datoteka)