Sa maikling tutorial na ito, pag-uusapan natin ang tungkol sa Excel SMALL function, kung paano ito gumagana at kung paano ito gamitin upang mahanap ang Nth pinakamaliit na numero, petsa, o oras.

Kailangan upang makahanap ng ilang pinakamababang numero sa isang worksheet? Ito ay medyo madaling gawin sa tampok na Excel Sort. Hindi nais na mag-aksaya ng oras sa muling pag-uuri ng iyong data sa bawat pagbabago? Tutulungan ka ng SMALL function na mabilis na mahanap ang pinakamababang value, pangalawa sa pinakamaliit, pangatlo sa pinakamaliit, at iba pa.

Excel SMALL function

Ang SMALL ay isang istatistikal na function na nagbabalik ang n-th na pinakamaliit na value sa isang set ng data.

Ang syntax ng SMALL function ay may kasamang dalawang argumento, na parehong kinakailangan.

SMALL(array, k)

Saan:

• Array - isang array o hanay ng mga cell kung saan kukunin ang pinakamaliit na value.
• K - isang integer na nagsasaad ng posisyon mula sa pinakamababang value na ibabalik, ibig sabihin, k-th pinakamaliit.

Available ang function sa lahat ng bersyon ng Excel para sa Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010, at mas maaga.

Tip. Upang mahanap ang k-th na pinakamababang halaga na may pamantayan, gamitin ang Excel SMALL IF formula.

Basic SMALL formula sa Excel

Ang MALIIT na formula sa pangunahing anyo nito ay napakadaling buuin - tukuyin mo lang ang range at ang posisyon mula sa pinakamaliit na item na ibabalik.

Sa listahan ng mga numero sa B2:B10, ipagpalagay na gusto mong kunin ang ika-3 pinakamaliit na value. Ang formula ay bilangsimple gaya ng:

=SMALL(B2:B10, 3)

Upang gawing mas madali para sa iyo na suriin ang resulta, ang column B ay pinagbubukod-bukod sa pataas na pagkakasunod-sunod:

4 na bagay na dapat mong malaman tungkol sa SMALL function

Ang sumusunod na mga tala sa paggamit ay makakatulong sa iyong mas maunawaan ang gawi ng SMALL function at maiwasan ang pagkalito kapag gumagawa ng sarili mong mga formula.

1. Anumang blank cell , text value, at logical value na TRUE at FALSE sa array na argument ay binabalewala.
2. Kung <1 Ang>array ay naglalaman ng isa o higit pang mga error , may ibinalik na error.
3. Kung sakaling mayroong mga duplicate sa array , ang iyong formula maaaring magresulta sa "tali". Halimbawa, kung ang dalawang cell ay naglalaman ng numero 1, at ang SMALL function ay na-configure upang ibalik ang pinakamaliit at ang 2nd pinakamaliit na halaga, makakakuha ka ng 1 sa parehong mga kaso.
4. Ipagpalagay na ang n ay ang bilang ng mga halaga sa array , ibabalik ng SMALL(array,1) ang pinakamababang value, at pipili ang SMALL(array,n) ng pinakamataas na value.

Paano gamitin ang SMALL function sa Excel - mga halimbawa ng formula

At ngayon, tingnan natin ang ilan pang halimbawa ng Excel SMALL function na higit pa sa pangunahing paggamit nito.

Hanapin ang ibabang 3, 5, 10, atbp. na mga halaga

Tulad ng alam mo na, ang SMALL function ay idinisenyo upang kalkulahin ang n-th na pinakamababang halaga. Ipinapakita ng halimbawang ito kung paano ito gagawin nang pinakamabisa.

Sa talahanayan sa ibaba, ipagpalagay na gusto mong hanapin ang nasa ibabang 3 value. Para dito, i-type angmga numero 1, 2 at 3 sa magkahiwalay na mga cell (D3, D4 at D5 sa aming kaso). Pagkatapos, ilagay ang sumusunod na formula sa E3 at i-drag ito pababa sa pamamagitan ng E5:

=SMALL($B$2:$B$10, D3)

Sa E3, kinukuha ng formula ang pinakamaliit na value gamit ang numero sa D3 para sa k argumento. Ang pangunahing bagay ay ang pagbibigay ng wastong mga sanggunian sa cell dahil sa kung saan ang formula ay nakopya nang tama sa iba pang mga cell: absolute para sa array at relative para sa k .

Ayaw mo bang mag-abala sa pag-type ng mga ranggo nang manu-mano? Gamitin ang function na ROWS na may reference na lumalawak na range para ibigay ang value na k . Para dito, gumawa kami ng ganap na reference para sa unang cell (o i-lock lang ang row coordinate tulad ng B$2) at relative reference para sa huling cell:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Bilang resulta, ang range lumalawak ang reference habang kinokopya ang formula sa column. Sa D2, ang ROWS(B$2:B2) ay gumagawa ng 1 para sa k , at ibinabalik ng formula ang pinakamababang halaga. Sa D3, ang ROWS(B$2:B3) ay magbubunga ng 2, at makuha namin ang ika-2 pinakamababang halaga, at iba pa.

Kopyahin lang ang formula sa pamamagitan ng 5 cell, at makakakuha ka ng pinakamababang 5 value:

Suum bottom N value

Gusto mo bang makahanap ng kabuuan ng pinakamaliit na n value sa isang dataset? Kung na-extract mo na ang mga value tulad ng ipinakita sa nakaraang halimbawa, ang pinakamadaling solusyon ay isang SUM formula tulad ng:

=SUM(E3:E5)

O maaari mong gumawa ng independiyenteng formula sa pamamagitan ng paggamit ng SMALL function kasama ng SUMPRODUCT:

Upang makuha ang kabuuan ng pinakamababang 3 value sa aming set ng data, ganito ang hugis ng formula :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

Ang SUM function ay maglalabas ng parehong resulta:

=SUM(SMALL(B2:B10, {1,2,3}))

Tandaan. Kung gumagamit ka ng mga cell reference sa halip na array constant para sa k , kailangan mong pindutin ang Ctrl + Shift + Enter upang gawin itong array formula. Sa Excel 365 na sumusuporta sa mga dynamic na array, gumagana ang SUM SMALL bilang isang regular na formula sa alinmang kaso.

Paano gumagana ang formula na ito:

Sa isang regular na formula, ang SMALL ay nagbabalik ng isang k-th na pinakamaliit na halaga sa isang hanay. Sa kasong ito, nagbibigay kami ng array constant tulad ng {1,2,3} para sa k argument, na pinipilit itong magbalik ng array ng pinakamaliit na 3 value:

{29240, 43610, 58860}

Ang SUMPRODUCT o Ang SUM function ay nagdaragdag ng mga numero sa array at naglalabas ng kabuuan. Iyon lang!

INDEX MATCH SMALL na formula para makakuha ng pinakamaliit na tugma

Sa sitwasyon kung kailan mo gustong kunin ang ilang data na nauugnay sa pinakamaliit na value, gamitin ang classic na INDEX MATCH na kumbinasyon sa SMALL para sa lookup value :

Saan :

• Return_array ay isang hanay kung saan kukuha ng nauugnay na data.
• Lookup_array ay isang hanay kung saan hahanapin ang pinakamababang n -th value.
• N ay ang posisyon ng pinakamaliit na halaga ng interes.

Para sahalimbawa, para makuha ang pangalan ng proyektong may pinakamababang gastos, ang formula sa E3 ay:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Kung saan A2:A10 ang mga pangalan ng proyekto, B2:B10 ang mga gastos at Ang D3 ay ang ranggo mula sa pinakamaliit.

Kopyahin ang formula sa mga cell sa ibaba (E4 at E5), at makukuha mo ang mga pangalan ng 3 pinakamurang proyekto:

Mga Tala:

• Ang solusyon na ito ay gumagana nang maayos para sa isang dataset na walang mga duplicate. Gayunpaman, ang dalawa o higit pang mga duplicate na halaga sa isang numeric na column ay maaaring lumikha ng "mga relasyon" sa pagraranggo, na hahantong sa mga maling resulta. Sa kasong ito, mangyaring gumamit ng medyo mas sopistikadong formula upang maputol ang mga ugnayan.
• Sa Excel 365, maaaring magawa ang gawaing ito sa tulong ng mga bagong function ng dynamic na array. Bukod sa pagiging mas simple, ang diskarte na ito ay awtomatikong malulutas ang problema ng mga relasyon. Para sa buong detalye, pakitingnan ang Paano i-filter ang ibabang mga halaga ng N sa Excel.

Pagbukud-bukurin ang mga numero mula sa pinakamababa hanggang sa pinakamataas gamit ang isang formula

Naniniwala akong alam ng lahat kung paano ayusin ang mga numero sa Tampok ng Excel Sort. Ngunit alam mo ba kung paano magsagawa ng pag-uuri gamit ang isang formula? Magagawa ito ng mga user ng Excel 365 sa madaling paraan gamit ang bagong SORT function. Sa Excel 2019, 2016 at mga naunang bersyon, hindi gumagana ang SORT, sayang. Ngunit magkaroon ng kaunting pananampalataya, at MALIIT ay darating upang iligtas :)

Tulad ng sa unang halimbawa, ginagamit namin ang ROWS function na may pagpapalawak ng saklaw na sanggunian sa pagtaas ng k ng 1 sa bawat row kung saan ang formulaay kinopya:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Ilagay ang formula sa unang cell, at pagkatapos ay i-drag ito pababa sa kasing dami ng mga cell na mayroong mga value sa orihinal na set ng data (C2:C10 sa halimbawang ito) :

Tip. Upang pag-uri-uriin ang pababa , gamitin ang LARGE function sa halip na SMALL.

Maliit na formula ng Excel para sa mga petsa at oras

Dahil ang mga petsa at oras ay mga numeric na halaga din (sa panloob na sistema ng Excel, ang mga petsa ay iniimbak bilang mga sequential na numero at mga oras bilang mga decimal fraction), ang SMALL function ay maaaring hawakan ang mga ito pati na rin nang walang anumang labis na pagsisikap sa iyong panig.

Tulad ng makikita mo sa mga screenshot sa ibaba, ang isang pangunahing formula na ginamit namin para sa mga numero ay gumagana nang maganda para sa mga petsa at oras:

=SMALL($B$2:$B$10, D2)

MALIIT na formula para mahanap ang pinakamaagang 3 petsa:

MALIIT na formula para makuha ang pinakamaikling 3 beses:

Ipinapakita ng susunod na halimbawa kung paano makakatulong sa iyo ang SMALL function na magawa ang isang mas partikular na gawain na may kaugnayan sa mga petsa.

Maghanap ng nakaraang petsa na pinakamalapit sa ngayon o tinukoy na petsa

Sa isang listahan ng mga petsa , kung gusto mong hanapin ang pinakamalapit na petsa bago ang isang tinukoy na petsa. Magagawa ito sa pamamagitan ng paggamit ng SMALL function kasama ng COUNTIF.

Gamit ang listahan ng mga petsa sa B2:B10 at ang target na petsa sa E1, ang sumusunod na formula ay magbabalik ng naunang petsa na pinakamalapit sa target na petsa:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

Upang mag-extract ng petsa na dalawang petsa bago ang petsa sa E1, ibig sabihin, isang nakaraang ngunit isang petsa, angang formula ay:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

Upang maghanap ng nakaraang petsa pinaka malapit sa ngayon , gamitin ang TODAY function para sa pamantayan ng COUNTIF:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

Tip. Para maiwasan ang mga error sa sitwasyon kung kailan hindi nakita ang petsang tumutugma sa iyong pamantayan, maaari mong ibalot ang IFERROR function sa iyong formula, tulad nito:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

Paano gumagana ang mga formula na ito:

Ang pangkalahatang ideya ay bilangin ang bilang ng mga petsa na mas maliit kaysa sa target na petsa gamit ang COUNTIF. At ang bilang na ito ay eksakto kung ano ang kailangan ng SMALL function para sa k argument.

Upang mas maunawaan ang konsepto, tingnan natin ito mula sa ibang anggulo:

Kung 1- Ang Agosto-2020 (ang target na petsa sa E1) ay lumabas sa aming dataset, ito ang magiging ika-7 pinakamalaking petsa sa listahan. Dahil dito, mayroong anim na petsa na mas maliit kaysa rito. Ibig sabihin, ang ika-6 na pinakamaliit na petsa ay ang nakaraang petsa na pinakamalapit sa target na petsa.

Kaya, kalkulahin muna namin kung ilang petsa ang mas maliit kaysa sa petsa sa E1 (ang resulta ay 6):

COUNTIF(B2:B10, "<"&E1)

At pagkatapos, isaksak ang bilang sa 2nd argument ng SMALL:

=SMALL(B2:B10, 6)

Upang makuha ang nakaraan ngunit isang petsa (na siyang ika-5 pinakamaliit na petsa sa aming kaso) , binabawasan namin ang 1 sa resulta ng COUNTIF.

Paano i-highlight ang mga pinakamababang halaga sa Excel

Upang i-highlight ang pinakamaliit na n value sa iyong talahanayan na may Excel conditional formatting, maaari mong gamitin ang alinman sa built-in na Top /Ibaba na opsyon o i-set up ang sarili mong panuntunan batay sa MALIIT na formula. Ang unang paraan ay mas mabilisat mas madaling ilapat, habang ang pangalawa ay nagbibigay ng higit na kontrol at flexibility. Ang mga hakbang sa ibaba ay gagabay sa iyo sa paggawa ng custom na panuntunan:

1. Piliin ang hanay kung saan mo gustong i-highlight ang mga pinakamababang halaga. Sa aming kaso, ang mga numero ay nasa B2:B10, kaya pinili namin ito. Kung gusto mong i-highlight ang buong mga row, pagkatapos ay piliin ang A2:B10.
2. Sa tab na Home , sa grupong Mga Estilo , i-click ang Conditional formatting > Bagong Panuntunan .
3. Sa dialog box na Bagong Panuntunan sa Pag-format , piliin ang Gumamit ng formula upang matukoy kung aling mga cell ang ipo-format.
4. Sa kahon ng Format value kung saan totoo ang formula na ito , maglagay ng formula na tulad nito:

   =B2<=SMALL($B$2:$B$10, 3)

   Kung saan ang B2 ang pinakakaliwang cell ng numeric hanay na susuriin, $B$2:$B$10 ang buong hanay, at ang 3 ay ang n na ibabang mga halaga na iha-highlight.

   Sa iyong formula, pakitandaan ang mga uri ng sanggunian: ang Ang pinakakaliwang cell ay isang kamag-anak na sanggunian (B2) habang ang hanay ay ang ganap na sanggunian ($B$2:$B$10).

5. I-click ang button na Format at pumili ng anumang format na gusto mo.
6. I-click ang OK nang dalawang beses upang isara ang parehong dialog window.

Tapos na! Ang 3 ibabang halaga sa column B ay naka-highlight:

Para sa higit pang impormasyon, pakitingnan ang Excel conditional formatting batay sa formula.

Excel SMALL function na hindi gumagana

Tulad ng nakita mo mula sa aming mga halimbawa, ang paggamit ng SMALL function sa Excel ay medyo madali, at ikaw aymalamang na hindi magkakaroon ng anumang mga paghihirap dito. Kung hindi gumana ang iyong formula, malamang na magiging #NUM iyon! error, na maaaring mangyari dahil sa mga sumusunod na dahilan:

• Array ay walang laman o hindi naglalaman ng iisang numerong halaga.
• Ang k ang value ay mas mababa sa zero (ang isang hangal na typo ay maaaring magdulot sa iyo ng mga oras ng pag-troubleshoot!) o lumampas sa bilang ng mga value sa array.

Iyan ay kung paano gumamit ng MALIIT na formula sa Excel upang mahanap at i-highlight ang mga numero sa ibaba sa isang set ng data. Kung alam mo ang anumang iba pang mga sitwasyon kung saan ang function ay madaling gamitin, malugod kang malugod na magbahagi sa mga komento. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo!

Magsanay ng workbook para sa pag-download

Mga halimbawa ng Excel SMALL na formula (.xlsx file)