În acest scurt tutorial, vom vorbi despre funcția Excel SMALL, cum funcționează și cum să o folosim pentru a găsi cel mai mic număr, dată sau oră.

Aveți nevoie să găsiți câteva dintre cele mai mici numere dintr-o foaie de calcul? Acest lucru este destul de ușor de realizat cu funcția Excel Sort. Nu doriți să pierdeți timp cu reorânduirea datelor la fiecare modificare? Funcția SMALL vă va ajuta să găsiți rapid cea mai mică valoare, a doua cea mai mică, a treia cea mai mică și așa mai departe.

Funcția Excel SMALL

SMALL este o funcție statistică care returnează a n-a cea mai mică valoare dintr-un set de date.

Sintaxa funcției SMALL include două argumente, ambele obligatorii.

SMALL(array, k)

Unde:

• Array - o matrice sau un interval de celule din care să se extragă cea mai mică valoare.
• K - un număr întreg care indică poziția de la cea mai mică valoare care trebuie returnată, adică a k-a cea mai mică.

Funcția este disponibilă în toate versiunile de Excel pentru Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010 și versiunile anterioare.

Sfat. Pentru a găsi a k-a cea mai mică valoare cu criterii, utilizați formula Excel SMALL IF.

Formulă de bază SMALL în Excel

O formulă SMALL în forma sa de bază este foarte ușor de construit - trebuie doar să specificați intervalul și poziția de la cel mai mic element care trebuie returnat.

În lista numerelor din B2:B10, presupunând că doriți să extrageți a 3-a cea mai mică valoare, formula este foarte simplă:

=SMALL(B2:B10, 3)

Pentru a vă facilita verificarea rezultatului, coloana B este sortată în ordine crescătoare:

4 lucruri pe care trebuie să le știți despre funcția SMALL

Următoarele note de utilizare vă vor ajuta să înțelegeți mai bine comportamentul funcției SMALL și să evitați confuziile atunci când vă construiți propriile formule.

1. Orice celule goale , text valorile și logic valorile TRUE și FALSE în array sunt ignorate.
2. Dacă array conține unul sau mai multe erori , se returnează o eroare.
3. În cazul în care există duplicate în array De exemplu, dacă două celule conțin numărul 1, iar funcția SMALL este configurată să returneze cea mai mică și a doua cea mai mică valoare, veți obține 1 în ambele cazuri.
4. Presupunând că n este numărul de valori din array , SMALL(array,1) va returna cea mai mică valoare, iar SMALL(array,n) va alege cea mai mare valoare.

Cum se utilizează funcția SMALL în Excel - exemple de formule

Și acum, să analizăm alte câteva exemple de utilizare a funcției Excel SMALL care depășesc utilizarea de bază a acesteia.

Găsiți valorile de jos 3, 5, 10, etc.

După cum știți deja, funcția SMALL este concepută pentru a calcula cea de-a n-a cea mai mică valoare. Acest exemplu arată cum se poate face acest lucru în modul cel mai eficient.

În tabelul de mai jos, să presupunem că doriți să găsiți cele 3 valori de jos. Pentru aceasta, introduceți numerele 1, 2 și 3 în celule separate (D3, D4 și D5 în cazul nostru). Apoi, introduceți următoarea formulă în E3 și trageți-o în jos prin E5:

=SMALL($B$2:$B$10, D3)

În E3, formula extrage cea mai mică valoare folosind numărul din D3 pentru k Argumentul cheie este să se furnizeze referințe de celule corespunzătoare, datorită cărora formula se copiază corect în alte celule: absolute pentru array și relativ pentru k .

Nu vreți să vă deranjați să tastați manual rangurile? Utilizați funcția ROWS cu un gamă în extindere de referință pentru a furniza k Pentru aceasta, facem o referință absolută pentru prima celulă (sau blocăm doar coordonatele rândului, cum ar fi B$2) și o referință relativă pentru ultima celulă:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Ca urmare, referința intervalului se extinde pe măsură ce formula este copiată în josul coloanei. În D2, ROWS(B$2:B2) produce 1 pentru k În D3, ROWS(B$2:B3) produce 2, iar noi obținem al doilea cost cel mai mic, și așa mai departe.

Copiați formula în 5 celule și veți obține cele 5 valori de jos:

Suma valorilor N de jos

Doriți să găsiți un total al celor mai mici n valori dintr-un set de date? Dacă ați extras deja valorile, așa cum se arată în exemplul anterior, cea mai simplă soluție ar fi o formulă SUM ca:

=SUM(E3:E5)

Sau puteți crea o formulă independentă utilizând funcția SMALL împreună cu SUMPRODUCT:

Pentru a obține suma celor 3 valori de jos din setul nostru de date, formula are următoarea formă:

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

Funcția SUM va produce același rezultat:

=SUM(SMALL(B2:B10, {1,2,3}))

Notă: Dacă utilizați referințe de celule mai degrabă decât o constantă de matrice pentru k , trebuie să apăsați Ctrl + Shift + Enter pentru a o transforma într-o formulă de matrice. În Excel 365 care acceptă matricele dinamice, SUM SMALL funcționează ca o formulă obișnuită în ambele cazuri.

Cum funcționează această formulă:

Într-o formulă obișnuită, SMALL returnează o singură valoare k-cea mai mică dintr-un interval. În acest caz, furnizăm o constantă de matrice ca {1,2,3} pentru argumentul k, forțând-o să returneze o matrice cu cele mai mici 3 valori:

{29240, 43610, 58860}

Funcția SUMPRODUCT sau SUM însumează numerele din tablou și scoate totalul. Asta este!

Formula INDEX MATCH SMALL pentru a obține cele mai mici potriviri

În situația în care doriți să preluați date asociate cu cea mai mică valoare, utilizați combinația clasică INDEX MATCH cu SMALL ca valoare de căutare:

Unde:

• Rețea de returnare este un interval din care se extrag datele asociate.
• Tablou_repertoriu este un interval în care se caută cea mai mică a n-a valoare.
• N este poziția celei mai mici valori de interes.

De exemplu, pentru a obține numele proiectului care are cel mai mic cost, formula din E3 este:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Unde A2:A10 sunt denumirile proiectelor, B2:B10 sunt costurile și D3 este rangul de la cel mai mic.

Copiați formula în celulele de mai jos (E4 și E5) și veți obține numele celor mai ieftine 3 proiecte:

Note:

• Această soluție funcționează bine pentru un set de date care nu are dubluri. Cu toate acestea, două sau mai multe valori duplicate într-o coloană numerică pot crea "egalități" în clasament, ceea ce va duce la rezultate greșite. În acest caz, vă rugăm să utilizați o formulă ceva mai sofisticată pentru a rupe egalitățile.
• În Excel 365, această sarcină poate fi îndeplinită cu ajutorul noilor funcții de matrice dinamică. Pe lângă faptul că este mult mai simplă, această abordare rezolvă automat problema egalităților. Pentru detalii complete, consultați Cum să filtrați valorile N de jos în Excel.

Sortarea numerelor de la cel mai mic la cel mai mare cu o formulă

Cred că toată lumea știe cum să pună numerele în ordine cu ajutorul funcției Excel Sort. Dar știți cum să efectuați sortarea cu o formulă? Utilizatorii de Excel 365 o pot face într-un mod simplu cu noua funcție SORT. În Excel 2019, 2016 și versiunile anterioare, SORT nu funcționează, din păcate. Dar aveți puțină încredere, iar SMALL va veni în ajutor :)

La fel ca în primul exemplu, folosim funcția ROWS cu o referință de extindere a intervalului pentru a incrementa k cu 1 în fiecare rând în care este copiată formula:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Introduceți formula în prima celulă, apoi trageți-o în jos în atâtea celule câte valori există în setul de date original (C2:C10 în acest exemplu):

Sfat. pentru a sorta descrescător , utilizați funcția LARGE în loc de SMALL.

Excel Formula SMALL pentru date și ore

Deoarece datele și orele sunt, de asemenea, valori numerice (în sistemul intern Excel, datele sunt stocate ca numere secvențiale, iar orele ca fracții zecimale), funcția SMALL le poate gestiona și pe acestea fără niciun efort suplimentar din partea dumneavoastră.

După cum puteți vedea în capturile de ecran de mai jos, o formulă de bază pe care am folosit-o pentru numere funcționează foarte bine și pentru date și ore:

=SMALL($B$2:$B$10, D2)

Formula SMALL pentru a găsi cele mai timpurii 3 date:

Formula SMALL pentru a obține cea mai scurtă de 3 ori:

Următorul exemplu arată cum funcția SMALL vă poate ajuta să îndepliniți o sarcină mai specifică legată de date.

Găsiți o dată anterioară cea mai apropiată de data de astăzi sau de o dată specificată

Într-o listă de date, să presupunem că doriți să găsiți cea mai apropiată dată înainte de o dată specificată. Acest lucru se poate face utilizând funcția SMALL în combinație cu COUNTIF.

Cu lista de date din B2:B10 și data țintă din E1, următoarea formulă va returna o dată anterioară cea mai apropiată de data țintă:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

Pentru a extrage o dată care este cu două date înainte de data din E1, adică o dată anterioară, dar una singură, formula este:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

Pentru a găsi o dată trecută cel mai apropiat de ziua de azi , utilizați funcția TODAY pentru criteriile COUNTIF:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY())))

Sfat: Pentru a preveni erorile în situația în care nu se găsește o dată care să corespundă criteriilor dvs., puteți înfășura funcția IFERROR în jurul formulei dvs., astfel:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

Cum funcționează aceste formule:

Ideea generală este de a număra numărul de date mai mici decât data țintă cu COUNTIF. Și acest număr este exact ceea ce are nevoie funcția SMALL pentru funcția k argument.

Pentru a înțelege mai bine acest concept, să privim din alt unghi:

Dacă 1-aug-2020 (data-țintă din E1) ar apărea în setul nostru de date, ar fi a 7-a cea mai mare dată din listă. În consecință, există șase date mai mici decât aceasta. Ceea ce înseamnă că a 6-a cea mai mică dată este data anterioară cea mai apropiată de data-țintă.

Deci, mai întâi calculăm câte date sunt mai mici decât data din E1 (rezultatul este 6):

COUNTIF(B2:B10, "<"&E1)

Apoi, introduceți numărul în cel de-al doilea argument al SMALL:

=SMALL(B2:B10, 6)

Pentru a obține penultima dată anterioară (care este a 5-a cea mai mică dată în cazul nostru), scădem 1 din rezultatul COUNTIF.

Cum se evidențiază valorile de jos în Excel

Pentru a evidenția cele mai mici n valori din tabelul dvs. cu formatarea condiționată Excel, puteți utiliza fie o opțiune încorporată Top/Bottom, fie puteți configura propria regulă bazată pe o formulă SMALL. Prima metodă este mai rapidă și mai ușor de aplicat, în timp ce a doua oferă mai mult control și flexibilitate. Pașii de mai jos vă vor ghida în crearea unei reguli personalizate:

1. Selectați intervalul în care doriți să evidențiați valorile de jos. În cazul nostru, numerele sunt în B2:B10, așa că îl selectăm. Dacă doriți să evidențiați rânduri întregi, selectați A2:B10.
2. Pe Acasă în fila Stiluri grup, faceți clic pe Formatare condiționată > Regula nouă .
3. În Regulă nouă de formatare caseta de dialog, alegeți Utilizați o formulă pentru a determina ce celule trebuie formatate.
4. În Formatați valorile în cazul în care această formulă este adevărată introduceți o formulă ca aceasta:

   =B2<=SMALL($B$2:$B$10, 3)

   Unde B2 este cea mai din stânga celulă din intervalul numeric care trebuie verificat, $B$2:$B$10 este întregul interval, iar 3 este n valorile de jos pentru a fi evidențiate.

   În formula dvs., vă rugăm să țineți cont de tipurile de referință: celula cea mai din stânga este o referință relativă (B2), în timp ce intervalul este o referință absolută ($B$2:$B$10).

5. Faceți clic pe butonul Format și alegeți orice format doriți.
6. Faceți clic pe OK de două ori pentru a închide ambele ferestre de dialog.

Cele 3 valori de jos din coloana B sunt evidențiate:

Pentru mai multe informații, consultați Formatarea condiționată Excel bazată pe formule.

Funcția Excel SMALL nu funcționează

După cum tocmai ați văzut din exemplele noastre, utilizarea funcției SMALL în Excel este destul de ușoară și este puțin probabil să întâmpinați dificultăți cu ea. Dacă formula dvs. nu funcționează, cel mai probabil va fi o eroare #NUM! care poate apărea din următoarele motive:

• Array este gol sau nu conține o singură valoare numerică.
• The k este mai mică decât zero (o greșeală de scriere stupidă vă poate costa ore întregi de depanare!) sau depășește numărul de valori din matrice.

Iată cum se utilizează o formulă SMALL în Excel pentru a găsi și evidenția numerele de jos într-un set de date. Dacă știți și alte scenarii în care funcția este utilă, sunteți bineveniți să le împărtășiți în comentarii. Vă mulțumesc pentru lectură și sper să ne vedem pe blog săptămâna viitoare!

Caietul de practică pentru descărcare

Exemple de formule Excel SMALL (fișier .xlsx)