En ĉi tiu mallonga lernilo, ni parolos pri Excel SMALL-funkcio, kiel ĝi funkcias kaj kiel uzi ĝin por trovi la N-an plej malgrandan nombron, daton aŭ horon.

Necesas. trovi kelkajn plej malaltajn nombrojn en laborfolio? Ĉi tio estas sufiĉe facila por fari kun la funkcio Excel Ordigo. Ĉu vi ne volas perdi tempon por reordigi viajn datumojn kun ĉiu ŝanĝo? La SMALL funkcio helpos vin rapide trovi la plej malaltan valoron, la duan plej malgrandan, la trian plej malgrandan, ktp.

Excel SMALL-funkcio

SMALL estas statistika funkcio kiu redonas la n-a plej malgranda valoro en datumaro.

La sintakso de la SMALL funkcio inkluzivas du argumentojn, kiuj ambaŭ estas bezonataj.

SMALL(tabelo, k)

Kie:

• Tabelo - tabelo aŭ gamo da ĉeloj el kiuj ĉerpi la plej malgrandan valoron.
• K - an entjero kiu indikas la pozicion de la plej malalta valoro por reveni, t.e. k-a plej malgranda.

La funkcio estas disponebla en ĉiuj versioj de Excel por Office 365, Excel 2021, Excel 2019, Excel 2016, Excel. 2013, Excel 2010, kaj pli frue.

Konsileto. Por trovi k-an plej malaltan valoron kun kriterioj, uzu Excel SMALL IF-formulo.

Baza SMALL-formulo en Excel

Malgranda formulo en sia baza formo estas tre facile konstruebla - vi nur specifu la intervalon kaj la pozicion de la plej malgranda aĵo reveninta.

En la listo de nombroj en B2:B10, supozante, ke vi volas ĉerpi la 3-an plej malgrandan valoron. La formulo estas kielsimpla kiel:

=SMALL(B2:B10, 3)

Por faciligi al vi kontroli la rezulton, kolumno B estas ordigita laŭkreska:

4 aferoj, kiujn vi devus scii pri MALGRETA funkcio

La sekvaj uznotoj helpos vin pli bone kompreni la konduton de la META funkcio kaj eviti konfuzon dum konstruado de viaj propraj formuloj.

1. Ajna malplenaj ĉeloj , tekstaj valoroj, kaj logikaj valoroj VERA kaj FALSA en la argumento tabelo estas ignoritaj.
2. Se tabelo enhavas unu aŭ plurajn erarojn , eraro estas resendita.
3. Se estas duplikatoj en tabelo , via formulo povas rezultigi "ligojn". Ekzemple, se du ĉeloj enhavas la nombron 1, kaj la META funkcio estas agordita por redoni la plej malgrandan kaj la duan plej malgrandan valoron, vi ricevos 1 en ambaŭ kazoj.
4. Supozinte n estas la nombro da valoroj en tabelo , SMALL(tabelo,1) redonos la plej malaltan valoron, kaj SMALL(tabelo,n) elektos la plej altan valoron.

Kiel uzi la SMALL-funkcion en Excel - formulekzemploj

Kaj nun, ni rigardu kelkajn pliajn ekzemplojn de la Excel SMALL-funkcio, kiuj superas ĝian bazan uzadon.

Trovu malsuprajn valorojn 3, 5, 10, ktp.

Kiel vi jam scias, la META funkcio estas desegnita por kalkuli la n-an plej malaltan valoron. Ĉi tiu ekzemplo montras kiel fari tion plej efike.

En la suba tabelo, supozu, ke vi volas trovi la malsuprajn 3 valorojn. Por tio, tajpu lanumeroj 1, 2 kaj 3 en apartaj ĉeloj (D3, D4 kaj D5 en nia kazo). Poste, enigu la sekvan formulon en E3 kaj trenu ĝin malsupren tra E5:

=SMALL($B$2:$B$10, D3)

En E3, la formulo ĉerpas la plej malgrandan valoron uzante la nombron en D3 por la k argumento. La ŝlosilo estas provizi taŭgajn ĉelreferencojn pro kiuj la formulo kopias ĝuste en aliaj ĉeloj: absoluta por tabelo kaj relativa por k .

Ĉu ne volas ĝeni tajpi la rangojn permane? Uzu la funkcion ROWS kun vastiga intervalo referenco por provizi la valoron k . Por tio, ni faras absolutan referencon por la unua ĉelo (aŭ nur ŝlosas la vickoordinaton kiel B$2) kaj relativan referencon por la lasta ĉelo:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Kiel rezulto, la intervalo referenco disetendiĝas kiam la formulo estas kopiita laŭ la kolumno. En D2, VICOJ(B$2:B2) produktas 1 por k , kaj la formulo liveras la plej malaltan koston. En D3, VICOJ(B$2:B3) donas 2, kaj ni ricevas la duan plej malaltan koston, kaj tiel plu.

Nur kopiu la formulon tra 5 ĉeloj, kaj vi ricevos la malsuprajn 5 valorojn:

Sumu malsuprajn N-valorojn

Ĉu vi volas trovi entuton de la plej malgrandaj n valoroj en datumaro? Se vi jam ĉerpis la valorojn kiel montrite en la antaŭa ekzemplo, la plej facila solvo estus SUMformulo kiel:

=SUM(E3:E5)

Aŭ vi povas faru sendependan formulon uzante la SMALL-funkcion kune kun SUMPRODUCT:

Por akiri la sumon de la malsupraj 3 valoroj en nia aro de datumoj, la formulo prenas ĉi tiun formon :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

La SUM-funkcio produktos la saman rezulton:

=SUM(SMALL(B2:B10, {1,2,3}))

Notu. Se vi uzas ĉelreferencojn prefere ol tabelkonstanto por k , vi devas premi Ctrl + Shift + Enter por fari ĝin tabelformulo. En Excel 365, kiu subtenas dinamikajn tabelojn, SUM SMALL funkcias kiel regula formulo en ambaŭ kazoj.

Kiel ĉi tiu formulo funkcias:

En regula formulo, SMALL liveras ununuran k-an plej malgrandan valoron en intervalo. En ĉi tiu kazo, ni provizas tabelkonstanton kiel {1,2,3} por la k argumento, devigante ĝin resendi tabelon de la plej malgrandaj 3 valoroj:

{29240, 43610, 58860}

La SUMPRODUTO aŭ SUM-funkcio sumigas la nombrojn en la tabelo kaj eligas la totalon. Jen ĝi!

INDEX MATCH SMALL formulo por akiri plej malgrandajn kongruojn

En situacio kiam vi volas retrovi iujn datumojn asociitajn kun la plej malgranda valoro, uzu la klasikan INDEX MATCH kombinaĵon kun SMALL por la serĉvaloro :

Kie :

• Return_array estas intervalo el kiu ĉerpi rilatajn datumojn.
• Lookup_array estas intervalo kie serĉi la plej malaltan n -a valoro.
• N estas la pozicio de la plej malgranda valoro de intereso.

Porekzemplo, por ricevi la nomon de la projekto kiu havas la plej malaltan koston, la formulo en E3 estas:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Kie A2:A10 estas la projektonomoj, B2:B10 estas la kostoj kaj D3 estas la rango de plej malgranda.

Kopiu la formulon al la subaj ĉeloj (E4 kaj E5), kaj vi ricevos la nomojn de la 3 plej malmultekostaj projektoj:

Notoj:

• Ĉi tiu solvo funkcias bone por datumaro, kiu ne havas duplikatojn. Tamen, du aŭ pli duplikataj valoroj en nombra kolumno povas krei "ligojn" en rangotabelo, kio kondukos al malĝustaj rezultoj. En ĉi tiu kazo, bonvolu uzi iom pli kompleksan formulon por rompi ligilojn.
• En Excel 365, ĉi tiu tasko povas esti plenumita helpe de la novaj dinamikaj tabelaj funkcioj. Krom esti multe pli simpla, ĉi tiu aliro aŭtomate solvas la problemon de ligoj. Por plenaj detaloj, bonvolu vidi Kiel filtri malsuprajn N-valorojn en Excel.

Ordigi nombrojn de plej malalta al plej alta per formulo

Mi kredas, ke ĉiuj scias kiel ordigi nombrojn per Excel Ordigo funkcio. Sed ĉu vi scias kiel fari ordigon per formulo? La uzantoj de Excel 365 povas fari ĝin facile per la nova SORT-funkcio. En Excel 2019, 2016 kaj pli fruaj versioj, SORT ne funkcias, ve. Sed iom fidu, kaj SMALL venos al la savo :)

Kiel en la unua ekzemplo, ni uzas la funkcion ROWS kun vastiga intervalreferenco por pligrandigi k je 1 en ĉiu vico kie la formuloestas kopiita:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Enigu la formulon en la unua ĉelo, kaj tiam trenu ĝin malsupren al tiom da ĉeloj kiom da valoroj estas en la originala datumaro (C2:C10 en ĉi tiu ekzemplo) :

Konsileto. Por ordigi malkreskan , uzu la GRANDA funkcion anstataŭ SMALL.

Excel MALGRATA formulo por datoj kaj tempoj

Ĉar datoj kaj tempoj ankaŭ estas nombraj valoroj (en la interna Excel-sistemo, datoj estas konservitaj kiel sinsekvaj nombroj kaj tempoj kiel dekumaj frakcioj), la MALGRETA funkcio povas trakti ilin. ankaŭ sen ekstra peno de via flanko.

Kiel vi povas vidi en la malsupraj ekrankopioj, baza formulo, kiun ni uzis por nombroj, bele funkcias ankaŭ por datoj kaj horoj:

=SMALL($B$2:$B$10, D2)

Malgranda formulo por trovi la plej fruajn 3 datojn:

Malgranda formulo por akiri la plej mallongajn 3 fojojn:

La sekva ekzemplo montras kiel la META funkcio povas helpi vin plenumi pli specifan taskon rilate al datoj.

Trovu antaŭan daton plej proksiman al hodiaŭ aŭ al specifita dato

En listo de datoj. , supozante, ke vi volas trovi la plej proksiman daton antaŭ difinita dato. Ĉi tio povas esti farita uzante la SMALL-funkcion en kombinaĵo kun COUNTIF.

Kun la listo de datoj en B2:B10 kaj la celdato en E1, la sekva formulo redonos antaŭan daton plej proksiman al la celdato:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

Por ĉerpi daton kiu estas du datoj antaŭ la dato en E1, t.e. antaŭa sed unu dato, laformulo estas:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

Por trovi pasintan daton plej proksiman al hodiaŭ , uzu la HODIAŬ-funkcion por la kriterioj de COUNTIF:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

Konsileto. Por malhelpi erarojn en situacio, kiam dato kongrua kun viaj kriterioj ne estas trovita, vi povas envolvi la funkcion IFERROR ĉirkaŭ via formulo, jene:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

Kiel ĉi tiuj formuloj funkcias:

La ĝenerala ideo estas kalkuli la nombron da datoj pli malgranda ol la celdato per COUNTIF. Kaj ĉi tiu kalkulo estas ĝuste tio, kion bezonas la META funkcio por la argumento k .

Por pli bone kompreni la koncepton, ni rigardu ĝin el alia angulo:

Se 1- Aŭg-2020 (la celdato en E1) aperis en nia datumaro, ĝi estus la 7-a plej granda dato en la listo. Sekve, estas ses datoj pli malgrandaj ol ĝi. Signifo, la 6-a plej malgranda dato estas la antaŭa dato plej proksima al la celdato.

Do, unue ni kalkulas kiom da datoj estas pli malgrandaj ol la dato en E1 (la rezulto estas 6):

COUNTIF(B2:B10, "<"&E1)

Kaj poste, enŝovu la kalkulon en la 2-an argumenton de SMALL:

=SMALL(B2:B10, 6)

Por akiri la antaŭan sed unu daton (kiu estas la 5-a plej malgranda dato en nia kazo) , ni subtrahas 1 el la rezulto de COUNTIF.

Kiel reliefigi malsuprajn valorojn en Excel

Por reliefigi la plej malgrandajn n valorojn en via tabelo per Excel-kondiĉa formatado, vi povas uzi aŭ enkonstruitan Supron. /Malsupra opcio aŭ starigu vian propran regulon bazitan sur MALGRATA formulo. La unua metodo estas pli rapidakaj pli facile apliki, dum la dua provizas pli da kontrolo kaj fleksebleco. La subaj paŝoj gvidos vin tra kreado de kutima regulo:

1. Elektu la intervalon en kiu vi volas reliefigi malsuprajn valorojn. En nia kazo, la nombroj estas en B2:B10, do ni elektas ĝin. Se vi volas reliefigi tutajn vicojn, tiam elektu A2:B10.
2. En la langeto Hejmo , en la grupo Stiloj , alklaku Kondiĉa formatado. > Nova Regulo .
3. En la dialogkesto Nova Formata Regulo , elektu Uzu formulon por determini kiujn ĉelojn formati.
4. En la Formati valorojn kie ĉi tiu formulo estas vera , enigu formulon kiel ĉi tiu:

   =B2<=SMALL($B$2:$B$10, 3)

   Kie B2 estas la plej maldekstra ĉelo de la nombra kontrolinda intervalo, $B$2:$B$10 estas la tuta intervalo, kaj 3 estas la n malsupraj valoroj por reliefigi.

   En via formulo, bonvolu atenti la referencajn tipojn: la plej maldekstra ĉelo estas relativa referenco (B2) dum la intervalo estas la absoluta referenco ($B$2:$B$10).

5. Alklaku la butonon Formati kaj elektu iun ajn formaton, kiun vi ŝatas.
6. Alklaku OK dufoje por fermi ambaŭ dialogfenestrojn.

Farita! La malsupraj 3 valoroj en kolumno B estas emfazitaj:

Por pliaj informoj, bonvolu vidi Excel-kondiĉan formatadon bazitan sur formulo.

Excel SMALL-funkcio ne funkcias

Kiel vi ĵus vidis el niaj ekzemploj, uzi la MALAGRAN funkcion en Excel estas sufiĉe facila, kaj vi estasverŝajne ne havos malfacilaĵojn kun ĝi. Se via formulo ne funkcias, plej verŝajne tio estos #NUM! eraro, kiu povas okazi pro la sekvaj kialoj:

• Tabelo estas malplena aŭ ne enhavas ununuran numeran valoron.
• La k valoro estas malpli ol nulo (malsaĝa tajperaro povas kosti al vi horojn da problemoj!) aŭ superas la nombron da valoroj en la tabelo.

Tiel uzi MALGRATAN formulon en Excel por trovi kaj reliefigi malsuprajn nombrojn en aro da datumoj. Se vi konas aliajn scenarojn, kie la funkcio utilas, vi bonvenas dividi en komentoj. Mi dankas vin pro legado kaj esperas vidi vin en nia blogo venontsemajne!

Praktiku laborlibron por elŝuto

Excel MALGRAJ formulekzemploj (.xlsx-dosiero)