Në këtë tutorial të shkurtër, ne do të flasim për funksionin e Excel SMALL, si funksionon dhe si ta përdorim atë për të gjetur numrin, datën ose kohën e nëntë më të vogël.

Nevojë për të gjetur disa numra më të ulët në një fletë pune? Kjo është mjaft e lehtë për t'u bërë me veçorinë Excel Sort. A nuk doni të humbni kohë për të riorganizuar të dhënat tuaja me çdo ndryshim? Funksioni SMALL do t'ju ndihmojë të gjeni shpejt vlerën më të ulët, të dytën më të vogël, të tretën më të vogël e kështu me radhë.

Funksioni Excel SMALL

SMALL është një funksion statistikor që kthen vlera n-të më e vogël në një grup të dhënash.

Sintaksa e funksionit SMALL përfshin dy argumente, që të dyja kërkohen.

SMALL(array, k)

Ku:

• Array - një grup ose një varg qelizash nga të cilat mund të nxirret vlera më e vogël.
• K - një numër i plotë që tregon pozicionin nga vlera më e ulët për t'u kthyer, d.m.th. k-të më e vogla.

Funksioni është i disponueshëm në të gjitha versionet e Excel për Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010 dhe më herët.

Këshillë. Për të gjetur vlerën k-të më të ulët me kritere, përdorni formulën Excel SMALL IF.

Formula bazë SMALL në Excel

Një formulë SMALL në formën e saj bazë është shumë e lehtë për t'u ndërtuar - thjesht specifikoni diapazoni dhe pozicioni nga artikulli më i vogël për t'u kthyer.

Në listën e numrave në B2:B10, duke supozuar se dëshironi të nxirrni vlerën e tretë më të vogël. Formula është sie thjeshtë si:

=SMALL(B2:B10, 3)

Për ta bërë më të lehtë për ju kontrollimin e rezultatit, kolona B renditet në rend rritës:

4 gjëra që duhet të dini për funksionin SMALL

Shënimet e mëposhtme të përdorimit do t'ju ndihmojnë të kuptoni më mirë sjelljen e funksionit SMALL dhe të shmangni konfuzionin kur ndërtoni formulat tuaja.

1. Çdo qelizat bosh , vlerat teksti dhe vlerat logjike TRUE dhe FALSE në argumentin array shpërfillen.
2. Nëse array përmban një ose më shumë gabime , një gabim kthehet.
3. Në rast se ka dublikatë në array , formula juaj mund të rezultojë në "lidhje". Për shembull, nëse dy qeliza përmbajnë numrin 1 dhe funksioni SMALL është konfiguruar që të kthejë vlerën më të vogël dhe vlerën e dytë më të vogël, do të merrni 1 në të dyja rastet.
4. Duke supozuar se n është numri i vlerave në array , SMALL(array,1) do të kthejë vlerën më të ulët dhe SMALL(array,n) do të zgjedhë vlerën më të lartë.

Si të përdorni funksionin SMALL në Excel - shembuj formulash

Dhe tani, le të shohim disa shembuj të tjerë të funksionit Excel SMALL që shkojnë përtej përdorimit të tij bazë.

Gjeni vlerat e poshtme 3, 5, 10, etj.

Siç e dini tashmë, funksioni SMALL është krijuar për të llogaritur vlerën n-të më të ulët. Ky shembull tregon se si ta bëni këtë në mënyrë më efektive.

Në tabelën e mëposhtme, supozoni se dëshironi të gjeni 3 vlerat e poshtme. Për këtë, shkruaninumrat 1, 2 dhe 3 në qeliza të veçanta (D3, D4 dhe D5 në rastin tonë). Më pas, futni formulën e mëposhtme në E3 dhe tërhiqeni poshtë përmes E5:

=SMALL($B$2:$B$10, D3)

Në E3, formula nxjerr vlerën më të vogël duke përdorur numrin në D3 për k argument. Gjëja kryesore është të jepni referencat e duhura të qelizave për shkak të të cilave formula kopjohet saktë në qelizat e tjera: absolute për array dhe relative për k .

Nuk doni të shqetësoheni për të shkruar me dorë renditjet? Përdorni funksionin ROWS me një referencë varg zgjerimi për të dhënë vlerën k . Për këtë, ne bëjmë një referencë absolute për qelizën e parë (ose mbyllim vetëm koordinatat e rreshtit si B$2) dhe referencë relative për qelizën e fundit:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Si rezultat, diapazoni referenca zgjerohet ndërsa formula kopjohet poshtë kolonës. Në D2, ROWS(B$2:B2) prodhon 1 për k dhe formula kthen koston më të ulët. Në D3, ROWS(B$2:B3) jep 2, dhe marrim koston e dytë më të ulët, e kështu me radhë.

Thjesht kopjoni formulën përmes 5 qelizave dhe do të merrni 5 vlerat e poshtme:

Sumoni N vlerat e poshtme

Doni të gjeni një total prej n vlerave më të vogla në një grup të dhënash? Nëse i keni nxjerrë tashmë vlerat si në shembullin e mëparshëm, zgjidhja më e lehtë do të ishte një formulë SUM si:

=SUM(E3:E5)

Ose mundeni bëni një formulë të pavarur duke përdorur funksionin SMALL së bashku me SUMPRODUCT:

Për të marrë shumën e 3 vlerave të poshtme në grupin tonë të të dhënave, formula merr këtë formë :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

Funksioni SUM do të prodhojë të njëjtin rezultat:

=SUM(SMALL(B2:B10, {1,2,3}))

Shënim. Nëse përdorni referencat e qelizave në vend të konstantës së grupit për k , duhet të shtypni Ctrl + Shift + Enter për ta bërë atë një formulë grupi. Në Excel 365 që mbështet vargje dinamike, SUM SMALL funksionon si një formulë e rregullt në secilin rast.

Si funksionon kjo formulë:

Në një formulë të rregullt, SMALL kthen një vlerë të vetme k-të më të vogël në një varg. Në këtë rast, ne japim një konstante grupi si {1,2,3} për argumentin k, duke e detyruar atë të kthejë një grup prej 3 vlerave më të vogla:

{29240, 43610, 58860}

SUMPRODUCT ose Funksioni SUM mbledh numrat në grup dhe nxjerr totalin. Kjo është e gjitha!

Formula INDEX MATCH SMALL për të marrë përputhjet më të vogla

Në situatën kur dëshironi të rikuperoni disa të dhëna të lidhura me vlerën më të vogël, përdorni kombinimin klasik INDEX MATCH me SMALL për vlerën e kërkimit :

Ku :

• Rreth_array është një gamë nga e cila mund të nxirren të dhënat e lidhura.
• Lookup_array është një diapazon ku mund të kërkoni për n më të ulët -vlera.
• N është pozicioni i vlerës më të vogël të interesit.

Përshembull, për të marrë emrin e projektit që ka koston më të ulët, formula në E3 është:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

ku A2:A10 janë emrat e projekteve, B2:B10 janë kostot dhe D3 është renditja nga më e vogla.

Kopjo formulën në qelizat e mëposhtme (E4 dhe E5) dhe do të marrësh emrat e 3 projekteve më të lira:

Shënime:

• Kjo zgjidhje funksionon mirë për një grup të dhënash që nuk ka dublikatë. Megjithatë, dy ose më shumë vlera të kopjuara në një kolonë numerike mund të krijojnë "lidhje" në renditje, gjë që do të çojë në rezultate të gabuara. Në këtë rast, ju lutemi përdorni një formulë pak më të sofistikuar për të prishur lidhjet.
• Në Excel 365, kjo detyrë mund të realizohet me ndihmën e funksioneve të reja të grupit dinamik. Përveçse është shumë më e thjeshtë, kjo qasje zgjidh automatikisht problemin e lidhjeve. Për detaje të plota, ju lutemi shihni Si të filtroni vlerat e poshtme N në Excel.

Renditni numrat nga më i ulëti tek më i larti me një formulë

Besoj se të gjithë e dinë se si t'i vendosin numrat në rend me Funksioni i renditjes në Excel. Por a dini si të kryeni renditjen me një formulë? Përdoruesit e Excel 365 mund ta bëjnë këtë në një mënyrë të thjeshtë me funksionin e ri SORT. Në Excel 2019, 2016 dhe versionet e mëparshme, SORT nuk funksionon, mjerisht. Por kini pak besim, dhe SMALL do të vijë në ndihmë :)

Si në shembullin e parë, ne përdorim funksionin ROWS me një referencë zgjerimi të gamës për rritjen k me 1 në çdo rreshti ku formulaështë kopjuar:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Futni formulën në qelizën e parë dhe më pas tërhiqeni në aq qeliza sa ka vlera në grupin e të dhënave origjinale (C2:C10 në këtë shembull) :

Këshillë. Për të renditur në zbritje , përdorni funksionin LARGE në vend të SMALL.

Formula Excel SMALL për datat dhe kohët

Për shkak se datat dhe orët janë gjithashtu vlera numerike (në sistemin e brendshëm Excel, datat ruhen si numra sekuencialë dhe kohët si thyesa dhjetore), funksioni SMALL mund t'i trajtojë ato gjithashtu pa ndonjë përpjekje shtesë nga ana juaj.

Siç mund ta shihni në pamjet e mëposhtme të ekranit, një formulë bazë që kemi përdorur për numrat funksionon bukur edhe për datat dhe kohët:

=SMALL($B$2:$B$10, D2)

Formula SALL për të gjetur 3 datat më të hershme:

Formula SALL për të marrë 3 herë më të shkurtër:

Shembulli tjetër tregon se si funksioni SMALL mund t'ju ndihmojë të përmbushni një detyrë më specifike në lidhje me datat.

Gjeni një datë të mëparshme më të afërt me sot ose datën e specifikuar

Në një listë datash , duke supozuar se dëshironi të gjeni datën më të afërt përpara një date të caktuar. Kjo mund të bëhet duke përdorur funksionin SMALL në kombinim me COUNTIF.

Me listën e datave në B2:B10 dhe datën e synuar në E1, formula e mëposhtme do të kthejë një datë të mëparshme më afër datës së synuar:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

Për të nxjerrë një datë që është dy data përpara datës në E1, d.m.th. një datë e mëparshme por një datë,formula është:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

Për të gjetur një datë të kaluar më afër sot , përdorni funksionin TODAY për kriteret e COUNTIF:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

Këshillë. Për të parandaluar gabimet në situatën kur nuk gjendet një datë që përputhet me kriteret tuaja, mund ta mbështillni funksionin IFERROR rreth formulës suaj, si kjo:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

Si funksionojnë këto formula:

Ideja e përgjithshme është të numëroni numrin e datave më të vogla se data e synuar me COUNTIF. Dhe ky numërim është pikërisht ajo që i nevojitet funksionit SMALL për argumentin k .

Për ta kuptuar më mirë konceptin, le ta shohim atë nga një kënd tjetër:

Nëse 1- Gusht-2020 (data e synuar në E1) u shfaq në grupin tonë të të dhënave, do të ishte data e 7-të më e madhe në listë. Rrjedhimisht, ka gjashtë data më të vogla se ajo. Do të thotë, data e 6-të më e vogël është data e mëparshme më afër datës së synuar.

Pra, fillimisht ne llogarisim sa data janë më të vogla se data në E1 (rezultati është 6):

COUNTIF(B2:B10, "<"&E1)

Dhe më pas, futni numërimin në argumentin e dytë të SMALL:

=SMALL(B2:B10, 6)

Për të marrë datën e mëparshme por një (që është data e 5-të më e vogël në rastin tonë) , ne zbresim 1 nga rezultati i COUNTIF.

Si të nënvizoni vlerat e poshtme në Excel

Për të nxjerrë në pah n ​​vlerat më të vogla në tabelën tuaj me formatimin e kushtëzuar të Excel, mund të përdorni ose një Top të integruar /Opsioni i poshtëm ose vendosni rregullin tuaj bazuar në një formulë të VOGËL. Metoda e parë është më e shpejtëdhe më e lehtë për t'u aplikuar, ndërsa e dyta ofron më shumë kontroll dhe fleksibilitet. Hapat e mëposhtëm do t'ju ndihmojnë të krijoni një rregull të personalizuar:

1. Zgjidhni diapazonin në të cilin dëshironi të nënvizoni vlerat e poshtme. Në rastin tonë, numrat janë në B2:B10, kështu që ne e zgjedhim atë. Nëse dëshironi të nënvizoni rreshta të tëra, atëherë zgjidhni A2:B10.
2. Në skedën Home , në grupin Stilet , kliko Formatimi i kushtëzuar > Rregull i ri .
3. Në kutinë e dialogut Rregulli i ri i formatimit , zgjidhni Përdor një formulë për të përcaktuar se cilat qeliza të formatohen.
4. Në kutinë Formati i vlerave ku kjo formulë është e vërtetë , vendosni një formulë si kjo:

   =B2<=SMALL($B$2:$B$10, 3)

   Ku B2 është qeliza më e majtë e numerikës diapazoni që do të kontrollohet, $B$2:$B$10 është i gjithë diapazoni dhe 3 është n vlerat e poshtme për t'u theksuar.

   Në formulën tuaj, ju lutemi mbani parasysh llojet e referencës: qeliza më e majtë është një referencë relative (B2) ndërsa diapazoni është referenca absolute ($B$2:$B$10).

5. Klikoni butonin Format dhe zgjidhni cilindo format që ju pëlqen.
6. Klikoni OK dy herë për të mbyllur të dy dritaret e dialogut.

U krye! 3 vlerat e poshtme në kolonën B janë theksuar:

Për më shumë informacion, ju lutemi shihni formatimin e kushtëzuar të Excel bazuar në formulë.

Funksioni Excel SMALL nuk funksionon

Siç e keni parë nga shembujt tanë, përdorimi i funksionit SMALL në Excel është mjaft i lehtë, dhe ju jeninuk ka gjasa të ketë ndonjë vështirësi me të. Nëse formula juaj nuk funksionon, ka shumë të ngjarë që do të jetë një #NUM! gabim, i cili mund të ndodhë për arsyet e mëposhtme:

• Array është bosh ose nuk përmban një vlerë të vetme numerike.
• k vlera është më e vogël se zero (një gabim shtypi budalla mund t'ju kushtojë orë të tëra zgjidhje të problemeve!) ose tejkalon numrin e vlerave në grup.

Kjo është se si të përdorni një formulë të Vogël në Excel për të gjetur dhe nënvizoni numrat e poshtëm në një grup të dhënash. Nëse dini ndonjë skenar tjetër ku funksioni është i dobishëm, jeni të mirëpritur të ndani në komente. Ju falënderoj që lexoni dhe shpresoj t'ju shohim në blogun tonë javën e ardhshme!

Praktikoni librin e punës për shkarkim

Shembuj të formulave të vogla Excel (skedari .xlsx)