Ushbu qisqa qo'llanmada biz Excelning KICHIK funksiyasi, uning qanday ishlashi va undan N-kichik raqam, sana yoki vaqtni topish uchun qanday foydalanish haqida gaplashamiz.

Kerak. ish varag'ida bir nechta eng past raqamlarni topish uchun? Buni Excel Sort xususiyati bilan qilish juda oson. Har bir o'zgarish bilan ma'lumotlaringizni qayta tartiblash uchun vaqt sarflashni xohlamaysizmi? KICHIK funksiyasi eng kichik qiymatni, ikkinchi eng kichikni, uchinchi eng kichikni va hokazolarni tezda topishga yordam beradi.

Excel KICHIK funksiya

KICHIK - bu statistik funktsiyani qaytaruvchi. ma'lumotlar to'plamidagi n-chi eng kichik qiymat.

KICHIK funksiyaning sintaksisi ikkita argumentni o'z ichiga oladi, ularning ikkalasi ham talab qilinadi.

KICHIK(massiv, k)

Bu yerda:

• Masiv - eng kichik qiymat chiqarish uchun massiv yoki hujayralar diapazoni.
• K - an Qaytish uchun eng past qiymatdan oʻrinni koʻrsatadigan butun son, yaʼni eng kichigi k-chi.

Funktsiya Office 365, Excel 2021, Excel 2019, Excel 2016, Excel uchun Excelning barcha versiyalarida mavjud. 2013, Excel 2010 va undan oldingi versiyalar.

Maslahat. Mezonlar bilan k-eng past qiymatni topish uchun Excel KICHIK IF formulasidan foydalaning.

Excel'dagi asosiy KICHIK formula

Asosiy shakldagi KICHIK formulani yaratish juda oson - siz shunchaki belgilang. diapazon va qaytariladigan eng kichik elementdan joy.

B2:B10dagi raqamlar ro'yxatida siz uchinchi eng kichik qiymatni chiqarmoqchi bo'lsangiz. Formula quyidagichaoddiy:

=SMALL(B2:B10, 3)

Natijani tekshirishni osonlashtirish uchun B ustuni o'sish tartibida tartiblangan:

KICHIK funksiya haqida bilishingiz kerak bo‘lgan 4 ta narsa

Quyidagi foydalanish eslatmalari SMALL funksiyasining harakatini yaxshiroq tushunishga va o‘z formulalaringizni yaratishda chalkashliklarning oldini olishga yordam beradi.

1. Har qanday bo'sh katakchalar , matn qiymatlari va massiv argumentidagi mantiqiy qiymatlari TRUE va FALSE hisobga olinmaydi.
2. Agar massiv bir yoki bir nechta xato ni o'z ichiga oladi, xato qaytariladi.
3. Agar massiv da takrorlash bo'lsa, formulangiz "bog'lanish" ga olib kelishi mumkin. Misol uchun, agar ikkita katakda 1 raqami bo'lsa va KICHIK funksiyasi eng kichik va ikkinchi eng kichik qiymatni qaytarish uchun sozlangan bo'lsa, siz ikkala holatda ham 1 ga ega bo'lasiz.
4. Agar n ni massiv , KICHIK(massiv,1) eng past qiymatni qaytaradi, KICHIK(massiv,n) esa eng yuqori qiymatni tanlaydi.

Excelda SMALL funksiyasidan qanday foydalanish - formula misollari

Endi esa Excel KICHIK funksiyasining asosiy qoʻllanilishidan tashqari yana bir qancha misollarni koʻrib chiqamiz.

Pastki 3, 5, 10 va hokazo qiymatlarni toping

Ma'lumki, KICHIK funksiya n-chi eng past qiymatni hisoblash uchun mo'ljallangan. Bu misol buni qanday qilib eng samarali bajarish mumkinligini ko'rsatadi.

Quyidagi jadvalda siz pastki 3 ta qiymatni topmoqchi bo'lsangiz, deylik. Buning uchun yozingalohida kataklarda 1, 2 va 3 raqamlari (bizning holatlarimizda D3, D4 va D5). Keyin, E3-ga quyidagi formulani kiriting va uni E5 orqali pastga torting:

=SMALL($B$2:$B$10, D3)

E3-da, formula k<2 uchun D3-dagi raqam yordamida eng kichik qiymatni chiqaradi> argument. Asosiysi, to'g'ri hujayra havolalarini taqdim etishdir, buning natijasida formula boshqa kataklarda to'g'ri nusxalanadi: massiv uchun mutlaq va k uchun nisbiy.

Raflarni qo'lda yozishni xohlamaysizmi? k qiymatini ta'minlash uchun kengayuvchi diapazon havolasi bilan ROWS funksiyasidan foydalaning. Buning uchun biz birinchi katak uchun mutlaq havola qilamiz (yoki faqat B$2 kabi qator koordinatasini bloklaymiz) va oxirgi katak uchun nisbiy havola qilamiz:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Natijada diapazon formula ustun boʻylab koʻchirilganda havola kengayadi. D2 da ROWS(B$2:B2) k uchun 1 hosil qiladi va formula eng past narxni qaytaradi. D3 da ROWS(B$2:B3) 2 hosil qiladi va biz 2-eng past xarajatni olamiz va hokazo.

Shunchaki formulani 5 katakchadan ko'chiring, shunda siz pastki 5 qiymatga ega bo'lasiz:

Pastki N qiymatlar yig'indisi

Ma'lumotlar to'plamidagi eng kichik n qiymatlarning jami topilishini xohlaysizmi? Agar oldingi misolda ko'rsatilganidek qiymatlarni chiqarib olgan bo'lsangiz, eng oson yechim SUM formulasi bo'ladi:

=SUM(E3:E5)

Yoki siz ham shunday qilishingiz mumkin. SOMPRODUCT:

Ma’lumotlar to‘plamimizdagi pastki 3 ta qiymat yig‘indisini olish uchun formula shu shaklni oladi. :

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

SUM funksiyasi bir xil natija beradi:

=SUM(SMALL(B2:B10, {1,2,3}))

Eslatma. Agar siz k uchun massiv doimiysi oʻrniga hujayra havolalari dan foydalansangiz, uni massiv formulasiga aylantirish uchun Ctrl + Shift + Enter tugmalarini bosishingiz kerak. Dinamik massivlarni qo'llab-quvvatlaydigan Excel 365 da SUM SMALL har ikkala holatda ham oddiy formula sifatida ishlaydi.

Ushbu formula qanday ishlaydi:

Oddiy formulada SMALL diapazondagi bitta k-chi eng kichik qiymatni qaytaradi. Bunday holda, biz k argumenti uchun {1,2,3} kabi massiv konstantasini beramiz va uni eng kichik 3 ta qiymatdan iborat massivni qaytarishga majbur qilamiz:

{29240, 43610, 58860}

SUMPRODUCT yoki SUM funktsiyasi massivdagi raqamlarni qo'shadi va jami chiqadi. Hammasi shunday!

Eng kichik mosliklarni olish uchun INDEX MATCH SMALL formulasi

Eng kichik qiymat bilan bog'liq ba'zi ma'lumotlarni olishni istasangiz, qidiruv qiymati uchun KICHIK bilan klassik INDEX MATCH kombinatsiyasidan foydalaning. :

Qaerda :

• Qaytish_massivi - bog'langan ma'lumotlarni ajratib olish uchun diapazon.
• Izlash_massivi - eng past n ni qidirish uchun diapazon. -chi qiymat.
• N - qiziqishning eng kichik qiymatining pozitsiyasi.

uchunMasalan, eng kam xarajatga ega bo'lgan loyiha nomini olish uchun E3 dagi formula:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Bu erda A2:A10 - loyiha nomlari, B2:B10 - xarajatlar va D3 eng kichigidan daraja.

Formulani quyidagi katakchalarga ko'chiring (E4 va E5) va siz uchta eng arzon loyiha nomini olasiz:

Eslatmalar:

• Ushbu yechim dublikatlari bo'lmagan ma'lumotlar to'plami uchun yaxshi ishlaydi. Biroq, raqamli ustundagi ikki yoki undan ortiq takroriy qiymatlar reytingda "bog'lanish" ni yaratishi mumkin, bu esa noto'g'ri natijalarga olib keladi. Bunday holda, aloqalarni uzish uchun biroz murakkabroq formuladan foydalaning.
• Excel 365 da bu vazifani yangi dinamik massiv funksiyalari yordamida bajarish mumkin. Juda sodda bo'lishidan tashqari, bu yondashuv bog'lanish muammosini avtomatik ravishda hal qiladi. To'liq ma'lumot olish uchun Excelda pastki N qiymatlarni qanday filtrlash bo'limiga qarang.

Raqamlarni formula bo'yicha eng pastdan yuqoriga saralash

Menimcha, hamma raqamlarni qanday tartibda joylashtirishni biladi. Excelni saralash xususiyati. Ammo formula bilan tartiblashni qanday amalga oshirishni bilasizmi? Excel 365 foydalanuvchilari buni yangi SORT funksiyasi bilan oson qilishlari mumkin. Excel 2019, 2016 va oldingi versiyalarida SORT ishlamaydi, afsuski. Ammo ozgina ishoning, shunda KICHIK yordamga keladi :)

Birinchi misoldagi kabi, biz ROWS funksiyasidan har birida k ni 1 ga oshirish uchun kengaytiruvchi diapazondan foydalanamiz. formula joylashgan qatornusxa ko'chiriladi:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Birinchi katakka formulani kiriting, so'ngra uni dastlabki ma'lumotlar to'plamidagi qiymatlar qancha bo'lsa, shuncha katakka torting (bu misolda C2:C10) :

Maslahat. kamayish bo'yicha tartiblash uchun KICHIK o'rniga KATTA funksiyasidan foydalaning.

Sana va vaqt uchun Excel KICHIK formulasi

Sana va vaqtlar ham raqamli qiymatlar bo'lganligi sababli (ichki Excel tizimida sanalar ketma-ket raqamlar va vaqtlar o'nli kasrlar sifatida saqlanadi), SMALL funksiyasi ularni boshqarishi mumkin. Shuningdek, siz tomondan hech qanday qo'shimcha kuch sarflamasdan.

Quyidagi skrinshotlarda ko'rib turganingizdek, biz raqamlar uchun ishlatgan asosiy formula sana va vaqt uchun ham yaxshi ishlaydi:

=SMALL($B$2:$B$10, D2)

Eng erta 3 ta sanani topish uchun KICHIK formula:

Eng qisqa 3 marta olish uchun KICHIK formula:

Keyingi misolda SMALL funksiyasi sanalar boʻyicha aniqroq vazifani bajarishda qanday yordam berishi mumkinligini koʻrsatadi.

Bugun yoki belgilangan sanaga eng yaqin oldingi sanani toping

Sanalar roʻyxatida , siz belgilangan sanadan oldin eng yaqin sanani topmoqchi bo'lsangiz. Buni COUNTIF bilan birgalikda KICHIK funksiyasidan foydalanish mumkin.

B2:B10da sanalar roʻyxati va E1da maqsadli sana bilan quyidagi formula maqsadli sanaga eng yaqin oldingi sanani qaytaradi:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

E1 sanasidan ikki kun oldin bo'lgan sanani, ya'ni oldingi, lekin bir sanani chiqarish uchunformula:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

O'tgan sanani topish uchun bugunga eng yaqin , COUNTIF mezonlari uchun TODAY funksiyasidan foydalaning:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

Maslahat. Mezonlaringizga mos keladigan sana topilmagan vaziyatda xatoliklarning oldini olish uchun IFERROR funksiyasini formulangiz atrofida oʻrashingiz mumkin, masalan:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Not Found")

Ushbu formulalar qanday ishlaydi:

Umumiy fikr COUNTIF bilan belgilangan sanadan kichikroq sanalar sonini hisoblashdir. Va bu hisoblash aynan k argumenti uchun KICHIK funksiyaga kerak bo'lgan narsadir.

Tushunchani yaxshiroq tushunish uchun keling, uni boshqa tomondan ko'rib chiqamiz:

Agar 1- Avgust-2020 (E1da maqsadli sana) bizning ma'lumotlar to'plamimizda paydo bo'ldi, bu ro'yxatdagi 7- eng katta sana bo'lardi. Binobarin, undan kichikroq oltita xurmo bor. Ya'ni, 6-eng kichik sana maqsadli sanaga eng yaqin oldingi sana hisoblanadi.

Shunday qilib, avval E1dagi sanadan qancha sana kichikligini hisoblaymiz (natija 6):

COUNTIF(B2:B10, "<"&E1)

Keyin, hisobni KICHIK ning 2-argumentiga kiriting:

=SMALL(B2:B10, 6)

Avvalgi, lekin bir sanani olish uchun (bu bizning holatlarimizda 5-chi eng kichik sana) , biz COUNTIF natijasidan 1ni ayirib olamiz.

Excelda pastki qiymatlarni qanday ajratib ko'rsatish mumkin

Excel shartli formatlash yordamida jadvalingizdagi eng kichik n qiymatni ajratib ko'rsatish uchun siz o'rnatilgan Top-dan foydalanishingiz mumkin. /Pastki variant yoki KICHIK formula asosida oʻz qoidangizni oʻrnating. Birinchi usul tezroqva qo'llash osonroq, ikkinchisi esa ko'proq nazorat va moslashuvchanlikni ta'minlaydi. Quyidagi qadamlar sizga maxsus qoida yaratish bo'yicha yordam beradi:

1. Pastki qiymatlarni ajratib ko'rsatmoqchi bo'lgan diapazonni tanlang. Bizning holatlarimizda raqamlar B2: B10 da, shuning uchun biz uni tanlaymiz. Agar siz butun qatorlarni ajratib koʻrsatishni istasangiz, A2:B10 ni tanlang.
2. Uy yorligʻida, Uslublar guruhida Shartli formatlash-ni bosing. > Yangi qoida .
3. Yangi formatlash qoidasi muloqot oynasida Qaysi katakchalarni formatlashni aniqlash uchun formuladan foydalaning.
4. Ushbu formula toʻgʻri boʻlgan qiymatlarni formatlash maydoniga quyidagi formulani kiriting:

   =B2<=SMALL($B$2:$B$10, 3)

   Bu yerda B2 sonning eng chap katagidir. tekshirilishi kerak bo'lgan diapazon, $B$2:$B$10 butun diapazon va 3 - ajratib ko'rsatish uchun n pastki qiymatlar.

   Formulangizda havola turlariga e'tibor bering: eng chap katak nisbiy mos yozuvlar (B2), diapazon esa mutlaq mos yozuvlar ($B$2:$B$10).

5. Format tugmasini bosing va oʻzingizga yoqqan formatni tanlang.
6. Ikkala muloqot oynasini yopish uchun OK tugmasini ikki marta bosing.

Bajarildi! B ustunidagi pastki 3 ta qiymat ajratilgan:

Qo'shimcha ma'lumot olish uchun formulaga asoslangan Excel shartli formatlashiga qarang.

Excel KICHIK funksiyasi ishlamayapti

Misollarimizdan ko'rganingizdek, Excelda KICHIK funksiyasidan foydalanish juda oson va sizu bilan hech qanday qiyinchilik tug'dirmaydi. Agar formulangiz ishlamasa, bu #NUM! quyidagi sabablarga ko'ra yuzaga kelishi mumkin bo'lgan xato:

• Masiv bo'sh yoki bitta raqamli qiymatni o'z ichiga olmaydi.
• k qiymati noldan kichik (ahmoqona matbaa xatosi bir necha soatlab muammolarni bartaraf etishi mumkin!) yoki massivdagi qiymatlar sonidan oshib ketadi.

Mana shunday qilib topish va Excelda KICHIK formuladan foydalanish mumkin. ma'lumotlar to'plamidagi pastki raqamlarni ajratib ko'rsatish. Funktsiya foydali bo'lgan boshqa stsenariylarni bilsangiz, sharhlarda baham ko'rishingiz mumkin. O'qiganingiz uchun tashakkur va keyingi haftada blogimizda ko'rishga umid qilaman!

Yuklab olish uchun mashq kitobi

Excel KICHIK formula misollari (.xlsx fayli)