Sa aming nakaraang tutorial, tinitingnan namin ang Excel If ay naglalaman ng mga formula na nagbabalik ng ilang halaga sa isa pang column kung ang isang target na cell ay naglalaman ng isang ibinigay na halaga. Bukod doon, ano pa ang maaari mong gawin kung ang isang cell ay naglalaman ng tiyak na teksto o numero? Iba't ibang bagay gaya ng pagbibilang o pagbubuod ng mga cell, pag-highlight, pag-alis o pagkopya ng buong row, at higit pa.

Excel 'Bilangin kung naglalaman ang cell' ng mga halimbawa ng formula

Sa Microsoft Excel, mayroong dalawang function upang mabilang ang mga cell batay sa kanilang mga halaga, COUNTIF at COUNTIFS. Ang mga function na ito ay sumasaklaw sa karamihan, bagaman hindi lahat, ng mga sitwasyon. Ang mga halimbawa sa ibaba ay magtuturo sa iyo kung paano pumili ng naaangkop na Bilang kung ang cell ay naglalaman ng formula para sa iyong partikular na gawain.

Bilangin kung ang cell ay naglalaman ng anumang teksto

Sa mga sitwasyon kung kailan mo gustong magbilang ng mga cell na naglalaman ng anumang teksto , gamitin ang asterisk wildcard na character bilang pamantayan sa iyong COUNTIF formula:

O, gamitin ang SUMPRODUCT function kasama ng ISTEXT:

Sa pangalawang formula, sinusuri ng ISTEXT function ang bawat cell sa tinukoy na range at nagbabalik ng array ng TRUE (text) at FALSE (not text) value; pinipilit ng double unary operator (--) ang TRUE at FALSE sa 1's at 0's; at ang SUMPRODUCT ay nagdaragdag ng mga numero.

Tulad ng ipinapakita sa screenshot sa ibaba, ang parehong mga formula ay nagbubunga ng parehong resulta:

=COUNTIF(A2:A10,"*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Maaaring gusto mo rintingnan kung paano magbilang ng mga cell na hindi walang laman sa Excel.

Bilangin kung naglalaman ang cell ng partikular na text

Upang bilangin ang mga cell na naglalaman ng partikular na text, gumamit ng simpleng COUNTIF formula tulad ng ipinapakita sa ibaba, kung saan <8 Ang>range ay ang mga cell na susuriin at ang text ay ang text string na hahanapin o isang reference sa cell na naglalaman ng text string.

Halimbawa, para magbilang ng mga cell sa hanay na A2:A10 na naglalaman ng salitang "dress", gamitin ang formula na ito:

=COUNTIF(A2:A10, "dress")

O ang ipinapakita sa screenshot:

Makakakita ka ng higit pang mga halimbawa ng formula dito: Paano magbilang ng mga cell na may text sa Excel: anuman, partikular, na-filter na mga cell.

Bilangin kung ang cell ay naglalaman ng text (bahagyang tugma)

Upang bilangin ang mga cell na naglalaman ng isang partikular na substring, gamitin ang COUNTIF function na may asterisk wildcard character (*).

Halimbawa, upang mabilang kung gaano karaming mga cell sa column A ang naglalaman ng "dress" bilang bahagi ng kanilang mga nilalaman, gamitin ang formula na ito:

=COUNTIF(A2:A10,"*dress*")

O, i-type ang gustong text sa ilang cell at pagdugtungin ang t cell na may mga wildcard na character:

=COUNTIF(A2:A10,"*"&D1&"*")

Para sa higit pang impormasyon, pakitingnan ang: COUNTIF na mga formula na may bahagyang tugma.

Bilangin kung cell ay naglalaman ng maraming substrings (AT logic)

Upang bilangin ang mga cell na may maraming kundisyon, gamitin ang COUNTIFS function. Ang Excel COUNTIFS ay maaaring humawak ng hanggang 127 range/criteria pairs, at ang mga cell lang na nakakatugon sa lahat ng tinukoy na kundisyon aybinibilang.

Halimbawa, para malaman kung ilang cell sa column A ang naglalaman ng "dress" AT "blue", gamitin ang isa sa mga sumusunod na formula:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

O

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Bilangin kung naglalaman ng numero ang cell

Ang formula sa pagbibilang ng mga cell na may mga numero ay ang pinakasimpleng formula na maiisip ng isang tao:

Pakitandaan na ang COUNT function sa Excel ay nagbibilang ng mga cell na naglalaman ng anumang numeric na halaga kabilang ang mga numero, petsa at oras, dahil sa mga tuntunin ng Excel ang huling dalawa ay mga numero din.

Sa aming kaso, ang formula ay sumusunod:

=COUNT(A2:A10)

Upang bilangin ang mga cell na HINDI naglalaman ng mga numero, gamitin ang SUMPRODUCT function kasama ng ISNUMBER at NOT:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Suum kung naglalaman ang cell ng text

Kung naghahanap ka ng formula ng Excel upang mahanap ang mga cell na naglalaman ng partikular na text at isama ang mga katumbas na halaga sa isa pang column, gamitin ang SUMIF function.

Halimbawa, para malaman kung ilang damit ang nasa stock, gamitin ang formula na ito:

=SUMIF(A2:A10,"*dress*",B2:B10)

Kung saan ang A2:A10 ay ang text value na susuriin at ang B2:B10 ay ang mga numerong susumahin.

O kaya, ilagay ang substring ng interes sa ilang cell (E1), at i-reference ang cell na iyon sa iyong formula, tulad ng ipinapakita sa screenshot sa ibaba:

Upang sum with multiple criteria , gamitin ang SUMIFS function.

Halimbawa, para malaman kung ilang asul na dress ang available, pumunta gamit ang formula na ito:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

O gamitin itoisa:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Kung saan ang A2:A10 ang mga cell na susuriin at ang B2:B10 ang mga cell na susumahin.

Isagawa iba't ibang kalkulasyon batay sa halaga ng cell

Sa aming huling tutorial, tinalakay namin ang tatlong magkakaibang formula upang subukan ang maraming kundisyon at ibalik ang iba't ibang mga halaga depende sa mga resulta ng mga pagsubok na iyon. At ngayon, tingnan natin kung paano ka makakapagsagawa ng iba't ibang mga kalkulasyon depende sa halaga sa isang target na cell.

Ipagpalagay na mayroon kang mga numero ng benta sa column B at gusto mong kalkulahin ang mga bonus batay sa mga numerong iyon: kung ang isang benta ay higit sa $300 , ang bonus ay 10%; para sa mga benta sa pagitan ng $201 at $300 ang bonus ay 7%; para sa mga benta sa pagitan ng $101 at $200 ang bonus ay 5%, at walang bonus para sa mas mababa sa $100 na benta.

Upang magawa ito, i-multiply lang ang mga benta (B2) sa katumbas na porsyento. Paano mo malalaman kung aling porsyento ang paramihin? Sa pamamagitan ng pagsubok sa iba't ibang kundisyon gamit ang mga nested IF:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

Sa totoong buhay na mga worksheet, maaaring mas maginhawang mag-input ng mga porsyento sa magkakahiwalay na mga cell at i-reference ang mga cell na iyon sa iyong formula:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Ang pangunahing bagay ay ang pag-aayos ng mga sanggunian ng mga bonus cell gamit ang $ sign upang pigilan ang mga ito na magbago kapag kinopya mo ang formula sa column.

Excel conditional formatting kung ang cell ay naglalaman ng partikular na text

Kung gusto mong i-highlight ang mga cell na may ilang partikular na text, mag-set up ng Excel conditional formatting rule batay sa isa sa mga sumusunodmga formula.

Case-insensitive:

Case-sensitive:

Halimbawa, para i-highlight ang mga SKU na naglalaman ng mga salitang "dress", gumawa ng conditional formatting rule gamit ang formula sa ibaba at ilapat ito sa kasing dami ng mga cell sa column A hangga't kailangan mo simula sa cell A2:

=SEARCH("dress", A2)>0

Excel conditional formatting formula: kung ang cell ay naglalaman ng text (maraming kundisyon)

Upang i-highlight ang mga cell na naglalaman ng dalawa o higit pang mga string ng text, maglagay ng ilang function ng Paghahanap sa loob ng isang AND formula. Halimbawa, upang i-highlight ang mga cell na "asul na damit," gumawa ng panuntunan batay sa formula na ito:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

Para sa mga detalyadong hakbang, pakitingnan ang Paano gumawa ng conditional formatting rule na may formula.

Kung ang cell ay naglalaman ng ilang partikular na text, alisin ang buong row

Kung sakaling gusto mong tanggalin ang mga row na naglalaman ng partikular na text, gamitin ang Excel's Find and Replace feature sa ganitong paraan :

1. Piliin ang lahat ng cell na gusto mong suriin.
2. Pindutin ang Ctrl + F upang buksan ang Hanapin at Palitan dialog box.
3. Sa ang kahon na Hanapin kung ano , i-type ang teksto o numero na iyong hinahanap, at i-click ang Hanapin Lahat
4. Mag-click sa anumang resulta ng paghahanap, at pagkatapos ay pindutin ang Ctrl + A para piliin lahat.
5. I-click ang button na Isara para isara ang Hanapin at Palitan
6. Pindutin ang Ctrl at ang minus na button nang sabay ( Ctrl - ), na siyang Excelshortcut para sa Tanggalin.
7. Sa dialog box na Tanggalin , piliin ang Buong row , at i-click ang OK. Tapos na!

Sa screenshot sa ibaba, tinatanggal namin ang mga row na naglalaman ng "dress":

Kung naglalaman ang cell, piliin o kopyahin ang buong row

Sa mga sitwasyon kung kailan mo gustong pumili o kumopya ng mga row na may nauugnay na data, gamitin ang AutoFilter ng Excel upang i-filter ang mga naturang row. Pagkatapos nito, pindutin ang Ctrl + A para piliin ang na-filter na data, Ctrl+C para kopyahin ito, at Ctrl+V para i-paste ang data sa ibang lokasyon.

Upang i-filter ang mga cell na may dalawa o higit pang pamantayan, gamitin ang Advanced na Filter upang mahanap ang mga naturang cell, at pagkatapos ay kopyahin ang buong mga hilera na may mga resulta o i-extract lamang ang mga partikular na column.

Ganito mo manipulahin ang mga cell batay sa kanilang halaga sa Excel. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo!

Practice workbook

Excel If Cell Contains Then - mga halimbawa (.xlsx file)