I denne korte vejledning vil vi tale om Excel SMALL-funktionen, hvordan den fungerer, og hvordan du bruger den til at finde det N-te mindste tal, dato eller klokkeslæt.

Har du brug for at finde nogle få laveste tal i et regneark? Det er ret nemt at gøre med Excel-sorteringsfunktionen. Vil du ikke spilde tid på at sortere dine data på ny ved hver ændring? SMALL-funktionen hjælper dig med hurtigt at finde den laveste værdi, den næstmindste, den tredjemindste osv.

Excel SMALL-funktion

SMALL er en statistisk funktion, der returnerer den n-t mindste værdi i et datasæt.

Syntaksen for SMALL-funktionen indeholder to argumenter, som begge er obligatoriske.

SMALL(array, k)

Hvor:

• Array - et array eller et område af celler, hvorfra den mindste værdi skal udtrækkes.
• K - et heltal, der angiver positionen fra den laveste værdi, der skal returneres, dvs. den k-te mindste.

Funktionen er tilgængelig i alle versioner af Excel til Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010 og tidligere versioner af Excel.

Tip. Hvis du vil finde den k-te laveste værdi med kriterierne, skal du bruge Excel SMALL IF-formlen.

Grundlæggende SMALL-formel i Excel

En SMALL-formel er i sin grundform meget nem at lave - du skal blot angive intervallet og positionen fra det mindste element, der skal returneres.

Hvis vi antager, at du i listen over tal i B2:B10 vil udtrække den 3. mindste værdi, er formlen så enkel som:

=SMALL(B2:B10, 3)

For at gøre det lettere for dig at kontrollere resultatet er kolonne B sorteret i stigende orden:

4 ting, du bør vide om SMALL-funktionen

De følgende brugsanvisninger hjælper dig med at forstå SMALL-funktionens adfærd bedre og undgå forvirring, når du opbygger dine egne formler.

1. Alle tomme celler , tekst værdier, og logisk værdierne TRUE og FALSE i array argumentet ignoreres.
2. Hvis array indeholder en eller flere fejl , returneres en fejl.
3. I tilfælde af at der er dubletter på array Hvis to celler f.eks. indeholder tallet 1, og SMALL-funktionen er konfigureret til at returnere den mindste og den næstmindste værdi, får du 1 i begge tilfælde.
4. Hvis man antager, at n er antallet af værdier i array , SMALL(array,1) returnerer den laveste værdi, og SMALL(array,n) vælger den højeste værdi.

Sådan bruger du funktionen SMALL i Excel - eksempler på formler

Lad os nu se på nogle flere eksempler på Excel-funktionen SMALL, der går ud over dens grundlæggende anvendelse.

Find de nederste 3, 5, 10, osv. værdier

Som du allerede ved, er SMALL-funktionen designet til at beregne den niende laveste værdi. Dette eksempel viser, hvordan dette gøres mest effektivt.

Antag, at du i tabellen nedenfor ønsker at finde de 3 nederste værdier. Skriv tallene 1, 2 og 3 i separate celler (D3, D4 og D5 i vores tilfælde). Indtast derefter følgende formel i E3 og træk den ned gennem E5:

=SMALL($B$2:$B$10, D3)

I E3 uddrager formlen den mindste værdi ved hjælp af tallet i D3 for den k Det vigtigste er at angive korrekte cellehenvisninger, som gør, at formlen kopieres korrekt i andre celler: absolut for array og for relative for k .

Hvis du ikke ønsker at skrive rækkerne manuelt, kan du bruge funktionen ROWS med en udvidelse af sortimentet reference til at give den k Hertil laver vi en absolut reference for den første celle (eller låser kun rækkekoordinaten som B$2) og en relativ reference for den sidste celle:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Resultatet er, at intervalreferencen udvides, efterhånden som formlen kopieres nedad i kolonnen. I D2 giver ROWS(B$2:B2) 1 for k I D3 giver ROWS(B$2:B3) 2, og vi får den næstlaveste omkostning, osv.

Du skal blot kopiere formlen gennem 5 celler, så får du de 5 nederste værdier:

Summen nederste N-værdier

Vil du finde en sum af de mindste n værdier i et datasæt? Hvis du allerede har udtrukket værdierne som vist i det foregående eksempel, er den nemmeste løsning en SUM-formel som:

=SUM(E3:E5)

Du kan også lave en uafhængig formel ved at bruge funktionen SMALL sammen med SUMPRODUCT:

For at få summen af de 3 nederste værdier i vores datasæt har formlen denne form:

=SUMPRODUKT(SMALL(B2:B10, {1,2,3}))

SUM-funktionen giver det samme resultat:

=SUM(SMALL(B2:B10, {1,2,3}))

Bemærk. Hvis du bruger cellehenvisninger i stedet for arraykonstant for k skal du trykke på Ctrl + Shift + Enter for at gøre det til en arrayformel. I Excel 365, der understøtter dynamiske arrays, fungerer SUM SMALL som en almindelig formel i begge tilfælde.

Sådan fungerer denne formel:

I en almindelig formel returnerer SMALL en enkelt k- mindste værdi i et område. I dette tilfælde angiver vi en array-konstant som {1,2,3} for k-argumentet, hvilket tvinger den til at returnere et array med de 3 mindste værdier:

{29240, 43610, 58860}

SUMPRODUCT- eller SUM-funktionen lægger tallene i arrayet sammen og udsender summen. Det er det hele!

INDEX MATCH SMALL-formel til at få de mindste matches

I situationer, hvor du ønsker at hente data, der er forbundet med den mindste værdi, skal du bruge den klassiske INDEX MATCH-kombination med SMALL som opslagsværdi:

Hvor:

• Return_array er et område, hvorfra der skal udtrækkes tilknyttede data.
• Opslag_array er et område, hvor der skal søges efter den laveste n-te værdi.
• N er placeringen af den mindste værdi af interesse.

For at få navnet på det projekt, der har de laveste omkostninger, er formlen i E3 f.eks:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Hvor A2:A10 er projektnavne, B2:B10 er omkostningerne og D3 er rangordenen fra den mindste til den mindste.

Kopier formlen til nedenstående celler (E4 og E5), og du vil få navnene på de 3 billigste projekter:

Bemærkninger:

• Denne løsning fungerer fint for et datasæt uden dubletter. Men hvis der er to eller flere dubletter i en numerisk kolonne, kan der opstå "uafgjort" i rangordningen, hvilket vil føre til forkerte resultater. I dette tilfælde skal du bruge en lidt mere sofistikeret formel til at bryde uafgjort.
• I Excel 365 kan denne opgave udføres ved hjælp af de nye dynamiske array-funktioner. Ud over at være meget enklere, løser denne fremgangsmåde automatisk problemet med bånd. Du kan finde alle detaljer i Sådan filtrerer du de nederste N-værdier i Excel.

Sortere tal fra lavest til højest med en formel

Jeg tror, at alle ved, hvordan man sætter tal i orden med Excel Sort-funktionen. Men ved du, hvordan man udfører sortering med en formel? Brugerne af Excel 365 kan gøre det på en nem måde med den nye SORT-funktion. I Excel 2019, 2016 og tidligere versioner fungerer SORT desværre ikke. Men hav lidt tillid, og SMALL kommer til undsætning :)

Ligesom i det første eksempel bruger vi ROWS-funktionen med en ekspanderende intervalreference til at øge k med 1 i hver række, hvor formlen er kopieret:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Indtast formlen i den første celle, og træk den derefter ned til lige så mange celler, som der er værdier i det oprindelige datasæt (C2:C10 i dette eksempel):

Tip. At sortere faldende , skal du bruge funktionen LARGE i stedet for SMALL.

Excel SMALL-formel for datoer og tidspunkter

Da datoer og tidspunkter også er numeriske værdier (i det interne Excel-system gemmes datoer som fortløbende tal og tidspunkter som decimalbrøker), kan SMALL-funktionen også håndtere dem uden nogen ekstra indsats fra din side.

Som du kan se på skærmbillederne nedenfor, fungerer en grundlæggende formel, som vi brugte til tal, også fint til datoer og tidspunkter:

=SMALL($B$2:$B$10, D2)

SMALL-formel til at finde de 3 tidligste datoer:

SMALL formel for at få de korteste 3 gange:

Det næste eksempel viser, hvordan funktionen SMALL kan hjælpe dig med at udføre en mere specifik opgave vedrørende datoer.

Find en tidligere dato, der ligger tættest på den dag i dag eller den angivne dato

Hvis du i en liste med datoer ønsker at finde den nærmeste dato før en bestemt dato, kan dette gøres ved at bruge funktionen SMALL i kombination med COUNTIF.

Med listen over datoer i B2:B10 og måldatoen i E1 returnerer følgende formel en tidligere dato, der ligger tættest på måldatoen:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

For at udtrække en dato, der ligger to datoer før datoen i E1, dvs. en tidligere dato, men én dato, er formlen:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

Sådan finder du en tidligere dato tættest på i dag , bruge funktionen TODAY til COUNTIF's kriterier:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

Tip. For at undgå fejl i situationer, hvor der ikke findes en dato, der matcher dine kriterier, kan du pakke IFERROR-funktionen ind i din formel, som her:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Ikke fundet")

Hvordan disse formler fungerer:

Den generelle idé er at tælle antallet af datoer, der er mindre end måldatoen med COUNTIF. Og denne optælling er præcis, hvad SMALL-funktionen har brug for til k argument.

Lad os se på det fra en anden vinkel for at forstå konceptet bedre:

Hvis 1-Aug-2020 (måldatoen i E1) optrådte i vores datasæt, ville det være den 7. største dato på listen. Der er derfor seks datoer mindre end den. Det betyder, at den 6. mindste dato er den dato, der ligger tættest på måldatoen.

Vi beregner først, hvor mange datoer der er mindre end datoen i E1 (resultatet er 6):

COUNTIF(B2:B10, "<"&E1)

Derefter indsættes tallet i det andet argument i SMALL:

=SMALL(B2:B10, 6)

For at få den næstsidste dato (som er den femte mindste dato i vores tilfælde), trækker vi 1 fra COUNTIFs resultat.

Sådan fremhæver du de nederste værdier i Excel

Hvis du vil fremhæve de mindste n værdier i din tabel med Excel betinget formatering, kan du enten bruge en indbygget Top/Bottom-indstilling eller oprette din egen regel baseret på en SMALL-formel. Den første metode er hurtigere og nemmere at anvende, mens den anden giver mere kontrol og fleksibilitet. De nedenstående trin viser dig, hvordan du opretter en brugerdefineret regel:

1. Vælg det område, hvor du vil fremhæve de nederste værdier. I vores tilfælde er tallene i B2:B10, så vi vælger det. Hvis du vil fremhæve hele rækker, skal du vælge A2:B10.
2. På den Hjem under fanen, i fanen Stilarter gruppe, klik på Betinget formatering > Ny regel .
3. I den Ny formateringsregel dialogboksen, vælg Brug en formel til at bestemme, hvilke celler der skal formateres.
4. I den Formater værdier, hvor denne formel er sand feltet, skal du indtaste en formel som denne:

   =B2<=SMALL($B$2:$B$10, 3)

   Hvor B2 er cellen længst til venstre i det numeriske område, der skal kontrolleres, $B$2:$B$10 er hele området, og 3 er den n de nederste værdier, der skal fremhæves.

   I din formel skal du være opmærksom på referencetyperne: den yderste venstre celle er en relativ reference (B2), mens intervallet er den absolutte reference ($B$2:$B$10).

5. Klik på den Format knappen og vælg det format, du ønsker.
6. Klik på OK to gange for at lukke begge dialogvinduer.

Færdig! De tre nederste værdier i kolonne B er fremhævet:

Du kan finde flere oplysninger under Excel betinget formatering baseret på formler.

Excel SMALL-funktionen virker ikke

Som du lige har set i vores eksempler, er det ret nemt at bruge SMALL-funktionen i Excel, og du vil sandsynligvis ikke have problemer med den. Hvis din formel ikke virker, vil det højst sandsynligt være en #NUM! fejl, som kan opstå af følgende årsager:

• Array er tom eller ikke indeholder en enkelt numerisk værdi.
• k værdien er mindre end nul (en dum slåfejl kan koste dig timevis af fejlfinding!) eller overstiger antallet af værdier i arrayet.

Sådan bruger du en SMALL-formel i Excel til at finde og fremhæve de nederste tal i et datasæt. Hvis du kender andre scenarier, hvor funktionen er nyttig, er du velkommen til at dele den i kommentarerne. Tak for læsningen og håber at se dig på vores blog i næste uge!

Arbejdsbog til download

Excel SMALL-formeleksempler (.xlsx-fil)