Trong hướng dẫn ngắn này, chúng ta sẽ nói về hàm SMALL trong Excel, cách thức hoạt động và cách sử dụng hàm này để tìm số, ngày hoặc giờ nhỏ nhất thứ N.

Cần để tìm một vài số thấp nhất trong một trang tính? Điều này khá dễ thực hiện với tính năng Sắp xếp của Excel. Bạn không muốn lãng phí thời gian sắp xếp lại dữ liệu của mình sau mỗi lần thay đổi? Hàm SMALL sẽ giúp bạn tìm nhanh giá trị nhỏ nhất, nhỏ thứ hai, nhỏ thứ ba, v.v.

Hàm SMALL trong Excel

SMALL là một hàm thống kê trả về giá trị nhỏ thứ n trong một tập dữ liệu.

Cú pháp của hàm SMALL bao gồm hai đối số, cả hai đều bắt buộc phải có.

SMALL(array, k)

Ở đâu:

• Mảng - một mảng hoặc một dải ô để trích xuất giá trị nhỏ nhất từ ​​đó.
• K - một số nguyên cho biết vị trí từ giá trị nhỏ nhất cần trả về, tức là nhỏ nhất thứ k.

Hàm này có sẵn trong tất cả các phiên bản Excel cho Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010 trở về trước.

Mẹo. Để tìm giá trị nhỏ thứ k với tiêu chí, hãy sử dụng công thức SMALL IF của Excel.

Công thức NHỎ cơ bản trong Excel

Một công thức NHỎ ở dạng cơ bản rất dễ tạo - bạn chỉ cần chỉ định phạm vi và vị trí từ mục nhỏ nhất cần trả về.

Trong danh sách các số ở B2:B10, giả sử bạn muốn trích xuất giá trị nhỏ thứ 3. Công thức là nhưđơn giản như:

=SMALL(B2:B10, 3)

Để giúp bạn dễ dàng kiểm tra kết quả, cột B được sắp xếp theo thứ tự tăng dần:

4 điều bạn nên biết về hàm SMALL

Những lưu ý sử dụng sau đây sẽ giúp bạn hiểu rõ hơn về hoạt động của hàm SMALL và tránh nhầm lẫn khi xây dựng công thức của riêng mình.

1. Bất kỳ <9 Các giá trị>ô trống , văn bản và các giá trị logic TRUE và FALSE trong đối số mảng sẽ bị bỏ qua.
2. Nếu mảng chứa một hoặc nhiều lỗi , một lỗi sẽ được trả về.
3. Trong trường hợp có mảng trùng lặp trong mảng , công thức của bạn có thể dẫn đến "quan hệ". Ví dụ: nếu hai ô chứa số 1 và hàm SMALL được định cấu hình để trả về giá trị nhỏ nhất và nhỏ thứ 2, thì bạn sẽ nhận được 1 trong cả hai trường hợp.
4. Giả sử n là số lượng giá trị trong array , SMALL(array,1) sẽ trả về giá trị thấp nhất và SMALL(array,n) sẽ chọn giá trị cao nhất.

Cách sử dụng hàm SMALL trong Excel - ví dụ về công thức

Và bây giờ, hãy xem xét một số ví dụ khác về hàm SMALL trong Excel vượt xa cách sử dụng cơ bản của nó.

Tìm các giá trị 3, 5, 10, v.v. dưới cùng

Như bạn đã biết, hàm SMALL được thiết kế để tính giá trị nhỏ nhất thứ n. Ví dụ này cho thấy cách thực hiện việc này một cách hiệu quả nhất.

Trong bảng bên dưới, giả sử bạn muốn tìm 3 giá trị dưới cùng. Đối với điều này, gõsố 1, 2 và 3 trong các ô riêng biệt (D3, D4 và D5 trong trường hợp của chúng tôi). Sau đó, nhập công thức sau vào E3 và kéo xuống qua E5:

=SMALL($B$2:$B$10, D3)

Trong E3, công thức trích xuất giá trị nhỏ nhất bằng cách sử dụng số trong D3 cho k lập luận. Điều quan trọng là cung cấp các tham chiếu ô phù hợp để công thức sao chép chính xác vào các ô khác: tuyệt đối cho mảng và tương đối cho k .

Không muốn mất công đánh thứ tự thủ công? Sử dụng hàm ROWS với tham chiếu phạm vi mở rộng để cung cấp giá trị k . Đối với điều này, chúng tôi tạo tham chiếu tuyệt đối cho ô đầu tiên (hoặc chỉ khóa tọa độ hàng như B$2) và tham chiếu tương đối cho ô cuối cùng:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Kết quả là phạm vi tham chiếu mở rộng khi công thức được sao chép xuống cột. Trong D2, ROWS(B$2:B2) tạo ra 1 cho k và công thức trả về chi phí thấp nhất. Trong D3, ROWS(B$2:B3) mang lại 2 và chúng tôi nhận được chi phí thấp thứ 2, v.v.

Chỉ cần sao chép công thức qua 5 ô và bạn sẽ nhận được 5 giá trị dưới cùng:

Tính tổng N giá trị dưới cùng

Bạn muốn tìm tổng n giá trị nhỏ nhất trong tập dữ liệu? Nếu bạn đã trích xuất các giá trị như minh họa trong ví dụ trước, giải pháp đơn giản nhất sẽ là một công thức SUM như:

=SUM(E3:E5)

Hoặc bạn có thể tạo một công thức độc lập bằng cách sử dụng hàm SMALL cùng với TÓM TẮT:

Để lấy tổng của 3 giá trị dưới cùng trong tập hợp dữ liệu của chúng ta, công thức có dạng này :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

Hàm SUM sẽ cho kết quả tương tự:

=SUM(SMALL(B2:B10, {1,2,3}))

Lưu ý. Nếu bạn sử dụng tham chiếu ô thay vì hằng số mảng cho k , bạn cần nhấn Ctrl + Shift + Enter để biến nó thành công thức mảng. Trong Excel 365 hỗ trợ mảng động, SUM NHỎ hoạt động như một công thức thông thường trong cả hai trường hợp.

Cách thức hoạt động của công thức này:

Trong một công thức thông thường, SMALL trả về một giá trị nhỏ nhất thứ k trong một phạm vi. Trong trường hợp này, chúng tôi cung cấp một hằng số mảng như {1,2,3} cho đối số k, buộc nó trả về một mảng gồm 3 giá trị nhỏ nhất:

{29240, 43610, 58860}

SUMPRODUCT hoặc Hàm SUM cộng các số trong mảng và xuất ra tổng. Vậy là xong!

Công thức INDEX MATCH SMALL để nhận kết quả khớp nhỏ nhất

Trong trường hợp bạn muốn truy xuất một số dữ liệu được liên kết với giá trị nhỏ nhất, hãy sử dụng kết hợp INDEX MATCH cổ điển với SMALL cho giá trị tra cứu :

Ở đâu :

• Return_array là phạm vi để trích xuất dữ liệu liên quan.
• Lookup_array là phạm vi để tìm kiếm n thấp nhất -th value.
• N là vị trí của giá trị quan tâm nhỏ nhất.

Forví dụ: để lấy tên của dự án có chi phí thấp nhất, công thức trong E3 là:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Trong đó A2:A10 là tên dự án, B2:B10 là chi phí và D3 là thứ hạng từ nhỏ nhất.

Sao chép công thức vào các ô bên dưới (E4 và E5) và bạn sẽ nhận được tên của 3 dự án rẻ nhất:

Lưu ý:

• Giải pháp này hoạt động tốt đối với tập dữ liệu không có dữ liệu trùng lặp. Tuy nhiên, hai hoặc nhiều giá trị trùng lặp trong một cột số có thể tạo ra "mối quan hệ" trong xếp hạng, điều này sẽ dẫn đến kết quả sai. Trong trường hợp này, vui lòng sử dụng công thức phức tạp hơn một chút để phá vỡ mối ràng buộc.
• Trong Excel 365, tác vụ này có thể được thực hiện với sự trợ giúp của các hàm mảng động mới. Ngoài việc đơn giản hơn nhiều, cách tiếp cận này tự động giải quyết vấn đề về dây buộc. Để biết đầy đủ chi tiết, vui lòng xem Cách lọc giá trị N dưới cùng trong Excel.

Sắp xếp các số từ thấp nhất đến cao nhất bằng công thức

Tôi tin rằng mọi người đều biết cách sắp xếp các số theo thứ tự Tính năng Sắp xếp Excel. Nhưng bạn có biết cách thực hiện sắp xếp theo công thức không? Người dùng Excel 365 có thể thực hiện dễ dàng với hàm SORT mới. Than ôi, trong Excel 2019, 2016 và các phiên bản cũ hơn, SORT không hoạt động. Nhưng hãy tin tưởng một chút, và NHỎ sẽ đến giải cứu :)

Giống như trong ví dụ đầu tiên, chúng tôi sử dụng hàm ROWS với tham chiếu phạm vi mở rộng để tăng k lên 1 trong mỗi hàng nơi công thứcđược sao chép:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Nhập công thức vào ô đầu tiên, sau đó kéo công thức đó xuống nhiều ô bằng số lượng giá trị trong tập dữ liệu gốc (C2:C10 trong ví dụ này) :

Mẹo. Để sắp xếp giảm dần , hãy sử dụng hàm LARGE thay vì SMALL.

Công thức Excel SMALL cho ngày và giờ

Vì ngày và giờ cũng là các giá trị số (trong hệ thống Excel nội bộ, ngày được lưu trữ dưới dạng số tuần tự và thời gian dưới dạng phân số thập phân), nên hàm SMALL có thể xử lý chúng mà không cần thêm bất kỳ nỗ lực nào từ phía bạn.

Như bạn có thể thấy trong ảnh chụp màn hình bên dưới, một công thức cơ bản mà chúng tôi sử dụng cho các số cũng hoạt động rất tốt cho ngày và giờ:

=SMALL($B$2:$B$10, D2)

Công thức NHỎ tìm 3 ngày sớm nhất:

Công thức NHỎ tìm 3 ngày ngắn nhất:

Ví dụ tiếp theo cho thấy cách hàm SMALL có thể giúp bạn hoàn thành một tác vụ cụ thể hơn liên quan đến ngày.

Tìm ngày trước đó gần nhất với ngày hôm nay hoặc ngày được chỉ định

Trong danh sách ngày , giả sử bạn muốn tìm ngày gần nhất trước một ngày cụ thể. Điều này có thể được thực hiện bằng cách sử dụng hàm SMALL kết hợp với COUNTIF.

Với danh sách ngày trong B2:B10 và ngày mục tiêu trong E1, công thức sau sẽ trả về ngày trước đó gần nhất với ngày mục tiêu:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

Để trích xuất một ngày trước ngày trong E1 hai ngày, tức là một ngày trước nhưng một ngày,công thức là:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

Để tìm ngày trong quá khứ gần ngày hôm nay nhất , hãy sử dụng hàm TODAY cho tiêu chí của COUNTIF:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

Mẹo. Để tránh xảy ra lỗi trong trường hợp không tìm thấy ngày phù hợp với tiêu chí của bạn, bạn có thể bọc hàm IFERROR xung quanh công thức của mình, như sau:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

Cách thức hoạt động của các công thức này:

Ý tưởng chung là đếm số ngày nhỏ hơn ngày đích bằng COUNTIF. Và số này chính xác là những gì hàm SMALL cần cho đối số k .

Để hiểu rõ hơn về khái niệm này, hãy xem xét nó từ một góc độ khác:

Nếu 1- Tháng 8 năm 2020 (ngày mục tiêu trong E1) đã xuất hiện trong tập dữ liệu của chúng tôi, đây sẽ là ngày lớn thứ 7 trong danh sách. Do đó, có sáu ngày nhỏ hơn nó. Có nghĩa là, ngày nhỏ thứ 6 là ngày trước đó gần ngày mục tiêu nhất.

Vì vậy, trước tiên, chúng tôi tính xem có bao nhiêu ngày nhỏ hơn ngày trong E1 (kết quả là 6):

COUNTIF(B2:B10, "<"&E1)

Sau đó, nhập số đếm vào đối số thứ 2 của SMALL:

=SMALL(B2:B10, 6)

Để lấy ngày trước đó trừ một ngày (là ngày nhỏ thứ 5 trong trường hợp của chúng tôi) , chúng tôi trừ 1 từ kết quả của COUNTIF.

Cách đánh dấu các giá trị dưới cùng trong Excel

Để đánh dấu các giá trị n nhỏ nhất trong bảng của bạn bằng định dạng có điều kiện của Excel, bạn có thể sử dụng Top tích hợp sẵn /Bottom hoặc thiết lập quy tắc của riêng bạn dựa trên công thức NHỎ. Phương pháp đầu tiên nhanh hơnvà dễ áp ​​dụng hơn, trong khi cách thứ hai cung cấp khả năng kiểm soát và linh hoạt hơn. Các bước bên dưới sẽ hướng dẫn bạn cách tạo quy tắc tùy chỉnh:

1. Chọn phạm vi mà bạn muốn đánh dấu các giá trị dưới cùng. Trong trường hợp của chúng tôi, các số nằm trong B2:B10, vì vậy chúng tôi chọn nó. Nếu bạn muốn đánh dấu toàn bộ hàng, hãy chọn A2:B10.
2. Trên tab Trang chủ , trong nhóm Kiểu , hãy nhấp vào Định dạng có điều kiện > Quy tắc mới .
3. Trong hộp thoại Quy tắc định dạng mới , hãy chọn Sử dụng công thức để xác định các ô cần định dạng.
4. Trong hộp Định dạng giá trị trong đó công thức này là đúng , nhập công thức như sau:

   =B2<=SMALL($B$2:$B$10, 3)

   Xem thêm: Cách nhân trong Excel: số, ô, cả cột

   Trong đó B2 là ô ngoài cùng bên trái của số phạm vi được kiểm tra, $B$2:$B$10 là toàn bộ phạm vi và 3 là n giá trị dưới cùng cần đánh dấu.

   Trong công thức của bạn, hãy lưu ý các loại tham chiếu: ô ngoài cùng bên trái là tham chiếu tương đối (B2) trong khi phạm vi là tham chiếu tuyệt đối ($B$2:$B$10).

5. Nhấp vào nút Định dạng và chọn bất kỳ định dạng nào bạn thích.
6. Nhấp hai lần vào OK để đóng cả hai cửa sổ hộp thoại.

Xong! 3 giá trị dưới cùng trong cột B được đánh dấu:

Để biết thêm thông tin, vui lòng xem phần định dạng có điều kiện của Excel dựa trên công thức.

Hàm EXCALL của Excel không hoạt động

Như bạn vừa thấy từ các ví dụ của chúng tôi, việc sử dụng hàm SMALL trong Excel khá dễ dàng và bạnkhông có bất kỳ khó khăn với nó. Nếu công thức của bạn không hoạt động, rất có thể đó sẽ là lỗi #NUM! lỗi, có thể xảy ra do những lý do sau:

• Mảng trống hoặc không chứa một giá trị số nào.
• The k nhỏ hơn 0 (một lỗi đánh máy ngớ ngẩn có thể khiến bạn mất nhiều giờ khắc phục sự cố!) hoặc vượt quá số lượng giá trị trong mảng.

Đó là cách sử dụng công thức NHỎ trong Excel để tìm và đánh dấu các số dưới cùng trong một tập hợp dữ liệu. Nếu bạn biết bất kỳ tình huống nào khác mà chức năng này có ích, rất mong bạn chia sẻ trong phần nhận xét. Tôi cảm ơn bạn đã đọc và hy vọng sẽ gặp bạn trên blog của chúng tôi vào tuần tới!

Sách bài tập thực hành để tải xuống

Các ví dụ về công thức Excel NHỎ (tệp .xlsx)