Í þessu stutta kennsluefni munum við tala um SMALL Excel aðgerðina, hvernig það virkar og hvernig á að nota það til að finna N. minnstu töluna, dagsetninguna eða tímann.

Þarf að finna nokkrar lægstu tölur í vinnublaði? Þetta er frekar auðvelt að gera með Excel Sort eiginleikanum. Viltu ekki eyða tíma í að endurflokka gögnin þín við hverja breytingu? SMALL aðgerðin mun hjálpa þér að finna fljótt lægsta gildið, næstminnsta, þriðja minnsta, og svo framvegis.

Excel SMALL fall

SMALL er tölfræðileg aðgerð sem skilar n-ta minnsta gildið í gagnamengi.

Setjafræði SMALL fallsins inniheldur tvær frumbreytur, sem báðar eru nauðsynlegar.

SMALL(fylki, k)

Hvar:

• Array - fylki eða svið af frumum sem hægt er að draga minnsta gildið úr.
• K - an heiltala sem gefur til kynna staðsetningu frá lægsta gildinu til að skila, þ.e.a.s. k-þ minnstu.

Aðgerðin er fáanleg í öllum útgáfum af Excel fyrir Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010 og fyrr.

Ábending. Til að finna k-þ lægsta gildi með viðmiðum, notaðu Excel SMALL IF formúlu.

Lítil formúla í Excel

LÍTIL formúla í grunnformi er mjög auðvelt að smíða - þú tilgreinir bara svið og staðsetningin frá minnsta hlutnum til að skila.

Í listanum yfir tölur í B2:B10, að því gefnu að þú viljir draga út 3. minnsta gildið. Formúlan er semeinfalt eins og:

=SMALL(B2:B10, 3)

Til að auðvelda þér að athuga niðurstöðuna er dálki B raðað í hækkandi röð:

4 hlutir sem þú ættir að vita um SMALL aðgerðina

Eftirfarandi notkunarskýringar munu hjálpa þér að skilja betur hegðun SMALL fallsins og forðast rugling þegar þú býrð til þínar eigin formúlur.

1. Allir auðu hólf , texta gildi og rökrétt gildi TRUE og FALSE í fylki röksemdinni eru hunsuð.
2. Ef fylki inniheldur eina eða fleiri villur , villu er skilað.
3. Ef það eru afrit í fylki , þá er formúlan þín getur leitt til "tengsla". Til dæmis, ef tvær frumur innihalda töluna 1, og SMALL aðgerðin er stillt til að skila minnstu og 2. minnstu gildinu, færðu 1 í báðum tilfellum.
4. Að því gefnu að n sé fjöldi gilda í fylki , SMALL(fylki,1) mun skila lægsta gildinu og SMALL(fylki,n) mun velja hæsta gildið.

Hvernig á að nota SMALL fallið í Excel - formúludæmi

Og nú skulum við skoða fleiri dæmi um Excel SMALL aðgerðina sem fara út fyrir grunnnotkun þess.

Finndu neðstu 3, 5, 10 o.s.frv. gildi

Eins og þú veist nú þegar er SMALL aðgerðin hönnuð til að reikna út n-ta lægsta gildið. Þetta dæmi sýnir hvernig á að gera þetta á skilvirkasta hátt.

Í töflunni hér að neðan, segjum að þú viljir finna 3 neðstu gildin. Fyrir þetta skaltu slá inntölur 1, 2 og 3 í aðskildum hólfum (D3, D4 og D5 í okkar tilviki). Sláðu síðan inn eftirfarandi formúlu í E3 og dragðu hana niður í gegnum E5:

=SMALL($B$2:$B$10, D3)

Í E3 dregur formúlan út minnsta gildið með því að nota töluna í D3 fyrir k rök. Lykilatriðið er að gefa upp viðeigandi frumutilvísanir, þar af leiðandi afritar formúlan rétt í aðrar frumur: algert fyrir fylki og afstætt fyrir k .

Viltu ekki nenna að slá inn röðina handvirkt? Notaðu ROWS fallið með stækkandi svið tilvísun til að gefa upp k gildið. Fyrir þetta gerum við algera tilvísun fyrir fyrsta reitinn (eða læsum aðeins línuhnitinum eins og B$2) og hlutfallslega tilvísun fyrir síðasta reitinn:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Þar af leiðandi er bilið tilvísun stækkar þegar formúlan er afrituð niður í dálkinn. Í D2 gefur ROWS(B$2:B2) 1 fyrir k og formúlan skilar lægsta kostnaði. Í D3 gefur ROWS(B$2:B3) 2 og við fáum 2. lægsta kostnaðinn og svo framvegis.

Afritaðu bara formúluna í gegnum 5 reiti og þú færð 5 neðstu gildin:

Neðstu N gildi samanlagt

Viltu finna samtals minnstu n gildin í gagnasafni? Ef þú hefur þegar dregið út gildin eins og sýnt er í fyrra dæmi, þá væri auðveldasta lausnin SUM formúla eins og:

=SUM(E3:E5)

Eða þú getur búa til sjálfstæða formúlu með því að nota SMALL fallið ásamt SUMPRODUCT:

Til að fá summan af 3 neðstu gildunum í gagnasafninu okkar tekur formúlan sér þessa lögun :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

SUM aðgerðin mun gefa sömu niðurstöðu:

=SUM(SMALL(B2:B10, {1,2,3}))

Athugið. Ef þú notar frumutilvísanir frekar en fylkisfasta fyrir k þarftu að ýta á Ctrl + Shift + Enter til að gera það að fylkisformúlu. Í Excel 365 sem styður kraftmikla fylki virkar SUM SMALL sem venjuleg formúla í báðum tilvikum.

Hvernig þessi formúla virkar:

Í venjulegri formúlu skilar SMALL einum k-þa minnsta gildi á bilinu. Í þessu tilviki gefum við fylkisfasta eins og {1,2,3} fyrir k-breytuna, sem neyðum hana til að skila fylki með minnstu 3 gildunum:

{29240, 43610, 58860}

SUMVARA eða SUM aðgerðin leggur saman tölurnar í fylkinu og gefur út heildina. Það er allt!

INDEX MATCH SMALL formúla til að fá minnstu samsvörun

Í þeim aðstæðum þegar þú vilt sækja gögn sem tengjast minnsta gildinu, notaðu klassísku INDEX MATCH samsetninguna með SMALL fyrir uppflettingargildið :

Hvar :

• Return_array er svið sem hægt er að draga tengd gögn úr.
• Útlitsfylki er svið þar sem leita á að lægsta n -th gildi.
• N er staðsetning minnsta verðgildisins.

Fyrir.dæmi, til að fá heiti verkefnisins sem hefur lægsta kostnaðinn er formúlan í E3:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Þar sem A2:A10 eru nöfn verksins, B2:B10 eru kostnaður og D3 er röðin frá minnstu.

Afritu formúluna í reitina hér að neðan (E4 og E5), og þú færð nöfn 3 ódýrustu verkefnanna:

Athugasemdir:

• Þessi lausn virkar vel fyrir gagnasafn sem hefur engar afrit. Hins vegar geta tvö eða fleiri tvítekin gildi í tölulegum dálki skapað „tengsl“ í röðun, sem mun leiða til rangra niðurstaðna. Í þessu tilfelli, vinsamlegast notaðu aðeins flóknari formúlu til að rjúfa tengsl.
• Í Excel 365 er hægt að framkvæma þetta verkefni með hjálp nýju kraftmikilla fylkisaðgerðanna. Fyrir utan að vera miklu einfaldari leysir þessi aðferð sjálfkrafa vandamálið við tengslin. Fyrir allar upplýsingar, vinsamlegast sjáðu Hvernig á að sía neðstu N gildi í Excel.

Raða tölur frá lægstu til hæstu með formúlu

Ég tel að allir viti hvernig á að setja tölur í röð með Excel flokkunaraðgerð. En veistu hvernig á að framkvæma flokkun með formúlu? Notendur Excel 365 geta gert það á auðveldan hátt með nýju SORT aðgerðinni. Í Excel 2019, 2016 og fyrri útgáfum virkar SORT ekki, því miður. En hafðu smá trú og þá mun SMALL koma til bjargar :)

Eins og í fyrsta dæminu notum við ROWS fallið með stækkandi sviðstilvísun til að auka k um 1 í hverjum röð þar sem formúlaner afritað:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Sláðu inn formúluna í fyrsta reitinn og dragðu hana svo niður í eins marga reiti og það eru gildi í upprunalega gagnasettinu (C2:C10 í þessu dæmi) :

Ábending. Til að flokka lækkandi , notaðu LARGE aðgerðina í stað SMALL.

Excel SMALL formúla fyrir dagsetningar og tíma

Vegna þess að dagsetningar og tímar eru líka tölugildi (í innra Excel kerfinu eru dagsetningar geymdar sem raðtölur og tímar sem tugabrot) ræður SMALL fallið við þær sömuleiðis án auka áreynslu af þinni hálfu.

Eins og þú sérð á skjáskotunum hér að neðan virkar grunnformúla sem við notuðum fyrir tölur líka fallega fyrir dagsetningar og tíma:

=SMALL($B$2:$B$10, D2)

LÍTIL formúla til að finna fyrstu 3 dagsetningarnar:

LÍTIL formúla til að fá stystu 3 skiptin:

Næsta dæmi sýnir hvernig SMALL aðgerðin getur hjálpað þér að framkvæma nákvæmari verkefni sem tengjast dagsetningum.

Finndu fyrri dagsetningu næst deginum í dag eða tilgreinda dagsetningu

Í lista yfir dagsetningar. , að því gefnu að þú viljir finna næstu dagsetningu fyrir tiltekna dagsetningu. Þetta er hægt að gera með því að nota SMALL fallið ásamt COUNTIF.

Með lista yfir dagsetningar í B2:B10 og markdagsetningu í E1 mun eftirfarandi formúla skila fyrri dagsetningu næst markdagsetningunni:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

Til að draga út dagsetningu sem er tveimur dagsetningum á undan dagsetningunni í E1, þ.e. fyrri en eina dagsetningu,formúlan er:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

Til að finna fyrri dagsetningu næst í dag , notaðu TODAY aðgerðina fyrir viðmið COUNTIF:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

Ábending. Til að koma í veg fyrir villur í aðstæðum þegar dagsetning sem samsvarar viðmiðunum þínum finnst ekki, geturðu sett IFERROR fallið utan um formúluna þína, svona:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

Hvernig þessar formúlur virka:

Almenna hugmyndin er að telja fjölda dagsetninga minni en markdagsetninguna með COUNTIF. Og þessi talning er nákvæmlega það sem SMALL fallið þarf fyrir k rökin.

Til að átta okkur betur á hugtakinu skulum við líta á það frá öðru sjónarhorni:

Ef 1- Ágúst-2020 (markdagsetningin í E1) birtist í gagnapakkanum okkar, það væri sjöunda stærsta dagsetningin á listanum. Þar af leiðandi eru sex dagsetningar minni en það. Sem þýðir að 6. minnsta dagsetningin er fyrri dagsetningin næst markdagsetningunni.

Svo fyrst reiknum við út hversu margar dagsetningar eru minni en dagsetningin í E1 (niðurstaðan er 6):

COUNTIF(B2:B10, "<"&E1)

Og þá skaltu tengja talninguna í 2. röksemdafærslu SMALL:

=SMALL(B2:B10, 6)

Til að fá fyrri en eina dagsetningu (sem er 5. minnsta dagsetningin í okkar tilfelli) , drögum við 1 frá niðurstöðu COUNTIF.

Hvernig á að auðkenna neðstu gildi í Excel

Til að auðkenna minnstu n gildin í töflunni þinni með Excel skilyrtu sniði, geturðu notað annað hvort innbyggt Top / Botn valkostur eða settu upp þína eigin reglu sem byggir á LÍTRI formúlu. Fyrsta aðferðin er hraðariog auðveldara í notkun, en annað veitir meiri stjórn og sveigjanleika. Eftirfarandi skref leiða þig í gegnum að búa til sérsniðna reglu:

1. Veldu svið þar sem þú vilt auðkenna neðstu gildi. Í okkar tilviki eru tölurnar í B2:B10, svo við veljum það. Ef þú vilt auðkenna heilar línur skaltu velja A2:B10.
2. Á flipanum Heima , í hópnum Stílar , smelltu á Skilyrt snið > Ný regla .
3. Í Ný sniðregla valmynd velurðu Nota formúlu til að ákvarða hvaða frumur á að forsníða.
4. Í reitnum Snið gildi þar sem þessi formúla er satt skaltu slá inn formúlu eins og þessa:

   =B2<=SMALL($B$2:$B$10, 3)

   Þar sem B2 er reitinn lengst til vinstri í tölustafnum svið sem á að athuga, $B$2:$B$10 er allt svið og 3 eru n neðstu gildin til að auðkenna.

   Í formúlunni þinni skaltu hafa í huga tilvísunargerðirnar: Vinstra hólfið er hlutfallsleg tilvísun (B2) en bilið er alger tilvísun ($B$2:$B$10).

5. Smelltu á hnappinn Format og veldu hvaða snið sem þú vilt.
6. Smelltu tvisvar á OK til að loka báðum glugganum.

Búið! Þrjú neðstu gildin í B dálki eru auðkennd:

Nánari upplýsingar er að finna í Excel skilyrt sniði byggt á formúlu.

Excel SMALL aðgerð virkar ekki

Eins og þú hefur nýlega séð af dæmunum okkar er það frekar auðvelt að nota SMALL aðgerðina í Excel og þú ertólíklegt að eiga í erfiðleikum með það. Ef formúlan þín virkar ekki er líklegast að það sé #NUM! villa, sem getur komið upp af eftirfarandi ástæðum:

• Array er tómt eða inniheldur ekki eitt tölugildi.
• The k gildi er minna en núll (kjánaleg innsláttarvilla getur kostað þig klukkutíma í bilanaleit!) eða fer yfir fjölda gilda í fylkinu.

Svona á að nota LÍTLA formúlu í Excel til að finna og auðkenna neðstu tölur í gagnasetti. Ef þú þekkir aðrar aðstæður þar sem aðgerðin kemur sér vel, þá er þér hjartanlega velkomið að deila í athugasemdum. Ég þakka þér fyrir lesturinn og vonast til að sjá þig á blogginu okkar í næstu viku!

Æfingabók til niðurhals

Excel LÍTIL formúludæmi (.xlsx skrá)