Yn y tiwtorial byr hwn, byddwn yn siarad am swyddogaeth Excel SMALL, sut mae'n gweithio a sut i'w ddefnyddio i ddod o hyd i'r Nfed rhif, dyddiad neu amser lleiaf.

Angen i ddod o hyd i ychydig o rifau isaf mewn taflen waith? Mae hyn yn eithaf hawdd i'w wneud gyda'r nodwedd Trefnu Excel. Ddim eisiau gwastraffu amser ar ail-ddidoli eich data gyda phob newid? Bydd y ffwythiant BACH yn eich helpu i ddod o hyd i'r gwerth isaf yn gyflym, yr ail leiaf, y trydydd lleiaf, ac yn y blaen. yr n-fed gwerth lleiaf mewn set ddata.

Mae cystrawen y ffwythiant BACH yn cynnwys dwy arg, y mae angen y ddwy ohonynt.

BACH(arae, k)

Ble:

• Arae - arae neu ystod o gelloedd i dynnu'r gwerth lleiaf ohonynt.
• K - an cyfanrif sy'n nodi'r safle o'r gwerth isaf i ddychwelyd, h.y. k-th lleiaf.

Mae'r swyddogaeth ar gael ym mhob fersiwn o Excel ar gyfer Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010, ac yn gynharach.

Awgrym. I ddod o hyd i k-th gwerth isaf gyda meini prawf, defnyddiwch fformiwla Excel SMALL IF.

Fformiwla sylfaenol BYCHAIN ​​yn Excel

Mae fformiwla BACH yn ei ffurf sylfaenol yn hawdd iawn i'w hadeiladu - dim ond nodi'r amrediad a'r safle o'r eitem leiaf i'w dychwelyd.

Yn y rhestr o rifau yn B2:B10, gan dybio eich bod am echdynnu'r 3ydd gwerth lleiaf. Mae'r fformiwla felsyml fel:

=SMALL(B2:B10, 3)

I'w gwneud yn haws i chi wirio'r canlyniad, mae colofn B wedi'i didoli yn nhrefn esgynnol:

4 peth y dylech wybod am swyddogaeth BACH

Bydd y nodiadau defnydd canlynol yn eich helpu i ddeall ymddygiad y ffwythiant BACH yn well ac osgoi dryswch wrth adeiladu eich fformiwlâu eich hun.

1. Unrhyw gelloedd gwag , gwerthoedd testun , a gwerthoedd rhesymegol GWIR ac ANGHYWIR yn y ddadl arae yn cael eu hanwybyddu.
2. Os <1 Mae amrywiaeth yn cynnwys un neu fwy o gwallau , dychwelir gwall.
3. Rhag ofn bod copau dyblyg yn arae , eich fformiwla gall arwain at "glymu". Er enghraifft, os yw dwy gell yn cynnwys y rhif 1, a bod y ffwythiant BACH wedi'i ffurfweddu i ddychwelyd y gwerth lleiaf a'r 2il lleiaf, fe gewch 1 yn y ddau achos.
4. A chymryd n yw nifer y gwerthoedd yn arae , bydd SMALL(arae,1) yn dychwelyd y gwerth isaf, a bydd SMALL(array,n) yn dewis y gwerth uchaf.

Sut i ddefnyddio'r swyddogaeth BACH yn Excel - enghreifftiau fformiwla

A nawr, gadewch i ni edrych ar rai enghreifftiau mwy o swyddogaeth Excel SMALL sy'n mynd y tu hwnt i'w ddefnydd sylfaenol.

Dod o hyd i werthoedd 3, 5, 10, ac ati gwaelod

Yn y tabl isod, mae'n debyg eich bod am ddod o hyd i'r 3 gwerth isaf. Ar gyfer hyn, teipiwch yrhifau 1, 2 a 3 mewn celloedd ar wahân (D3, D4 a D5 yn ein hachos ni). Yna, rhowch y fformiwla ganlynol yn E3 a'i llusgo i lawr trwy E5:

=SMALL($B$2:$B$10, D3)

Yn E3, mae'r fformiwla'n echdynnu'r gwerth lleiaf gan ddefnyddio'r rhif yn D3 ar gyfer y k dadl. Y peth allweddol yw darparu cyfeirnodau celloedd cywir y mae'r fformiwla yn eu copïo'n gywir mewn celloedd eraill: absoliwt ar gyfer arae a pherthynas ar gyfer k .

Ddim eisiau trafferthu teipio'r rhengoedd â llaw? Defnyddiwch y ffwythiant ROWS gyda chyfeirnod amrediad ehangu i ddarparu'r gwerth k . Ar gyfer hyn, rydym yn gwneud cyfeiriad absoliwt ar gyfer y gell gyntaf (neu dim ond cloi'r cyfesuryn rhes fel B$2) a chyfeiriad cymharol ar gyfer y gell olaf:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

O'r canlyniad, yr amrediad mae'r cyfeiriad yn ehangu wrth i'r fformiwla gael ei chopïo i lawr y golofn. Yn D2, mae ROWS(B$2:B2) yn cynhyrchu 1 am k , a'r fformiwla sy'n dychwelyd y gost isaf. Yn D3, mae ROWS(B$2:B3) yn rhoi 2, ac rydym yn cael yr 2il gost isaf, ac yn y blaen.

Copïwch y fformiwla trwy 5 cell, a byddwch yn cael y 5 gwerth isaf:<3

Swm gwaelod N gwerthoedd

Am ganfod cyfanswm o'r gwerthoedd n lleiaf mewn set ddata? Os ydych eisoes wedi echdynnu'r gwerthoedd fel y dangoswyd yn yr enghraifft flaenorol, yr ateb hawsaf fyddai fformiwla SUM fel:

=SUM(E3:E5)

Neu gallwch gwnewch fformiwla annibynnol gan ddefnyddio'r ffwythiant BACH ynghyd â SUMPRODUCT:

I gael swm y 3 gwerth isaf yn ein set o ddata, mae'r fformiwla yn cymryd y siâp hwn :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

Bydd y ffwythiant SUM yn cynhyrchu'r un canlyniad:

=SUM(SMALL(B2:B10, {1,2,3}))

Nodyn. Os ydych chi'n defnyddio cyfeirnodau cell yn hytrach na chysonyn arae ar gyfer k , mae angen i chi wasgu Ctrl + Shift + Enter i'w wneud yn fformiwla arae. Yn Excel 365 sy'n cefnogi araeau deinamig, mae SUM SMALL yn gweithio fel fformiwla reolaidd yn y naill achos neu'r llall.

Sut mae'r fformiwla hon yn gweithio:

Mewn fformiwla reolaidd, mae SMALL yn dychwelyd un k-th gwerth lleiaf mewn amrediad. Yn yr achos hwn, rydym yn cyflenwi cysonyn arae fel {1,2,3} ar gyfer y ddadl k, gan ei orfodi i ddychwelyd arae o'r 3 gwerth lleiaf:

{29240, 43610, 58860}

Y SUMPRODUCT neu Mae ffwythiant SUM yn adio'r rhifau yn yr arae ac yn allbynnu'r cyfanswm. Dyna ni!

MYNEGAI MATCH Fformiwla FACH i gael y paru lleiaf

Mewn sefyllfa pan fyddwch yn dymuno adfer rhywfaint o ddata sy'n gysylltiedig â'r gwerth lleiaf, defnyddiwch y cyfuniad MYNDEX MATCH clasurol gyda SMALL ar gyfer y gwerth chwilio :

Ble :

• Return_array yn ystod ar gyfer echdynnu data cysylltiedig.
• Lookup_array yn ystod lle i chwilio am yr isaf n -fed gwerth.
• N yw safle'r gwerth llog lleiaf.

Ar gyferenghraifft, i gael enw'r prosiect sydd â'r gost isaf, y fformiwla yn E3 yw:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Lle mae A2:A10 yn enwau'r prosiectau, B2:B10 yw'r costau a D3 yw'r safle o'r lleiaf.

Copïwch y fformiwla i'r celloedd isod (E4 ac E5), a chewch enwau'r 3 phrosiect rhataf:

Nodiadau:

• Mae'r datrysiad hwn yn gweithio'n iawn ar gyfer set ddata nad oes ganddi unrhyw ddyblygiadau. Fodd bynnag, gall dau neu fwy o werthoedd dyblyg mewn colofn rifol greu "cysylltiadau" yn y safle, a fydd yn arwain at ganlyniadau anghywir. Yn yr achos hwn, defnyddiwch fformiwla ychydig yn fwy soffistigedig i dorri cysylltiadau.
• Yn Excel 365, gellir cyflawni'r dasg hon gyda chymorth y swyddogaethau arae deinamig newydd. Ar wahân i fod yn llawer symlach, mae'r dull hwn yn datrys problem cysylltiadau yn awtomatig. Am fanylion llawn, gweler Sut i hidlo gwerthoedd N gwaelod yn Excel.

Trefnu rhifau o'r isaf i'r uchaf gyda fformiwla

Rwy'n credu bod pawb yn gwybod sut i roi rhifau mewn trefn gyda Nodwedd Trefnu Excel. Ond a ydych chi'n gwybod sut i berfformio didoli gyda fformiwla? Gall defnyddwyr Excel 365 ei wneud yn ffordd hawdd gyda'r swyddogaeth SORT newydd. Yn Excel 2019, 2016 a fersiynau cynharach, nid yw SORT yn gweithio, gwaetha'r modd. Ond mae gennych ychydig o ffydd, a bydd BACH yn dod i'r adwy :)

Fel yn yr enghraifft gyntaf, rydym yn defnyddio'r swyddogaeth ROWS gydag ystod ehangu cyfeiriad at gynyddiad k gan 1 ym mhob rhes lle mae'r fformiwlayn cael ei gopïo:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Rhowch y fformiwla yn y gell gyntaf, ac yna ei llusgo i lawr i gynifer o gelloedd ag sydd yn y set ddata wreiddiol (C2: C10 yn yr enghraifft hon) :

Awgrym. I ddidoli tuag i lawr , defnyddiwch y ffwythiant LARGE yn lle SMALL.

Fformiwla BACH Excel ar gyfer dyddiadau ac amseroedd

Oherwydd bod dyddiadau ac amseroedd hefyd yn werthoedd rhifol (yn y system Excel fewnol, mae dyddiadau'n cael eu storio fel rhifau dilyniannol ac amseroedd fel ffracsiynau degol), gall y ffwythiant BACH ymdrin â nhw hefyd heb unrhyw ymdrech ychwanegol ar eich ochr.

Fel y gwelwch yn y sgrinluniau isod, mae fformiwla sylfaenol a ddefnyddiwyd gennym ar gyfer rhifau yn gweithio'n hyfryd ar gyfer dyddiadau ac amseroedd hefyd:

=SMALL($B$2:$B$10, D2)

Fformiwla FACH i ddarganfod y 3 dyddiad cynharaf:

Mae'r enghraifft nesaf yn dangos sut gall y ffwythiant BACH eich helpu i gyflawni tasg fwy penodol yn ymwneud â dyddiadau.

Dod o hyd i ddyddiad blaenorol sydd agosaf at heddiw neu ddyddiad penodedig

Mewn rhestr o ddyddiadau , gan dybio eich bod am ddod o hyd i'r dyddiad agosaf cyn dyddiad penodol. Gellir gwneud hyn trwy ddefnyddio'r ffwythiant BACH ar y cyd â COUNTIF.

Gyda'r rhestr o ddyddiadau yn B2:B10 a'r dyddiad targed yn E1, bydd y fformiwla ganlynol yn dychwelyd dyddiad blaenorol sydd agosaf at y dyddiad targed:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

I dynnu dyddiad sydd ddau ddyddiad cyn y dyddiad yn E1, h.y. dyddiad blaenorol ond un, mae’ry fformiwla yw:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

I ddod o hyd i ddyddiad gorffennol agosaf at heddiw , defnyddiwch y ffwythiant HEDDIW ar gyfer meini prawf COUNTIF:<3

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

26>

Awgrym. Er mwyn atal gwallau mewn sefyllfa pan na chanfyddir dyddiad sy'n cyfateb i'ch meini prawf, gallwch lapio'r ffwythiant IFERROR o amgylch eich fformiwla, fel hyn:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

Sut mae'r fformiwlâu hyn yn gweithio:

Y syniad cyffredinol yw cyfrif nifer y dyddiadau sy'n llai na'r dyddiad targed gyda COUNTIF. A dyma'r union beth sydd ei angen ar y ffwythiant BACH ar gyfer y ddadl k .

I ddeall y cysyniad yn well, gadewch i ni edrych arno o ongl arall:

Os 1- Ymddangosodd Awst-2020 (y dyddiad targed yn E1) yn ein set ddata, hwn fyddai'r 7fed dyddiad mwyaf ar y rhestr. O ganlyniad, mae chwe dyddiad yn llai nag ef. Ystyr, y 6ed dyddiad lleiaf yw'r dyddiad blaenorol agosaf at y dyddiad targed.

Felly, yn gyntaf rydym yn cyfrifo faint o ddyddiadau sy'n llai na'r dyddiad yn E1 (y canlyniad yw 6):

COUNTIF(B2:B10, "<"&E1)

Ac wedyn, plygiwch y cyfrif i mewn i'r 2il arg o BACH:

=SMALL(B2:B10, 6)

I gael y dyddiad blaenorol ond un (sef y 5ed dyddiad lleiaf yn ein hachos ni) , rydym yn tynnu 1 o ganlyniad COUNTIF.

Sut i amlygu gwerthoedd gwaelod yn Excel

I amlygu'r gwerthoedd n lleiaf yn eich tabl gyda fformat amodol Excel, gallwch ddefnyddio naill ai Top adeiledig /Opsiwn gwaelod neu sefydlwch eich rheol eich hun yn seiliedig ar fformiwla BACH. Mae'r dull cyntaf yn gyflymachac yn haws ei gymhwyso, tra bod yr ail yn darparu mwy o reolaeth a hyblygrwydd. Bydd y camau isod yn eich arwain trwy greu rheol arferiad:

1. Dewiswch yr ystod yr ydych am amlygu gwerthoedd gwaelod ynddi. Yn ein hachos ni, mae'r niferoedd yn B2: B10, felly rydyn ni'n ei ddewis. Os hoffech chi amlygu rhesi cyfan, yna dewiswch A2:B10.
2. Ar y tab Cartref , yn y grŵp Styles , cliciwch Fformatio amodol > Rheol Newydd .
3. Yn y blwch deialog Rheol Fformatio Newydd , dewiswch Defnyddiwch fformiwla i benderfynu pa gelloedd i'w fformatio.<2
4. Yn y blwch Fformat gwerthoedd lle mae'r fformiwla hon yn wir , rhowch fformiwla fel yr un yma:

   =B2<=SMALL($B$2:$B$10, 3)

   Ble B2 yw cell mwyaf chwith y rhifolyn amrediad i'w wirio, $B$2:$B$10 yw'r amrediad cyfan, a 3 yw'r gwerthoedd gwaelod n i'w hamlygu.

   Yn eich fformiwla, cofiwch y mathau o gyfeirnod: y Mae'r gell fwyaf chwith yn gyfeirnod cymharol (B2) a'r amrediad yw'r cyfeirnod absoliwt ($B$2:$B$10).

5. Cliciwch y botwm Fformat a dewiswch unrhyw fformat yr hoffech.
6. Cliciwch Iawn ddwywaith i gau'r ddwy ffenestr ymgom.

Wedi'i wneud! Mae'r 3 gwerth isaf yng ngholofn B wedi'u hamlygu:

Am ragor o wybodaeth, gweler Excel fformatio amodol yn seiliedig ar fformiwla.

Excel BACH swyddogaeth ddim yn gweithio

Fel yr ydych newydd weld o'n henghreifftiau, mae defnyddio'r swyddogaeth BACH yn Excel yn eithaf hawdd, ac rydych ynannhebygol o gael unrhyw anawsterau ag ef. Os nad yw'ch fformiwla'n gweithio, mae'n debyg mai #NUM fydd hwnnw! gwall, a all ddigwydd oherwydd y rhesymau canlynol:

• Arae yn wag neu nid yw'n cynnwys un gwerth rhifol.
• Y k gwerth yn llai na sero (gall teipio gwirion gostio oriau i chi o ddatrys problemau!) neu'n fwy na nifer y gwerthoedd yn yr arae.

Dyna sut i ddefnyddio fformiwla BACH yn Excel i ddarganfod a amlygu niferoedd gwaelod mewn set o ddata. Os ydych chi'n gwybod am unrhyw senarios eraill lle mae'r swyddogaeth yn ddefnyddiol, mae croeso mawr i chi rannu sylwadau. Diolch i chi am ddarllen a gobeithio eich gweld ar ein blog wythnos nesaf!

Gweithlyfr ymarfer i'w lawrlwytho

Enghreifftiau fformiwla Excel BACH (ffeil .xlsx)