V tem kratkem vodniku bomo govorili o Excelovi funkciji SMALL, kako deluje in kako jo uporabiti za iskanje N-tega najmanjšega števila, datuma ali časa.

Potrebujete najti nekaj najnižjih številk v delovnem listu? To je povsem enostavno s funkcijo Excel Sort. Ne želite izgubljati časa s ponovnim razvrščanjem podatkov ob vsaki spremembi? Funkcija SMALL vam bo pomagala hitro najti najnižjo vrednost, drugo najmanjšo, tretjo najmanjšo in tako naprej.

Excelova funkcija SMALL

SMALL je statistična funkcija, ki vrne n-to najmanjšo vrednost v nizu podatkov.

Sintaksa funkcije SMALL vključuje dva argumenta, ki sta obvezna.

SMALL(polje, k)

Kje:

• Polje - polje ali niz celic, iz katerih se izlušči najmanjša vrednost.
• K - celo število, ki označuje položaj od najnižje vrednosti, ki se vrne, tj. k-ta najmanjša vrednost.

Funkcija je na voljo v vseh različicah programov Excel za Office 365, Excel 2021, Excel 2019, Excel 2016, Excel 2013, Excel 2010 in prejšnjih.

Nasvet. Če želite poiskati k-to najnižjo vrednost z merili, uporabite Excelovo formulo SMALL IF.

Osnovna formula SMALL v Excelu

Formula SMALL je v svoji osnovni obliki zelo enostavna za sestavo - določite le območje in položaj od najmanjšega elementa, ki ga želite vrniti.

V seznamu števil v B2:B10 želite izpisati tretjo najmanjšo vrednost. Formula je preprosta:

=SMALL(B2:B10, 3)

Za lažje preverjanje rezultatov je stolpec B razvrščen v naraščajočem vrstnem redu:

4 stvari, ki jih morate vedeti o funkciji SMALL

Naslednje opombe o uporabi vam bodo pomagale bolje razumeti obnašanje funkcije SMALL in se izogniti zmedi pri oblikovanju lastnih formul.

1. Vse prazne celice , besedilo vrednosti in logično vrednosti TRUE in FALSE v polje se ne upošteva.
2. Če polje vsebuje enega ali več napake , je vrnjena napaka.
3. V primeru, da obstajajo podvojitve na spletnem mestu polje Če na primer dve celici vsebujeta število 1 in je funkcija SMALL nastavljena tako, da vrne najmanjšo in drugo najmanjšo vrednost, boste v obeh primerih dobili 1.
4. Ob predpostavki, da je n število vrednosti v polje , SMALL(array,1) bo vrnil najnižjo vrednost, SMALL(array,n) pa bo izbral najvišjo vrednost.

Kako uporabljati funkcijo SMALL v Excelu - primeri formul

Zdaj pa si oglejmo še nekaj primerov Excelove funkcije SMALL, ki presegajo njeno osnovno uporabo.

Poiščite spodnje 3, 5, 10 itd. vrednosti

Kot že veste, je funkcija SMALL zasnovana tako, da izračuna n-to najmanjšo vrednost. Ta primer prikazuje, kako to storiti najučinkoviteje.

V spodnji tabeli, recimo, želite poiskati spodnje 3 vrednosti. V ta namen vnesite številke 1, 2 in 3 v ločene celice (v našem primeru D3, D4 in D5). Nato vnesite naslednjo formulo v E3 in jo povlecite navzdol skozi E5:

=SMALL($B$2:$B$10, D3)

V E3 formula pridobi najmanjšo vrednost z uporabo števila v D3 za k argument. Ključno je, da navedete ustrezne reference na celice, zaradi katerih se formula pravilno kopira v druge celice: absolutno za polje in relativno za k .

Ne želite ročno vnašati vrstic? Uporabite funkcijo ROWS z razširitev ponudbe sklic na zagotavljanje k Za to naredimo absolutno referenco za prvo celico (ali zaklenemo samo koordinato vrstice, kot je B$2) in relativno referenco za zadnjo celico:

=SMALL($B$2:$B$10, ROWS(B$2:B2))

Zaradi tega se referenca območja razširi, ko se formula kopira navzdol po stolpcu. V D2, ROWS(B$2:B2) ustvari 1 za k V vrstici D3 je rezultat ROWS(B$2:B3) 2 in dobimo drugi najnižji strošek in tako naprej.

Prekopirajte formulo skozi 5 celic in dobili boste spodnjih 5 vrednosti:

Vsota spodnjih vrednosti N

Če ste že izločili vrednosti, kot je prikazano v prejšnjem primeru, je najlažja rešitev formula SUM, kot je:

=SUM(E3:E5)

Lahko pa pripravite neodvisno formulo z uporabo funkcije SMALL skupaj s funkcijo SUMPRODUCT:

Če želimo dobiti vsoto spodnjih treh vrednosti v našem nizu podatkov, je formula takšna:

=SUMPRODUKT(SMALL(B2:B10, {1,2,3})

Funkcija SUM bo dala enak rezultat:

=SUM(SMALL(B2:B10, {1,2,3})

Opomba: Če uporabljate reference na celice namesto konstantnega polja za k , morate pritisniti kombinacijo tipk Ctrl + Shift + Enter, da postane formula za matriko. V Excelu 365, ki podpira dinamične matrike, deluje SUM SMALL v obeh primerih kot običajna formula.

Kako deluje ta formula:

V običajni formuli SMALL vrne eno samo najmanjšo vrednost v območju k. V tem primeru za argument k podamo konstanto polja, kot je {1,2,3}, kar prisili formulo, da vrne polje treh najmanjših vrednosti:

{29240, 43610, 58860}

Funkcija SUMPRODUCT ali SUM sešteje števila v polju in izpiše skupno vrednost. To je to!

Formula INDEX MATCH SMALL za iskanje najmanjših zadetkov

Če želite pridobiti podatke, povezane z najmanjšo vrednostjo, uporabite klasično kombinacijo INDEX MATCH s SMALL za vrednost iskanja:

Kje:

• Return_array je območje, iz katerega se pridobijo povezani podatki.
• Lookup_array je območje, v katerem se išče n-ta najnižja vrednost.
• N je položaj najmanjše zanimive vrednosti.

Če želite na primer dobiti ime projekta z najnižjimi stroški, je formula v E3 naslednja:

=INDEX($A$2:$A$10, MATCH(SMALL($B$2:$B$10, D3), $B$2:$B$10, 0))

Pri čemer so A2:A10 imena projektov, B2:B10 so stroški, D3 pa je vrstni red od najmanjšega.

Kopirajte formulo v spodnji celici (E4 in E5) in dobili boste imena treh najcenejših projektov:

Opombe:

• Ta rešitev je primerna za nabor podatkov, ki nima podvojenih vrednosti. Vendar pa lahko dve ali več podvojenih vrednosti v številčnem stolpcu ustvarita "povezave" pri razvrščanju, kar privede do napačnih rezultatov. V tem primeru uporabite nekoliko bolj izpopolnjeno formulo za prekinitev povezav.
• V Excelu 365 lahko to nalogo opravite s pomočjo novih funkcij dinamičnega polja. Poleg tega, da je ta pristop veliko preprostejši, samodejno reši tudi problem povezav. Za vse podrobnosti glejte Kako filtrirati spodnje N vrednosti v Excelu.

Razvrščanje številk od najmanjše do največje s formulo

Verjamem, da vsi veste, kako razvrstiti številke s funkcijo Excel Sort. Toda ali veste, kako izvesti razvrščanje s formulo? Uporabniki programa Excel 365 lahko to storijo na preprost način z novo funkcijo SORT. V Excelu 2019, 2016 in prejšnjih različicah funkcija SORT žal ne deluje. Toda imejte malo vere in funkcija SMALL vam bo priskočila na pomoč :)

Tako kot v prvem primeru uporabimo funkcijo ROWS s sklicem na razširitveno območje za povečanje k za 1 v vsaki vrstici, v katero je kopirana formula:

=SMALL($A$2:$A$10, ROWS(A$2:A2))

V prvo celico vnesite formulo in jo povlecite navzdol v toliko celic, kolikor je vrednosti v prvotnem nizu podatkov (C2:C10 v tem primeru):

Nasvet. Za razvrščanje padajoče namesto funkcije SMALL uporabite funkcijo LARGE.

Excelova mala formula za datume in čase

Ker so tudi datumi in časi številčne vrednosti (v notranjem sistemu Excel so datumi shranjeni kot zaporedna števila, časi pa kot desetiški ulomki), jih lahko funkcija SMALL obdeluje tudi brez dodatnega truda na vaši strani.

Kot lahko vidite na spodnjih slikah, osnovna formula, ki smo jo uporabili za številke, odlično deluje tudi za datume in čase:

=SMALL($B$2:$B$10, D2)

MALA formula za iskanje prvih treh datumov:

Majhna formula za najkrajši 3-kratni čas:

Naslednji primer prikazuje, kako vam lahko funkcija SMALL pomaga opraviti bolj specifično nalogo v zvezi z datumi.

Poiščite prejšnji datum, ki je najbližji današnjemu ali določenemu datumu

Predpostavljajte, da želite na seznamu datumov poiskati najbližji datum pred določenim datumom. To lahko storite z uporabo funkcije SMALL v kombinaciji s COUNTIF.

S seznamom datumov v B2:B10 in ciljnim datumom v E1 bo naslednja formula vrnila predhodni datum, ki je najbližji ciljnemu datumu:

=SMALL(B2:B10, COUNTIF(B2:B10,"<"&E1))

Za izpis datuma, ki je dva datuma pred datumom v E1, tj. predpretekli datum, je formula naslednja:

=SMALL(B2:B10, COUNTIF(B2:B10,"<"&E1)-1)

Iskanje preteklega datuma najbližje današnjemu dnevu , za merila COUNTIF uporabite funkcijo TODAY:

=SMALL(B2:B10, COUNTIF(B2:B10, "<"&TODAY())

Nasvet. Če želite preprečiti napake v primerih, ko datum, ki ustreza vašim merilom, ni najden, lahko funkcijo IFERROR ovijete okoli svoje formule, kot sledi:

=IFERROR(SMALL(B2:B10, COUNTIF(B2:B10,"<"&E1)-1), "Ni najden")

Kako te formule delujejo:

Splošna zamisel je, da s COUNTIF preštejemo število datumov, ki so manjši od ciljnega datuma. To število je točno tisto, kar funkcija SMALL potrebuje za k argument.

Za boljše razumevanje koncepta si ga oglejmo z drugega zornega kota:

Če bi se 1. avgust 2020 (ciljni datum v E1) pojavil v našem naboru podatkov, bi bil sedmi največji datum na seznamu. Posledično je od njega manjših datumov šest. To pomeni, da je šesti najmanjši datum prejšnji datum, ki je najbližji ciljnemu datumu.

Najprej izračunamo, koliko datumov je manjših od datuma v E1 (rezultat je 6):

COUNTIF(B2:B10, "<"&E1)

Nato število vstavite v 2. argument v ukazu SMALL:

=SMALL(B2:B10, 6)

Da bi dobili predzadnji datum (ki je v našem primeru peti najmanjši datum), od rezultata COUNTIF odštejemo 1.

Kako poudariti spodnje vrednosti v Excelu

Če želite s pogojnim oblikovanjem v Excelu poudariti najmanjše n vrednosti v tabeli, lahko uporabite vgrajeno možnost Top/Bottom ali pa določite lastno pravilo na podlagi formule SMALL. Prvi način je hitrejši in enostavnejši za uporabo, drugi pa omogoča več nadzora in prilagodljivosti. V spodnjih korakih boste spoznali, kako ustvariti pravilo po meri:

1. Izberite območje, v katerem želite poudariti spodnje vrednosti. V našem primeru so številke v B2:B10, zato ga izberemo. Če želite poudariti celotne vrstice, izberite A2:B10.
2. Na Domov v zavihku Stili skupino, kliknite Pogojno oblikovanje > Novo pravilo .
3. V Novo pravilo za oblikovanje pogovorno okno, izberite S formulo določite, katere celice je treba oblikovati.
4. V Oblikovanje vrednosti, pri katerih je ta formula resnična vnesite formulo, kot je ta:

   =B2<=SMALL($B$2:$B$10, 3)

   Pri čemer je B2 skrajna leva celica številskega območja, ki ga je treba preveriti, $B$2:$B$10 je celotno območje, 3 pa je n spodnje vrednosti, ki jih želite poudariti.

   V formuli ne pozabite na vrste referenc: najbolj leva celica je relativna referenca (B2), območje pa je absolutna referenca ($B$2:$B$10).

5. Kliknite na Format in izberite želeno obliko.
6. Dvakrat kliknite OK, da zaprete obe pogovorni okni.

Končano! Spodnje tri vrednosti v stolpcu B so označene:

Za več informacij glejte Excelovo pogojno oblikovanje na podlagi formule.

Excelova funkcija SMALL ne deluje

Kot ste pravkar videli iz naših primerov, je uporaba funkcije SMALL v Excelu precej preprosta in verjetno ne boste imeli težav z njo. Če vaša formula ne deluje, bo to najverjetneje napaka #NUM!, do katere lahko pride zaradi naslednjih razlogov:

• Polje je prazna ali ne vsebuje ene same številčne vrednosti.
• Spletna stran k je manjša od nič (neumna tiskarska napaka vas lahko stane več ur odpravljanja težav!) ali presega število vrednosti v polju.

To je način uporabe formule SMALL v Excelu za iskanje in poudarjanje najnižjih številk v nizu podatkov. Če poznate še kakšne druge scenarije, kjer funkcija pride prav, vas vabim, da jih delite v komentarjih. Zahvaljujem se vam za branje in upam, da se naslednji teden vidimo na našem blogu!

Praktični delovni zvezek za prenos

Primeri Excelovih MALIH formul (.xlsx datoteka)