Dans notre précédent tutoriel, nous avons examiné Excel Si contient des formules qui renvoient une valeur à une autre colonne si une cellule cible contient une valeur donnée. En dehors de cela, que pouvez-vous faire d'autre si une cellule contient un texte ou un nombre spécifique ? Une variété de choses telles que compter ou additionner des cellules, mettre en évidence, supprimer ou copier des lignes entières, et plus encore.

Exemples de formules Excel "Compter si la cellule contient".

Dans Microsoft Excel, il existe deux fonctions permettant de compter les cellules en fonction de leurs valeurs, COUNTIF et COUNTIFS. Ces fonctions couvrent la plupart des scénarios, mais pas tous. Les exemples ci-dessous vous apprendront à choisir une formule Count if cell contains appropriée pour votre tâche particulière.

Compter si la cellule contient du texte

Lorsque vous souhaitez compter les cellules contenant du texte, utilisez le caractère générique astérisque comme critère dans votre formule COUNTIF :

Ou bien, utilisez la fonction SUMPRODUCT en combinaison avec ISTEXT :

Dans la deuxième formule, la fonction ISTEXT évalue chaque cellule de la plage spécifiée et renvoie un tableau de valeurs VRAIES (texte) et FAUX (pas de texte) ; l'opérateur double unaire (--) transforme les valeurs VRAIES et FAUX en 1 et 0 ; et SUMPRODUCT additionne les nombres.

Comme le montre la capture d'écran ci-dessous, les deux formules donnent le même résultat :

=COUNTIF(A2:A10, "*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Vous pouvez également consulter la rubrique Comment compter les cellules non vides dans Excel.

Compter si la cellule contient un texte spécifique

Pour compter les cellules qui contiennent un texte spécifique, utilisez une simple formule COUNTIF comme indiqué ci-dessous, où gamme est la cellule à vérifier et texte est la chaîne de texte à rechercher ou une référence à la cellule contenant la chaîne de texte.

Par exemple, pour compter les cellules de la plage A2:A10 qui contiennent le mot "robe", utilisez cette formule :

=COUNTIF(A2:A10, "robe")

Ou celui qui est montré dans la capture d'écran :

Vous trouverez d'autres exemples de formules ici : Comment compter les cellules contenant du texte dans Excel : cellules quelconques, spécifiques, filtrées.

Compter si la cellule contient du texte (correspondance partielle)

Pour compter les cellules qui contiennent une certaine sous-chaîne, utilisez la fonction COUNTIF avec le caractère générique astérisque (*).

Par exemple, pour compter combien de cellules de la colonne A contiennent "robe" dans leur contenu, utilisez cette formule :

=COUNTIF(A2:A10,"*dress*")

Vous pouvez également saisir le texte souhaité dans une cellule et concaténer cette cellule avec les caractères génériques :

=COUNTIF(A2:A10,"*"&D1&"*")

Pour plus d'informations, veuillez consulter : Formules COUNTIF avec correspondance partielle.

Compter si la cellule contient plusieurs sous-chaînes (logique AND)

Pour compter les cellules avec plusieurs conditions, utilisez la fonction COUNTIFS. Excel COUNTIFS peut gérer jusqu'à 127 paires plage/critères, et seules les cellules qui remplissent toutes les conditions spécifiées seront comptées.

Par exemple, pour savoir combien de cellules de la colonne A contiennent "robe" ET "bleu", utilisez l'une des formules suivantes :

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Ou

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Compter si la cellule contient un nombre

La formule pour compter les cellules avec des chiffres est la formule la plus simple que l'on puisse imaginer :

N'oubliez pas que la fonction COUNT d'Excel compte les cellules contenant toute valeur numérique, y compris les nombres, les dates et les heures, car, dans Excel, ces deux dernières sont également des nombres.

Dans notre cas, la formule est la suivante :

=COUNT(A2:A10)

Pour compter les cellules qui ne contiennent PAS de chiffres, utilisez la fonction SUMPRODUCT avec ISNUMBER et NOT :

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Somme si la cellule contient du texte

Si vous recherchez une formule Excel pour trouver des cellules contenant un texte spécifique et additionner les valeurs correspondantes dans une autre colonne, utilisez la fonction SUMIF.

Par exemple, pour savoir combien de robes sont en stock, utilisez cette formule :

=SUMIF(A2:A10,"*dress*",B2:B10)

Où A2:A10 sont les valeurs de texte à vérifier et B2:B10 sont les nombres à additionner.

Ou bien, placez la sous-chaîne qui vous intéresse dans une cellule (E1), et faites référence à cette cellule dans votre formule, comme le montre la capture d'écran ci-dessous :

A somme avec plusieurs critères utilisez la fonction SUMIFS.

Par exemple, pour savoir combien de robes bleues sont disponibles, utilisez la formule suivante :

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Ou utilisez celui-ci :

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Où A2:A10 sont les cellules à vérifier et B2:B10 sont les cellules à additionner.

Effectuer différents calculs en fonction de la valeur de la cellule

Dans notre dernier tutoriel, nous avons abordé trois formules différentes pour tester plusieurs conditions et renvoyer différentes valeurs en fonction des résultats de ces tests. Maintenant, voyons comment effectuer différents calculs en fonction de la valeur d'une cellule cible.

Supposons que vous ayez des chiffres de vente dans la colonne B et que vous souhaitiez calculer les primes en fonction de ces chiffres : si une vente est supérieure à 300 $, la prime est de 10 % ; pour les ventes comprises entre 201 et 300 $, la prime est de 7 % ; pour les ventes comprises entre 101 et 200 $, la prime est de 5 %, et aucune prime pour les ventes inférieures à 100 $.

Pour ce faire, il suffit de multiplier les ventes (B2) par un pourcentage correspondant. Comment savoir par quel pourcentage multiplier ? En testant différentes conditions avec des IF imbriqués :

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

Dans les feuilles de calcul réelles, il peut être plus pratique de saisir les pourcentages dans des cellules séparées et de faire référence à ces cellules dans votre formule :

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

L'essentiel est de fixer les références des cellules bonus avec le signe $ pour éviter qu'elles ne changent lorsque vous copiez la formule vers le bas de la colonne.

Mise en forme conditionnelle d'Excel si la cellule contient un texte spécifique

Si vous voulez mettre en évidence les cellules contenant un certain texte, configurez une règle de formatage conditionnel Excel basée sur l'une des formules suivantes.

Insensible à la casse :

Sensible à la casse :

Par exemple, pour mettre en évidence les UGS contenant les mots "robe", créez une règle de formatage conditionnel avec la formule ci-dessous et appliquez-la à autant de cellules de la colonne A que nécessaire en commençant par la cellule A2 :

=SEARCH("dress", A2)>0

Formule de mise en forme conditionnelle d'Excel : si la cellule contient du texte (conditions multiples)

Pour mettre en évidence les cellules qui contiennent deux chaînes de texte ou plus, imbriquez plusieurs fonctions de recherche dans une formule ET. Par exemple, pour mettre en évidence les cellules "robe bleue", créez une règle basée sur cette formule :

=AND(SEARCH("robe", A2)>0, SEARCH("bleu", A2)>0)

Pour les étapes détaillées, veuillez consulter Comment créer une règle de mise en forme conditionnelle avec une formule.

Si la cellule contient un certain texte, supprimer la ligne entière

Si vous souhaitez supprimer des lignes contenant un texte spécifique, utilisez la fonction Rechercher et remplacer d'Excel de cette manière :

1. Sélectionnez toutes les cellules que vous voulez vérifier.
2. Appuyez sur Ctrl + F pour ouvrir le Rechercher et remplacer de la boîte de dialogue.
3. Dans le Trouvez ce que tapez le texte ou le nombre que vous recherchez, puis cliquez sur le bouton de la souris. Trouver tout
4. Cliquez sur un résultat de recherche, puis appuyez sur Ctrl + A pour tout sélectionner.
5. Cliquez sur le bouton Fermer pour fermer l'écran Rechercher et remplacer
6. Appuyez sur la touche Ctrl et le bouton moins en même temps (Ctrl - ), qui est le raccourci Excel pour Supprimer.
7. Dans le Supprimer sélectionnez Ligne entière et cliquez sur OK. C'est fait !

Dans la capture d'écran ci-dessous, nous supprimons les lignes contenant "robe" :

Si la cellule contient, sélectionner ou copier des lignes entières

Dans les situations où vous souhaitez sélectionner ou copier des lignes contenant des données pertinentes, utilisez le filtre automatique d'Excel pour filtrer ces lignes. Ensuite, appuyez sur Ctrl + A pour sélectionner les données filtrées, Ctrl + C pour les copier et Ctrl + V pour coller les données à un autre emplacement.

Pour filtrer les cellules avec deux critères ou plus, utilisez le filtre avancé pour trouver ces cellules, puis copiez les lignes entières avec les résultats ou extrayez uniquement des colonnes spécifiques.

C'est ainsi que vous manipulez les cellules en fonction de leur valeur dans Excel. Je vous remercie de votre lecture et j'espère vous voir sur notre blog la semaine prochaine !

Cahier d'exercices

Excel If Cell Contains Then - exemples (fichier .xlsx)