En aquest breu tutorial, parlarem de la funció SMALL d'Excel, de com funciona i de com utilitzar-la per trobar el nombre, la data o l'hora més petit enèsimo.

Necessitat. per trobar uns quants nombres més baixos en un full de treball? Això és bastant fàcil de fer amb la funció d'ordenació d'Excel. No voleu perdre el temps reordenant les vostres dades amb cada canvi? La funció SMALL us ajudarà a trobar ràpidament el valor més baix, el segon més petit, el tercer més petit, etc.

La funció SMALL d'Excel

SMALL és una funció estadística que retorna l'enèsimo valor més petit d'un conjunt de dades.

La sintaxi de la funció SMALL inclou dos arguments, tots dos obligatoris.

SMALL(array, k)

On:

• Matriu : una matriu o un rang de cel·les des d'on extreure el valor més petit.
• K - un enter que indica la posició del valor més baix a retornar, és a dir, k-è més petit.

La funció està disponible a totes les versions d'Excel per a Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010 i anteriors.

Consell. Per trobar el k-èsimo valor més baix amb criteris, utilitzeu la fórmula SMALL IF d'Excel.

Fórmula SMALL bàsica a Excel

Una fórmula SMALL en la seva forma bàsica és molt fàcil de crear; només cal que especifiqueu la rang i la posició de l'element més petit a retornar.

A la llista de nombres de B2:B10, suposant que voleu extreure el tercer valor més petit. La fórmula és comsenzill com:

=SMALL(B2:B10, 3)

Per facilitar-vos la comprovació del resultat, la columna B s'ordena en ordre ascendent:

4 coses que hauríeu de saber sobre la funció SMALL

Les notes d'ús següents us ajudaran a entendre millor el comportament de la funció SMALL i evitaran confusions a l'hora de crear les vostres pròpies fórmules.

1. Qualsevol <9 Les>cel·les en blanc , els valors text i els valors lògics TRUE i FALSE a l'argument matriu s'ignoren.
2. Si matriu conté un o més errors , es retorna un error.
3. En cas que hi hagi duplicats a matriu , la vostra fórmula pot donar lloc a "llaços". Per exemple, si dues cel·les contenen el número 1 i la funció SMALL està configurada per retornar el valor més petit i el segon més petit, obtindreu 1 en tots dos casos.
4. Suposant que n és el nombre de valors a array , SMALL(array,1) retornarà el valor més baix i SMALL(array,n) triarà el valor més alt.

Com utilitzar la funció SMALL a Excel - exemples de fórmules

I ara, mirem alguns exemples més de la funció SMALL d'Excel que van més enllà del seu ús bàsic.

Cerca els valors inferiors 3, 5, 10, etc.

Com ja sabeu, la funció SMALL està dissenyada per calcular l'enèsimo valor més baix. Aquest exemple mostra com fer-ho de la manera més eficaç.

A la taula següent, suposem que voleu trobar els 3 valors inferiors. Per a això, escriviu elels números 1, 2 i 3 en cel·les separades (D3, D4 i D5 en el nostre cas). A continuació, introduïu la fórmula següent a E3 i arrossegueu-la cap avall per E5:

=SMALL($B$2:$B$10, D3)

A E3, la fórmula extreu el valor més petit utilitzant el nombre de D3 per a k argument. La clau és proporcionar les referències de cel·les adequades perquè la fórmula es copie correctament en altres cel·les: absolut per a matriu i relatiu per a k .

No voleu molestar-vos a escriure les classificacions manualment? Utilitzeu la funció ROWS amb una referència interval expansible per proporcionar el valor k . Per a això, fem una referència absoluta per a la primera cel·la (o només bloquegem la coordenada de la fila com B$2) i una referència relativa per a l'última cel·la:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Com a resultat, l'interval la referència s'expandeix a mesura que la fórmula es copia a la columna. A D2, ROWS(B$2:B2) produeix 1 per a k i la fórmula retorna el cost més baix. A D3, ROWS(B$2:B3) n'obté 2 i obtenim el segon cost més baix, i així successivament.

Copieu la fórmula a través de 5 cel·les i obtindreu els 5 valors inferiors:

Suma els N valors inferiors

Vols trobar un total dels n valors més petits d'un conjunt de dades? Si ja heu extret els valors com es mostra a l'exemple anterior, la solució més senzilla seria una fórmula SUMA com:

=SUM(E3:E5)

O podeu feu una fórmula independent utilitzant la funció SMALL juntament amb SUMPRODUCT:

Per obtenir la suma dels 3 valors inferiors del nostre conjunt de dades, la fórmula pren aquesta forma :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

La funció SUMA produirà el mateix resultat:

=SUM(SMALL(B2:B10, {1,2,3}))

Nota. Si utilitzeu referències de cel·les en lloc de la constant de matriu per a k , heu de prémer Ctrl + Maj + Retorn per convertir-la en una fórmula de matriu. A Excel 365 que admet matrius dinàmiques, SUM SMALL funciona com una fórmula normal en tots dos casos.

Com funciona aquesta fórmula:

En una fórmula normal, SMALL retorna un sol k-èsimo valor més petit d'un interval. En aquest cas, proporcionem una constant de matriu com {1,2,3} per a l'argument k, forçant-lo a retornar una matriu dels 3 valors més petits:

{29240, 43610, 58860}

El PRODUCTE SUMA o La funció SUMA suma els números de la matriu i dóna el total. Això és tot!

Fórmula INDEX MATCH SMALL per obtenir coincidències més petites

En cas que vulgueu recuperar algunes dades associades amb el valor més petit, utilitzeu la clàssica combinació INDEX MATCH amb SMALL per al valor de cerca :

On :

• Return_array és un interval des del qual s'extreuen les dades associades.
• Lookup_array és un interval on cercar la n més baixa -è valor.
• N és la posició del valor d'interès més petit.

Per aPer exemple, per obtenir el nom del projecte que té el cost més baix, la fórmula a E3 és:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

On A2:A10 són els noms del projecte, B2:B10 són els costos i D3 és el rang del més petit.

Copieu la fórmula a les cel·les següents (E4 i E5) i obtindreu els noms dels 3 projectes més barats:

Notes:

• Aquesta solució funciona bé per a un conjunt de dades que no té duplicats. No obstant això, dos o més valors duplicats en una columna numèrica poden crear "vincles" en la classificació, cosa que donarà lloc a resultats incorrectes. En aquest cas, utilitzeu una fórmula una mica més sofisticada per trencar llaços.
• A Excel 365, aquesta tasca es pot fer amb l'ajuda de les noves funcions de matriu dinàmica. A part de ser molt més senzill, aquest enfocament resol automàticament el problema dels llaços. Per obtenir-ne tots els detalls, vegeu Com filtrar els valors N inferiors a Excel.

Ordeneu els números de més baix a més alt amb una fórmula

Crec que tothom sap com ordenar els números amb Funció d'ordenació d'Excel. Però, saps com fer l'ordenació amb una fórmula? Els usuaris d'Excel 365 ho poden fer d'una manera fàcil amb la nova funció SORT. A Excel 2019, 2016 i versions anteriors, SORT no funciona, per desgràcia. Però tingueu una mica de fe i SMALL vindrà al rescat :)

Com en el primer exemple, utilitzem la funció ROWS amb una referència d'interval d'expansió per incrementar k en 1 a cada fila on la fórmulaes copia:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Introduïu la fórmula a la primera cel·la i arrossegueu-la cap avall fins a tantes cel·les com valors hi hagi al conjunt de dades original (C2:C10 en aquest exemple) :

Consell. Per ordenar decreixent , utilitzeu la funció GRAN en comptes de PETIT.

Fórmula SMALL d'Excel per a dates i hores

Com que les dates i les hores també són valors numèrics (al sistema Excel intern, les dates s'emmagatzemen com a nombres seqüencials i les hores com a fraccions decimals), la funció SMALL pot gestionar-les. també sense cap esforç addicional del vostre costat.

Com podeu veure a les captures de pantalla següents, una fórmula bàsica que hem utilitzat per als números també funciona molt bé per a dates i hores:

=SMALL($B$2:$B$10, D2)

Fórmula PETITA per trobar les 3 dates més primerenques:

Fórmula PETITA per obtenir les 3 vegades més curtes:

L'exemple següent mostra com la funció SMALL us pot ajudar a realitzar una tasca més específica relacionada amb les dates.

Cerqueu una data anterior més propera a la d'avui o a la data especificada

En una llista de dates , suposant que voleu trobar la data més propera abans d'una data especificada. Això es pot fer utilitzant la funció SMALL en combinació amb COUNTIF.

Amb la llista de dates a B2:B10 i la data objectiu a E1, la fórmula següent retornarà la data anterior més propera a la data objectiu:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

Per extreure una data que és dues dates abans de la data de E1, és a dir, una data anterior però una, elLa fórmula és:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

Per trobar una data passada més propera a l'avui , utilitzeu la funció AVUI per als criteris de COUNTIF:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

Consell. Per evitar errors en la situació en què no es trobi una data que coincideixi amb els vostres criteris, podeu embolicar la funció IFERROR al voltant de la vostra fórmula, com aquesta:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

Com funcionen aquestes fórmules:

La idea general és comptar el nombre de dates més petit que la data objectiu amb COUNTIF. I aquest recompte és exactament el que necessita la funció SMALL per a l'argument k .

Per comprendre millor el concepte, mirem-lo des d'un altre angle:

Si 1- Agost de 2020 (la data objectiu a l'E1) va aparèixer al nostre conjunt de dades, seria la setena data més important de la llista. En conseqüència, hi ha sis dates més petites que ella. És a dir, la sisena data més petita és la data anterior més propera a la data objectiu.

Per tant, primer calculem quantes dates són més petites que la data a E1 (el resultat és 6):

COUNTIF(B2:B10, "<"&E1)

A continuació, connecteu el recompte al segon argument de SMALL:

=SMALL(B2:B10, 6)

Per obtenir l'anterior però una data (que és la cinquena data més petita en el nostre cas) , restem 1 del resultat de COUNTIF.

Com ressaltar els valors inferiors a Excel

Per ressaltar els n valors més petits de la vostra taula amb el format condicional d'Excel, podeu utilitzar una part superior integrada / Opció inferior o configureu la vostra pròpia regla basada en una fórmula PETITA. El primer mètode és més ràpidi més fàcil d'aplicar, mentre que el segon proporciona més control i flexibilitat. Els passos següents us guiaran per crear una regla personalitzada:

1. Seleccioneu l'interval en què voleu ressaltar els valors inferiors. En el nostre cas, els números estan en B2:B10, així que el seleccionem. Si voleu ressaltar files senceres, seleccioneu A2:B10.
2. A la pestanya Inici , al grup Estils , feu clic a Format condicional. > Nova regla .
3. Al quadre de diàleg Nova regla de format , trieu Utilitza una fórmula per determinar quines cel·les voleu donar format.
4. Al quadre Format dels valors on aquesta fórmula és certa , introduïu una fórmula com aquesta:

   =B2<=SMALL($B$2:$B$10, 3)

   On B2 és la cel·la més a l'esquerra del numèric l'interval que cal comprovar, $B$2:$B$10 és tot l'interval i 3 són els n valors inferiors a ressaltar.

   A la vostra fórmula, tingueu en compte els tipus de referència: el La cel·la més a l'esquerra és una referència relativa (B2) mentre que l'interval és la referència absoluta ($B$2:$B$10).

5. Feu clic al botó Format i trieu el format que vulgueu.
6. Feu clic a D'acord dues vegades per tancar les dues finestres de diàleg.

Fet! Els 3 valors inferiors de la columna B es destaquen:

Per obtenir més informació, vegeu Format condicional d'Excel basat en la fórmula.

La funció Excel SMALL no funciona

Com acabeu de veure en els nostres exemples, utilitzar la funció SMALL a Excel és bastant fàcil i jaés poc probable que tingui cap dificultat amb això. Si la vostra fórmula no funciona, el més probable és que sigui un #NUM! error, que es pot produir pels motius següents:

• La matriu està buida o no conté un sol valor numèric.
• El k és inferior a zero (una errada d'ortografia et pot costar hores de resolució de problemes!) o supera el nombre de valors de la matriu.

Així és com s'utilitza una fórmula PETITA a Excel per trobar i ressalteu els números inferiors en un conjunt de dades. Si coneixeu altres escenaris en què la funció us sigui útil, us convidem a compartir-ho als comentaris. Us agraeixo la lectura i esperem veure-us al nostre bloc la setmana vinent!

Quader de pràctiques per descarregar

Excels de fórmules SMALL d'Excel (fitxer .xlsx)