W naszym poprzednim samouczku przyglądaliśmy się Excelowi Jeśli zawiera formuły, które zwracają jakąś wartość do innej kolumny, jeśli komórka docelowa zawiera daną wartość. Poza tym, co jeszcze można zrobić, jeśli komórka zawiera określony tekst lub liczbę? Wiele rzeczy, takich jak liczenie lub sumowanie komórek, podświetlanie, usuwanie lub kopiowanie całych wierszy i wiele innych.

Excel "Licz, jeśli komórka zawiera" przykłady formuł

W programie Microsoft Excel istnieją dwie funkcje do zliczania komórek na podstawie ich wartości, COUNTIF i COUNTIFS. Funkcje te obejmują większość, choć nie wszystkie scenariusze. Poniższe przykłady nauczą Cię, jak wybrać odpowiednią formułę Count if cell contains dla konkretnego zadania.

Policz, czy komórka zawiera jakiś tekst

W sytuacjach, gdy chcesz zliczyć komórki zawierające dowolny tekst, użyj znaku wieloznacznego gwiazdka jako kryterium w formule COUNTIF:

Można też użyć funkcji SUMPRODUCT w połączeniu z ISTEXT:

W drugiej formule funkcja ISTEXT ocenia każdą komórkę w określonym zakresie i zwraca tablicę wartości TRUE (tekst) i FALSE (nie tekst); podwójny operator jednoargumentowy (--) zamienia TRUE i FALSE na 1 i 0; a SUMPRODUCT sumuje liczby.

Jak widać na poniższym zrzucie ekranu, obie formuły dają ten sam wynik:

=COUNTIF(A2:A10, "*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Możesz również chcieć spojrzeć na to, jak liczyć niepuste komórki w Excelu.

Policz, czy komórka zawiera określony tekst

Aby policzyć komórki zawierające określony tekst, należy użyć prostej formuły COUNTIF, jak pokazano poniżej, gdzie zakres to komórki do sprawdzenia i tekst to łańcuch tekstowy do wyszukania lub odwołanie do komórki zawierającej łańcuch tekstowy.

Na przykład, aby policzyć komórki z zakresu A2:A10, które zawierają słowo "sukienka", użyj tej formuły:

=COUNTIF(A2:A10, "sukienka")

Albo ten pokazany na zrzucie ekranu:

Więcej przykładów formuł znajdziesz tutaj: Jak liczyć komórki z tekstem w Excelu: dowolne, określone, filtrowane komórki.

Policz, czy komórka zawiera tekst (dopasowanie częściowe)

Aby zliczyć komórki, które zawierają określony podłańcuch, użyj funkcji COUNTIF ze znakiem wieloznacznym gwiazdki (*).

Na przykład, aby policzyć, ile komórek w kolumnie A zawiera "sukienkę" jako część ich zawartości, użyj tej formuły:

=COUNTIF(A2:A10,"*dress*")

Albo wpisz żądany tekst w jakiejś komórce i połącz tę komórkę ze znakami wieloznacznymi:

=COUNTIF(A2:A10,"*"&D1&"*")

Więcej informacji znajdziesz na stronie: formuły COUNTIF z częściowym dopasowaniem.

Policz, czy komórka zawiera wiele podciągów (logika AND)

Aby zliczyć komórki z wieloma warunkami, należy użyć funkcji COUNTIFS. Excel COUNTIFS może obsłużyć do 127 par zakres/kryterium, a zliczone zostaną tylko komórki spełniające wszystkie określone warunki.

Na przykład, aby dowiedzieć się, ile komórek w kolumnie A zawiera "sukienkę" ORAZ "niebieski", użyj jednej z następujących formuł:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Albo

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Policz, czy komórka zawiera liczbę

Formuła do zliczania komórek z liczbami jest najprostszą formułą, jaką można sobie wyobrazić:

Należy pamiętać, że funkcja COUNT w Excelu zlicza komórki zawierające dowolną wartość liczbową, w tym liczby, daty i godziny, ponieważ w ujęciu Excela dwie ostatnie są również liczbami.

W naszym przypadku formuła przebiega następująco:

=COUNT(A2:A10)

Aby policzyć komórki, które NIE zawierają liczb, użyj funkcji SUMPRODUCT wraz z ISNUMBER i NOT:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Suma, jeśli komórka zawiera tekst

Jeśli szukasz formuły Excela, która pozwoli Ci znaleźć komórki zawierające określony tekst i zsumować odpowiadające im wartości w innej kolumnie, użyj funkcji SUMIF.

Na przykład, aby dowiedzieć się, ile sukienek jest w magazynie, użyj tego wzoru:

=SUMIF(A2:A10,"*dress*",B2:B10)

Gdzie A2:A10 to wartości tekstowe do sprawdzenia, a B2:B10 to liczby do zsumowania.

Lub umieść podłańcuch zainteresowania w jakiejś komórce (E1) i odwołaj się do tej komórki w swojej formule, jak pokazano na poniższym zrzucie ekranu:

Do suma z wieloma kryteriami , użyj funkcji SUMIFS.

Na przykład, aby dowiedzieć się, ile niebieskich sukienek jest dostępnych, przejdź z tym wzorem:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Albo użyj tego:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Gdzie A2:A10 to komórki do sprawdzenia, a B2:B10 to komórki do zsumowania.

Wykonywanie różnych obliczeń na podstawie wartości komórki

W naszym ostatnim tutorialu omówiliśmy trzy różne formuły do testowania wielu warunków i zwracania różnych wartości w zależności od wyników tych testów. A teraz zobaczmy, jak można wykonać różne obliczenia w zależności od wartości w komórce docelowej.

Załóżmy, że masz liczby sprzedaży w kolumnie B i chcesz obliczyć premie w oparciu o te liczby: jeśli sprzedaż jest powyżej 300 dolarów, premia wynosi 10%; dla sprzedaży między 201 a 300 dolarów premia wynosi 7%; dla sprzedaży między 101 a 200 dolarów premia wynosi 5%, a brak premii dla sprzedaży poniżej 100 dolarów.

Aby to zlecić, wystarczy pomnożyć sprzedaż (B2) przez odpowiedni procent. Skąd wiadomo, przez który procent pomnożyć? Testując różne warunki za pomocą zagnieżdżonych IF:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

W rzeczywistych arkuszach może być wygodniej wprowadzać procenty w oddzielnych komórkach i odwoływać się do tych komórek w swojej formule:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Kluczową rzeczą jest ustalenie referencji komórek bonusowych ze znakiem $, aby zapobiec ich zmianie, gdy kopiujesz formułę w dół kolumny.

Formatowanie warunkowe w programie Excel, jeśli komórka zawiera określony tekst

Jeśli chcesz podkreślenie komórek z określonym tekstem, skonfiguruj regułę formatowania warunkowego programu Excel opartą na jednej z poniższych formuł.

Wielkość liter nie ma znaczenia:

Rozróżnianie wielkości liter:

Na przykład, aby wyróżnić SKU, które zawierają słowa "sukienka", utwórz regułę formatowania warunkowego z poniższą formułą i zastosuj ją do tylu komórek w kolumnie A, ile potrzebujesz, zaczynając od komórki A2:

=SEARCH("dress", A2)>0

Formuła formatowania warunkowego w Excelu: jeśli komórka zawiera tekst (wiele warunków)

Aby podświetlić komórki zawierające dwa lub więcej ciągów tekstowych, zagnieżdż kilka funkcji Szukaj w ramach formuły AND. Na przykład, aby podświetlić komórki "niebieska sukienka", utwórz regułę opartą na tej formule:

=AND(SEARCH("sukienka", A2)>0, SEARCH("niebieski", A2)>0)

Szczegółowe kroki znajdziesz w rozdziale Jak utworzyć regułę formatowania warunkowego za pomocą formuły.

Jeśli komórka zawiera określony tekst, usuń cały wiersz

W przypadku, gdy chcesz usunąć wiersze zawierające określony tekst, użyj w tym celu funkcji Znajdź i zamień programu Excel:

1. Zaznacz wszystkie komórki, które chcesz sprawdzić.
2. Naciśnij Ctrl + F, aby otworzyć Znajdź i zamień okno dialogowe.
3. W Znajdź to, co wpisać szukany tekst lub liczbę, a następnie kliknąć przycisk Znajdź wszystkie
4. Kliknij na dowolny wynik wyszukiwania, a następnie naciśnij Ctrl + A, aby wybrać wszystkie.
5. Kliknij przycisk Zamknij aby zamknąć Znajdź i zamień
6. Naciśnij jednocześnie klawisz Ctrl i przycisk minus ( Ctrl - ), który jest skrótem Excela do Delete.
7. W Usuń okno dialogowe, wybierz Cały rząd i kliknij OK. Gotowe!

Na poniższym zrzucie ekranu usuwamy wiersze zawierające "sukienkę":

Jeśli komórka zawiera, wybierz lub skopiuj całe wiersze

W sytuacjach, gdy chcesz zaznaczyć lub skopiować wiersze z odpowiednimi danymi, użyj AutoFiltra Excela, aby przefiltrować takie wiersze. Następnie naciśnij Ctrl + A, aby zaznaczyć przefiltrowane dane, Ctrl + C, aby je skopiować, i Ctrl + V, aby wkleić dane w innym miejscu.

Aby filtrować komórki z dwoma lub więcej kryteriami, użyj Filtra zaawansowanego, aby znaleźć takie komórki, a następnie skopiuj całe wiersze z wynikami lub wyodrębnij tylko określone kolumny.

Tak właśnie manipuluje się komórkami na podstawie ich wartości w Excelu. Dziękuję za przeczytanie i mam nadzieję, że zobaczymy się na naszym blogu za tydzień!

Zeszyt ćwiczeń

Excel If Cell Contains Then - przykłady (plik .xlsx)