زموږ په مخکني ټیوټوریل کې، موږ د Excel If ګورو چې فورمولونه لري چې یو څه ارزښت بل کالم ته راګرځوي که چیرې هدف سیل یو ورکړل شوی ارزښت ولري. له دې پرته، تاسو نور څه کولی شئ که چیرې یوه حجره ځانګړی متن یا شمیره ولري؟ مختلف شیان لکه د حجرو شمیرل یا لنډول، روښانه کول، د ټولو قطارونو لرې کول یا کاپي کول، او نور.

Excel 'شمیرنه که چیرې حجره ولري' فورمول مثالونه

په د مایکروسافټ ایکسل ، د دوی ارزښتونو پراساس د حجرو شمیرلو لپاره دوه دندې شتون لري ، COUNTIF او COUNTIFS. دا دندې ډیری پوښښ کوي، که څه هم ټول نه، سناریوګانې. لاندې مثالونه به تاسو ته درس درکړي چې څنګه یو مناسب شمیره غوره کړئ که چیرې حجره ستاسو د ځانګړي دندې لپاره فارمول ولري.

شمیر کړئ که چیرې حجره کوم متن ولري

په داسې شرایطو کې کله چې تاسو غواړئ حجرې شمیرل کړئ کوم متن لري , په خپل COUNTIF فارمول کې د معیارونو په توګه د ستوري وائلډ کارډ کرکټر وکاروئ:

یا، د SUMPRODUCT فعالیت د ISTEXT سره په ترکیب کې وکاروئ:

په دویمه فورمول کې، د ISTEXT فنکشن په ټاکل شوي حد کې هر حجره ارزوي او د ریښتیا (متن) او غلط (متن نه) ارزښتونو لړۍ بیرته راګرځوي؛ ډبل یونیری آپریټر (--) په 1's او 0's کې سم او غلط مجبوروي؛ او SUMPRODUCT شمیرې زیاتوي.

لکه څنګه چې په لاندې سکرین شاټ کې ښودل شوي، دواړه فارمولونه ورته پایله ورکوي:

=COUNTIF(A2:A10,"*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

تاسو هم وغواړئوګورئ چې څنګه په Excel کې د غیر خالي حجرو شمیرل کیږي.

شمیر کړئ که چیرې حجره ځانګړي متن ولري

د حجرو شمیرلو لپاره چې ځانګړي متن لري، د ساده COUNTIF فارمول څخه کار واخلئ لکه لاندې ښودل شوي، چیرته چې رینج هغه حجرې دي چې د چک کولو لپاره دي او متن د لټون کولو لپاره د متن تار دی یا د هغه حجرې لپاره حواله ده چې متن یې لري.

د مثال په توګه، د A2:A10 په حد کې د حجرو شمیرلو لپاره چې د "جامې" کلمه لري، دا فورمول وکاروئ:

=COUNTIF(A2:A10, "dress")

یا هغه یو چې په سکرین شاټ کې ښودل شوی:

تاسو کولی شئ دلته د فورمولونو نور مثالونه ومومئ: په Excel کې د متن سره حجرې څنګه شمیرل کیږي: هر ډول، ځانګړي، فلټر شوي حجرې.

شمیر کړئ که چیرې حجره متن ولري (جزوي میچ)

د هغه حجرو شمیرلو لپاره چې یو ځانګړی سبسټرینګ لري، د COUNTIF فنکشن د ستوري وائلډ کارډ کرکټر (*) سره وکاروئ.

د مثال په توګه د شمیرلو لپاره په A کالم کې څومره حجرې د محتوياتو د یوې برخې په توګه "لباس" لري، دا فورمول وکاروئ:

=COUNTIF(A2:A10,"*dress*")

یا، په ځینو حجرو کې مطلوب متن ټایپ کړئ او د هغې سره یوځای کړئ. t حجره د وائلډ کارډ حروف سره:

=COUNTIF(A2:A10,"*"&D1&"*")

د نورو معلوماتو لپاره، مهرباني وکړئ وګورئ: COUNTIF فارمولونه د جزوي میچ سره.

شمیر که حجره څو فرعي سټینګونه لري (او منطق)

د ډیرو شرایطو سره د حجرو شمیرلو لپاره، د COUNTIFS فعالیت وکاروئ. Excel COUNTIFS کولی شي تر 127 حد / معیارونو جوړه جوړه کړي، او یوازې هغه حجرې چې ټول ټاکل شوي شرایط پوره کويشمیرل کیږي.

د مثال په توګه، د دې معلومولو لپاره چې په A کالم کې څومره حجرې "جامې" او "نیلي" لري، د لاندې فورمولونو څخه یو کار واخلئ:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

یا

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

شمیر کړئ که چیرې حجره شمیره ولري

د شمیرو سره د حجرو شمیرلو فورمول ترټولو ساده فورمول دی چې یو یې تصور کولی شي:

مهرباني وکړئ په یاد ولرئ چې په Excel کې د COUNT فعالیت حجرې شمیري کوم چې شمیرې، نیټې او وختونه لري، ځکه چې د Excel په شرایطو کې وروستي دوه هم شمیرې دي.

زموږ په قضیه کې، فورمول په لاندې ډول دی:

=COUNT(A2:A10)

د هغو حجرو شمیرلو لپاره چې شمیرې نلري، د SUMPRODUCT فعالیت د ISNUMBER او NOT سره یوځای وکاروئ:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

که چیرې حجره متن ولري مجموعه

که تاسو د Excel فارمول په لټه کې یاست ترڅو هغه حجرې ومومئ چې ځانګړي متن لري او د اړونده ارزښتونو مجموعه په کې بل کالم، د SUMIF فنکشن وکاروئ.

د مثال په توګه، د دې لپاره چې څومره جامې په ذخیره کې دي، دا فورمول وکاروئ:

=SUMIF(A2:A10,"*dress*",B2:B10)

چیرته چې A2:A10 دي متن د کتلو لپاره ارزښتونه او B2:B10 هغه شمیرې دي چې د مجموعې لپاره دي.

یا، په ځینو حجرو (E1) کې د ګټو سبسټرینګ واچوئ، او هغه حجره په خپل فورمول کې حواله کړئ، لکه څنګه چې په لاندې سکرین شاټ کې ښودل شوي:

د څو معیارونو سره جماع کولو لپاره ، د SUMIFS فنکشن وکاروئ.

د مثال په توګه، د موندلو لپاره چې څومره نیلي جامې شتون لري، لاړ شئ د دې فورمول سره:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

یا دا وکاروئیو:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

چیرته چې A2:A10 د چک کولو حجرې دي او B2:B10 هغه حجرې دي چې جمع کیږي.

کارول د حجرو د ارزښت پر بنسټ مختلف حسابونه

زموږ په وروستي ټیوټوریل کې، موږ د ډیری شرایطو ازموینې او د دې ازموینو پایلو پورې اړوند مختلف ارزښتونو بیرته راستنولو لپاره درې مختلف فارمولونه بحث کړل. او اوس، راځئ وګورو چې تاسو څنګه کولی شئ په نښه شوي حجره کې د ارزښت پراساس مختلف محاسبې ترسره کړئ.

فرض کړئ چې تاسو په B کالم کې د پلور شمیرې لرئ او غواړئ د دې شمیرو پراساس بونس محاسبه کړئ: که چیرې پلور له $ 300 ډالرو څخه ډیر وي , بونس 10٪ دی؛ د $201 او $300 ترمنځ د پلور لپاره بونس 7% دی؛ د $101 او $200 تر منځ د پلور لپاره بونس %5 دی، او د $100 څخه کم پلور لپاره هیڅ بونس نشته.

د دې ترسره کولو لپاره، په ساده ډول د پلور (B2) د اړوند فیصدي سره ضرب کړئ. تاسو څنګه پوهیږئ چې کوم فیصده باید ضرب شي؟ د نیست شوي IFs سره د مختلف شرایطو ازموینې په واسطه:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

په ریښتیني ژوند ورکشیټونو کې ، دا ممکن ډیر اسانه وي چې په جلا حجرو کې سلنه داخل کړئ او دا حجرې ستاسو په فورمول کې حواله کړئ:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

مهم شی د $ نښه سره د بونس حجرو حوالې تنظیم کول دي ترڅو د کالم لاندې فارمول کاپي کولو پرمهال د دوی د بدلون مخه ونیسي.

د ایکسل مشروط فارمیټ کول که چیرې حجره ځانګړی متن ولري

که تاسو غواړئ د ځانګړي متن سره حجرې روښانه کړئ ، د لاندې څخه یو پراساس د Excel مشروط فارمیټینګ قاعده تنظیم کړئفورمولونه.

د قضیې حساس:

د قضیې حساس:

د مثال په توګه، د SKUs روښانه کولو لپاره چې د "لباس" کلمې لري، د لاندې فورمول سره د مشروط فارمیټینګ قاعده جوړه کړئ او پلي یې کړئ په کالم A کې څومره حجرو ته چې تاسو اړتیا لرئ د A2 حجرې سره پیل کړئ:

=SEARCH("dress", A2)>0

د ایکسل مشروط فارمیټ فارمول: که چیرې حجره متن ولري (ډیری شرایط)

د هغو حجرو د روښانه کولو لپاره چې دوه یا ډیر متن تارونه لري، په AND فورمول کې د لټون ډیری فعالیتونه نیسټ کړئ. د مثال په توګه، د "نیلي جامو" حجرو روښانه کولو لپاره، د دې فورمول پر بنسټ یو قواعد جوړ کړئ:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

د تفصيلي ګامونو لپاره، مهرباني وکړئ وګورئ چې څنګه د فورمول سره د مشروط فارمیټینګ قاعده جوړه کړئ.

که په حجره کې یو مشخص متن وي، ټول قطار لرې کړئ

که تاسو غواړئ هغه قطارونه حذف کړئ چې ځانګړي متن لري، د Excel د موندلو او بدلولو فیچر په دې ډول وکاروئ :

1. ټول هغه حجرې وټاکئ چې تاسو یې چک کول غواړئ.
2. د موندل او بدل کړئ د ډیالوګ بکس خلاصولو لپاره Ctrl + F فشار ورکړئ.
3. په کې د څه ومومئ بکس، هغه متن یا شمیره ولیکئ چې تاسو یې په لټه کې یاست، او کلیک وکړئ ټول ومومئ 24>
4. د لټون پایلې باندې کلیک وکړئ، او بیا Ctrl + A فشار ورکړئ د ټولو غوره کولو لپاره.
5. د تړلو تڼۍ کلیک وکړئ د بندولو لپاره موندل او بدل کړئ
6. په ورته وخت کې Ctrl او د منفي تڼۍ فشار ورکړئ (Ctrl - )، کوم چې Excel دید ړنګولو لپاره شارټ کټ.
7. د حذف ډیالوګ بکس کې، ټول قطار غوره کړئ، او په سمه توګه کلیک وکړئ. بشپړ شوی!

په لاندې سکرین شاټ کې، موږ هغه قطارونه ړنګ کوو چې "لباس" لري:

که چیرې حجره ولري، ټول قطارونه وټاکئ یا کاپي کړئ

په داسې حالاتو کې چې تاسو غواړئ د اړونده معلوماتو سره قطارونه وټاکئ یا کاپي کړئ، د داسې قطارونو فلټر کولو لپاره د Excel AutoFilter وکاروئ. له هغې وروسته، د فلټر شوي ډاټا غوره کولو لپاره Ctrl + A، د کاپي کولو لپاره Ctrl+C، او بل ځای ته ډاټا پیسټ کولو لپاره Ctrl+V فشار ورکړئ.

د دوو یا ډیرو معیارونو سره د حجرو فلټر کولو لپاره، پرمختللي فلټر وکاروئ د دې ډول حجرو موندلو لپاره، او بیا د پایلو سره ټول قطارونه کاپي کړئ یا یوازې ځانګړي کالمونه راوباسئ.

دا دا ده چې تاسو په Excel کې د دوی د ارزښت پراساس حجرې اداره کوئ. زه ستاسو د لوستلو لپاره مننه کوم او هیله لرم چې راتلونکې اونۍ زموږ په بلاګ کې وګورم!

د تمرین کاري کتاب

Excel که چیرې حجره ولري نو بیا - مثالونه (.xlsx فایل)