У нашым папярэднім уроку мы разглядалі Excel If змяшчае формулы, якія вяртаюць некаторы значэнне ў іншы слупок, калі мэтавая ячэйка змяшчае зададзенае значэнне. Акрамя гэтага, што яшчэ можна зрабіць, калі ячэйка змяшчае пэўны тэкст або лік? Розныя рэчы, такія як падлік або сумаванне ячэек, вылучэнне, выдаленне або капіраванне цэлых радкоў і многае іншае.

Прыклады формул Excel «Падлічыць, калі ячэйка змяшчае»

У Microsoft Excel, ёсць дзве функцыі для падліку ячэек на аснове іх значэнняў, COUNTIF і COUNTIFS. Гэтыя функцыі ахопліваюць большасць, хоць і не ўсе сцэнарыі. Прыведзеныя ніжэй прыклады навучаць вас, як выбраць адпаведны падлік, калі ячэйка змяшчае формулу для вашай канкрэтнай задачы.

Падлічыць, калі ячэйка ўтрымлівае тэкст

У сітуацыях, калі вы хочаце падлічыць вочкі, якія змяшчаюць любы тэкст , выкарыстоўвайце знак падстаноўкі зорачкі ў якасці крытэрыю ў вашай формуле COUNTIF:

Або выкарыстоўвайце функцыю SUMPRODUCT у спалучэнні з ISTEXT:

У другой формуле функцыя ISTEXT ацэньвае кожную ячэйку ў зададзеным дыяпазоне і вяртае масіў значэнняў TRUE (тэкст) і FALSE (не тэкст); двайны унарны аператар (--) зводзіць TRUE і FALSE на 1 і 0; і SUMPRODUCT складае лічбы.

Як паказана на скрыншоце ніжэй, абедзве формулы даюць аднолькавы вынік:

=COUNTIF(A2:A10,"*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Вы таксама можаце захацецьпаглядзіце, як падлічыць непустыя ячэйкі ў Excel.

Падлічыць, калі ячэйка змяшчае пэўны тэкст

Каб падлічыць ячэйкі, якія змяшчаюць пэўны тэкст, выкарыстоўвайце простую формулу COUNTIF, як паказана ніжэй, дзе дыяпазон - гэта ячэйкі для праверкі, а тэкст - тэкставы радок для пошуку або спасылка на ячэйку, якая змяшчае тэкставы радок.

Напрыклад, каб падлічыць вочкі ў дыяпазоне A2:A10, якія змяшчаюць слова "сукенка", выкарыстоўвайце наступную формулу:

=COUNTIF(A2:A10, "dress")

Або паказанае на скрыншоце:

Вы можаце знайсці больш прыкладаў формул тут: Як падлічыць ячэйкі з тэкстам у Excel: любыя, пэўныя, адфільтраваныя ячэйкі.

Падлічыць, калі ячэйка змяшчае тэкст (частковае супадзенне)

Каб падлічыць вочкі, якія ўтрымліваюць пэўны падрадок, выкарыстоўвайце функцыю COUNTIF са знакам падстаноўкі зорачкай (*).

Напрыклад, каб падлічыць Колькі ячэек у слупку A змяшчае «сукенку» як частку свайго змесціва, выкарыстоўвайце наступную формулу:

=COUNTIF(A2:A10,"*dress*")

Або ўвядзіце патрэбны тэкст у нейкую ячэйку і аб'яднайце яго t-ячэйка з сімваламі падстаноўкі:

=COUNTIF(A2:A10,"*"&D1&"*")

Для атрымання дадатковай інфармацыі, калі ласка, глядзіце: формулы COUNTIF з частковым супадзеннем.

Падлічыць, калі ячэйка змяшчае некалькі падрадкоў (логіка І)

Каб падлічыць вочкі з некалькімі ўмовамі, выкарыстоўвайце функцыю COUNTIFS. Excel COUNTIFS можа апрацоўваць да 127 пар дыяпазон/крытэрый, і толькі ячэйкі, якія адпавядаюць усім зададзеным умовам, будуцьпадлічаны.

Напрыклад, каб даведацца, колькі ячэек у слупку A змяшчае «сукенка» І «сіні», выкарыстоўвайце адну з наступных формул:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Або

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Палічыць, калі ячэйка змяшчае лік

Формула для падліку ячэек з лічбамі - гэта самая простая формула, якую можна сабе ўявіць:

Майце на ўвазе, што функцыя COUNT у Excel падлічвае ячэйкі, якія змяшчаюць любыя лікавыя значэнні, уключаючы лічбы, даты і час, таму што з пункту гледжання Excel дзве апошнія таксама з'яўляюцца лічбамі.

У нашым выпадку формула выглядае наступным чынам:

=COUNT(A2:A10)

Каб падлічыць ячэйкі, якія НЕ ўтрымліваюць лікаў, выкарыстоўвайце функцыю SUMPRODUCT разам з ISNUMBER і НЕ:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Сума, калі ячэйка ўтрымлівае тэкст

Калі вы шукаеце формулу Excel для пошуку ячэек, якія змяшчаюць пэўны тэкст, і сумавання адпаведных значэнняў у іншы слупок, выкарыстоўвайце функцыю SUMIF.

Напрыклад, каб даведацца, колькі сукенак ёсць у наяўнасці, выкарыстоўвайце наступную формулу:

=SUMIF(A2:A10,"*dress*",B2:B10)

Дзе A2:A10 - тэкст значэнні для праверкі, а B2:B10 - лікі для сумавання.

Або змясціце цікавы падрадок у якую-небудзь ячэйку (E1) і спасылайцеся на гэтую ячэйку ў вашай формуле, як паказана на скрыншоце ніжэй:

Каб сумаваць па некалькіх крытэрыях , выкарыстоўвайце функцыю SUMIFS.

Напрыклад, каб даведацца, колькі сініх сукенак даступна, перайдзіце з гэтай формулай:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Або выкарыстоўвайце гэтаадзін:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Дзе A2:A10 - ячэйкі для праверкі, а B2:B10 - ячэйкі для сумавання.

Выканайце розныя вылічэнні на аснове значэння ячэйкі

У нашым апошнім уроку мы абмяркоўвалі тры розныя формулы для праверкі некалькіх умоў і вяртання розных значэнняў у залежнасці ад вынікаў гэтых тэстаў. А цяпер давайце паглядзім, як можна выконваць розныя вылічэнні ў залежнасці ад значэння ў мэтавай ячэйцы.

Выкажам здагадку, што ў вас ёсць лічбы продажаў у слупку B і вы хочаце разлічыць бонусы на аснове гэтых лічбаў: калі продаж перавышае 300 долараў , бонус складае 10%; для продажаў ад $201 да $300 бонус складае 7%; для продажаў ад 101 да 200 долараў бонус складае 5%, а пры продажах менш за 100 долараў бонуса няма.

Каб гэта зрабіць, проста памножце аб'ём продажаў (B2) на адпаведны працэнт. Як даведацца, на які працэнт трэба памножыць? Выпрабоўваючы розныя ўмовы з дапамогай укладзеных IF:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

У рэальных працоўных аркушах можа быць зручней уводзіць працэнты ў асобныя ячэйкі і спасылацца на гэтыя ячэйкі ў формуле:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Ключавая рэч - гэта выправіць спасылкі на бонусныя ячэйкі са знакам $, каб прадухіліць іх змяненне пры капіраванні формулы ўніз па слупку.

Умоўнае фарматаванне Excel, калі ячэйка змяшчае пэўны тэкст

Калі вы хочаце вылучыць вочкі з пэўным тэкстам, усталюйце правіла ўмоўнага фарматавання Excel на аснове аднаго з наступныхформулы.

Улічваючы рэгістр:

Улічваючы рэгістр:

Напрыклад, каб вылучыць SKU, якія змяшчаюць словы "сукенка", стварыце правіла ўмоўнага фарматавання з прыведзенай ніжэй формулай і прымяніце яго да неабходнай колькасці ячэек у слупку A, пачынаючы з ячэйкі A2:

=SEARCH("dress", A2)>0

Формула ўмоўнага фарматавання Excel: калі ячэйка змяшчае тэкст (некалькі ўмоў)

Каб вылучыць ячэйкі, якія змяшчаюць два ці больш тэкставых радкоў, укладзіце некалькі функцый пошуку ў формулу І. Напрыклад, каб вылучыць ячэйкі "блакітная сукенка", стварыце правіла на аснове гэтай формулы:

=AND(SEARCH("dress", A2)>0, SEARCH("blue", A2)>0)

Падрабязныя крокі можна знайсці ў раздзеле "Як" стварыце правіла ўмоўнага фарматавання з дапамогай формулы.

Калі ячэйка змяшчае пэўны тэкст, выдаліце ​​ўвесь радок

Калі вы хочаце выдаліць радкі, якія змяшчаюць пэўны тэкст, выкарыстоўвайце функцыю пошуку і замены Excel такім чынам :

1. Выберыце ўсе ячэйкі, якія хочаце праверыць.
2. Націсніце Ctrl + F, каб адкрыць дыялогавае акно Знайсці і замяніць .
3. У у поле Знайсці што , увядзіце тэкст або нумар, які вы шукаеце, і націсніце Знайсці ўсё
4. Націсніце любы вынік пошуку, а потым націсніце Ctrl + A каб выбраць усё.
5. Націсніце кнопку Зачыніць , каб закрыць Знайсці і замяніць
6. Націсніце Ctrl і кнопку мінус адначасова ( Ctrl - ), які з'яўляецца Excelярлык для Выдаліць.
7. У дыялогавым акне Выдаліць абярыце Увесь радок і націсніце OK. Гатова!

На скрыншоце ніжэй мы выдаляем радкі, якія змяшчаюць «сукенку»:

Калі ячэйка змяшчае, выберыце або скапіруйце цэлыя радкі

У сітуацыях, калі вы хочаце выбраць або скапіяваць радкі з адпаведнымі дадзенымі, выкарыстоўвайце аўтафільтр Excel для фільтрацыі такіх радкоў. Пасля гэтага націсніце Ctrl + A, каб выбраць адфільтраваныя даныя, Ctrl+C, каб скапіяваць іх, і Ctrl+V, каб уставіць даныя ў іншае месца.

Каб адфільтраваць ячэйкі па двух ці больш крытэрыях, выкарыстоўвайце пашыраны фільтр каб знайсці такія ячэйкі, а потым скапіяваць усе радкі з вынікамі або вылучыць толькі пэўныя слупкі.

Вось як вы маніпулюеце ячэйкамі на аснове іх значэнняў у Excel. Я дзякую вам за чытанне і спадзяюся ўбачыць вас у нашым блогу на наступным тыдні!

Практычны сшытак

Excel If Cell Contains Then - прыклады (файл .xlsx)