Az előző oktatóanyagunkban az Excel Ha tartalmaz képleteket néztük, amelyek valamilyen értéket adnak vissza egy másik oszlopba, ha egy célcella tartalmaz egy adott értéket. Ezen kívül mit tehet még, ha egy cella tartalmaz egy adott szöveget vagy számot? Számos dolgot, például cellák számolását vagy összegzését, kiemelését, egész sorok eltávolítását vagy másolását és még sok mást.

Excel 'Számlálás, ha a cella tartalmazza' formula példák

A Microsoft Excelben két függvény áll rendelkezésre a cellák értékek alapján történő megszámlálására: COUNTIF és COUNTIFS. Ezek a függvények a legtöbb, bár nem minden forgatókönyvet lefednek. Az alábbi példákból megtudhatja, hogyan válassza ki az adott feladathoz a megfelelő Számlálás, ha a cella tartalmaz képletet.

Számolja meg, hogy a cella tartalmaz-e szöveget

Azokban az esetekben, amikor bármilyen szöveget tartalmazó cellákat szeretne megszámolni, használja a csillag helyettesítő karaktert a COUNTIF képletben:

Vagy használja a SUMPRODUCT funkciót az ISTEXT funkcióval kombinálva:

A második képletben az ISTEXT függvény kiértékeli a megadott tartomány minden egyes celláját, és egy TRUE (szöveg) és FALSE (nem szöveg) értékekből álló tömböt ad vissza; a kettős unáris operátor (--) a TRUE és FALSE értékeket 1-es és 0-s értékekre kényszeríti; a SUMPRODUCT pedig összeadja a számokat.

Amint az alábbi képernyőképen látható, mindkét képlet ugyanazt az eredményt adja:

=COUNTIF(A2:A10, "*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Érdemes megnézni, hogyan számolja a nem üres cellákat az Excelben.

Számolja meg, ha a cella tartalmaz egy adott szöveget

A meghatározott szöveget tartalmazó cellák számolásához használjon egy egyszerű COUNTIF képletet az alábbiak szerint, ahol tartomány az ellenőrizendő cellák és szöveg a keresendő szöveges karakterlánc vagy a szöveges karakterláncot tartalmazó cellára való hivatkozás.

Ha például az A2:A10 tartományban lévő, a "ruha" szót tartalmazó cellákat szeretné megszámolni, használja ezt a képletet:

=COUNTIF(A2:A10, "ruha")

Vagy a képernyőképen láthatót:

További képletpéldákat talál itt: Hogyan számoljuk meg a szöveges cellákat az Excelben: bármely, meghatározott, szűrt cellák.

Számolja meg, ha a cella szöveget tartalmaz (részleges egyezés)

Egy adott részláncot tartalmazó cellák számolásához használja a COUNTIF függvényt a csillag helyettesítő karakterrel (*).

Ha például azt szeretné megszámolni, hogy az A oszlop hány cellája tartalmazza a "ruha" szót, használja ezt a képletet:

=COUNTIF(A2:A10,"*dress*")

Vagy írja be a kívánt szöveget valamelyik cellába, és kapcsolja össze a cellát a helyettesítő karakterekkel:

=COUNTIF(A2:A10,"*"&D1&"*")

További információért lásd: COUNTIF képletek részleges egyezéssel.

Számolja meg, ha a cella több részláncot tartalmaz (ÉS logika)

A több feltételhez tartozó cellák számolásához használja a COUNTIFS függvényt. Az Excel COUNTIFS legfeljebb 127 tartomány/kritérium párost tud kezelni, és csak azokat a cellákat számolja meg, amelyek megfelelnek az összes megadott feltételnek.

Ha például azt szeretné megtudni, hogy az A oszlop hány cellája tartalmazza a "ruha" ÉS a "kék" szót, használja a következő képletek egyikét:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Vagy

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Számolja meg, ha a cella számot tartalmaz

A számokat tartalmazó cellák számolásának képlete a legegyszerűbb képlet, amit el lehet képzelni:

Ne feledje, hogy az Excelben a COUNT funkció bármilyen numerikus értéket tartalmazó cellákat számol, beleértve a számokat, dátumokat és időpontokat, mivel az Excel szempontjából az utóbbi kettő is szám.

A mi esetünkben a képlet a következőképpen néz ki:

=COUNT(A2:A10)

A számokat NEM tartalmazó cellák számolásához használja a SUMPRODUCT függvényt az ISNUMBER és a NOT függvénnyel együtt:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Összegzés, ha a cella szöveget tartalmaz

Ha olyan Excel-képletet keres, amellyel megkeresheti a meghatározott szöveget tartalmazó cellákat, és összegezheti a megfelelő értékeket egy másik oszlopban, használja a SUMIF függvényt.

Ha például azt szeretné megtudni, hogy hány ruha van raktáron, használja ezt a képletet:

=SUMIF(A2:A10,"*dress*",B2:B10)

Ahol A2:A10 az ellenőrizendő szöveges értékek, B2:B10 pedig az összegzendő számok.

Vagy helyezze az érdekes részláncot egy cellába (E1), és hivatkozzon erre a cellára a képletben, ahogy az alábbi képernyőképen látható:

A címre. összegzés több kritériummal , használja a SUMIFS függvényt.

Ha például azt szeretné megtudni, hogy hány kék ruha áll rendelkezésre, használja ezt a képletet:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Vagy használja ezt:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Ahol A2:A10 az ellenőrizendő cellák és B2:B10 az összegzendő cellák.

Különböző számítások elvégzése a cella értéke alapján

A legutóbbi bemutatóban három különböző képletet tárgyaltunk, amelyekkel többféle feltételt tesztelhetünk, és a tesztek eredményétől függően különböző értékeket adhatunk vissza. Most pedig nézzük meg, hogyan végezhetünk különböző számításokat a célcellában lévő értéktől függően.

Tegyük fel, hogy a B oszlopban vannak az értékesítési számok, és ezek alapján szeretnénk kiszámítani a bónuszokat: ha az értékesítés meghaladja a 300 dollárt, a bónusz 10%; a 201 és 300 dollár közötti értékesítés esetén a bónusz 7%; a 101 és 200 dollár közötti értékesítés esetén a bónusz 5%, és a 100 dollár alatti értékesítés esetén nincs bónusz.

Ehhez egyszerűen szorozza meg az eladásokat (B2) a megfelelő százalékkal. Honnan tudja, hogy melyik százalékkal kell szorozni? Különböző feltételek tesztelésével, egymásba ágyazott IF-ekkel:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

A valós munkalapokon kényelmesebb lehet, ha a százalékokat külön cellákba írja be, és a képletben ezekre a cellákra hivatkozik:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

A legfontosabb dolog a bónuszcellák hivatkozásainak rögzítése a $ jellel, hogy megakadályozza, hogy azok megváltozzanak, amikor a képletet az oszlopba másolja.

Excel feltételes formázás, ha a cella meghatározott szöveget tartalmaz

Ha azt szeretné, hogy kiemelni cellák bizonyos szöveggel, állítson be egy Excel feltételes formázási szabályt az alábbi képletek valamelyikén alapulva.

Nagy- és kisbetű-érzékeny:

Nagy- és kisbetű-érzékeny:

Ha például ki szeretné emelni a "ruha" szót tartalmazó SKU-kat, készítsen egy feltételes formázási szabályt az alábbi képlettel, és alkalmazza azt az A oszlop annyi cellájára, ahányra szüksége van, kezdve az A2 cellával:

=SEARCH("dress", A2)>0

Excel feltételes formázási képlet: ha a cella szöveget tartalmaz (több feltétel)

A két vagy több szöveges karakterláncot tartalmazó cellák kiemeléséhez fészkeljünk be több Keresési függvényt egy ÉS képletbe. Például a "kék ruha" cellák kiemeléséhez hozzunk létre egy szabályt ezen a képleten alapulva:

=AND(SEARCH("ruha", A2)>0, SEARCH("kék", A2)>0)

A részletes lépésekért lásd: Hogyan hozzunk létre feltételes formázási szabályt képlettel?

Ha a cella tartalmaz bizonyos szöveget, távolítsa el az egész sort

Ha egy adott szöveget tartalmazó sorokat szeretne törölni, használja az Excel Keresés és csere funkcióját ilyen módon:

1. Jelölje ki az összes ellenőrizni kívánt cellát.
2. Nyomja meg a Ctrl + F billentyűkombinációt a Keresés és csere párbeszédpanel.
3. A Találd meg, mit mezőbe, írja be a keresett szöveget vagy számot, és kattintson a Mindent megtalálni
4. Kattintson bármelyik keresési eredményre, majd nyomja meg a Ctrl + A billentyűkombinációt az összes kiválasztásához.
5. Kattintson a Zárja be a gomb megnyomásával bezárja a Keresés és csere
6. Nyomja le egyszerre a Ctrl és a mínusz gombot ( Ctrl - ), ami az Excelben a Delete (Törlés) parancsikonja.
7. A Törölje a címet. párbeszédpanelen válassza a Teljes sor , és kattintson az OK gombra. Kész!

Az alábbi képernyőképen a "ruha" szót tartalmazó sorokat töröljük:

Ha a cella tartalmaz, válassza ki vagy másolja az egész sorokat

Olyan helyzetekben, amikor releváns adatokat tartalmazó sorokat szeretne kijelölni vagy másolni, használja az Excel automatikus szűrőjét az ilyen sorok szűréséhez. Ezután nyomja meg a Ctrl+A billentyűkombinációt a szűrt adatok kijelöléséhez, a Ctrl+C billentyűkombinációt a másoláshoz, a Ctrl+V billentyűkombinációt pedig az adatok más helyre történő beillesztéséhez.

Ha két vagy több kritériumot tartalmazó cellákat szeretne szűrni, a Speciális szűrővel keresse meg az ilyen cellákat, majd másolja ki az eredményeket tartalmazó teljes sorokat, vagy csak bizonyos oszlopokat vonjon ki.

Így manipulálhatod a cellákat az értékük alapján az Excelben. Köszönöm, hogy elolvastad, és remélem, jövő héten találkozunk a blogon!

Gyakorló munkafüzet

Excel If Cell Contains Then - példák (.xlsx fájl)