U našem prethodnom vodiču gledali smo Excel Ako sadrži formule koje vraćaju neku vrijednost u drugi stupac ako ciljna ćelija sadrži zadanu vrijednost. Osim toga, što još možete učiniti ako ćelija sadrži određeni tekst ili broj? Razne stvari poput brojanja ili zbrajanja ćelija, isticanja, uklanjanja ili kopiranja cijelih redaka i još mnogo toga.

Excel 'Broj ako ćelija sadrži' primjeri formula

U Microsoft Excel, postoje dvije funkcije za brojanje ćelija na temelju njihovih vrijednosti, COUNTIF i COUNTIFS. Ove funkcije pokrivaju većinu, ali ne sve scenarije. Donji primjeri će vas naučiti kako odabrati odgovarajući broj ako ćelija sadrži formulu za vaš određeni zadatak.

Brojte ako ćelija sadrži tekst

U situacijama kada želite brojati ćelije koje sadrže bilo koji tekst , upotrijebite zamjenski znak zvjezdice kao kriterij u formuli COUNTIF:

Ili upotrijebite funkciju SUMPRODUCT u kombinaciji s ISTEXT:

U drugoj formuli, funkcija ISTEXT procjenjuje svaku ćeliju u navedenom rasponu i vraća niz vrijednosti TRUE (tekst) i FALSE (ne tekst); dvostruki unarni operator (--) pretvara TRUE i FALSE u 1 i 0; a SUMPRODUCT zbraja brojeve.

Kao što je prikazano na slici ispod, obje formule daju isti rezultat:

=COUNTIF(A2:A10,"*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Možda biste također željelipogledajte kako brojati ćelije koje nisu prazne u Excelu.

Brojite ako ćelija sadrži određeni tekst

Da biste brojali ćelije koje sadrže određeni tekst, koristite jednostavnu formulu COUNTIF kao što je prikazano u nastavku, gdje range su ćelije koje treba provjeriti, a text je tekstualni niz za pretraživanje ili referenca na ćeliju koja sadrži tekstualni niz.

Na primjer, za brojanje ćelija u rasponu A2:A10 koje sadrže riječ "haljina", koristite ovu formulu:

=COUNTIF(A2:A10, "dress")

Ili onaj prikazan na snimci zaslona:

Ovdje možete pronaći više primjera formula: Kako brojati ćelije s tekstom u Excelu: bilo koje, specifične, filtrirane ćelije.

Broj ako ćelija sadrži tekst (djelomično podudaranje)

Za prebrojavanje ćelija koje sadrže određeni podniz, upotrijebite funkciju COUNTIF sa zamjenskim znakom zvjezdice (*).

Na primjer, za prebrojavanje koliko ćelija u stupcu A sadrži "haljinu" kao dio svog sadržaja, upotrijebite ovu formulu:

=COUNTIF(A2:A10,"*dress*")

Ili upišite željeni tekst u neku ćeliju i spojite ga t ćelija sa zamjenskim znakovima:

=COUNTIF(A2:A10,"*"&D1&"*")

Za više informacija pogledajte: COUNTIF formule s djelomičnim podudaranjem.

Broj ako ćelija sadrži više podnizova (I logika)

Za brojanje ćelija s više uvjeta koristite funkciju COUNTIFS. Excel COUNTIFS može obraditi do 127 parova raspona/kriterija, a samo će ćelije koje ispunjavaju sve navedene uvjete bitiprebrojano.

Na primjer, da biste saznali koliko ćelija u stupcu A sadrži "haljina" I "plavo", upotrijebite jednu od sljedećih formula:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Ili

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Broji ako ćelija sadrži broj

Formula za brojanje ćelija s brojevima je najjednostavnija formula koju čovjek može zamisliti:

Imajte na umu da funkcija COUNT u Excelu broji ćelije koje sadrže bilo koju numeričku vrijednost uključujući brojeve, datume i vremena, jer su u Excelu posljednja dva također brojevi.

U našem slučaju, formula je sljedeća:

=COUNT(A2:A10)

Za brojanje ćelija koje NE sadrže brojeve, koristite funkciju SUMPRODUCT zajedno s ISNUMBER, a NE:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Zbroj ako ćelija sadrži tekst

Ako tražite Excel formulu za pronalaženje ćelija koje sadrže određeni tekst i zbrajanje odgovarajućih vrijednosti u drugom stupcu, upotrijebite funkciju SUMIF.

Na primjer, da biste saznali koliko haljina ima na zalihama, upotrijebite ovu formulu:

=SUMIF(A2:A10,"*dress*",B2:B10)

Gdje su A2:A10 teksta vrijednosti za provjeru, a B2:B10 su brojevi za zbrajanje.

Ili, stavite podniz od interesa u neku ćeliju (E1) i referencirajte tu ćeliju u svojoj formuli, kao što je prikazano na slici ispod:

Za zbroj s više kriterija koristite funkciju SUMIFS.

Na primjer, da biste saznali koliko je plavih haljina dostupno, idite ovom formulom:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Ili upotrijebite ovojedan:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Gdje su A2:A10 ćelije za provjeru, a B2:B10 ćelije za zbroj.

Izvedite različiti izračuni na temelju vrijednosti ćelije

U našem prošlom vodiču raspravljali smo o tri različite formule za testiranje više uvjeta i vraćanje različitih vrijednosti ovisno o rezultatima tih testova. A sada, da vidimo kako možete izvesti različite izračune ovisno o vrijednosti u ciljnoj ćeliji.

Pretpostavimo da imate brojeve prodaje u stupcu B i želite izračunati bonuse na temelju tih brojeva: ako je prodaja veća od 300 USD , bonus je 10%; za prodaju između $201 i $300 bonus je 7%; za prodaju između 101 i 200 USD bonus iznosi 5%, a nema bonusa za prodaju ispod 100 USD.

Da biste to učinili, jednostavno pomnožite prodaju (B2) s odgovarajućim postotkom. Kako znate s kojim postotkom množiti? Testiranjem različitih uvjeta s ugniježđenim IF-ovima:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

U stvarnim radnim listovima može biti prikladnije unijeti postotke u zasebne ćelije i referencirati te ćelije u vašoj formuli:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Ključna stvar je popravljanje referenci bonus ćelija sa znakom $ kako bi se spriječilo njihovo mijenjanje kada kopirate formulu niz stupac.

Uvjetno oblikovanje programa Excel ako ćelija sadrži određeni tekst

Ako želite istaknuti ćelije određenim tekstom, postavite pravilo uvjetnog oblikovanja programa Excel na temelju jednog od sljedećegformule.

Neosjetljivo na velika i mala slova:

Razlikuje velika i mala slova:

Na primjer, da biste istaknuli SKU-ove koji sadrže riječi "haljina", napravite pravilo uvjetnog oblikovanja pomoću formule u nastavku i primijenite ga na onoliko ćelija u stupcu A koliko vam je potrebno počevši od ćelije A2:

=SEARCH("dress", A2)>0

Formula uvjetnog oblikovanja programa Excel: ako ćelija sadrži tekst (više uvjeta)

Da biste istaknuli ćelije koje sadrže dva ili više tekstualnih nizova, ugniježdite nekoliko funkcija pretraživanja unutar I formule. Na primjer, da biste istaknuli ćelije "plava haljina", stvorite pravilo na temelju ove formule:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

Za detaljne korake pogledajte Kako izradite pravilo uvjetnog oblikovanja s formulom.

Ako ćelija sadrži određeni tekst, uklonite cijeli red

U slučaju da želite izbrisati retke koji sadrže određeni tekst, koristite Excelovu značajku Pronađi i zamijeni na ovaj način :

1. Odaberite sve ćelije koje želite provjeriti.
2. Pritisnite Ctrl + F za otvaranje dijaloškog okvira Pronađi i zamijeni .
3. U okvir Pronađi što , upišite tekst ili broj koji tražite i kliknite Pronađi sve
4. Kliknite bilo koji rezultat pretraživanja, a zatim pritisnite Ctrl + A za odabir svih.
5. Kliknite gumb Zatvori da zatvorite Pronađi i zamijeni
6. Pritisnite Ctrl i gumb minus u isto vrijeme ( Ctrl - ), što je Excelprečac za brisanje.
7. U dijaloškom okviru Brisanje odaberite Cijeli red i kliknite U redu. Gotovo!

Na snimci zaslona u nastavku brišemo retke koji sadrže "haljinu":

Ako ćelija sadrži, odaberite ili kopirajte cijele retke

U situacijama kada želite odabrati ili kopirati retke s relevantnim podacima, koristite Excelov AutoFilter za filtriranje takvih redaka. Nakon toga pritisnite Ctrl + A za odabir filtriranih podataka, Ctrl+C za kopiranje i Ctrl+V za lijepljenje podataka na drugu lokaciju.

Za filtriranje ćelija s dva ili više kriterija upotrijebite napredni filtar pronaći takve ćelije, a zatim kopirati cijele retke s rezultatima ili izdvojiti samo određene stupce.

Ovo je način na koji manipulirate ćelijama na temelju njihove vrijednosti u Excelu. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeći tjedan!

Radna bilježnica za vježbe

Excel If Cell Contains Then - primjeri (.xlsx datoteka)