Dalam tutorial ringkas ini, kita akan bercakap tentang fungsi Excel SMALL, cara ia berfungsi dan cara menggunakannya untuk mencari nombor, tarikh atau masa terkecil ke-N.

Perlu untuk mencari beberapa nombor terendah dalam lembaran kerja? Ini agak mudah dilakukan dengan ciri Excel Sort. Tidak mahu membuang masa untuk menyusun semula data anda dengan setiap perubahan? Fungsi SMALL akan membantu anda mencari nilai terendah dengan cepat, kedua terkecil, ketiga terkecil dan seterusnya.

Fungsi Excel SMALL

SMALL ialah fungsi statistik yang mengembalikan nilai terkecil ke-n dalam set data.

Sintaks fungsi SMALL termasuk dua argumen, kedua-duanya diperlukan.

SMALL(array, k)

Di mana:

• Array - tatasusunan atau julat sel untuk mengekstrak nilai terkecil.
• K - satu integer yang menunjukkan kedudukan daripada nilai terendah untuk dikembalikan, iaitu ke-k terkecil.

Fungsi ini tersedia dalam semua versi Excel untuk Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010 dan lebih awal.

Petua. Untuk mencari nilai terendah ke-k dengan kriteria, gunakan formula Excel SMALL IF.

Formula KECIL asas dalam Excel

Formula KECIL dalam bentuk asasnya sangat mudah untuk dibina - anda hanya tentukan julat dan kedudukan daripada item terkecil untuk dikembalikan.

Dalam senarai nombor dalam B2:B10, andaikan anda ingin mengekstrak nilai terkecil ke-3. Formulanya adalah sebagaimudah seperti:

=SMALL(B2:B10, 3)

Untuk memudahkan anda menyemak keputusan, lajur B diisih mengikut tertib menaik:

4 perkara yang perlu anda ketahui tentang fungsi KECIL

Nota penggunaan berikut akan membantu anda memahami dengan lebih baik gelagat fungsi KECIL dan mengelakkan kekeliruan semasa membina formula anda sendiri.

1. Mana-mana sel kosong , nilai teks dan nilai logik TRUE dan FALSE dalam argumen array diabaikan.
2. Jika array mengandungi satu atau lebih ralat , ralat dikembalikan.
3. Sekiranya terdapat pendua dalam array , formula anda boleh mengakibatkan "ikatan". Sebagai contoh, jika dua sel mengandungi nombor 1, dan fungsi SMALL dikonfigurasikan untuk mengembalikan nilai terkecil dan ke-2 terkecil, anda akan mendapat 1 dalam kedua-dua kes.
4. Dengan mengandaikan n ialah bilangan nilai dalam array , SMALL(array,1) akan mengembalikan nilai terendah dan SMALL(array,n) akan memilih nilai tertinggi.

Cara menggunakan fungsi SMALL dalam Excel - contoh formula

Dan sekarang, mari kita lihat beberapa lagi contoh fungsi Excel SMALL yang melangkaui penggunaan asasnya.

Cari nilai bawah 3, 5, 10, dsb.

Seperti yang anda sedia maklum, fungsi SMALL direka untuk mengira nilai terendah ke-n. Contoh ini menunjukkan cara untuk melakukan ini dengan paling berkesan.

Dalam jadual di bawah, katakan anda ingin mencari 3 nilai terbawah. Untuk ini, taipkannombor 1, 2 dan 3 dalam sel berasingan (D3, D4 dan D5 dalam kes kami). Kemudian, masukkan formula berikut dalam E3 dan seret ke bawah melalui E5:

=SMALL($B$2:$B$10, D3)

Dalam E3, formula mengekstrak nilai terkecil menggunakan nombor dalam D3 untuk k hujah. Perkara utama ialah membekalkan rujukan sel yang betul kerana formula itu disalin dengan betul dalam sel lain: mutlak untuk tatasusunan dan relatif untuk k .

Tidak mahu bersusah payah menaip pangkat secara manual? Gunakan fungsi ROWS dengan rujukan mengembangkan julat untuk memberikan nilai k . Untuk ini, kami membuat rujukan mutlak untuk sel pertama (atau hanya mengunci koordinat baris seperti B$2) dan rujukan relatif untuk sel terakhir:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Hasilnya, julat rujukan mengembang apabila formula disalin ke bawah lajur. Dalam D2, ROWS(B$2:B2) menghasilkan 1 untuk k dan formula mengembalikan kos terendah. Dalam D3, ROWS(B$2:B3) menghasilkan 2, dan kami mendapat kos ke-2 terendah, dan seterusnya.

Hanya salin formula melalui 5 sel, dan anda akan mendapat 5 nilai terbawah:

Jumlah nilai N bawah

Ingin mencari jumlah nilai n terkecil dalam set data? Jika anda telah mengekstrak nilai seperti yang ditunjukkan dalam contoh sebelumnya, penyelesaian paling mudah ialah formula SUM seperti:

=SUM(E3:E5)

Atau anda boleh buat formula bebas dengan menggunakan fungsi SMALL bersama-sama dengan SUMPRODUCT:

Untuk mendapatkan jumlah 3 nilai terbawah dalam set data kami, formula mengambil bentuk ini :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

Fungsi SUM akan menghasilkan hasil yang sama:

=SUM(SMALL(B2:B10, {1,2,3}))

Nota. Jika anda menggunakan rujukan sel dan bukannya pemalar tatasusunan untuk k , anda perlu menekan Ctrl + Shift + Enter untuk menjadikannya formula tatasusunan. Dalam Excel 365 yang menyokong tatasusunan dinamik, SUM SMALL berfungsi sebagai formula biasa dalam mana-mana kes.

Cara formula ini berfungsi:

Dalam formula biasa, SMALL mengembalikan satu k-th nilai terkecil dalam julat. Dalam kes ini, kami membekalkan pemalar tatasusunan seperti {1,2,3} untuk hujah k, memaksanya untuk mengembalikan tatasusunan 3 nilai terkecil:

{29240, 43610, 58860}

SUMPRODUCT atau Fungsi SUM menjumlahkan nombor dalam tatasusunan dan mengeluarkan jumlahnya. Itu sahaja!

Formula KECIL PADANAN INDEX untuk mendapatkan padanan terkecil

Dalam situasi apabila anda ingin mendapatkan semula beberapa data yang dikaitkan dengan nilai terkecil, gunakan kombinasi PADAN INDEX klasik dengan KECIL untuk nilai carian :

Di mana :

• Return_array ialah julat untuk mengekstrak data yang berkaitan.
• Lookup_array ialah julat untuk mencari n terendah -nilai ke-.
• N ialah kedudukan nilai faedah terkecil.

Untukcontoh, untuk mendapatkan nama projek yang mempunyai kos terendah, formula dalam E3 ialah:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Di mana A2:A10 ialah nama projek, B2:B10 ialah kos dan D3 ialah pangkat dari terkecil.

Salin formula ke sel di bawah (E4 dan E5), dan anda akan mendapat nama 3 projek termurah:

Nota:

• Penyelesaian ini berfungsi dengan baik untuk set data yang tidak mempunyai pendua. Walau bagaimanapun, dua atau lebih nilai pendua dalam lajur berangka boleh mencipta "ikatan" dalam kedudukan, yang akan membawa kepada hasil yang salah. Dalam kes ini, sila gunakan formula yang lebih canggih untuk memutuskan hubungan.
• Dalam Excel 365, tugas ini boleh dicapai dengan bantuan fungsi tatasusunan dinamik baharu. Selain daripada lebih mudah, pendekatan ini secara automatik menyelesaikan masalah pertalian. Untuk butiran penuh, sila lihat Cara menapis nilai N bawah dalam Excel.

Isih nombor daripada terendah ke tertinggi dengan formula

Saya percaya semua orang tahu cara menyusun nombor dengan Ciri Isih Excel. Tetapi adakah anda tahu cara melakukan pengisihan dengan formula? Pengguna Excel 365 boleh melakukannya dengan cara yang mudah dengan fungsi SORT baharu. Dalam Excel 2019, 2016 dan versi terdahulu, SORT tidak berfungsi, malangnya. Tetapi percayalah sedikit, dan KECIL akan datang untuk menyelamatkan :)

Seperti dalam contoh pertama, kami menggunakan fungsi ROWS dengan rujukan julat yang berkembang untuk menambah k sebanyak 1 dalam setiap baris mana formuladisalin:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Masukkan formula dalam sel pertama, dan kemudian seret ke bawah ke seberapa banyak sel kerana terdapat nilai dalam set data asal (C2:C10 dalam contoh ini) :

Petua. Untuk mengisih menurun , gunakan fungsi BESAR dan bukannya KECIL.

Formula KECIL Excel untuk tarikh dan masa

Oleh kerana tarikh dan masa juga merupakan nilai berangka (dalam sistem Excel dalaman, tarikh disimpan sebagai nombor berurutan dan masa sebagai pecahan perpuluhan), fungsi SMALL boleh mengendalikannya serta tanpa sebarang usaha tambahan di pihak anda.

Seperti yang anda boleh lihat dalam tangkapan skrin di bawah, formula asas yang kami gunakan untuk nombor berfungsi dengan baik untuk tarikh dan masa juga:

=SMALL($B$2:$B$10, D2)

Formula KECIL untuk mencari 3 tarikh terawal:

Formula KECIL untuk mendapatkan 3 kali terpendek:

Contoh seterusnya menunjukkan cara fungsi SMALL boleh membantu anda menyelesaikan tugas yang lebih khusus berkaitan dengan tarikh.

Cari tarikh sebelumnya yang paling hampir dengan hari ini atau tarikh yang ditentukan

Dalam senarai tarikh , andaikan anda ingin mencari tarikh terdekat sebelum tarikh yang ditentukan. Ini boleh dilakukan dengan menggunakan fungsi SMALL dalam kombinasi dengan COUNTIF.

Dengan senarai tarikh dalam B2:B10 dan tarikh sasaran dalam E1, formula berikut akan mengembalikan tarikh sebelumnya yang paling hampir dengan tarikh sasaran:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

Untuk mengekstrak tarikh iaitu dua tarikh sebelum tarikh dalam E1, iaitu tarikh sebelumnya tetapi satu tarikh,formula ialah:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

Untuk mencari tarikh lepas paling hampir dengan hari ini , gunakan fungsi TODAY untuk kriteria COUNTIF:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

Petua. Untuk mengelakkan ralat dalam situasi apabila tarikh yang sepadan dengan kriteria anda tidak ditemui, anda boleh membungkus fungsi IFERROR di sekeliling formula anda, seperti ini:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

Cara formula ini berfungsi:

Idea umum ialah mengira bilangan tarikh yang lebih kecil daripada tarikh sasaran dengan COUNTIF. Dan kiraan ini adalah apa yang diperlukan oleh fungsi SMALL untuk hujah k .

Untuk memahami konsep dengan lebih baik, mari lihat dari sudut lain:

Jika 1- Ogos-2020 (tarikh sasaran dalam E1) muncul dalam set data kami, ia akan menjadi tarikh ke-7 terbesar dalam senarai. Akibatnya, terdapat enam buah kurma yang lebih kecil daripadanya. Bermaksud, tarikh ke-6 terkecil ialah tarikh sebelumnya yang paling hampir dengan tarikh sasaran.

Jadi, mula-mula kita mengira bilangan tarikh yang lebih kecil daripada tarikh dalam E1 (hasilnya ialah 6):

COUNTIF(B2:B10, "<"&E1)

Kemudian, palamkan kiraan ke dalam argumen ke-2 SMALL:

=SMALL(B2:B10, 6)

Untuk mendapatkan tarikh sebelumnya tetapi satu (iaitu tarikh ke-5 terkecil dalam kes kami) , kami menolak 1 daripada hasil COUNTIF.

Cara menyerlahkan nilai bawah dalam Excel

Untuk menyerlahkan nilai n terkecil dalam jadual anda dengan pemformatan bersyarat Excel, anda boleh menggunakan sama ada Top terbina dalam /Pilihan bawah atau sediakan peraturan anda sendiri berdasarkan formula KECIL. Kaedah pertama adalah lebih cepatdan lebih mudah untuk digunakan, manakala yang kedua memberikan lebih kawalan dan fleksibiliti. Langkah di bawah akan memandu anda membuat peraturan tersuai:

1. Pilih julat yang anda ingin serlahkan nilai bawah. Dalam kes kami, nombornya adalah dalam B2:B10, jadi kami memilihnya. Jika anda ingin menyerlahkan keseluruhan baris, kemudian pilih A2:B10.
2. Pada tab Laman Utama , dalam kumpulan Gaya , klik Pemformatan bersyarat > Peraturan Baharu .
3. Dalam kotak dialog Peraturan Pemformatan Baharu , pilih Gunakan formula untuk menentukan sel yang hendak diformatkan.
4. Dalam kotak Format nilai di mana formula ini adalah benar , masukkan formula seperti ini:

   =B2<=SMALL($B$2:$B$10, 3)

   Di mana B2 ialah sel paling kiri nombor julat untuk disemak, $B$2:$B$10 ialah keseluruhan julat dan 3 ialah nilai bawah n untuk diserlahkan.

   Dalam formula anda, sila ambil perhatian jenis rujukan: sel paling kiri ialah rujukan relatif (B2) manakala julat ialah rujukan mutlak ($B$2:$B$10).

5. Klik butang Format dan pilih mana-mana format yang anda suka.
6. Klik OK dua kali untuk menutup kedua-dua tetingkap dialog.

Selesai! 3 nilai terbawah dalam lajur B diserlahkan:

Untuk mendapatkan maklumat lanjut, sila lihat pemformatan bersyarat Excel berdasarkan formula.

Fungsi Excel SMALL tidak berfungsi

Seperti yang baru anda lihat daripada contoh kami, menggunakan fungsi KECIL dalam Excel agak mudah, dan andatidak mungkin menghadapi sebarang kesulitan dengannya. Jika formula anda tidak berkesan, kemungkinan besar ia akan menjadi #NUM! ralat, yang mungkin berlaku kerana sebab berikut:

• Array kosong atau tidak mengandungi satu nilai angka.
• k nilai kurang daripada sifar (salah taip bodoh boleh menyebabkan anda menghabiskan masa berjam-jam untuk menyelesaikan masalah!) atau melebihi bilangan nilai dalam tatasusunan.

Begitulah cara menggunakan formula KECIL dalam Excel untuk mencari dan serlahkan nombor bawah dalam set data. Jika anda mengetahui sebarang senario lain di mana fungsi itu berguna, anda amat dialu-alukan untuk berkongsi dalam ulasan. Saya mengucapkan terima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan!

Latihan buku kerja untuk muat turun

Contoh formula KECIL Excel (fail.xlsx)