이 짧은 자습서에서는 Excel SMALL 함수의 작동 방식과 N번째로 작은 숫자, 날짜 또는 시간을 찾는 데 사용하는 방법에 대해 설명합니다.

필요 워크시트에서 몇 개의 가장 낮은 숫자를 찾으려면? 이것은 Excel 정렬 기능을 사용하면 매우 쉽습니다. 변경할 때마다 데이터를 다시 정렬하는 데 시간을 낭비하고 싶지 않으십니까? SMALL 함수는 가장 낮은 값, 두 번째로 작은 값, 세 번째로 작은 값 등을 빠르게 찾을 수 있도록 도와줍니다.

Excel SMALL 함수

SMALL은 다음을 반환하는 통계 함수입니다. 데이터 세트에서 n번째로 작은 값.

SMALL 함수의 구문에는 두 개의 인수가 포함되며 둘 다 필수입니다.

SMALL(array, k)

여기서:

• Array - 가장 작은 값을 추출할 배열 또는 셀 범위입니다.
• K - an 반환할 가장 낮은 값부터의 위치를 ​​나타내는 정수, 즉 k번째로 작은 값.

이 함수는 모든 버전의 Excel for Office 365, Excel 2021, Excel 2019, Excel 2016, Excel에서 사용할 수 있습니다. 2013, Excel 2010 및 이전 버전.

팁. 기준에 따라 k 번째로 낮은 값을 찾으려면 Excel SMALL IF 수식을 사용하십시오.

Excel의 기본 SMALL 수식

기본 형식의 SMALL 수식은 작성하기가 매우 쉽습니다. 반환할 가장 작은 항목의 범위 및 위치.

B2:B10의 숫자 목록에서 세 번째로 작은 값을 추출한다고 가정합니다. 공식은 다음과 같습니다.간단함:

=SMALL(B2:B10, 3)

결과를 쉽게 확인할 수 있도록 열 B는 오름차순으로 정렬됩니다.

SMALL 함수에 대해 알아야 할 4가지 사항

다음 사용 참고 사항은 SMALL 함수의 동작을 더 잘 이해하고 고유한 수식을 작성할 때 혼동을 피하는 데 도움이 됩니다.

1. 모든 빈 셀 , 텍스트 값 및 논리 값 array 인수의 TRUE 및 FALSE는 무시됩니다.
2. If array 에 하나 이상의 errors 가 포함되어 있으면 오류가 반환됩니다.
3. array 에 duplicates 가 있는 경우 수식이 "동점"이 발생할 수 있습니다. 예를 들어 두 개의 셀에 숫자 1이 포함되어 있고 SMALL 함수가 가장 작은 값과 두 번째로 작은 값을 반환하도록 구성되어 있으면 두 경우 모두 1이 됩니다.
4. n이 <에 있는 값의 개수라고 가정합니다. 1>array , SMALL(array,1)은 가장 낮은 값을 반환하고 SMALL(array,n)은 가장 높은 값을 선택합니다.

엑셀에서 SMALL 함수를 사용하는 방법 - 수식 예제

이제 기본 사용법 외에 Excel SMALL 함수의 예제를 더 살펴보겠습니다.

하단 3, 5, 10 등 값 찾기

이미 아시다시피 SMALL 함수는 n번째로 낮은 값을 계산하도록 설계되었습니다. 이 예는 이를 가장 효과적으로 수행하는 방법을 보여줍니다.

아래 표에서 하위 3개 값을 찾으려고 한다고 가정합니다. 이를 위해 다음을 입력하십시오.별도의 셀에 있는 숫자 1, 2 및 3(이 경우 D3, D4 및 D5). 그런 다음 E3에 다음 수식을 입력하고 E5를 통해 아래로 드래그합니다.

=SMALL($B$2:$B$10, D3)

E3에서 수식은 k<2에 대해 D3의 숫자를 사용하여 가장 작은 값을 추출합니다> 인수. 중요한 것은 배열 의 절대값과 k .

<의 상대값 등 수식이 다른 셀에서 올바르게 복사되도록 적절한 셀 참조를 제공하는 것입니다. 3>

수동으로 순위를 입력하고 싶지 않으세요? 확장 범위 참조와 함께 ROWS 함수를 사용하여 k 값을 제공합니다. 이를 위해 첫 번째 셀에 대한 절대 참조(또는 B$2와 같은 행 좌표만 잠그기)와 마지막 셀에 대한 상대 참조를 만듭니다.

=SMALL($B$2:$B$10, ROWS(B$2:B2))

결과적으로 범위는 수식이 열 아래로 복사됨에 따라 참조가 확장됩니다. D2에서 ROWS(B$2:B2)는 k 에 대해 1을 생성하고 수식은 최저 비용을 반환합니다. D3에서 ROWS(B$2:B3)는 2를 생성하고 두 번째로 낮은 비용을 얻습니다.

수식을 5개 셀에 복사하면 하위 5개 값을 얻을 수 있습니다.

하위 N 값 합계

데이터 집합에서 가장 작은 n 값의 합계를 찾고 싶습니까? 이전 예에서와 같이 값을 이미 추출한 경우 가장 쉬운 솔루션은 다음과 같은 SUM 공식입니다.

=SUM(E3:E5)

또는 다음을 수행할 수 있습니다. SUMPRODUCT:

데이터 세트에서 하위 3개 값의 합계를 구하기 위해 공식은 다음과 같은 형태를 취합니다. :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

SUM 함수는 동일한 결과를 생성합니다.

=SUM(SMALL(B2:B10, {1,2,3}))

참고. k 에 배열 상수가 아닌 셀 참조 를 사용하는 경우 Ctrl + Shift + Enter를 눌러 배열 수식으로 만들어야 합니다. 동적 배열을 지원하는 Excel 365에서 SUM SMALL은 두 경우 모두 일반 수식으로 작동합니다.

수식 작동 방식:

일반 수식에서 SMALL은 범위에서 k번째로 작은 단일 값을 반환합니다. 이 경우 k 인수에 대해 {1,2,3}과 같은 배열 상수를 제공하여 가장 작은 3개 값의 배열을 반환하도록 합니다.

{29240, 43610, 58860}

SUMPRODUCT 또는 SUM 함수는 배열의 숫자를 더하고 합계를 출력합니다. 그게 다야!

가장 작은 일치 항목을 얻기 위한 INDEX MATCH SMALL 수식

가장 작은 값과 관련된 일부 데이터를 검색하려는 경우 조회 값에 대한 고전적인 INDEX MATCH 조합과 SMALL을 사용합니다. :

여기서 :

• Return_array 는 연관된 데이터를 추출할 범위입니다.
• Lookup_array 는 가장 낮은 n을 검색할 범위입니다. -번째 값.
• N 은 관심 있는 가장 작은 값의 위치입니다.

For예를 들어 비용이 가장 낮은 프로젝트의 이름을 가져오려면 E3의 공식은 다음과 같습니다.

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

여기서 A2:A10은 프로젝트 이름이고 B2:B10은 비용이고 D3은 가장 작은 순위입니다.

공식을 아래 셀(E4 및 E5)에 복사하면 가장 저렴한 프로젝트 3개의 이름을 얻을 수 있습니다.

참고:

• 이 솔루션은 중복이 없는 데이터 세트에 적합합니다. 그러나 숫자 열에 있는 두 개 이상의 중복 값은 순위에서 "동일"을 만들어 잘못된 결과를 초래할 수 있습니다. 이 경우 좀 더 정교한 수식을 사용하여 관계를 끊으십시오.
• Excel 365에서는 새로운 동적 배열 기능을 사용하여 이 작업을 수행할 수 있습니다. 훨씬 간단하다는 점 외에도 이 접근 방식은 연결 문제를 자동으로 해결합니다. 자세한 내용은 Excel에서 하위 N 값을 필터링하는 방법을 참조하세요.

수식을 사용하여 숫자를 낮은 값에서 높은 값으로 정렬

누구나 숫자를 순서대로 입력하는 방법을 알고 있다고 생각합니다. 엑셀 정렬 기능. 하지만 수식을 사용하여 정렬하는 방법을 알고 있습니까? Excel 365 사용자는 새로운 SORT 기능을 사용하여 쉽게 할 수 있습니다. Excel 2019, 2016 및 이전 버전에서는 SORT가 작동하지 않습니다. 그러나 약간의 믿음이 있으면 SMALL이 구조에 올 것입니다 :)

첫 번째 예에서와 같이 확장 범위 참조와 함께 ROWS 함수를 사용하여 k 를 1씩 증가시킵니다. 수식이 있는 행복사됨:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

첫 번째 셀에 수식을 입력한 다음 원래 데이터 세트(이 예에서는 C2:C10)에 있는 값만큼 많은 셀로 드래그합니다. :

팁. 내림차순 을 정렬하려면 SMALL 대신 LARGE 함수를 사용하십시오.

날짜 및 시간에 대한 Excel SMALL 수식

날짜 및 시간도 숫자 값이므로(내부 Excel 시스템에서 날짜는 연속된 숫자로 저장되고 시간은 소수점 이하로 저장됨) SMALL 함수로 처리할 수 있습니다. 추가 노력 없이도 가능합니다.

아래 스크린샷에서 볼 수 있듯이 숫자에 사용한 기본 공식은 날짜와 시간에도 잘 작동합니다.

=SMALL($B$2:$B$10, D2)

가장 빠른 3개의 날짜를 찾는 작은 공식:

가장 짧은 3개의 날짜를 찾는 작은 공식:

다음 예는 SMALL 함수가 날짜와 관련된 보다 구체적인 작업을 수행하는 데 어떻게 도움이 되는지 보여줍니다.

오늘 또는 지정된 날짜에 가장 가까운 이전 날짜 찾기

날짜 목록에서 , 지정된 날짜 이전의 가장 가까운 날짜를 찾으려고 한다고 가정합니다. 이는 COUNTIF와 함께 SMALL 함수를 사용하여 수행할 수 있습니다.

B2:B10의 날짜 목록과 E1의 대상 날짜를 사용하여 다음 수식은 대상 날짜에 가장 가까운 이전 날짜를 반환합니다.

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

E1의 날짜보다 두 날짜 이전인 날짜, 즉 하나의 이전 날짜를 추출하려면수식은 다음과 같습니다.

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

지난 날짜 오늘과 가장 가까운 을 찾으려면 COUNTIF의 기준에 TODAY 함수를 사용하세요.

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

팁. 기준과 일치하는 날짜를 찾을 수 없는 상황에서 오류를 방지하려면 다음과 같이 수식 주위에 IFERROR 함수를 래핑할 수 있습니다.

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

이 수식이 작동하는 방식:

일반적인 아이디어는 COUNTIF로 목표 날짜보다 작은 날짜의 수를 세는 것입니다. 그리고 이 개수는 SMALL 함수가 k 인수에 정확히 필요한 것입니다.

개념을 더 잘 이해하기 위해 다른 각도에서 살펴보겠습니다.

If 1- 2020년 8월(E1의 대상 날짜)이 데이터 세트에 나타나면 목록에서 7번째로 큰 날짜가 됩니다. 따라서 이보다 작은 날짜가 6개 있습니다. 즉, 6번째 작은 날짜는 목표 날짜에 가장 가까운 이전 날짜입니다.

그래서 먼저 E1의 날짜보다 작은 날짜가 몇 개인지 계산합니다(결과는 6):

COUNTIF(B2:B10, "<"&E1)

그런 다음 개수를 SMALL의 두 번째 인수에 연결합니다.

=SMALL(B2:B10, 6)

단 하나의 이전 날짜를 가져오려면(우리의 경우 다섯 번째로 작은 날짜) , COUNTIF의 결과에서 1을 뺍니다.

Excel에서 하위 값을 강조 표시하는 방법

Excel 조건부 서식을 사용하여 테이블에서 가장 작은 n 값을 강조 표시하려면 내장된 Top /Bottom 옵션을 선택하거나 SMALL 수식을 기반으로 자신만의 규칙을 설정합니다. 첫 번째 방법이 더 빠름적용하기 쉽고 두 번째는 더 많은 제어와 유연성을 제공합니다. 아래 단계는 사용자 지정 규칙을 만드는 과정을 안내합니다.

1. 하한 값을 강조 표시할 범위를 선택합니다. 우리의 경우 숫자는 B2:B10에 있으므로 선택합니다. 전체 행을 강조 표시하려면 A2:B10을 선택합니다.
2. 홈 탭의 스타일 그룹에서 조건부 서식을 클릭합니다. > 새 규칙 .
3. 새 서식 규칙 대화 상자에서 수식을 사용하여 서식을 지정할 셀 결정<2을 선택합니다>
4. 이 수식이 참인 값 서식 지정 상자에 다음과 같은 수식을 입력합니다.

   =B2<=SMALL($B$2:$B$10, 3)

   여기서 B2는 숫자의 맨 왼쪽 셀입니다. 확인할 범위, $B$2:$B$10은 전체 범위, 3은 강조할 n 개의 하위 값입니다.

   수식에서 참조 유형에 유의하세요. 가장 왼쪽 셀은 상대 참조(B2)이고 범위는 절대 참조($B$2:$B$10)입니다.

5. 포맷 버튼을 클릭하고 원하는 형식을 선택합니다.
6. 확인을 두 번 클릭하여 두 대화 창을 닫습니다.

완료! B 열의 하단 3개 값이 강조 표시됩니다.

자세한 내용은 수식 기반 Excel 조건부 서식을 참조하세요.

Excel SMALL 함수가 작동하지 않음

예제에서 보셨듯이 Excel에서 SMALL 함수를 사용하는 것은 매우 쉽습니다.그것에 어려움이 없을 것입니다. 수식이 작동하지 않으면 #NUM이 될 가능성이 큽니다! 오류는 다음과 같은 이유로 발생할 수 있습니다.

• Array 가 비어 있거나 단일 숫자 값을 포함하지 않습니다.
• The k 값이 0보다 작거나(어리석은 오타로 인해 문제 해결에 많은 시간이 소요될 수 있습니다!) 배열의 값 수를 초과합니다.

Excel에서 작은 수식을 사용하여 찾고 데이터 집합에서 하위 숫자를 강조 표시합니다. 이 기능이 유용한 다른 시나리오를 알고 있다면 의견을 공유하는 것을 환영합니다. 읽어 주셔서 감사합니다. 다음 주에 저희 블로그에서 뵙기를 바랍니다!

다운로드용 실습 워크북

Excel 작은 수식 예제(.xlsx 파일)