Во овој краток туторијал, ќе зборуваме за функцијата Excel SMALL, како функционира и како да ја искористиме за да го пронајдеме N-тиот најмал број, датум или време.

Потребно е да најдете неколку најниски броеви во работниот лист? Ова е прилично лесно да се направи со функцијата Excel Sort. Не сакате да губите време за повторно сортирање на вашите податоци со секоја промена? Функцијата SMALL ќе ви помогне брзо да ја пронајдете најниската вредност, втората најмала, третата најмала и така натаму.

Excel SMALL функцијата

SMALL е статистичка функција која враќа n-та најмала вредност во множество податоци.

Синтаксата на функцијата SMALL вклучува два аргументи, од кои и двата се потребни.

SMALL(низа, k)

Каде:

• Низа - низа или опсег на ќелии од кои може да се извлече најмалата вредност.
• K - an цел број што ја означува позицијата од најниската вредност што треба да се врати, односно k-та најмала.

Функцијата е достапна во сите верзии на Excel за Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010 и порано.

Совет. За да ја пронајдете k-та најниска вредност со критериуми, користете ја формулата Excel SMALL IF.

Основна формула SMALL во Excel

МАЛА формула во нејзината основна форма е многу лесна за градење - само наведете ја опсегот и позицијата од најмалата ставка што треба да се врати.

Во списокот со броеви во B2:B10, под претпоставка дека сакате да ја извлечете третата најмала вредност. Формулата е какоедноставно како:

=SMALL(B2:B10, 3)

За да ви биде полесно да го проверите резултатот, колоната Б е подредена по растечки редослед:

4 работи што треба да ги знаете за SMALL функцијата

Следните белешки за употреба ќе ви помогнат подобро да го разберете однесувањето на функцијата SMALL и да избегнете забуна при градењето на сопствените формули.

1. Секое празни ќелии , текст вредности и логичките вредностите TRUE и FALSE во аргументот низа се игнорираат.
2. Ако низата содржи една или повеќе грешки , се враќа грешка.
3. Во случај да има дупликати во низа , вашата формула може да резултира со „врски“. На пример, ако две ќелии го содржат бројот 1, а функцијата SMALL е конфигурирана да ја враќа најмалата и втората најмалата вредност, ќе добиете 1 во двата случаи.
4. Претпоставувајќи дека n е бројот на вредности во низа , SMALL(низа,1) ќе ја врати најниската вредност, а SMALL(низа, n) ќе ја избере највисоката вредност.

Како да ја користите функцијата SMALL во Excel - примери на формула

И сега, ајде да погледнеме уште неколку примери на функцијата Excel SMALL кои ја надминуваат нејзината основна употреба.

Најдете ги долните вредности 3, 5, 10, итн.

Како што веќе знаете, функцијата SMALL е дизајнирана да ја пресмета n-тата најниска вредност. Овој пример покажува како да го направите тоа најефективно.

Во табелата подолу, да претпоставиме дека сакате да ги најдете долните 3 вредности. За ова, напишете гоброеви 1, 2 и 3 во посебни ќелии (Д3, Д4 и Д5 во нашиот случај). Потоа, внесете ја следната формула во E3 и повлечете ја надолу низ E5:

=SMALL($B$2:$B$10, D3)

Во E3, формулата ја извлекува најмалата вредност користејќи го бројот во D3 за k аргумент. Клучната работа е да се обезбедат соодветни референци на ќелиите поради што формулата правилно се копира во другите ќелии: апсолутна за низа и релативна за k .

Не сакате да се мачите рачно да ги пишувате ранговите? Користете ја функцијата ROWS со референца проширен опсег за да ја обезбедите вредноста k . За ова, правиме апсолутна референца за првата ќелија (или само ја заклучуваме координатата на редот како B$2) и релативна референца за последната ќелија:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Како резултат, опсегот референцата се проширува додека формулата се копира во колоната. Во D2, ROWS(B$2:B2) произведува 1 за k , а формулата враќа најниска цена. Во D3, ROWS(B$2:B3) дава 2, и ја добиваме втората најниска цена и така натаму.

Само копирајте ја формулата низ 5 ќелии и ќе ги добиете долните 5 вредности:

Збир на долни N вредности

Сакате да најдете вкупно најмалите n вредности во базата на податоци? Ако веќе сте ги извлекле вредностите како што е прикажано во претходниот пример, најлесното решение би било формулата SUM како:

=SUM(E3:E5)

Или можете направи независна формула користејќи ја функцијата SMALL заедно со SUMPRODUCT:

За да се добие збирот на долните 3 вредности во нашиот сет на податоци, формулата го зема овој облик :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

Функцијата SUM ќе го произведе истиот резултат:

=SUM(SMALL(B2:B10, {1,2,3}))

Забелешка. Ако користите референци за ќелии наместо константа на низа за k , треба да притиснете Ctrl + Shift + Enter за да ја направите формула за низа. Во Excel 365 кој поддржува динамички низи, SUM SMALL работи како редовна формула во секој случај.

Како функционира оваа формула:

Во обична формула, SMALL враќа единечна k-та најмала вредност во опсегот. Во овој случај, даваме константа на низа како {1,2,3} за аргументот k, принудувајќи го да врати низа од најмалите 3 вредности:

{29240, 43610, 58860}

The SUMPRODUCT или Функцијата SUM ги собира броевите во низата и го дава вкупниот број. Тоа е тоа!

INDEX MATCH SMALL формула за да добиете најмали совпаѓања

Во ситуација кога сакате да вратите некои податоци поврзани со најмалата вредност, користете ја класичната комбинација INDEX MATCH со SMALL за вредноста за пребарување :

Каде :

• Return_array е опсег од кој се извлекуваат поврзани податоци.
• Lookup_array е опсег каде што се бара најниската n -та вредност.
• N е позицијата на најмалата вредност на каматата.

Зана пример, за да се добие името на проектот кој има најниска цена, формулата во Е3 е:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Каде што A2:A10 се имињата на проектот, B2:B10 се трошоците и D3 е рангирањето од најмалите.

Копирајте ја формулата во долунаведените ќелии (E4 и E5) и ќе ги добиете имињата на 3-те најевтини проекти:

Забелешки:

• Ова решение работи добро за база на податоци што нема дупликати. Сепак, две или повеќе дупликати вредности во нумеричка колона може да создадат „врски“ во рангирањето, што ќе доведе до погрешни резултати. Во овој случај, ве молиме користете малку пософистицирана формула за раскинување на врските.
• Во Excel 365, оваа задача може да се постигне со помош на новите функции на динамичка низа. Освен што е многу поедноставен, овој пристап автоматски го решава проблемот со вратоврските. За целосни детали, погледнете Како да ги филтрирате долните N вредности во Excel.

Соредете ги броевите од најниско до највисоко со формула

Верувам дека секој знае како да ги подреди броевите со Функција за сортирање на Excel. Но, дали знаете како да извршите сортирање со формула? Корисниците на Excel 365 можат да го направат тоа на лесен начин со новата функција SORT. Во Excel 2019, 2016 и претходните верзии, SORT не работи, за жал. Но, имајте малку вера, и SMALL ќе ви помогне :)

Како во првиот пример, ја користиме функцијата ROWS со референца за проширување на опсегот за зголемување k за 1 во секоја ред каде формулатасе копира:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Внесете ја формулата во првата ќелија, а потоа повлечете ја надолу во онолку ќелии колку што има вредности во оригиналниот сет на податоци (C2:C10 во овој пример) :

Совет. За подредување опаѓачки , користете ја функцијата LARGE наместо SMALL.

Excel SMALL формула за датуми и времиња

Бидејќи датумите и времињата се исто така нумерички вредности (во внатрешниот систем на Excel, датумите се зачувуваат како секвенцијални броеви и времињата како децимални фракции), функцијата SMALL може да се справи со нив како и без дополнителен напор на ваша страна.

Како што можете да видите на сликите од екранот подолу, основната формула што ја користевме за бројки работи одлично и за датуми и времиња:

=SMALL($B$2:$B$10, D2)

МАЛА формула за наоѓање на најраните 3 датуми:

МАЛА формула за да се добие најкратката 3 пати:

Следниот пример покажува како функцијата SMALL може да ви помогне да постигнете поконкретна задача поврзана со датумите.

Најдете претходен датум најблизок до денес или наведен датум

Во список со датуми , претпоставувајќи дека сакате да го најдете најблискиот датум пред одреден датум. Ова може да се направи со користење на функцијата SMALL во комбинација со COUNTIF.

Со списокот со датуми во B2:B10 и целниот датум во E1, следнава формула ќе врати претходен датум најблизок до целниот датум:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

За да се извлече датум кој е два дата пред датумот во Е1, т.е. претходен, но еден датум,формулата е:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

За да најдете минат датум најблиску до денес , користете ја функцијата ДЕНЕС за критериумите на COUNTIF:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

Совет. За да спречите грешки во ситуација кога не е пронајден датум што одговара на вашите критериуми, можете да ја завиткате функцијата IFERROR околу вашата формула, вака:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

Како функционираат овие формули:

Општата идеја е да се брои бројот на датуми помали од целниот датум со COUNTIF. И ова броење е токму она што и е потребно на функцијата SMALL за аргументот k .

За подобро да го сфатиме концептот, ајде да го погледнеме од друг агол:

Ако 1- Август-2020 (целниот датум во Е1) се појави во нашата база на податоци, тоа ќе биде седмиот најголем датум на листата. Следствено, има шест датуми помали од него. Што значи, 6-тиот најмал датум е претходниот датум најблиску до целниот датум.

Значи, прво пресметуваме колку датуми се помали од датумот во Е1 (резултатот е 6):

COUNTIF(B2:B10, "<"&E1)

И потоа, приклучете го броењето во вториот аргумент на SMALL:

=SMALL(B2:B10, 6)

За да го добиете претходниот, но еден датум (што е петтиот најмал датум во нашиот случај) , ние одземаме 1 од резултатот на COUNTIF.

Како да ги истакнете долните вредности во Excel

За да ги истакнете најмалите n вредности во вашата табела со условно форматирање на Excel, можете да користите или вградена горна /Долна опција или поставете сопствено правило врз основа на МАЛА формула. Првиот метод е побрзи полесно се применува, додека вториот обезбедува поголема контрола и флексибилност. Следните чекори ќе ве водат низ создавање на приспособено правило:

1. Изберете го опсегот во кој сакате да ги истакнете долните вредности. Во нашиот случај, броевите се во B2:B10, па го избираме. Ако сакате да означите цели редови, потоа изберете A2:B10.
2. На картичката Почетна , во групата Стилови , кликнете Условно форматирање > Ново правило .
3. Во полето за дијалог Ново правило за форматирање , изберете Користете формула за да одредите кои ќелии да се форматираат.
4. Во полето Форматирајте вредности каде оваа формула е вистинита , внесете формула како оваа:

   =B2<=SMALL($B$2:$B$10, 3)

   Каде што B2 е најлевата ќелија од нумеричката опсегот што треба да се провери, $B$2:$B$10 е целиот опсег, а 3 е n долните вредности што треба да се истакнат.

   Во вашата формула, ве молиме имајте ги предвид референтните типови: најлевата ќелија е релативна референца (B2), додека опсегот е апсолутна референца ($B$2:$B$10).

5. Кликнете на копчето Формат и изберете кој било формат што го сакате.
6. Кликнете ОК двапати за да ги затворите двата прозореца за дијалог.

Направено! Долните 3 вредности во колоната Б се означени:

За повеќе информации, погледнете го условното форматирање на Excel врз основа на формулата.

Функцијата Excel SMALL не работи

Како што штотуку видовте од нашите примери, користењето на функцијата SMALL во Excel е прилично лесно, а вие стеверојатно нема да има никакви тешкотии со тоа. Ако вашата формула не работи, најверојатно тоа ќе биде #NUM! грешка, која може да се појави поради следните причини:

• Низата е празна или не содржи една нумеричка вредност.
• k вредноста е помала од нула (глупава печатна грешка може да ве чини со часови решавање проблеми!) или го надминува бројот на вредности во низата.

Така да користите МАЛА формула во Excel за да пронајдете и означете ги долните броеви во збир на податоци. Ако знаете некои други сценарија каде што функцијата ви е добро, добредојдени сте да ги споделите во коментари. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела!

Вежбајте работна книга за преземање

Примери на МАЛИ формула на Excel (датотека .xlsx)