Í fyrri kennslunni okkar vorum við að skoða Excel Ef inniheldur formúlur sem skila einhverju gildi í annan dálk ef markreitur inniheldur tiltekið gildi. Fyrir utan það, hvað annað geturðu gert ef reit inniheldur ákveðinn texta eða númer? Ýmislegt eins og að telja eða leggja saman frumur, auðkenna, fjarlægja eða afrita heilar línur og fleira.

Excel 'Count if cell contains' formúludæmi

Í Microsoft Excel, það eru tvær aðgerðir til að telja frumur út frá gildum þeirra, COUNTIF og COUNTIFS. Þessar aðgerðir ná yfir flestar, þó ekki allar, aðstæður. Dæmin hér að neðan munu kenna þér hvernig á að velja viðeigandi Talning ef reit inniheldur formúlu fyrir tiltekið verkefni.

Telja ef reit inniheldur einhvern texta

Í aðstæðum þegar þú vilt telja reiti sem innihalda hvaða texta sem er. , notaðu stjörnumerkið sem viðmið í COUNTIF formúlunni þinni:

Eða notaðu SUMPRODUCT aðgerðina ásamt ISTEXT:

Í annarri formúlunni metur ISTEXT fallið hverja reit á tilgreindu bili og skilar fylki TRUE (texta) og FALSE (ekki texta) gildi; tvöfaldur einfaldur reikniþáttur (--) þvingar TRUE og FALSE í 1 og 0; og SUMPRODUCT leggur saman tölurnar.

Eins og sést á skjámyndinni hér að neðan gefa báðar formúlurnar sömu niðurstöðu:

=COUNTIF(A2:A10,"*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Þú gætir líka viljað þaðskoðaðu hvernig á að telja reiti sem ekki eru tómar í Excel.

Telja ef reit inniheldur ákveðinn texta

Til að telja reiti sem innihalda ákveðinn texta skaltu nota einfalda COUNTIF formúlu eins og sýnt er hér að neðan, þar sem svið er hólfin sem á að athuga og texti er textastrengurinn sem á að leita að eða tilvísun í reitinn sem inniheldur textastrenginn.

Til dæmis, til að telja frumur á bilinu A2:A10 sem innihalda orðið "kjóll", notaðu þessa formúlu:

=COUNTIF(A2:A10, "dress")

Eða sú sem sýnd er á skjámyndinni:

Þú getur fundið fleiri formúludæmi hér: Hvernig á að telja frumur með texta í Excel: hvaða, sérstakar, síaðar frumur.

Telja ef reit inniheldur texta (samsvörun að hluta)

Til að telja reiti sem innihalda ákveðinn undirstreng, notaðu COUNTIF aðgerðina með stjörnumerkinu (*).

Til dæmis til að telja hversu margar frumur í dálki A innihalda "dress" sem hluta af innihaldi þeirra, notaðu þessa formúlu:

=COUNTIF(A2:A10,"*dress*")

Eða sláðu inn þann texta sem þú vilt í einhvern reit og sameinaðu það t reit með algildisstöfunum:

=COUNTIF(A2:A10,"*"&D1&"*")

Nánari upplýsingar er að finna í: COUNTIF formúlur með hluta samsvörun.

Teldu ef klefi inniheldur marga undirstrengi (AND logic)

Til að telja frumur með mörgum skilyrðum, notaðu COUNTIFS fallið. Excel COUNTIFS getur séð um allt að 127 svið/viðmiðapör og aðeins frumur sem uppfylla öll tilgreind skilyrði verðatalið.

Til dæmis, til að komast að því hversu margar frumur í dálki A innihalda "kjóll" OG "bláan", notaðu eina af eftirfarandi formúlum:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Eða

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Telja ef reit inniheldur tölu

Formúlan til að telja frumur með tölum er einfaldasta formúlan sem hægt er að ímynda sér:

Vinsamlegast hafðu í huga að COUNT fallið í Excel telur frumur sem innihalda hvaða tölugildi sem er, þar með talið tölur, dagsetningar og tíma, því hvað varðar Excel eru síðustu tveir líka tölur.

Í okkar tilviki er formúlan svona:

=COUNT(A2:A10)

Til að telja frumur sem innihalda EKKI tölur, notaðu SUMPRODUCT aðgerðina ásamt ISNUMBER og NOT:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Summa ef reit inniheldur texta

Ef þú ert að leita að Excel formúlu til að finna reiti sem innihalda ákveðinn texta og leggja saman samsvarandi gildi í annan dálk, notaðu SUMIF aðgerðina.

Til dæmis, til að finna út hversu margir kjólar eru á lager, notaðu þessa formúlu:

=SUMIF(A2:A10,"*dress*",B2:B10)

Þar sem A2:A10 eru texti gildi til að athuga og B2:B10 eru tölurnar sem á að leggja saman.

Eða settu undirstrenginn sem vekur áhuga í einhvern reit (E1) og vísaðu til þess reits í formúlunni þinni, eins og sýnt er á skjámyndinni hér að neðan:

Til að summa saman með mörgum forsendum , notaðu SUMIFS aðgerðina.

Til að finna út hversu margir bláir kjólar eru í boði skaltu fara með þessari formúlu:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Eða notaðu þettaeitt:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Þar sem A2:A10 eru frumurnar sem á að athuga og B2:B10 eru frumurnar sem á að leggja saman.

Framkvæma mismunandi útreikningar byggðir á frumugildi

Í síðasta kennsluefni okkar ræddum við þrjár mismunandi formúlur til að prófa margar aðstæður og skila mismunandi gildum eftir niðurstöðum þessara prófa. Og nú skulum við sjá hvernig þú getur framkvæmt mismunandi útreikninga eftir gildinu í markhólfi.

Svo sem þú hefur sölutölur í dálki B og viljir reikna bónusa út frá þeim tölum: ef sala er yfir $300 , bónusinn er 10%; fyrir sölu á milli $201 og $300 er bónus 7%; fyrir sölu á milli $101 og $200 er bónus 5%, og enginn bónus fyrir sölu undir $100.

Til að gera það, margfaldaðu einfaldlega söluna (B2) með samsvarandi prósentu. Hvernig veistu með hvaða prósentu á að margfalda? Með því að prófa mismunandi aðstæður með hreiðri IF:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

Í raunverulegum vinnublöðum gæti verið hentugra að setja inn prósentur í aðskildar reiti og vísa til þeirra hólfa í formúlunni þinni:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Aðalatriðið er að laga tilvísanir bónusfrumna með $ tákninu til að koma í veg fyrir að þær breytist þegar þú afritar formúluna niður í dálkinn.

Excel skilyrt snið ef reit inniheldur ákveðinn texta

Ef þú vilt auðkenna frumur með ákveðnum texta skaltu setja upp Excel skilyrt sniðsreglu sem byggir á einni af eftirfarandiformúlur.

Lágstafa-ónæmir:

Tilgreinanlegt:

Til dæmis, til að auðkenna SKU sem innihalda orðin "kjóll", búðu til skilyrta sniðsreglu með formúlunni hér að neðan og notaðu hana í eins margar frumur í dálki A og þú þarft og byrjar á reit A2:

=SEARCH("dress", A2)>0

Excel skilyrt sniðformúla: ef reit inniheldur texta (mörg skilyrði)

Til að auðkenna frumur sem innihalda tvo eða fleiri textastrengi, hreiðurðu nokkrar leitaraðgerðir innan OG formúlu. Til dæmis, til að auðkenna „blár kjóll“ frumur, búðu til reglu byggða á þessari formúlu:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

Fyrir nákvæmar skref, vinsamlegast sjáðu Hvernig á að búðu til skilyrta sniðsreglu með formúlu.

Ef reit inniheldur ákveðinn texta skaltu fjarlægja alla línuna

Ef þú vilt eyða línum sem innihalda ákveðinn texta, notaðu Excel's Find and Replace eiginleikann á þennan hátt :

1. Veldu allar frumur sem þú vilt athuga.
2. Ýttu á Ctrl + F til að opna Finna og skipta út svarglugganum.
3. Í Finndu hvað reitinn, sláðu inn textann eða númerið sem þú ert að leita að og smelltu á Finna allt
4. Smelltu á hvaða leitarniðurstöðu sem er og ýttu svo á Ctrl + A til að velja allt.
5. Smelltu á hnappinn Loka til að loka Finna og skipta út
6. Ýttu á Ctrl og mínushnappinn á sama tíma ( Ctrl - ), sem er Excelflýtileið fyrir Eyða.
7. Í Eyða valmyndinni skaltu velja Alla röðina og smella á OK. Búið!

Í skjámyndinni hér að neðan erum við að eyða línum sem innihalda "dress":

Ef reit inniheldur skaltu velja eða afrita heilar línur

Í aðstæðum þegar þú vilt velja eða afrita línur með viðeigandi gögnum, notaðu sjálfvirka síun Excel til að sía slíkar línur. Eftir það skaltu ýta á Ctrl + A til að velja síuðu gögnin, Ctrl+C til að afrita þau og Ctrl+V til að líma gögnin á annan stað.

Til að sía frumur með tveimur eða fleiri forsendum, notaðu Advanced Filter til að finna slíkar frumur og afritaðu síðan heilu línurnar með niðurstöðunum eða dragðu aðeins út tiltekna dálka.

Svona vinnur þú með frumum út frá gildi þeirra í Excel. Ég þakka þér fyrir lesturinn og vonast til að sjá þig á blogginu okkar í næstu viku!

Æfingabók

Excel Ef klefi inniheldur þá - dæmi (.xlsx skrá)