Neste breve tutorial, falaremos sobre a función PEQUENA de Excel, como funciona e como usala para atopar o número, a data ou a hora máis pequenos.

Necesitas para atopar algúns números máis baixos nunha folla de traballo? Isto é bastante sinxelo de facer coa función de clasificación de Excel. Non queres perder o tempo en reordenar os teus datos con cada cambio? A función PEQUENO axudarache a atopar rapidamente o valor máis baixo, o segundo máis pequeno, o terceiro máis pequeno, etc.

A función PEQUENA de Excel

PEQUENA é unha función estatística que devolve o n-ésimo valor máis pequeno dun conxunto de datos.

A sintaxe da función PEQUENO inclúe dous argumentos, os dous son obrigatorios.

SMALL(matriz, k)

Onde:

• Matriz : unha matriz ou un intervalo de celas das que extraer o valor máis pequeno.
• K : un enteiro que indica a posición desde o valor máis baixo para devolver, é dicir, o k-ésimo máis pequeno.

A función está dispoñible en todas as versións de Excel para Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010 e anteriores.

Consello. Para atopar o k-ésimo valor máis baixo con criterios, use a fórmula SMALL IF de Excel.

Fórmula PEQUENA básica en Excel

Unha fórmula PEQUENA na súa forma básica é moi doada de construír; basta con especificar o rango e a posición do elemento máis pequeno a devolver.

Na lista de números en B2:B10, supoñendo que quere extraer o terceiro valor máis pequeno. A fórmula é comosimple como:

=SMALL(B2:B10, 3)

Para facilitarche a comprobación do resultado, a columna B ordénase en orde ascendente:

4 cousas que debes saber sobre a función SMALL

As seguintes notas de uso axudaranche a comprender mellor o comportamento da función SMALL e evitarán confusións ao crear as túas propias fórmulas.

1. Calquera <9 Os valores>celdas en branco , texto e os valores lóxicos VERDADEIRO e FALSO no argumento matriz son ignorados.
2. Se matriz contén un ou máis erros , devólvese un erro.
3. No caso de que haxa duplicados en matriz , a súa fórmula pode dar lugar a "lazos". Por exemplo, se dúas celas conteñen o número 1 e a función PEQUENA está configurada para devolver o valor máis pequeno e o segundo máis pequeno, obterá 1 en ambos os casos.
4. Asumindo que n é o número de valores en matriz , SMALL(matriz,1) devolverá o valor máis baixo e SMALL(matriz,n) escollerá o valor máis alto.

Como usar a función PEQUENA en Excel - exemplos de fórmulas

E agora, vexamos algúns exemplos máis da función PEQUENA de Excel que van máis alá do seu uso básico.

Atopa os valores inferiores 3, 5, 10, etc.

Como xa sabes, a función PEQUENA está deseñada para calcular o n-ésimo valor máis baixo. Este exemplo mostra como facelo de forma máis eficaz.

Na táboa seguinte, supoña que quere atopar os 3 valores inferiores. Para iso, escriba onúmeros 1, 2 e 3 en celas separadas (D3, D4 e D5 no noso caso). A continuación, introduza a seguinte fórmula en E3 e arrástrea cara abaixo ata E5:

=SMALL($B$2:$B$10, D3)

En E3, a fórmula extrae o valor máis pequeno usando o número en D3 para o k argumento. A clave é proporcionar referencias de cela adecuadas, polo que a fórmula se copia correctamente noutras celas: absoluta para matriz e relativa para k .

Non queres molestarte en escribir as clasificacións manualmente? Use a función ROWS cunha referencia de intervalo de expansión para proporcionar o valor k . Para iso, facemos unha referencia absoluta para a primeira cela (ou só bloqueamos a coordenada da fila como B$2) e unha referencia relativa para a última cela:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Como resultado, o intervalo a referencia se expande a medida que se copia a fórmula na columna. En D2, ROWS(B$2:B2) produce 1 para k e a fórmula devolve o custo máis baixo. En D3, ROWS(B$2:B3) obtén 2 e obtemos o segundo custo máis baixo, etc.

Copie a fórmula a través de 5 celas e obterá os 5 valores inferiores:

Suma dos N valores inferiores

Queres atopar un total dos n valores máis pequenos dun conxunto de datos? Se xa extraeu os valores como se mostra no exemplo anterior, a solución máis sinxela sería unha fórmula de SUMA como:

=SUM(E3:E5)

Ou pode faga unha fórmula independente usando a función PEQUENO xunto con SUMAPRODUTO:

Para obter a suma dos 3 valores inferiores do noso conxunto de datos, a fórmula toma esta forma :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

A función SUMA producirá o mesmo resultado:

=SUM(SMALL(B2:B10, {1,2,3}))

Nota. Se usa referencias de cela en lugar de constante matricial para k , cómpre premer Ctrl + Maiús + Intro para que sexa unha fórmula matricial. En Excel 365 que admite matrices dinámicas, SUM SMALL funciona como unha fórmula normal en calquera dos casos.

Como funciona esta fórmula:

Nunha fórmula normal, SMALL devolve un k-ésimo valor máis pequeno dun intervalo. Neste caso, fornecemos unha constante matricial como {1,2,3} para o argumento k, forzándoo a devolver unha matriz dos 3 valores máis pequenos:

{29240, 43610, 58860}

O PRODUTO SUMA ou A función SUMA suma os números da matriz e mostra o total. Isto é todo!

Fórmula INDEX MATCH SMALL para obter coincidencias máis pequenas

En caso de querer recuperar algúns datos asociados co valor máis pequeno, use a clásica combinación INDEX MATCH con SMALL para o valor de busca :

Onde :

• Return_array é un intervalo do que se extraen os datos asociados.
• Lookup_array é un intervalo onde se busca o n máis baixo. -ésimo valor.
• N é a posición do menor valor de interese.

Paraexemplo, para obter o nome do proxecto que ten o custo máis baixo, a fórmula en E3 é:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Onde A2:A10 son os nomes do proxecto, B2:B10 son os custos e D3 é o rango de menor.

Copia a fórmula nas celas de abaixo (E4 e E5) e obterás os nomes dos 3 proxectos máis baratos:

Notas:

• Esta solución funciona ben para un conxunto de datos que non ten duplicados. Non obstante, dous ou máis valores duplicados nunha columna numérica poden crear "empates" na clasificación, o que levará a resultados incorrectos. Neste caso, use unha fórmula un pouco máis sofisticada para romper os lazos.
• En Excel 365, esta tarefa pódese realizar coa axuda das novas funcións de matriz dinámica. Ademais de ser moito máis sinxelo, este enfoque resolve automaticamente o problema dos lazos. Para obter máis información, consulte Como filtrar os valores N inferiores en Excel.

Ordenar os números de menor a maior cunha fórmula

Creo que todo o mundo sabe ordenar os números con Función de clasificación de Excel. Pero sabes como facer a clasificación cunha fórmula? Os usuarios de Excel 365 poden facelo dun xeito sinxelo coa nova función ORDENAR. En Excel 2019, 2016 e versións anteriores, SORT non funciona, por desgraza. Pero ten un pouco de fe, e PEQUENO acudirá ao rescate :)

Como no primeiro exemplo, usamos a función ROWS cunha referencia de intervalo de expansión para incrementar k en 1 en cada fila onde a fórmulacópiase:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Introduza a fórmula na primeira cela e arrástrea cara abaixo ata tantas celas como valores haxa no conxunto de datos orixinal (C2:C10 neste exemplo) :

Consello. Para ordenar descendente , use a función GRANDE en lugar de PEQUENO.

Fórmula SMALL de Excel para datas e horas

Debido a que as datas e as horas tamén son valores numéricos (no sistema Excel interno, as datas gárdanse como números secuenciais e as horas como fraccións decimais), a función PEQUENA pode manexalas tamén sen ningún esforzo adicional do teu lado.

Como podes ver nas capturas de pantalla que aparecen a continuación, unha fórmula básica que usamos para os números tamén funciona moi ben para as datas e as horas:

=SMALL($B$2:$B$10, D2)

Fórmula PEQUENA para atopar as 3 datas máis antigas:

Fórmula PEQUENA para obter as 3 veces máis curtas:

O seguinte exemplo mostra como a función PEQUENA pode axudarche a realizar unha tarefa máis específica relacionada coas datas.

Busca unha data anterior máis próxima a hoxe ou a data especificada

Nunha lista de datas , supoñendo que quere atopar a data máis próxima antes dunha data especificada. Pódese facer usando a función PEQUENA en combinación con COUNTIF.

Coa lista de datas en B2:B10 e a data de destino en E1, a seguinte fórmula devolverá a data anterior máis próxima á data de destino:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

Para extraer unha data que está dúas datas antes da data en E1, é dicir, unha data anterior pero unha, oa fórmula é:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

Para buscar unha data pasada máis próxima a hoxe , use a función HOXE para os criterios de CONTARSE:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

Consello. Para evitar erros na situación en que non se atopa unha data que coincida cos teus criterios, podes envolver a función IFERROR na túa fórmula, como esta:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

Como funcionan estas fórmulas:

A idea xeral é contar o número de datas menor que a data de destino con COUNTIF. E este reconto é exactamente o que necesita a función PEQUENA para o argumento k .

Para comprender mellor o concepto, mirámolo desde outro ángulo:

Se 1- Ago-2020 (a data obxectivo no E1) apareceu no noso conxunto de datos, sería a sétima data máis importante da lista. En consecuencia, hai seis datas máis pequenas que el. É dicir, a sexta data máis pequena é a data anterior máis próxima á data de destino.

Entón, primeiro calculamos cantas datas son máis pequenas que a data en E1 (o resultado é 6):

COUNTIF(B2:B10, "<"&E1)

E logo, conecta o reconto no segundo argumento de SMALL:

=SMALL(B2:B10, 6)

Para obter a data anterior pero única (que é a quinta data máis pequena no noso caso) , restamos 1 do resultado de COUNTIF.

Como resaltar os valores inferiores en Excel

Para resaltar os valores n máis pequenos da túa táboa co formato condicional de Excel, podes utilizar un elemento superior integrado. / Opción inferior ou configura a túa propia regra baseada nunha fórmula PEQUENA. O primeiro método é máis rápidoe máis fácil de aplicar, mentres que o segundo proporciona máis control e flexibilidade. Os pasos seguintes guiaranche a través da creación dunha regra personalizada:

1. Selecciona o intervalo no que queres resaltar os valores inferiores. No noso caso, os números están en B2:B10, polo que o seleccionamos. Se queres resaltar filas enteiras, selecciona A2:B10.
2. Na pestana Inicio , no grupo Estilos , fai clic en Formato condicional > Nova regra .
3. Na caixa de diálogo Nova regra de formato , escolla Usar unha fórmula para determinar as celas que desexa dar formato.
4. Na caixa Formato de valores onde esta fórmula é verdadeira , introduza unha fórmula como esta:

   =B2<=SMALL($B$2:$B$10, 3)

   Onde B2 é a cela máis á esquerda do número numérico intervalo a comprobar, $B$2:$B$10 é o intervalo completo e 3 son os n valores inferiores a destacar.

   Na súa fórmula, teña en conta os tipos de referencia: o A cela máis á esquerda é unha referencia relativa (B2) mentres que o intervalo é a referencia absoluta ($B$2:$B$10).

5. Fai clic no botón Formato e escolla o formato que desexe.
6. Faga clic en Aceptar dúas veces para pechar as dúas ventás de diálogo.

Feito! Resáltanse os 3 valores inferiores da columna B:

Para obter máis información, consulte Formato condicional de Excel baseado na fórmula.

A función PEQUENA de Excel non funciona

Como acabas de ver nos nosos exemplos, usar a función PEQUENA en Excel é bastante sinxelo e estásé improbable que teña dificultades con el. Se a túa fórmula non funciona, o máis probable é que sexa un #NUM! erro, que pode ocorrer polos seguintes motivos:

• A matriz está baleira ou non contén un só valor numérico.
• O k é inferior a cero (unha erro tipográfico pode custarche horas de resolución de problemas!) ou supera o número de valores da matriz.

Así é como usar unha fórmula PEQUENA en Excel para atopar e resalte os números inferiores nun conxunto de datos. Se coñeces outros escenarios nos que a función sexa útil, podes compartilo nos comentarios. Grazas por ler e espero verte no noso blogue a vindeira semana!

Caderno de prácticas para descargar

Exemplos de fórmulas PEQUENAS de Excel (ficheiro .xlsx)