Bu qısa dərslikdə biz Excel KÜÇÜK funksiyası, onun necə işlədiyi və N-ci ən kiçik rəqəmi, tarixi və ya vaxtı tapmaq üçün ondan necə istifadə etmək haqqında danışacağıq.

Ehtiyac var. iş vərəqində bir neçə ən aşağı rəqəmi tapmaq üçün? Excel Sort xüsusiyyəti ilə bunu etmək olduqca asandır. Hər dəyişikliklə məlumatlarınızı yenidən çeşidləmək üçün vaxt itirmək istəmirsiniz? SMALL funksiyası sizə ən aşağı dəyəri, ikinci ən kiçik, üçüncü ən kiçik və s. cəld tapmağa kömək edəcək.

Excel SMALL funksiyası

SMALL qaytaran statistik funksiyadır. verilənlər dəstindəki n-ci ən kiçik dəyər.

KİÇƏK funksiyasının sintaksisi iki arqumenti ehtiva edir, hər ikisi də tələb olunur.

SMALL(massiv, k)

Burada:

• Masiv - ən kiçik dəyərin çıxarılması üçün massiv və ya xanalar diapazonu.
• K - an qaytarılacaq ən aşağı dəyərdən mövqeyi göstərən tam ədəd, yəni k-ci ən kiçik.

Funksiya Office 365, Excel 2021, Excel 2019, Excel 2016, Excel üçün Excel-in bütün versiyalarında mövcuddur. 2013, Excel 2010 və daha əvvəllər.

İpucu. Kriteriyalarla k-ci ən aşağı dəyəri tapmaq üçün Excel KÜÇÜK ƏGƏR düsturundan istifadə edin.

Excel-də əsas KİÇİK düsturu

Əsas formada KİÇİK düsturu qurmaq çox asandır - sadəcə olaraq siz diapazon və qaytarılacaq ən kiçik elementdən mövqe.

B2:B10-dakı rəqəmlər siyahısında, 3-cü ən kiçik dəyəri çıxarmaq istədiyinizi fərz edin. Formula belədirsadədir:

=SMALL(B2:B10, 3)

Nəticəni yoxlamağı asanlaşdırmaq üçün B sütunu artan qaydada sıralanır:

SMALL funksiyası haqqında bilməli olduğunuz 4 şey

Aşağıdakı istifadə qeydləri SMALL funksiyasının davranışını daha yaxşı başa düşməyə və öz düsturlarınızı qurarkən çaşqınlığın qarşısını almağa kömək edəcək.

1. İstənilən boş xanalar , mətn dəyərləri və massiv arqumentində məntiqi dəyərlər TRUE və FALSE nəzərə alınmır.
2. Əgər massiv bir və ya daha çox səhv ehtiva edir, xəta qaytarılır.
3. massiv -də dublikat olduqda, düsturunuz “bağları” ilə nəticələnə bilər. Məsələn, əgər iki xanada 1 rəqəmi varsa və KÖÇÜK funksiyası ən kiçik və 2-ci ən kiçik dəyəri qaytarmaq üçün konfiqurasiya edilibsə, hər iki halda siz 1 alacaqsınız.
4. Fərz etsək ki, n <-dəki dəyərlərin sayıdır. 1>massiv , SMALL(massiv,1) ən aşağı dəyəri qaytaracaq və SMALL(massiv,n) isə ən yüksək dəyəri seçəcək.

Excel-də SMALL funksiyasından necə istifadə etmək olar - düstur nümunələri

İndi isə Excel SMALL funksiyasının əsas istifadəsindən kənara çıxan daha bir neçə nümunəyə baxaq.

Alt 3, 5, 10 və s. dəyərləri tapın

Artıq bildiyiniz kimi, SMALL funksiyası n-ci ən aşağı dəyəri hesablamaq üçün nəzərdə tutulmuşdur. Bu misal bunu ən effektiv şəkildə necə edəcəyinizi göstərir.

Aşağıdakı cədvəldə tutaq ki, siz aşağı 3 dəyəri tapmaq istəyirsiniz. Bunun üçün yazınayrı xanalarda 1, 2 və 3 nömrələri (bizim vəziyyətimizdə D3, D4 və D5). Sonra E3-ə aşağıdakı düsturu daxil edin və onu E5-ə qədər aşağı sürükləyin:

=SMALL($B$2:$B$10, D3)

E3-də düstur k<2 üçün D3-dəki rəqəmdən istifadə edərək ən kiçik dəyəri çıxarır> arqument. Əsas odur ki, düsturun digər xanalarda düzgün surətdə kopyalanması üçün lazımi xana istinadlarını təmin etməkdir: massiv üçün mütləq və k üçün nisbi.

Rütbələri əl ilə yazmaqla narahat olmaq istəmirsiniz? k dəyərini təmin etmək üçün genişlənən diapazon istinadı ilə SATIR funksiyasından istifadə edin. Bunun üçün biz birinci xana üçün mütləq istinad edirik (və ya yalnız B$2 kimi sıra koordinatını kilidləyirik) və sonuncu xana üçün nisbi istinad edirik:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Nəticədə diapazon düstur sütuna köçürüldükcə istinad genişlənir. D2-də ROWS(B$2:B2) k üçün 1 yaradır və düstur ən aşağı qiyməti qaytarır. D3-də ROWS(B$2:B3) 2 verir və biz 2-ci ən aşağı qiyməti əldə edirik və s>

Aşağı N dəyərləri cəmləyin

Data dəstində ən kiçik n dəyərin cəmini tapmaq istəyirsiniz? Əvvəlki nümunədə göstərildiyi kimi dəyərləri artıq çıxarmısınızsa, ən asan həlli SUM düsturudur:

=SUM(E3:E5)

Və ya edə bilərsiniz SUMPRODUCT:

Məlumat dəstimizdə ən aşağı 3 dəyərin cəmini əldə etmək üçün düstur bu formanı alır :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

SUM funksiyası eyni nəticəni verəcək:

=SUM(SMALL(B2:B10, {1,2,3}))

Qeyd. Əgər k üçün massiv sabiti əvəzinə xana istinadları istifadə edirsinizsə, onu massiv düsturuna çevirmək üçün Ctrl + Shift + Enter düymələrini sıxmalısınız. Dinamik massivləri dəstəkləyən Excel 365-də SUM SMALL hər iki halda adi düstur kimi işləyir.

Bu düstur necə işləyir:

Adi düsturda SMALL diapazonda tək k-ci ən kiçik dəyəri qaytarır. Bu halda, biz k arqumenti üçün {1,2,3} kimi massiv sabitini veririk və onu ən kiçik 3 qiymətdən ibarət massivi qaytarmağa məcbur edirik:

{29240, 43610, 58860}

QÜMƏT və ya SUM funksiyası massivdəki ədədləri toplayır və cəmini çıxarır. Budur!

Ən kiçik uyğunluqları əldə etmək üçün INDEX MATCH SMALL düsturu

Ən kiçik dəyərlə əlaqəli bəzi məlumatları əldə etmək istədiyiniz halda, axtarış dəyəri üçün KİÇİ ilə klassik INDEX MATCH kombinasiyasından istifadə edin. :

Harada :

• Qayıt_massiv əlaqəli verilənlərin çıxarılması üçün diapazondur.
• Axtarış_massivi ən aşağı n-nin axtarılacağı diapazondur. -ci dəyər.
• N faizin ən kiçik dəyərinin mövqeyidir.

Üçünməsələn, ən aşağı qiymətə malik olan layihənin adını almaq üçün E3-də düstur belədir:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

A2:A10 layihə adları, B2:B10 xərclər və D3 ən kiçikdən tutmuş dərəcədir.

Düsulu aşağıdakı xanalara köçürün (E4 və E5) və siz 3 ən ucuz layihənin adını əldə edəcəksiniz:

Qeydlər:

• Bu həll dublikatı olmayan verilənlər toplusu üçün yaxşı işləyir. Bununla belə, ədədi sütunda iki və ya daha çox dublikat dəyər sıralamada "bağlar" yarada bilər ki, bu da yanlış nəticələrə gətirib çıxarır. Bu halda, əlaqəni kəsmək üçün bir az daha mürəkkəb düsturdan istifadə edin.
• Excel 365-də bu tapşırığı yeni dinamik massiv funksiyalarının köməyi ilə yerinə yetirmək olar. Çox sadə olmaqla yanaşı, bu yanaşma avtomatik olaraq qalstuk problemini həll edir. Tam təfərrüatlar üçün lütfən, Excel-də aşağı N dəyərlərini necə süzgəcdən keçirməyə baxın.

Düsturla ədədləri aşağıdan yuxarıya doğru çeşidləyin

İnanıram ki, hər kəs nömrələri necə sıralamağı bilir. Excel Sort xüsusiyyəti. Bəs düsturla çeşidləmənin necə aparılacağını bilirsinizmi? Excel 365 istifadəçiləri bunu yeni SORT funksiyası ilə asan şəkildə edə bilərlər. Excel 2019, 2016 və əvvəlki versiyalarda SORT, təəssüf ki, işləmir. Ancaq bir az inanın, KİÇƏK kömək edəcək :)

Birinci misalda olduğu kimi, biz hər dəfə k -ni 1-ə artırmaq üçün genişlənən diapazonlu SATIRLAR funksiyasından istifadə edirik. düsturun olduğu sırakopyalanır:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Düsulu birinci xanaya daxil edin və sonra onu orijinal məlumat dəstində dəyərlər olduğu qədər xanaya sürükləyin (bu nümunədə C2:C10) :

İpucu. azalan -u çeşidləmək üçün KİÇİ əvəzinə BÖYÜK funksiyasından istifadə edin.

Tarixlər və vaxtlar üçün Excel KÜÇÜK düsturu

Tarixlər və vaxtlar həm də rəqəmli dəyərlər olduğundan (daxili Excel sistemində tarixlər ardıcıl ədədlər və vaxtlar onluq kəsrlər kimi saxlanılır), SMALL funksiyası onları idarə edə bilər. həmçinin sizin tərəfinizdən heç bir əlavə səy göstərmədən.

Aşağıdakı ekran görüntülərində gördüyünüz kimi, rəqəmlər üçün istifadə etdiyimiz əsas düstur tarixlər və vaxtlar üçün də gözəl işləyir:

=SMALL($B$2:$B$10, D2)

Ən erkən 3 tarixi tapmaq üçün KİÇİ düstur:

Ən qısa 3 dəfə əldə etmək üçün KİÇİ düstur:

Növbəti nümunə SMALL funksiyasının tarixlərlə bağlı daha konkret tapşırığı yerinə yetirməkdə sizə necə kömək edə biləcəyini göstərir.

Bu günə və ya müəyyən edilmiş tarixə ən yaxın olan əvvəlki tarixi tapın

Tarixlər siyahısında , fərz edək ki, müəyyən bir tarixdən əvvəl ən yaxın tarixi tapmaq istəyirsiniz. Bunu COUNTIF ilə birlikdə SMALL funksiyasından istifadə etməklə etmək olar.

B2:B10-da tarixlər siyahısı və E1-də hədəf tarixlə aşağıdakı düstur hədəf tarixə ən yaxın olan əvvəlki tarixi qaytaracaq:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

E1-dəki tarixdən iki tarix əvvəl olan tarixi, yəni əvvəlki, lakin bir tarix çıxarmaq üçündüstur:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

Keçmiş tarixi tapmaq üçün bu günə ən yaxın , COUNTIF meyarları üçün TODAY funksiyasından istifadə edin:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

İpucu. Kriteriyalarınıza uyğun gələn tarix tapılmadıqda səhvlərin qarşısını almaq üçün IFERROR funksiyasını düsturunuzun ətrafına bu şəkildə bağlaya bilərsiniz:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

Bu düsturlar necə işləyir:

Ümumi fikir COUNTIF ilə hədəf tarixdən kiçik tarixlərin sayını hesablamaqdır. Və bu sayma məhz k arqumenti üçün SMALL funksiyasının ehtiyac duyduğu şeydir.

Konsepti daha yaxşı başa düşmək üçün ona başqa bucaqdan baxaq:

Əgər 1- Avqust-2020 (E1-də hədəf tarix) verilənlər bazamızda göründü, bu siyahıda 7-ci ən böyük tarix olardı. Deməli, ondan kiçik altı xurma var. Yəni, 6-cı ən kiçik tarix hədəf tarixə ən yaxın olan əvvəlki tarixdir.

Beləliklə, əvvəlcə E1-dəki tarixdən neçə tarixin kiçik olduğunu hesablayırıq (nəticə 6-dır):

COUNTIF(B2:B10, "<"&E1)

Və sonra, SMALL-ın 2-ci arqumentinə sayı əlavə edin:

=SMALL(B2:B10, 6)

Əvvəlki, lakin bir tarixi əldə etmək üçün (bizim vəziyyətimizdə bu, 5-ci ən kiçik tarixdir) , biz COUNTIF-in nəticəsindən 1 çıxırıq.

Excel-də aşağı dəyərləri necə vurğulamaq olar

Cədvəlinizdə Excel şərti formatı ilə ən kiçik n dəyəri vurğulamaq üçün ya daxili yuxarıdan istifadə edə bilərsiniz. /Aşağı seçim və ya KİÇİK düstur əsasında öz qaydanızı qurun. Birinci üsul daha sürətlidirvə tətbiqi daha asan, ikincisi isə daha çox nəzarət və çeviklik təmin edir. Aşağıdakı addımlar sizə fərdi qayda yaratmağa kömək edəcək:

1. Aşağıdakı dəyərləri vurğulamaq istədiyiniz diapazonu seçin. Bizim vəziyyətimizdə rəqəmlər B2:B10-dadır, ona görə də onu seçirik. Bütün sətirləri vurğulamaq istəyirsinizsə, A2:B10 seçin.
2. Ev tabında, Üslublar qrupunda Şərti formatlaşdırma üzərinə klikləyin. > Yeni Qayda .
3. Yeni Formatlaşdırma Qaydası dialoq qutusunda Hansı xanaların formatlanacağını müəyyən etmək üçün düsturdan istifadə edin.
4. Bu düsturun doğru olduğu dəyərləri formatla xanasına belə bir düstur daxil edin:

   =B2<=SMALL($B$2:$B$10, 3)

   Burada B2 rəqəmin ən sol xanasıdır yoxlanılacaq diapazon, $B$2:$B$10 bütün diapazon, 3 isə vurğulanacaq n aşağı dəyərlərdir.

   Düsturunuzda istinad növlərinə diqqət yetirin: ən soldakı xana nisbi istinaddır (B2), diapazon isə mütləq istinaddır ($B$2:$B$10).

5. Format düyməsini klikləyin və istədiyiniz formatı seçin.
6. Hər iki dialoq pəncərəsini bağlamaq üçün OK düyməsini iki dəfə klikləyin.

Bitdi! B sütununda aşağı 3 dəyər vurğulanır:

Ətraflı məlumat üçün düstura əsaslanan Excel şərti formatına baxın.

Excel SMALL funksiyası işləmir

Nümunələrimizdən gördüyünüz kimi, Excel-də KİÇƏK funksiyasından istifadə etmək olduqca asandır və sizçətin ki, bununla bağlı çətinlik yaransın. Düsturunuz işləmirsə, çox güman ki, bu #NUM olacaq! aşağıdakı səbəblərdən yarana bilən xəta:

• Massiv boşdur və ya tək ədədi dəyərdən ibarət deyil.
• k dəyəri sıfırdan azdır (ağılsız hərf xətası sizə problemlərin aradan qaldırılması saatlarına başa gələ bilər!) və ya massivdəki dəyərlərin sayını aşır.

Bu, tapmaq və tapmaq üçün Excel-də KİÇİ düsturdan istifadə etməkdir. verilənlər toplusunda aşağı nömrələri vurğulayın. Funksiyanın faydalı olduğu hər hansı digər ssenariləri bilirsinizsə, şərhlərdə paylaşmağınız çox xoşdur. Oxuduğunuz üçün sizə təşəkkür edirəm və sizi gələn həftə bloqumuzda görməyə ümid edirəm!

Endirmək üçün məşq iş dəftəri

Excel KİÇİK düstur nümunələri (.xlsx faylı)