San oideachadh ghoirid seo, bruidhnidh sinn mu dheidhinn gnìomh Excel SMALL, mar a dh'obraicheas e agus mar a chleachdas tu e gus an Nmh àireamh, ceann-latha no àm as lugha a lorg.

Feumach gus beagan àireamhan as ìsle a lorg ann an duilleag-obrach? Tha seo gu math furasta a dhèanamh leis an fheart Excel Sort. Nach eil thu airson ùine a chaitheamh air an dàta agad ath-sheòrsachadh leis a h-uile atharrachadh? Cuidichidh an gnìomh SMALL thu gu sgiobalta gus an luach as ìsle a lorg, an dàrna fear as lugha, an treas fear as lugha, is mar sin air adhart. an n-th luach as lugha ann an seata dàta.

Tha dà argamaid ann an co-chòrdadh a' ghnìomh SMALL, agus tha feum air an dà chuid.

SMALL(eagar, k)

Càite:

• Array - sreath no raon de cheallan às an toirear an luach as lugha.
• K - an integer a tha a’ comharrachadh an t-suidheachaidh bhon luach as ìsle gu tilleadh, i.e. k-th as lugha. 2013, Excel 2010, agus na bu tràithe.

  Tip. Gus k-th an luach as ìsle a lorg le slatan-tomhais, cleachd foirmle Excel SMALL IF.

  Foirmle bunaiteach SMALL ann an Excel

  Tha foirmle BHEAG anns a’ chruth bhunaiteach aice gu math furasta a thogail - cha leig thu leas ach am faidhle a shònrachadh. raon agus an suidheachadh bhon nì as lugha ri tilleadh.

  Ann an liosta nan àireamhan ann am B2:B10, a’ creidsinn gu bheil thu airson an 3mh luach as lugha a thoirt a-mach. Tha am foirmle marsìmplidh mar:

  =SMALL(B2:B10, 3)

  Gus a dhèanamh nas fhasa dhut an toradh a sgrùdadh, tha colbh B air a sheòrsachadh ann an òrdugh dìreadh:

  

  4 rudan air am bu chòir dhut fios a bhith agad mu ghnìomh SMALL

  Cuidichidh na notaichean cleachdaidh a leanas thu gus tuigse nas fheàrr fhaighinn air giùlan na gnìomh SMALL agus seachain troimh-chèile nuair a bhios tu a’ togail na foirmlean agad fhèin.

  1. Sam bith ceallan bàn , luachan teacsa , agus luachan loidsigeach TRUE agus FALSE san argamaid eagar air an leigeil seachad.
  2. Ma tha <1 Tha aon mhearachd no barrachd ann an> eagar , thèid mearachd a thilleadh.
  3. Air eagal gu bheil dùblaidhean ann an eagar , am foirmle agad dh’ fhaodadh “ceangail” a thighinn gu buil. Mar eisimpleir, ma tha an àireamh 1 ann an dà chealla, agus an gnìomh SMALL air a rèiteachadh gus an luach as lugha agus an 2na luach as lugha a thilleadh, gheibh thu 1 anns gach cùis.
  4. A’ gabhail ris gur e n an àireamh de luachan ann an eagar , tillidh SMALL(eagrachadh,1) an luach as ìsle, agus taghaidh SMALL(array,n) an luach as àirde.

  Mar a chleachdas tu an gnìomh SMALL ann an Excel - eisimpleirean foirmle

  Agus a-nis, leig dhuinn sùil a thoirt air eisimpleirean eile den ghnìomh Excel SMALL a tha a’ dol seachad air a chleachdadh bunaiteach. 0> Mar a tha fios agad mu thràth, tha an gnìomh SMALL air a dhealbhadh gus an n-mh luach as ìsle obrachadh a-mach. Tha an eisimpleir seo a' sealltainn mar a nì thu seo nas èifeachdaiche.

  Sa chlàr gu h-ìosal, saoil gu bheil thu airson na 3 luachan as ìsle a lorg. Airson seo, cuir a-steach anàireamhan 1, 2 agus 3 ann an ceallan fa leth (D3, D4 agus D5 sa chùis againn). An uairsin, cuir a-steach am foirmle a leanas ann an E3 agus slaod sìos e tro E5:

  =SMALL($B$2:$B$10, D3)

  Ann an E3, bidh am foirmle a’ toirt a-mach an luach as lugha a’ cleachdadh an àireamh ann an D3 airson an k argamaid. 'S e am prìomh rud iomraidhean cealla ceart a sholarachadh air sgàth 's gu bheil an fhoirmle a' dèanamh lethbhreac ceart ann an ceallan eile: iomlan airson eagar agus càirdeach airson k .

  

  Nach eil thu airson dragh a chur air na h-ìrean a thaipeadh le làimh? Cleachd an gnìomh ROWS le iomradh raon leudachaidh gus an luach k a sholarachadh. Airson seo, bidh sinn a’ toirt iomradh iomlan airson a’ chiad chill (no dìreach glas an co-chomharran loidhne mar B$2) agus iomradh càirdeach airson a’ chill mu dheireadh:

  =SMALL($B$2:$B$10, ROWS(B$2:B2))

  Mar thoradh air an sin, tha an raon bidh an t-iomradh a’ leudachadh mar a tha am foirmle air a chopaigeadh sìos a’ cholbh. Ann an D2, bidh ROWS (B$2:B2) a’ toirt a-mach 1 airson k , agus tillidh am foirmle a’ chosgais as ìsle. Ann an D3, bheir ROWS(B$2:B3) 2 a-mach, agus gheibh sinn an dàrna cosgais as ìsle, is mar sin air adhart.

  Dìreach dèan lethbhreac dhen fhoirmle tro 5 ceallan, agus gheibh thu 5 luachan aig a’ bhonn:<3

  

  Suim aig a’ bhonn luachan N

  A bheil thu airson na luachan n as lugha gu h-iomlan a lorg ann an stòr-dàta? Ma tha thu air na luachan mar a chithear san eisimpleir roimhe a thoirt a-mach mu thràth, is e am fuasgladh as fhasa foirmle SUM mar:

  =SUM(E3:E5)

  

  No faodaidh tu dèan foirmle neo-eisimeileach le bhith a' cleachdadh a' ghnìomh SMALL còmhla ri SUMPRODUCT:

  SUMPRODUCT(SMALL( eagar , {1, …, n }))

  Gus suim nan 3 luachan as ìsle san t-seata dàta againn fhaighinn, gabhaidh am foirmle an cumadh seo :

  =SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

  

  Bheir an gnìomh SUM an aon toradh:

  =SUM(SMALL(B2:B10, {1,2,3}))

  Nòta. Ma chleachdas tu iomraidhean cealla seach rèite seasmhach airson k , feumaidh tu Ctrl + Shift + Enter a bhrùthadh gus a dhèanamh na fhoirmle rèite. Ann an Excel 365 a bheir taic do arrays fiùghantach, bidh SUM SMALL ag obair mar fhoirmle cunbhalach anns gach suidheachadh.

  Mar a dh’obraicheas am foirmle seo:

  Ann am foirmle chunbhalach, bidh SMALL a’ tilleadh aon k-th luach as lugha ann an raon. Anns a’ chùis seo, bidh sinn a’ toirt seachad sreath seasmhach mar {1,2,3} airson an argamaid k, a’ toirt air ais sreath de na 3 luachan as lugha a thilleadh:

  {29240, 43610, 58860}

  Faic cuideachd: Dearbhadh dàta ann an Excel: mar a chuireas tu ris, a chleachdas agus a bheir thu air falbh

  An SUMPRODUCT no Bidh gnìomh SUM a’ cur suas na h-àireamhan san raon agus a’ toirt a-mach an àireamh iomlan. Sin agad e!

  Index MATCH MATCH foirmle gus na maidsean as lugha fhaighinn

  San suidheachadh nuair a tha thu airson beagan dàta fhaighinn air ais co-cheangailte ris an luach as lugha, cleachd am measgachadh clasaigeach INDEX MATCH le SMALL airson an luach seallaidh :

  INDEX( return_array , MATCH(SMALL( lookup_array , n ), lookup_array , 0))

  Càite :

  • Return_array 'S e raon às an toir thu dàta co-cheangailte ris.
  • Lookup_array 'S e raon far an lorgar an n as ìsle. -th luach.
  • 'S e N suidheachadh an luach ùidh as lugha.

  Airsonmar eisimpleir, gus ainm a’ phròiseict aig a bheil a’ chosgais as ìsle fhaighinn, is e am foirmle ann an E3:

  =INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

  Càit a bheil A2:A10 ainmean a’ phròiseict, is e B2:B10 na cosgaisean agus 'S e D3 an ìre bhon fheadhainn as lugha.

  Dèan lethbhreac dhen fhoirmle gu na ceallan gu h-ìosal (E4 agus E5), agus gheibh thu ainmean nan 3 pròiseactan as saoire:

  

  Notaichean:

  • Tha am fuasgladh seo ag obair gu math airson stòr-dàta aig nach eil dùblaidhean. Ach, dh’ fhaodadh dà luach dùblaichte no barrachd ann an colbh àireamhach “ceanglaichean” a chruthachadh ann an rangachadh, a bheir gu toraidhean ceàrr. Anns a’ chùis seo, feuch an cleachd thu foirmle beagan nas ionnsaichte gus ceanglaichean a bhriseadh.
  • Ann an Excel 365, faodar an obair seo a choileanadh le cuideachadh bho na gnìomhan rèite fiùghantach ùr. A bharrachd air a bhith tòrr nas sìmplidh, bidh an dòigh-obrach seo gu fèin-ghluasadach a’ fuasgladh duilgheadas ceangail. Airson làn fhiosrachadh, faic Mar a shìoladh tu luachan N aig a’ bhonn ann an Excel.

  Deasaich àireamhan bhon ìre as ìsle chun as àirde le foirmle

  Tha mi a’ creidsinn gu bheil fios aig a h-uile duine mar a chuireas iad àireamhan ann an òrdugh le Feart Deasaich Excel. Ach a bheil fios agad mar a nì thu rèiteachadh le foirmle? Faodaidh luchd-cleachdaidh Excel 365 a dhèanamh ann an dòigh fhurasta leis a’ ghnìomh SORT ùr. Ann an Excel 2019, 2016 agus dreachan nas tràithe, chan eil SORT ag obair, alas. Ach biodh beagan creideamh agad, agus thig SMALL gu teasairginn :)

  Mar a’ chiad eisimpleir, bidh sinn a’ cleachdadh an gnìomh ROWS le iomradh raon leudachaidh air àrdachadh k le 1 anns gach sreath far a bheil am foirmleair a chopaigeadh:

  =SMALL($A$2:$A$10, ROWS(A$2:A2))

  Cuir a-steach am foirmle sa chiad chill, agus an uairsin slaod e sìos gu na h-uimhir de cheallan ’s a tha luachan san t-seata dàta tùsail (C2: C10 san eisimpleir seo) :

  

  Tip. Airson teàrnadh a sheòrsachadh, cleachd an gnìomh LARGE an àite SMALL.

  Foirmle Excel SMALL airson cinn-latha agus amannan

  Leis gu bheil cinn-latha agus amannan cuideachd nan luachan àireamhach (ann an siostam Excel a-staigh, tha cinn-latha air an stòradh mar àireamhan sreathach agus amannan mar bloighean deicheach), is urrainn don ghnìomh SMALL an làimhseachadh cuideachd gun oidhirp a bharrachd air do thaobh.

  Mar a chì thu sna glacaidhean-sgrìn gu h-ìosal, tha foirmle bunaiteach a chleachd sinn airson àireamhan ag obair gu h-àlainn airson cinn-latha agus amannan cuideachd:

  =SMALL($B$2:$B$10, D2)

  Foirmle BEAG airson na 3 cinn-latha as tràithe a lorg:

  

  Foirmle BHEAG gus na 3 tursan as giorra fhaighinn:

  

  Tha an ath eisimpleir a’ sealltainn mar a chuidicheas an gnìomh SMALL thu gus gnìomh nas mionaidiche a choileanadh co-cheangailte ri cinn-latha.

  Lorg ceann-latha roimhe as fhaisge air an-diugh no ceann-latha ainmichte

  Ann an liosta chinn-latha , a’ smaoineachadh gu bheil thu airson an ceann-latha as fhaisge a lorg ro cheann-latha ainmichte. Faodar seo a dhèanamh le bhith a' cleachdadh a' ghnìomh SMALL còmhla ri COUNTIF.

  Le liosta nan cinn-latha ann am B2:B10 agus an ceann-latha ann an E1, tillidh am foirmle a leanas ceann-latha ro-làimh as fhaisge air a' cheann-latha targaide:

  =SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

  Gus ceann-latha a thoirt a-mach a tha dà cheann-latha ron cheann-latha ann an E1, i.e. ceann-latha roimhe ach aon cheann-latha, bidh anis e am foirmle:

  =SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

  

  Gus an ceann-latha a dh’ fhalbh as fhaisge air an-diugh a lorg, cleachd an gnìomh TODAY airson slatan-tomhais COUNTIF:

  Faic cuideachd: 3 dòighean air beàrnan a thoirt air falbh eadar faclan / àireamhan ann an ceallan Excel

  =SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

  

  Tip. Gus casg a chuir air mearachdan ann an suidheachadh nuair nach lorgar ceann-latha a tha a rèir do shlatan-tomhais, is urrainn dhut an gnìomh IFERROR a phasgadh timcheall na foirmle agad, mar seo:

  =IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

  Mar a dh’obraicheas na foirmlean seo:

  Is e am beachd coitcheann an àireamh de chinn-latha nas lugha na an ceann-latha targaid a chunntadh le COUNTIF. Agus 's e an cunntadh seo dìreach a tha a dhìth air a' ghnìomh SMALL airson na h-argamaid k .

  Gus tuigse nas fheàrr fhaighinn air a' bhun-bheachd, leig dhuinn sùil a thoirt air bho cheàrn eile:

  Ma tha 1- Nochd Aug-2020 (an ceann-latha targaid ann an E1) anns an t-seata dàta againn, is e seo an 7mh ceann-latha as motha air an liosta. Mar thoradh air an sin, tha sia cinn-latha nas lugha na e. Ciall, 's e an 6mh ceann-latha as lugha an ceann-latha roimhe as fhaisge air a' cheann-latha targaide.

  Mar sin, an-toiseach nì sinn obrachadh a-mach cia mheud ceann-latha a tha nas lugha na an ceann-latha ann an E1 (is e an toradh 6):

  COUNTIF(B2:B10, "<"&E1)

  Agus an uairsin, plug an cunntas a-steach don 2na argamaid de SMALL:

  =SMALL(B2:B10, 6)

  Gus an ceann-latha roimhe ach aon cheann-latha fhaighinn (is e sin an 5mh ceann-latha as lugha nar cùise) , bheir sinn air falbh 1 à toradh COUNTIF.

  Mar a chomharraicheas tu na luachan as ìsle ann an Excel

  Gus na luachan n as lugha sa bhòrd agad a shoilleireachadh le cruth cumhach Excel, faodaidh tu an dàrna cuid Top togte a chleachdadh / Roghainn aig a’ bhonn no stèidhich do riaghailt fhèin stèidhichte air foirmle SMALL. Tha a 'chiad dòigh nas luaitheagus nas fhasa a chuir an sàs, fhad ‘s a tha an dàrna fear a’ toirt barrachd smachd agus sùbailteachd. Coisichidh na ceumannan gu h-ìosal thu tro bhith a’ cruthachadh riaghailt àbhaisteach:

  1. Tagh an raon anns a bheil thu airson luachan bun a chomharrachadh. Anns a 'chùis againn, tha na h-àireamhan ann am B2: B10, agus mar sin bidh sinn ga thaghadh. Ma tha thu airson sreathan slàn a chomharrachadh, tagh A2:B10.
  2. Air an taba Home , sa chuantal Styles , briog air Cruthachadh cumhach > Riaghailt Ùr .
  3. Anns a' bhogsa deasbaid Riaghailt Fòrmatadh Ùr , tagh Cleachd foirmle gus faighinn a-mach dè na ceallan a bu chòir an cruth.<2
  4. Anns a’ bhogsa Format luachan far a bheil am foirmle seo fìor , cuir a-steach foirmle mar an tè seo:

     =B2<=SMALL($B$2:$B$10, 3)

     Far a bheil B2 a’ chill as fhaide air falbh den àireamhair raon ri sgrùdadh, $B$2:$B$10 an raon gu lèir, agus 's e 3 na n bun-luachan airson an soilleireachadh.

     San fhoirmle agad, feuch na seòrsaichean iomraidh: an 'S e iomradh càirdeach (B2) a th' anns a' chill as fhaide air falbh agus is e an raon an t-iomradh iomlan ($B$2:$B$10).

  5. Briog air a' phutan Format agus tagh fòrmat sam bith a thogras tu.
  6. Briog air OK dà uair gus an dà uinneag còmhraidh a dhùnadh.

  Dèanta! Tha na 3 luachan gu h-ìosal ann an colbh B air an comharrachadh:

  

  Airson tuilleadh fiosrachaidh, faic cruth cumhach Excel stèidhichte air foirmle.

  Excel SMALL function not working

  Mar a tha thu dìreach air fhaicinn bho na h-eisimpleirean againn, tha e furasta an gnìomh SMALL a chleachdadh ann an Excel, agus tha thueu-coltach ri duilgheadas sam bith leis. Mura obraich am foirmle agad, is coltaiche gur e #NUM a bhios ann! mearachd, a dh'fhaodadh tachairt air sgàth nan adhbharan a leanas:

  • Tha eagar falamh no chan eil aon luach àireamhach ann.
  • An k luach nas lugha na neoni (faodaidh teip gòrach cosg a chur ort uairean a thìde airson fuasgladh cheistean!) No nas àirde na an àireamh de luachan san raon.

  Sin mar a chleachdas tu foirmle SMALL ann an Excel gus lorg agus comharraich na h-àireamhan as ìsle ann an seata dàta. Ma tha thu eòlach air suidheachadh sam bith eile far a bheil an gnìomh a’ tighinn gu feum, tha fàilte mhòr ort beachdan a thoirt seachad. Tha mi a' toirt taing dhut airson an leughadh agus an dòchas ur faicinn air a' bhlog againn an ath sheachdain!

  Leabhar-obrach cleachdaidh airson a luchdachadh sìos

  Eisempleirean foirmle Excel SMALL (faidhle .xlsx)