In unserem vorangegangenen Tutorial haben wir uns mit Excel Wenn-Formeln befasst, die einen Wert in eine andere Spalte zurückgeben, wenn eine Zielzelle einen bestimmten Wert enthält. Was kann man sonst noch tun, wenn eine Zelle einen bestimmten Text oder eine Zahl enthält? Eine Vielzahl von Dingen wie das Zählen oder Summieren von Zellen, das Hervorheben, das Entfernen oder Kopieren ganzer Zeilen und vieles mehr.

Beispiele für Excel-Formeln 'Zählen, wenn Zelle enthält'.

In Microsoft Excel gibt es zwei Funktionen zum Zählen von Zellen auf der Grundlage ihrer Werte, COUNTIF und COUNTIFS. Diese Funktionen decken die meisten, wenn auch nicht alle Szenarien ab. In den folgenden Beispielen lernen Sie, wie Sie eine geeignete Formel zum Zählen von Zellen für Ihre spezielle Aufgabe auswählen.

Zählen, ob eine Zelle Text enthält

Wenn Sie Zellen zählen möchten, die beliebigen Text enthalten, verwenden Sie den Stern als Platzhalter in Ihrer COUNTIF-Formel:

Oder verwenden Sie die Funktion SUMPRODUCT in Kombination mit ISTEXT:

In der zweiten Formel wertet die Funktion ISTEXT jede Zelle im angegebenen Bereich aus und gibt eine Reihe von TRUE- (Text) und FALSE- (kein Text) Werten zurück; der doppelte unäre Operator (--) verwandelt TRUE und FALSE in 1en und 0en; und SUMPRODUCT addiert die Zahlen.

Wie in der folgenden Abbildung zu sehen ist, führen beide Formeln zum gleichen Ergebnis:

=COUNTIF(A2:A10, "*")

=SUMPRODUCT(--(ISTEXT(A2:A10)))

Sie können sich auch ansehen, wie man in Excel nicht leere Zellen zählt.

Zählen, ob die Zelle einen bestimmten Text enthält

Um Zellen zu zählen, die einen bestimmten Text enthalten, verwenden Sie eine einfache COUNTIF-Formel wie unten gezeigt, wobei Bereich ist die zu prüfende Zelle und Text ist die zu suchende Textzeichenfolge oder ein Verweis auf die Zelle, die die Textzeichenfolge enthält.

Um zum Beispiel die Zellen im Bereich A2:A10 zu zählen, die das Wort "Kleid" enthalten, verwenden Sie diese Formel:

=COUNTIF(A2:A10, "Kleid")

Oder die im Screenshot gezeigte:

Weitere Beispiele für Formeln finden Sie hier: So zählen Sie Zellen mit Text in Excel: beliebige, bestimmte, gefilterte Zellen.

Zählen, ob die Zelle Text enthält (teilweise Übereinstimmung)

Um Zellen zu zählen, die eine bestimmte Teilzeichenkette enthalten, verwenden Sie die Funktion COUNTIF mit dem Platzhalterzeichen (*).

Um zum Beispiel zu zählen, wie viele Zellen in Spalte A "Kleid" als Teil ihres Inhalts enthalten, verwenden Sie diese Formel:

=COUNTIF(A2:A10,"*dress*")

Oder Sie geben den gewünschten Text in eine Zelle ein und verketten diese Zelle mit den Platzhalterzeichen:

=COUNTIF(A2:A10,"*"&D1&"*")

Für weitere Informationen siehe: COUNTIF-Formeln mit teilweiser Übereinstimmung.

Zählen, ob die Zelle mehrere Teilstrings enthält (UND-Logik)

Um Zellen mit mehreren Bedingungen zu zählen, verwenden Sie die Funktion COUNTIFS. Excel COUNTIFS kann bis zu 127 Bereich/Kriterien-Paare verarbeiten, und es werden nur Zellen gezählt, die alle angegebenen Bedingungen erfüllen.

Um zum Beispiel herauszufinden, wie viele Zellen in Spalte A "Kleid" UND "blau" enthalten, verwenden Sie eine der folgenden Formeln:

=COUNTIFS(A2:A10,"*dress*", A2:A10,"*blue*")

Oder

=COUNTIFS(A2:A10,"*"&D1&"*", A2:A10,"*"&D2&"*")

Zählen, wenn die Zelle eine Zahl enthält

Die Formel zum Zählen von Zellen mit Zahlen ist die einfachste Formel, die man sich vorstellen kann:

Bitte beachten Sie, dass die Funktion COUNT in Excel Zellen zählt, die einen beliebigen numerischen Wert enthalten, einschließlich Zahlen, Datums- und Zeitangaben, da die beiden letztgenannten in Excel ebenfalls Zahlen sind.

In unserem Fall lautet die Formel wie folgt:

=COUNT(A2:A10)

Um Zellen zu zählen, die KEINE Zahlen enthalten, verwenden Sie die Funktion SUMPRODUCT zusammen mit ISNUMBER und NOT:

=SUMPRODUCT(--NOT(ISNUMBER(A2:A10)))

Summe, wenn Zelle Text enthält

Wenn Sie eine Excel-Formel suchen, um Zellen zu finden, die bestimmten Text enthalten, und die entsprechenden Werte in einer anderen Spalte zu summieren, verwenden Sie die Funktion SUMIF.

Um zum Beispiel herauszufinden, wie viele Kleider auf Lager sind, verwenden Sie diese Formel:

=SUMIF(A2:A10,"*dress*",B2:B10)

Dabei sind A2:A10 die zu prüfenden Textwerte und B2:B10 die zu summierenden Zahlen.

Oder legen Sie die gewünschte Teilzeichenkette in eine Zelle (E1) und referenzieren Sie diese Zelle in Ihrer Formel, wie in der folgenden Abbildung gezeigt:

An Summe mit mehreren Kriterien verwenden Sie die Funktion SUMIFS.

Um zum Beispiel herauszufinden, wie viele blaue Kleider verfügbar sind, gehen Sie nach dieser Formel vor:

=SUMIFS(B2:B10, A2:A10,"*dress*",A2:A10,"*blue*")

Oder verwenden Sie diese:

=SUMIFS(B2:B10, A2:A10,"*"&E1&"*",A2:A10,"*"&E2&"*")

Dabei sind A2:A10 die zu prüfenden Zellen und B2:B10 die zu summierenden Zellen.

Verschiedene Berechnungen auf der Grundlage von Zellwerten durchführen

In unserem letzten Tutorial haben wir drei verschiedene Formeln besprochen, mit denen Sie mehrere Bedingungen testen und je nach Ergebnis unterschiedliche Werte zurückgeben können. Jetzt wollen wir sehen, wie Sie je nach Wert in einer Zielzelle unterschiedliche Berechnungen durchführen können.

Angenommen, Sie haben Umsatzzahlen in Spalte B und möchten auf der Grundlage dieser Zahlen Boni berechnen: Bei einem Umsatz von über 300 $ beträgt der Bonus 10 %; bei einem Umsatz zwischen 201 und 300 $ beträgt der Bonus 7 %; bei einem Umsatz zwischen 101 und 200 $ beträgt der Bonus 5 % und bei einem Umsatz von unter 100 $ gibt es keinen Bonus.

Dazu multiplizieren Sie einfach den Umsatz (B2) mit einem entsprechenden Prozentsatz. Woher wissen Sie, mit welchem Prozentsatz Sie multiplizieren müssen? Indem Sie verschiedene Bedingungen mit verschachtelten IFs testen:

=B2*IF(B2>=300,10%, IF(B2>=200,7%, IF(B2>=100,5%,0)))

In realen Arbeitsblättern kann es bequemer sein, Prozentsätze in separate Zellen einzugeben und in der Formel auf diese Zellen zu verweisen:

=B2*IF(B2>=300,$F$5,IF(B2>=200,$F$4,IF(B2>=100,$F$3,$F$2)))

Das Wichtigste ist, die Referenzen der Bonuszellen mit dem $-Zeichen zu fixieren, damit sie sich nicht ändern, wenn Sie die Formel in die Spalte kopieren.

Excel bedingte Formatierung, wenn eine Zelle bestimmten Text enthält

Wenn Sie möchten, dass Highlight Zellen mit bestimmtem Text zu formatieren, richten Sie eine bedingte Excel-Formatierungsregel ein, die auf einer der folgenden Formeln basiert.

Groß- und Kleinschreibung wird nicht berücksichtigt:

Groß- und Kleinschreibung wird beachtet:

Um zum Beispiel SKUs hervorzuheben, die das Wort "Kleid" enthalten, erstellen Sie eine bedingte Formatierungsregel mit der unten stehenden Formel und wenden Sie diese auf so viele Zellen in Spalte A an, wie Sie benötigen, beginnend mit Zelle A2:

=SEARCH("Kleid", A2)>0

Excel-Formel für bedingte Formatierung: wenn Zelle Text enthält (mehrere Bedingungen)

Um Zellen hervorzuheben, die zwei oder mehr Textzeichenfolgen enthalten, verschachteln Sie mehrere Suchfunktionen in einer UND-Formel. Um beispielsweise Zellen mit "blauem Kleid" hervorzuheben, erstellen Sie eine Regel, die auf dieser Formel basiert:

=AND(SUCHEN("Kleid", A2)>0, SUCHEN("Blau", A2)>0)

Ausführliche Informationen finden Sie unter Wie man eine bedingte Formatierungsregel mit einer Formel erstellt.

Wenn die Zelle einen bestimmten Text enthält, die gesamte Zeile entfernen

Wenn Sie Zeilen löschen möchten, die einen bestimmten Text enthalten, verwenden Sie auf diese Weise die Funktion Suchen und Ersetzen in Excel:

1. Markieren Sie alle Zellen, die Sie prüfen möchten.
2. Drücken Sie Strg + F, um die Suchen und Ersetzen Dialogfeld.
3. In der Was finden ein, geben Sie den gesuchten Text oder die Zahl ein und klicken Sie auf die Schaltfläche Alle finden
4. Klicken Sie auf ein beliebiges Suchergebnis und drücken Sie dann Strg + A, um alles auszuwählen.
5. Klicken Sie auf die Schließen Sie zum Schließen des Suchen und Ersetzen
6. Drücken Sie gleichzeitig die Strg-Taste und die Minus-Taste ( Strg - ), das ist das Excel-Kürzel für Löschen.
7. In der Löschen wählen Sie im Dialogfenster Gesamte Zeile und klicken Sie auf OK. Fertig!

In der folgenden Abbildung werden Zeilen gelöscht, die "Kleid" enthalten:

Wenn Zelle enthält, ganze Zeilen markieren oder kopieren

Wenn Sie Zeilen mit relevanten Daten markieren oder kopieren möchten, verwenden Sie den AutoFilter von Excel, um solche Zeilen zu filtern. Drücken Sie anschließend Strg+A, um die gefilterten Daten zu markieren, Strg+C, um sie zu kopieren, und Strg+V, um die Daten an einer anderen Stelle einzufügen.

Um Zellen mit zwei oder mehr Kriterien zu filtern, verwenden Sie den erweiterten Filter, um solche Zellen zu finden, und kopieren Sie dann die gesamten Zeilen mit den Ergebnissen oder extrahieren Sie nur bestimmte Spalten.

So manipulieren Sie Zellen auf der Grundlage ihres Wertes in Excel. Ich danke Ihnen für die Lektüre und hoffe, Sie nächste Woche in unserem Blog begrüßen zu dürfen!

Arbeitsbuch für die Praxis

Excel If Cell Contains Then - Beispiele (.xlsx-Datei)