Selles lühikeses õpetuses räägime Exceli funktsioonist SMALL, kuidas see töötab ja kuidas seda kasutada N-kordse väikseima arvu, kuupäeva või kellaaja leidmiseks.

Vajadus leida töölehel mõned kõige väiksemad numbrid? Seda on üsna lihtne teha Exceli sorteerimisfunktsiooniga. Sa ei taha raisata aega andmete uuesti sorteerimisele iga muudatuse korral? Funktsioon SMALL aitab sul kiiresti leida kõige väiksema väärtuse, suuruselt teise, kolmanda ja nii edasi.

Exceli SMALL funktsioon

SMALL on statistiline funktsioon, mis tagastab andmekogumi n-ndat väikseimat väärtust.

Funktsiooni SMALL süntaks sisaldab kahte argumenti, mis on mõlemad nõutavad.

SMALL(array, k)

Kus:

• Array - massiivi või lahtrite vahemiku, millest eraldada väikseim väärtus.
• K - täisarv, mis näitab positsiooni madalaimast tagastatavast väärtusest, st k-ndast väikseimast.

Funktsioon on saadaval kõigis Exceli versioonides Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010 ja varasemates versioonides.

Näpunäide. Kriteeriumidega k-ndale madalaima väärtuse leidmiseks kasutage Exceli valemit SMALL IF.

Põhiline SMALL valem Excelis

SMALL valemit on selle põhivormis väga lihtne koostada - te lihtsalt määrate vahemiku ja positsiooni väikseimast tagastatavast elemendist.

Oletame, et soovime välja võtta numbrite nimekirjast B2:B10 3. väikseima väärtuse. Valem on nii lihtne kui:

=SMALL(B2:B10, 3)

Et teil oleks lihtsam tulemust kontrollida, on veerg B järjestatud kasvavas järjekorras:

4 asja, mida peaksite teadma SMALL funktsiooni kohta

Järgnevad kasutamismärkused aitavad teil paremini mõista funktsiooni SMALL käitumist ja vältida segadust oma valemite koostamisel.

1. Iga tühjad lahtrid , tekst väärtused ja loogiline väärtused TRUE ja FALSE massiivi argumenti ignoreeritakse.
2. Kui massiivi sisaldab ühte või mitut vead tagastatakse viga.
3. Juhul, kui on olemas duplikaadid aadressil massiivi Näiteks kui kaks lahtrit sisaldavad arvu 1 ja funktsioon SMALL on konfigureeritud nii, et see tagastab väikseima ja teise väikseima väärtuse, siis saate mõlemal juhul 1.
4. Eeldades, et n on väärtuste arv aastal massiivi , SMALL(array,1) tagastab väikseima väärtuse ja SMALL(array,n) valib suurima väärtuse.

Kuidas kasutada funktsiooni SMALL Excelis - valemite näited

Ja nüüd vaatame veel mõned näited Exceli funktsiooni SMALL kohta, mis lähevad selle põhikasutusest kaugemale.

Leia 3, 5, 10 jne. alumist väärtust.

Nagu te juba teate, on funktsioon SMALL mõeldud selleks, et arvutada n-ndat väikseimat väärtust. See näide näitab, kuidas seda kõige tõhusamalt teha.

Oletame, et soovite leida allolevas tabelis 3 alumist väärtust. Selleks sisestage numbrid 1, 2 ja 3 eraldi lahtritesse (meie puhul D3, D4 ja D5). Seejärel sisestage E3 lahtrisse järgmine valem ja lohistage see läbi E5:

=SMALL($B$2:$B$10, D3)

E3 valemis võetakse väikseim väärtus, kasutades numbri D3 jaoks esitatud arvu k argument. Oluline on anda õiged lahtriviited, tänu millele valem kopeerub korrektselt teistesse lahtritesse: absoluutne for massiivi ja suhteline k .

Sa ei taha vaeva näha ridade käsitsi sisestamisega? Kasuta funktsiooni ROWS koos funktsiooniga laienev valik viide, et anda k väärtus. Selleks teeme esimese lahtri jaoks absoluutse viite (või lukustame ainult rea koordinaadi nagu B$2) ja viimase lahtri jaoks suhtelise viite:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Selle tulemusena laieneb vahemiku viide, kui valemit kopeeritakse veeru alla. D2-s annab ROWS(B$2:B2) 1 jaoks k ja valem annab madalaima maksumuse. D3-s annab ROWS(B$2:B3) tulemuseks 2 ja me saame 2. madalaima maksumuse jne.

Lihtsalt kopeeri valem läbi 5 lahtri ja saad 5 alumist väärtust:

Summa alumine N väärtus

Tahad leida andmekogumi väikseimate n väärtuste summa? Kui oled juba väärtused välja võtnud, nagu eelmises näites näidatud, on kõige lihtsam lahendus selline SUMMA valem:

=SUM(E3:E5)

Või saate teha sõltumatu valemi, kasutades funktsiooni SMALL koos funktsiooniga SUMPRODUCT:

Et saada meie andmekogumi 3 alumise väärtuse summa, võtab valem sellise kuju:

=SUMPRODUCT(SMALL(B2:B10, {1,2,3}))

Funktsioon SUM annab sama tulemuse:

=SUM(SMALL(B2:B10, {1,2,3}))

Märkus. Kui kasutate lahtri viited mitte massiivi konstant jaoks k , peate vajutama Ctrl + Shift + Enter, et muuta see massiivi valemiks. Excel 365s, mis toetab dünaamilisi massiive, töötab SUM SMALL mõlemal juhul tavalise valemina.

Kuidas see valem töötab:

Tavalise valemi puhul tagastab SMALL ühe k-kümnenda väikseima väärtuse vahemikus. Sel juhul anname k argumendiks massiivi konstandi {1,2,3}, mis sunnib seda tagastama 3 väikseima väärtuse massiivi:

{29240, 43610, 58860}

Funktsioon SUMPRODUCT või SUMM liidab massiivi numbrid kokku ja väljastab kogusumma. See on kõik!

INDEX MATCH SMALL valemiga saada väikseimad vasted

Olukorras, kus soovite leida väikseima väärtusega seotud andmeid, kasutage klassikalist INDEX MATCH-kombinatsiooni koos SMALL-iga otsinguväärtuse jaoks:

Kus:

• Return_array on vahemik, millest eraldatakse seotud andmed.
• Lookup_array on vahemik, kus otsitakse väikseimat n-ndat väärtust.
• N on väikseima huvipakkuva väärtuse asukoht.

Näiteks, et saada kõige madalama maksumusega projekti nimi, on E3 valem järgmine:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Kus A2:A10 on projekti nimed, B2:B10 on kulud ja D3 on järjestus alates väikseimast.

Kopeerige valem allolevatesse lahtritesse (E4 ja E5) ja saate 3 kõige odavama projekti nimed:

Märkused:

• See lahendus töötab hästi andmekogumi puhul, millel ei ole dubleeringuid. Kaks või enam dubleerivat väärtust numbrilises veerus võivad aga tekitada pingereas "sidemeid", mis viivad valede tulemusteni. Sellisel juhul kasutage sidemete katkestamiseks veidi keerukamat valemit.
• Excel 365s saab seda ülesannet täita uute dünaamiliste massiivi funktsioonide abil. Lisaks sellele, et see on palju lihtsam, lahendab see lähenemisviis automaatselt ka sidemete probleemi. Täielikumat teavet leiate jaotisest Kuidas filtreerida N alumist väärtust Excelis.

Sorteeri numbrid madalaimast kõrgeimani valemiga

Usun, et kõik teavad, kuidas Exceli sorteerimisfunktsiooniga numbreid järjestada. Aga kas te teate, kuidas teha sorteerimist valemiga? Excel 365 kasutajad saavad seda teha lihtsal viisil uue funktsiooniga SORT. Excel 2019, 2016 ja varasemates versioonides SORT paraku ei tööta. Aga uskuge natuke ja SORT tuleb appi :)

Nagu esimeses näites, kasutame me funktsiooni ROWS koos laiendava vahemiku viitega, et suurendada k 1 võrra igas reas, kuhu valemit kopeeritakse:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

Sisestage valem esimesse lahtrisse ja lohistage see seejärel nii paljudesse lahtritesse, kui palju on väärtusi algses andmekogumis (antud näites C2:C10):

Näpunäide. Sorteerimiseks laskuv , kasutage funktsiooni LARGE asemel SMALL.

Exceli SMALL valem kuupäevade ja kellaaegade jaoks

Kuna kuupäevad ja kellaajad on samuti numbrilised väärtused (Exceli sisesüsteemis salvestatakse kuupäevad järjestikuste numbritena ja kellaajad kümnendmurdudena), saab funktsioon SMALL neid samuti käsitleda, ilma et te peaksite tegema lisapingutusi.

Nagu näete allolevatel ekraanipiltidel, töötab põhivalem, mida kasutasime numbrite puhul, suurepäraselt ka kuupäevade ja kellaaegade puhul:

=SMALL($B$2:$B$10, D2)

Väike valem, et leida 3 varaseimat kuupäeva:

SMALL valemiga saada lühim 3 korda:

Järgmine näide näitab, kuidas funktsioon SMALL aitab teil täita konkreetsemat kuupäeva puudutavat ülesannet.

Leia eelmine kuupäev, mis on kõige lähemal tänasele või määratud kuupäevale.

Oletame, et soovite leida kuupäevade loetelust lähima kuupäeva enne määratud kuupäeva. Seda saab teha, kasutades funktsiooni SMALL koos funktsiooniga COUNTIF.

Kui kuupäevade nimekiri on B2:B10 ja sihtkuupäev on E1, annab järgmine valem tagasi sihtkuupäevale lähima eelneva kuupäeva:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1))

Selleks, et eraldada kuupäev, mis on kaks kuupäeva enne kuupäeva E1, st eelmine, kuid üks kuupäev, on valem järgmine:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1)

Mineviku kuupäeva leidmiseks kõige lähemal tänasele päevale , kasutage COUNTIFi kriteeriumide jaoks funktsiooni TODAY:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY()))

Vihje. Et vältida vigu olukorras, kus teie kriteeriumidele vastavat kuupäeva ei leita, võite oma valemi ümber mähida funktsiooni IFERROR, näiteks nii:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10, "<"&E1)-1), "Ei leitud")

Kuidas need valemid toimivad:

Üldine mõte on loendada COUNTIFi abil sihtkuupäevast väiksemate kuupäevade arvu. Ja just seda loendust vajab funktsioon SMALL funktsiooni k argument.

Et mõistet paremini mõista, vaatleme seda teise nurga alt:

Kui meie andmekogumisse ilmuks 1-august-2020 (sihtkuupäev E1), oleks see nimekirjas 7. suurim kuupäev. Järelikult on sellest kuus väiksemat kuupäeva. See tähendab, et 6. väikseim kuupäev on sihtkuupäevale kõige lähemal asuv eelmine kuupäev.

Niisiis, kõigepealt arvutame, mitu kuupäeva on väiksem kui kuupäev E1 (tulemus on 6):

COUNTIF(B2:B10, "<"&E1)

Ja siis ühendage arv SMALLi 2. argumenti:

=SMALL(B2:B10, 6)

Et saada üle-eelmine kuupäev (mis on meie puhul 5. väikseim kuupäev), lahutame COUNTIFi tulemusest 1.

Kuidas Excelis alumisi väärtusi esile tõsta

Selleks, et Exceli tingimusliku vormindamisega tabelis kõige väiksemaid n väärtusi esile tõsta, saate kasutada kas sisseehitatud ÜLEMINE/ALAMINE võimalust või luua omaenda reegli, mis põhineb valemil SMALL. Esimene meetod on kiirem ja lihtsamini rakendatav, teine aga pakub rohkem kontrolli ja paindlikkust. Allpool toodud sammud juhatavad teid läbi kohandatud reegli loomise:

1. Valige vahemik, mille alumist väärtust soovite esile tõsta. Meie puhul on numbrid vahemikus B2:B10, seega valime selle. Kui soovite esile tõsta terveid ridu, siis valige A2:B10.
2. On Kodu vahekaardil Stiilid rühma, klõpsake Tingimuslik vormindamine > Uus reegel .
3. In the Uus vormindamise reegel dialoogiaknas valige Kasutage valemit, et määrata, millised lahtrid tuleb vormindada.
4. In the Vormindage väärtused, mille puhul see valem on tõene kasti sisestage selline valem:

   =B2<=SMALL($B$2:$B$10, 3)

   Kus B2 on kontrollitava numbrilise vahemiku kõige vasakpoolsem lahter, $B$2:$B$10 on kogu vahemik ja 3 on n alumised väärtused, mida esile tõsta.

   Pidage oma valemis silmas viitetüüpe: kõige vasakpoolsem lahter on suhteline viide (B2), samas kui vahemik on absoluutne viide ($B$2:$B$10).

5. Klõpsake nuppu Formaat nuppu ja valige mis tahes formaat, mis teile meeldib.
6. Mõlema dialoogiakna sulgemiseks klõpsake kaks korda OK.

Valmis! 3 alumist väärtust veerus B on esile tõstetud:

Lisateavet leiate jaotisest Exceli tingimuslik vormindamine valemi alusel.

Exceli SMALL funktsioon ei tööta

Nagu meie näidetest just nägite, on funktsiooni SMALL kasutamine Excelis üsna lihtne ja tõenäoliselt ei teki teil sellega raskusi. Kui teie valem ei tööta, siis on tõenäoliselt tegemist #NUM! veaga, mis võib tekkida järgmistel põhjustel:

• Array on tühi või ei sisalda ühtegi arvväärtust.
• The k väärtus on väiksem kui null (rumal trükiviga võib maksta teile tundide kaupa veaotsingut!) või ületab massiivi väärtuste arvu.

See ongi, kuidas kasutada Excelis valemit SMALL, et leida ja esile tõsta alumine number andmekogumis. Kui te teate muid stsenaariume, kus see funktsioon tuleb kasuks, olete väga oodatud jagama kommentaarides. Tänan teid lugemise eest ja loodan, et näeme teid järgmisel nädalal meie blogis!

Praktiline töövihik allalaadimiseks

Excel SMALL valemite näited (.xlsx fail)